ui/touch_selection/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/ui.gni")
   6 import("//testing/test.gni")
   7
   8 if (is_android) {
   9   import("//build/config/android/rules.gni")
  10 }
  11
  12 component("touch_selection") {
  13   output_name = "ui_touch_selection"
  14
  15   sources = [
  16     "longpress_drag_selector.cc",
  17     "longpress_drag_selector.h",
  18     "selection_event_type.h",
  19     "touch_handle.cc",
  20     "touch_handle.h",
  21     "touch_handle_orientation.h",
  22     "touch_selection_controller.cc",
  23     "touch_selection_controller.h",
  24     "touch_selection_draggable.h",
  25     "ui_touch_selection_export.h",
  26   ]
  27
  28   defines = [ "UI_TOUCH_SELECTION_IMPLEMENTATION" ]
  29
  30   deps = [
  31     "//base:base",
  32     "//ui/base:base",
  33     "//ui/events:events",
  34     "//ui/events:gesture_detection",
  35     "//ui/gfx/geometry:geometry",
  36   ]
  37
  38   if (use_aura) {
  39     deps += [
  40       "//skia:skia",
  41       "//ui/aura:aura",
  42       "//ui/aura_extra:aura_extra",
  43       "//ui/compositor:compositor",
  44       "//ui/gfx:gfx",
  45     ]
  46
  47     sources += [
  48       "touch_handle_drawable_aura.cc",
  49       "touch_handle_drawable_aura.h",
  50       "touch_selection_menu_runner.cc",
  51       "touch_selection_menu_runner.h",
  52     ]
  53   }
  54 }
  55
  56 test("ui_touch_selection_unittests") {
  57   sources = [
  58     "longpress_drag_selector_unittest.cc",
  59     "touch_handle_unittest.cc",
  60     "touch_selection_controller_unittest.cc",
  61   ]
  62
  63   deps = [
  64     ":touch_selection",
  65     "//base/test:run_all_unittests",
  66     "//testing/gmock:gmock",
  67     "//testing/gtest:gtest",
  68     "//ui/base:base",
  69     "//ui/events:test_support",
  70     "//ui/gfx:gfx",
  71     "//ui/gfx:test_support",
  72   ]
  73 }
  74
  75 if (is_android) {
  76   java_cpp_enum("ui_touch_selection_enums_srcjar") {
  77     sources = [
  78       "selection_event_type.h",
  79     ]
  80     outputs = [
  81       "org/chromium/ui/touch_selection/SelectionEventType.java",
  82     ]
  83   }
  84   java_cpp_enum("ui_touch_handle_orientation_srcjar") {
  85     sources = [
  86       "touch_handle_orientation.h",
  87     ]
  88     outputs = [
  89       "org/chromium/ui/touch_selection/TouchHandleOrientation.java",
  90     ]
  91   }
  92 }