gin/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/module_args/v8.gni")
   6 import("//testing/test.gni")
   7
   8 component("gin") {
   9   sources = [
  10     "arguments.cc",
  11     "arguments.h",
  12     "array_buffer.cc",
  13     "array_buffer.h",
  14     "context_holder.cc",
  15     "converter.cc",
  16     "converter.h",
  17     "debug_impl.cc",
  18     "debug_impl.h",
  19     "dictionary.cc",
  20     "dictionary.h",
  21     "function_template.cc",
  22     "function_template.h",
  23     "gin_export.h",
  24     "handle.h",
  25     "interceptor.cc",
  26     "interceptor.h",
  27     "isolate_holder.cc",
  28     "modules/console.cc",
  29     "modules/console.h",
  30     "modules/file_module_provider.cc",
  31     "modules/file_module_provider.h",
  32     "modules/module_registry.cc",
  33     "modules/module_registry.h",
  34     "modules/module_registry_observer.h",
  35     "modules/module_runner_delegate.cc",
  36     "modules/module_runner_delegate.h",
  37     "modules/timer.cc",
  38     "modules/timer.h",
  39     "object_template_builder.cc",
  40     "object_template_builder.h",
  41     "per_context_data.cc",
  42     "per_context_data.h",
  43     "per_isolate_data.cc",
  44     "per_isolate_data.h",
  45     "public/context_holder.h",
  46     "public/debug.h",
  47     "public/gin_embedders.h",
  48     "public/isolate_holder.h",
  49     "public/v8_platform.h",
  50     "public/wrapper_info.h",
  51     "run_microtasks_observer.cc",
  52     "run_microtasks_observer.h",
  53     "runner.cc",
  54     "runner.h",
  55     "shell_runner.cc",
  56     "shell_runner.h",
  57     "try_catch.cc",
  58     "try_catch.h",
  59     "v8_initializer.cc",
  60     "v8_initializer.h",
  61     "v8_isolate_memory_dump_provider.cc",
  62     "v8_isolate_memory_dump_provider.h",
  63     "v8_platform.cc",
  64     "wrappable.cc",
  65     "wrappable.h",
  66     "wrapper_info.cc",
  67   ]
  68
  69   defines = [ "GIN_IMPLEMENTATION" ]
  70
  71   public_deps = [
  72     "//base",
  73     "//v8",
  74   ]
  75   deps = [
  76     "//base/third_party/dynamic_annotations",
  77   ]
  78   if (v8_use_external_startup_data && is_win) {
  79     deps += [
  80       ":gin_v8_snapshot_fingerprint",
  81       "//crypto:crypto",
  82     ]
  83     sources += [ "$target_gen_dir/v8_snapshot_fingerprint.cc" ]
  84     defines += [ "V8_VERIFY_EXTERNAL_STARTUP_DATA" ]
  85   }
  86 }
  87
  88 if (v8_use_external_startup_data) {
  89   action("gin_v8_snapshot_fingerprint") {
  90     script = "//gin/fingerprint/fingerprint_v8_snapshot.py"
  91
  92     snapshot_file = "$root_build_dir/snapshot_blob.bin"
  93     natives_file = "$root_build_dir/natives_blob.bin"
  94     output_file = "$target_gen_dir/v8_snapshot_fingerprint.cc"
  95
  96     args = [
  97       "--snapshot_file",
  98       rebase_path(snapshot_file, root_build_dir),
  99       "--natives_file",
 100       rebase_path(natives_file, root_build_dir),
 101       "--output_file",
 102       rebase_path(output_file, root_build_dir),
 103     ]
 104     inputs = [
 105       snapshot_file,
 106       natives_file,
 107     ]
 108     outputs = [
 109       output_file,
 110     ]
 111   }
 112 }
 113
 114 executable("gin_shell") {
 115   sources = [
 116     "shell/gin_main.cc",
 117   ]
 118
 119   deps = [
 120     ":gin",
 121     "//base",
 122     "//base:i18n",
 123     "//v8",
 124   ]
 125 }
 126
 127 source_set("gin_test") {
 128   testonly = true
 129   sources = [
 130     "test/file.cc",
 131     "test/file.h",
 132     "test/file_runner.cc",
 133     "test/file_runner.h",
 134     "test/gc.cc",
 135     "test/gc.h",
 136     "test/gtest.cc",
 137     "test/gtest.h",
 138     "test/v8_test.cc",
 139     "test/v8_test.h",
 140   ]
 141
 142   public_deps = [
 143     ":gin",
 144     "//testing/gtest",
 145   ]
 146   deps = [
 147     "//v8",
 148   ]
 149 }
 150
 151 test("gin_unittests") {
 152   sources = [
 153     "converter_unittest.cc",
 154     "interceptor_unittest.cc",
 155     "modules/module_registry_unittest.cc",
 156     "modules/timer_unittest.cc",
 157     "per_context_data_unittest.cc",
 158     "shell/gin_shell_unittest.cc",
 159     "shell_runner_unittest.cc",
 160     "test/run_all_unittests.cc",
 161     "test/run_js_tests.cc",
 162     "wrappable_unittest.cc",
 163   ]
 164
 165   deps = [
 166     ":gin_test",
 167     "//base/test:test_support",
 168     "//v8",
 169   ]
 170 }