chrome/version.gni

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/chrome_build.gni")
   6
   7 # Runs the version processing script over the given template file to produce
   8 # an output file. This is used for generating various forms of files that
   9 # incorporate the product name and version.
  10 #
  11 # Unlike GYP, this will actually compile the resulting file, so you don't need
  12 # to add it separately to the sources, just depend on the target.
  13 #
  14 # This template automatically includes VERSION, LASTCHANGE, and BRANDING. It
  15 # automatically uses the template file .
  16 # GYP parameterizes this template file but all current invocations use this
  17 # same one. If in the future we need to set it, this should be added as an
  18 # optional argument.
  19 #
  20 # In GYP this is a rule that runs once per ".ver" file. In GN this just
  21 # processes one file per invocation of the template so you may have to have
  22 # multiple targets.
  23 #
  24 # You must specify either sources or a template_file, or both.
  25 #
  26 # Parameters:
  27 #   sources (optional):
  28 #     List of file names to read. When converting a GYP target, this should
  29 #     list the 'source' (see above) as well as any extra_variable_files.
  30 #
  31 #   output:
  32 #     File name of file to write. In GYP this is unspecified and it will
  33 #     make up a file name for you based on the input name, and tack on
  34 #     "_version.rc" to the end. But in GN you need to specify the full name.
  35 #
  36 #   template_file (optional):
  37 #     Template file to use (not a list). Defaults to
  38 #     //chrome/app/chrome_version.rc.version if unspecified.
  39 #
  40 #   extra_args (optional):
  41 #     Extra arguments to pass to version.py. Any "-f <filename>" args should
  42 #     use sources instead.
  43 #
  44 #   visibility (optional)
  45 #
  46 # Example:
  47 #   process_version("myversion") {
  48 #     sources = [ "myfile.h.in" ]
  49 #     output = "$target_gen_dir/myfile.h"
  50 #     extra_args = ["-e", "FOO=42"]
  51 #     extra_files = [ "foo/BRANDING" ]
  52 #   }
  53 template("process_version") {
  54   assert(defined(invoker.sources) || defined(invoker.template_file),
  55          "Either sources or template_file must be defined for $target_name")
  56   assert(defined(invoker.output), "Output must be defined for $target_name")
  57
  58   action_name = target_name + "_action"
  59   source_set_name = target_name
  60
  61   action(action_name) {
  62     visibility = [ ":$source_set_name" ]
  63     script = "//build/util/version.py"
  64
  65     lastchange_path = "//build/util/LASTCHANGE"
  66     version_path = "//chrome/VERSION"
  67     if (is_chrome_branded) {
  68       branding_path = "//chrome/app/theme/google_chrome/BRANDING"
  69     } else {
  70       branding_path = "//chrome/app/theme/chromium/BRANDING"
  71     }
  72     if (defined(invoker.template_file)) {
  73       template_path = invoker.template_file
  74     } else {
  75       template_path = "//chrome/app/chrome_version.rc.version"
  76     }
  77
  78     inputs = [
  79       version_path,
  80       lastchange_path,
  81       branding_path,
  82       template_path,
  83     ]
  84
  85     outputs = [
  86       invoker.output,
  87     ]
  88
  89     args = []
  90
  91     if (defined(invoker.sources)) {
  92       inputs += invoker.sources
  93       foreach(i, invoker.sources) {
  94         args += [
  95           "-f",
  96           rebase_path(i, root_build_dir),
  97         ]
  98       }
  99     }
 100
 101     args += [
 102       "-f",
 103       rebase_path(version_path, root_build_dir),
 104       "-f",
 105       rebase_path(branding_path, root_build_dir),
 106       "-f",
 107       rebase_path(lastchange_path, root_build_dir),
 108     ]
 109     if (defined(invoker.extra_args)) {
 110       args += invoker.extra_args
 111     }
 112     args += [
 113       rebase_path(template_path, root_build_dir),
 114       rebase_path(invoker.output, root_build_dir),
 115     ]
 116   }
 117
 118   source_set(source_set_name) {
 119     if (defined(invoker.visibility)) {
 120       visibility = invoker.visibility
 121     }
 122     sources = get_target_outputs(":$action_name")
 123     deps = [
 124       ":$action_name",
 125     ]
 126   }
 127 }