media/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/android/config.gni")
   6 import("//build/config/arm.gni")
   7 import("//build/config/features.gni")
   8 import("//build/config/linux/pkg_config.gni")
   9 import("//build/config/ui.gni")
  10 import("//media/media_options.gni")
  11 import("//testing/test.gni")
  12
  13 # Common configuration for targets in the media directory.
  14 # NOT for exporting.
  15 config("media_config") {
  16   defines = []
  17   if (!media_use_libvpx) {
  18     defines += [ "MEDIA_DISABLE_LIBVPX" ]
  19   }
  20   if (!media_use_ffmpeg) {
  21     defines += [ "MEDIA_DISABLE_FFMPEG" ]
  22   }
  23   if (current_cpu == "arm" && arm_use_neon) {
  24     defines += [ "USE_NEON" ]
  25   }
  26   if (use_pulseaudio) {
  27     defines += [ "USE_PULSEAUDIO" ]
  28     if (!link_pulseaudio) {
  29       defines += [ "DLOPEN_PULSEAUDIO" ]
  30     }
  31   }
  32   if (use_cras) {
  33     defines += [ "USE_CRAS" ]
  34   }
  35 }
  36
  37 config("media_implementation") {
  38   defines = [ "MEDIA_IMPLEMENTATION" ]
  39 }
  40
  41 config("media_dependent_config") {
  42   defines = []
  43   if (!media_use_libvpx) {
  44     defines += [ "MEDIA_DISABLE_LIBVPX" ]
  45   }
  46   if (!media_use_ffmpeg) {
  47     defines += [ "MEDIA_DISABLE_FFMPEG" ]
  48   }
  49   if (is_win) {
  50     ldflags = [
  51       "/DELAYLOAD:mf.dll",
  52       "/DELAYLOAD:mfplat.dll",
  53       "/DELAYLOAD:mfreadwrite.dll",
  54     ]
  55   }
  56 }
  57
  58 if (use_ozone) {
  59   action("generate_ozone_constructor_list") {
  60     # Ozone platform objects are auto-generated using similar
  61     # patterns for naming and classes constructors. Here we build the
  62     # object MediaOzonePlatform.
  63     script = "../ui/ozone/generate_constructor_list.py"
  64
  65     platform_list_txt_file = "$target_gen_dir/../ui/ozone/platform_list.txt"
  66     constructor_list_cc_file = "$target_gen_dir/ozone/constructor_list.cc"
  67
  68     sources = [
  69       platform_list_txt_file,
  70     ]
  71     outputs = [
  72       constructor_list_cc_file,
  73     ]
  74     args = [
  75       "--platform_list=" + rebase_path(platform_list_txt_file, root_build_dir),
  76       "--output_cc=" + rebase_path(constructor_list_cc_file, root_build_dir),
  77       "--namespace=media",
  78       "--typename=MediaOzonePlatform",
  79       "--include=\"media/ozone/media_ozone_platform.h\"",
  80     ]
  81     deps = [
  82       "//ui/ozone:generate_ozone_platform_list",
  83     ]
  84   }
  85 }
  86
  87 component("media") {
  88   sources = [
  89     "blink/skcanvas_video_renderer.cc",
  90     "blink/skcanvas_video_renderer.h",
  91     "capture/animated_content_sampler.cc",
  92     "capture/animated_content_sampler.h",
  93     "capture/capture_resolution_chooser.cc",
  94     "capture/capture_resolution_chooser.h",
  95     "capture/feedback_signal_accumulator.cc",
  96     "capture/feedback_signal_accumulator.h",
  97     "capture/screen_capture_device_core.cc",
  98     "capture/screen_capture_device_core.h",
  99     "capture/smooth_event_sampler.cc",
 100     "capture/smooth_event_sampler.h",
 101     "capture/thread_safe_capture_oracle.cc",
 102     "capture/thread_safe_capture_oracle.h",
 103     "capture/video_capture_oracle.cc",
 104     "capture/video_capture_oracle.h",
 105     "cdm/aes_decryptor.cc",
 106     "cdm/aes_decryptor.h",
 107     "cdm/default_cdm_factory.cc",
 108     "cdm/default_cdm_factory.h",
 109     "cdm/json_web_key.cc",
 110     "cdm/json_web_key.h",
 111     "cdm/key_system_names.cc",
 112     "cdm/key_system_names.h",
 113     "cdm/player_tracker_impl.cc",
 114     "cdm/player_tracker_impl.h",
 115     "cdm/proxy_decryptor.cc",
 116     "cdm/proxy_decyrptor.h",
 117     "ffmpeg/ffmpeg_deleters.h",
 118     "filters/audio_clock.cc",
 119     "filters/audio_clock.h",
 120     "filters/audio_renderer_algorithm.cc",
 121     "filters/audio_renderer_algorithm.h",
 122     "filters/chunk_demuxer.cc",
 123     "filters/chunk_demuxer.h",
 124     "filters/context_3d.h",
 125     "filters/decoder_selector.cc",
 126     "filters/decoder_selector.h",
 127     "filters/decoder_stream.cc",
 128     "filters/decoder_stream.h",
 129     "filters/decoder_stream_traits.cc",
 130     "filters/decoder_stream_traits.h",
 131     "filters/decrypting_audio_decoder.cc",
 132     "filters/decrypting_audio_decoder.h",
 133     "filters/decrypting_demuxer_stream.cc",
 134     "filters/decrypting_demuxer_stream.h",
 135     "filters/decrypting_video_decoder.cc",
 136     "filters/decrypting_video_decoder.h",
 137     "filters/default_media_permission.cc",
 138     "filters/default_media_permission.h",
 139     "filters/file_data_source.cc",
 140     "filters/file_data_source.h",
 141     "filters/frame_processor.cc",
 142     "filters/frame_processor.h",
 143     "filters/gpu_video_decoder.cc",
 144     "filters/gpu_video_decoder.h",
 145     "filters/h264_bit_reader.cc",
 146     "filters/h264_bit_reader.h",
 147     "filters/h264_parser.cc",
 148     "filters/h264_parser.h",
 149     "filters/jpeg_parser.cc",
 150     "filters/jpeg_parser.h",
 151     "filters/source_buffer_platform.cc",
 152     "filters/source_buffer_platform.h",
 153     "filters/source_buffer_range.cc",
 154     "filters/source_buffer_range.h",
 155     "filters/source_buffer_stream.cc",
 156     "filters/source_buffer_stream.h",
 157     "filters/stream_parser_factory.cc",
 158     "filters/stream_parser_factory.h",
 159     "filters/video_cadence_estimator.cc",
 160     "filters/video_cadence_estimator.h",
 161     "filters/video_renderer_algorithm.cc",
 162     "filters/video_renderer_algorithm.h",
 163     "filters/vp8_bool_decoder.cc",
 164     "filters/vp8_bool_decoder.h",
 165     "filters/vp8_parser.cc",
 166     "filters/vp8_parser.h",
 167     "filters/webvtt_util.h",
 168     "filters/wsola_internals.cc",
 169     "filters/wsola_internals.h",
 170     "formats/common/offset_byte_queue.cc",
 171     "formats/common/offset_byte_queue.h",
 172     "formats/webm/webm_audio_client.cc",
 173     "formats/webm/webm_audio_client.h",
 174     "formats/webm/webm_cluster_parser.cc",
 175     "formats/webm/webm_cluster_parser.h",
 176     "formats/webm/webm_constants.cc",
 177     "formats/webm/webm_constants.h",
 178     "formats/webm/webm_content_encodings.cc",
 179     "formats/webm/webm_content_encodings.h",
 180     "formats/webm/webm_content_encodings_client.cc",
 181     "formats/webm/webm_content_encodings_client.h",
 182     "formats/webm/webm_crypto_helpers.cc",
 183     "formats/webm/webm_crypto_helpers.h",
 184     "formats/webm/webm_info_parser.cc",
 185     "formats/webm/webm_info_parser.h",
 186     "formats/webm/webm_parser.cc",
 187     "formats/webm/webm_parser.h",
 188     "formats/webm/webm_stream_parser.cc",
 189     "formats/webm/webm_stream_parser.h",
 190     "formats/webm/webm_tracks_parser.cc",
 191     "formats/webm/webm_tracks_parser.h",
 192     "formats/webm/webm_video_client.cc",
 193     "formats/webm/webm_video_client.h",
 194     "formats/webm/webm_webvtt_parser.cc",
 195     "formats/webm/webm_webvtt_parser.h",
 196     "renderers/audio_renderer_impl.cc",
 197     "renderers/audio_renderer_impl.h",
 198     "renderers/default_renderer_factory.cc",
 199     "renderers/default_renderer_factory.h",
 200     "renderers/gpu_video_accelerator_factories.h",
 201     "renderers/renderer_impl.cc",
 202     "renderers/renderer_impl.h",
 203     "renderers/video_renderer_impl.cc",
 204     "renderers/video_renderer_impl.h",
 205     "video/capture/fake_video_capture_device.cc",
 206     "video/capture/fake_video_capture_device.h",
 207     "video/capture/fake_video_capture_device_factory.cc",
 208     "video/capture/fake_video_capture_device_factory.h",
 209     "video/capture/file_video_capture_device.cc",
 210     "video/capture/file_video_capture_device.h",
 211     "video/capture/file_video_capture_device_factory.cc",
 212     "video/capture/file_video_capture_device_factory.h",
 213     "video/capture/linux/v4l2_capture_delegate.cc",
 214     "video/capture/linux/v4l2_capture_delegate.h",
 215     "video/capture/linux/v4l2_capture_delegate_multi_plane.cc",
 216     "video/capture/linux/v4l2_capture_delegate_multi_plane.h",
 217     "video/capture/linux/v4l2_capture_delegate_single_plane.cc",
 218     "video/capture/linux/v4l2_capture_delegate_single_plane.h",
 219     "video/capture/linux/video_capture_device_chromeos.cc",
 220     "video/capture/linux/video_capture_device_chromeos.h",
 221     "video/capture/linux/video_capture_device_factory_linux.cc",
 222     "video/capture/linux/video_capture_device_factory_linux.h",
 223     "video/capture/linux/video_capture_device_linux.cc",
 224     "video/capture/linux/video_capture_device_linux.h",
 225     "video/capture/mac/platform_video_capturing_mac.h",
 226     "video/capture/mac/video_capture_device_avfoundation_mac.h",
 227     "video/capture/mac/video_capture_device_avfoundation_mac.mm",
 228     "video/capture/mac/video_capture_device_decklink_mac.h",
 229     "video/capture/mac/video_capture_device_decklink_mac.mm",
 230     "video/capture/mac/video_capture_device_factory_mac.h",
 231     "video/capture/mac/video_capture_device_factory_mac.mm",
 232     "video/capture/mac/video_capture_device_mac.h",
 233     "video/capture/mac/video_capture_device_mac.mm",
 234     "video/capture/mac/video_capture_device_qtkit_mac.h",
 235     "video/capture/mac/video_capture_device_qtkit_mac.mm",
 236     "video/capture/video_capture_device.cc",
 237     "video/capture/video_capture_device.h",
 238     "video/capture/video_capture_device_factory.cc",
 239     "video/capture/video_capture_device_factory.h",
 240     "video/capture/video_capture_device_info.cc",
 241     "video/capture/video_capture_device_info.h",
 242     "video/capture/win/capability_list_win.cc",
 243     "video/capture/win/capability_list_win.h",
 244     "video/capture/win/filter_base_win.cc",
 245     "video/capture/win/filter_base_win.h",
 246     "video/capture/win/pin_base_win.cc",
 247     "video/capture/win/pin_base_win.h",
 248     "video/capture/win/sink_filter_observer_win.h",
 249     "video/capture/win/sink_filter_win.cc",
 250     "video/capture/win/sink_filter_win.h",
 251     "video/capture/win/sink_input_pin_win.cc",
 252     "video/capture/win/sink_input_pin_win.h",
 253     "video/capture/win/video_capture_device_factory_win.cc",
 254     "video/capture/win/video_capture_device_factory_win.h",
 255     "video/capture/win/video_capture_device_mf_win.cc",
 256     "video/capture/win/video_capture_device_mf_win.h",
 257     "video/capture/win/video_capture_device_win.cc",
 258     "video/capture/win/video_capture_device_win.h",
 259     "video/fake_video_encode_accelerator.cc",
 260     "video/fake_video_encode_accelerator.h",
 261     "video/gpu_memory_buffer_video_frame_pool.cc",
 262     "video/gpu_memory_buffer_video_frame_pool.h",
 263     "video/h264_poc.cc",
 264     "video/h264_poc.h",
 265     "video/jpeg_decode_accelerator.cc",
 266     "video/jpeg_decode_accelerator.h",
 267     "video/picture.cc",
 268     "video/picture.h",
 269     "video/video_decode_accelerator.cc",
 270     "video/video_decode_accelerator.h",
 271     "video/video_encode_accelerator.cc",
 272     "video/video_encode_accelerator.h",
 273   ]
 274
 275   configs += [
 276     ":media_config",
 277     ":media_implementation",
 278
 279     # TODO(wolenetz): Fix size_t to int trunctaion in win64.
 280     # See http://crbug.com/171009
 281     "//build/config/compiler:no_size_t_to_int_warning",
 282   ]
 283   all_dependent_configs = [ ":media_dependent_config" ]
 284
 285   allow_circular_includes_from = []
 286   cflags = []
 287   libs = []
 288   defines = []
 289   deps = []
 290
 291   include_dirs = [ "." ]
 292   if (media_use_ffmpeg) {
 293     deps += [ "//third_party/ffmpeg" ]
 294     sources += [
 295       "ffmpeg/ffmpeg_common.cc",
 296       "ffmpeg/ffmpeg_common.h",
 297       "filters/audio_file_reader.cc",
 298       "filters/audio_file_reader.h",
 299       "filters/blocking_url_protocol.cc",
 300       "filters/blocking_url_protocol.h",
 301       "filters/ffmpeg_audio_decoder.cc",
 302       "filters/ffmpeg_audio_decoder.h",
 303       "filters/ffmpeg_bitstream_converter.h",
 304       "filters/ffmpeg_demuxer.cc",
 305       "filters/ffmpeg_demuxer.h",
 306       "filters/ffmpeg_glue.cc",
 307       "filters/ffmpeg_glue.h",
 308       "filters/ffmpeg_video_decoder.cc",
 309       "filters/ffmpeg_video_decoder.h",
 310       "filters/in_memory_url_protocol.cc",
 311       "filters/in_memory_url_protocol.h",
 312     ]
 313     if (proprietary_codecs) {
 314       sources += [
 315         "filters/ffmpeg_aac_bitstream_converter.cc",
 316         "filters/ffmpeg_aac_bitstream_converter.h",
 317         "filters/ffmpeg_h264_to_annex_b_bitstream_converter.cc",
 318         "filters/ffmpeg_h264_to_annex_b_bitstream_converter.h",
 319       ]
 320     }
 321   }
 322
 323   if (current_cpu == "arm" && arm_use_neon) {
 324     defines += [ "USE_NEON" ]
 325   }
 326
 327   if (media_use_libvpx) {
 328     sources += [
 329       "filters/vpx_video_decoder.cc",
 330       "filters/vpx_video_decoder.h",
 331     ]
 332     deps += [ "//third_party/libvpx" ]
 333   }
 334
 335   if (is_android) {
 336     sources += [
 337       "video/capture/android/video_capture_device_android.cc",
 338       "video/capture/android/video_capture_device_android.h",
 339       "video/capture/android/video_capture_device_factory_android.cc",
 340       "video/capture/android/video_capture_device_factory_android.h",
 341     ]
 342     deps += [
 343       "//media/base/android",
 344       "//media/base/android:media_jni_headers",
 345       "//media/base/android:video_capture_jni_headers",
 346     ]
 347     allow_circular_includes_from = [ "//media/base/android" ]
 348   } else {
 349     sources += [
 350       "filters/opus_audio_decoder.cc",
 351       "filters/opus_audio_decoder.h",
 352     ]
 353   }
 354
 355   if (current_cpu != "arm" && is_chromeos) {
 356     sources += [
 357       "filters/h264_bitstream_buffer.cc",
 358       "filters/h264_bitstream_buffer.h",
 359     ]
 360   }
 361
 362   # A simple WebM encoder for animated avatars on ChromeOS.
 363
 364   if (use_ozone) {
 365     # Used for the generated listing header (ui/ozone/platform_list.h)
 366     include_dirs += [ target_gen_dir ]
 367
 368     sources += [
 369                  "ozone/media_ozone_platform.cc",
 370                  "ozone/media_ozone_platform.h",
 371                ] + get_target_outputs(":generate_ozone_constructor_list")
 372
 373     deps += [
 374       ":generate_ozone_constructor_list",
 375       "//ui/ozone",
 376     ]
 377   }
 378
 379   if (is_mac) {
 380     deps += [
 381       "//media/base/mac",
 382       "//third_party/decklink",
 383     ]
 384     libs += [
 385       "CoreVideo.framework",
 386       "OpenGL.framework",
 387       "QTKit.framework",
 388     ]
 389   }
 390
 391   if (is_openbsd) {
 392     sources -= [
 393       "video/capture/linux/v4l2_capture_delegate_multi_plane.cc",
 394       "video/capture/linux/v4l2_capture_delegate_multi_plane.h",
 395     ]
 396   }
 397
 398   if (is_ios) {
 399     deps += [ "//media/base/mac" ]
 400   }
 401
 402   if (is_win) {
 403     deps += [ "//media/base/win" ]
 404     libs += [
 405       "mf.lib",
 406       "mfplat.lib",
 407       "mfreadwrite.lib",
 408       "mfuuid.lib",
 409     ]
 410   }
 411
 412   if (proprietary_codecs) {
 413     sources += [
 414       "cdm/cenc_utils.cc",
 415       "cdm/cenc_utils.h",
 416       "filters/h264_to_annex_b_bitstream_converter.cc",
 417       "filters/h264_to_annex_b_bitstream_converter.h",
 418       "formats/mp2t/es_adapter_video.cc",
 419       "formats/mp2t/es_adapter_video.h",
 420       "formats/mp2t/es_parser.cc",
 421       "formats/mp2t/es_parser.h",
 422       "formats/mp2t/es_parser_adts.cc",
 423       "formats/mp2t/es_parser_adts.h",
 424       "formats/mp2t/es_parser_h264.cc",
 425       "formats/mp2t/es_parser_h264.h",
 426       "formats/mp2t/es_parser_mpeg1audio.cc",
 427       "formats/mp2t/es_parser_mpeg1audio.h",
 428       "formats/mp2t/mp2t_common.h",
 429       "formats/mp2t/mp2t_stream_parser.cc",
 430       "formats/mp2t/mp2t_stream_parser.h",
 431       "formats/mp2t/timestamp_unroller.cc",
 432       "formats/mp2t/timestamp_unroller.h",
 433       "formats/mp2t/ts_packet.cc",
 434       "formats/mp2t/ts_packet.h",
 435       "formats/mp2t/ts_section.h",
 436       "formats/mp2t/ts_section_pat.cc",
 437       "formats/mp2t/ts_section_pat.h",
 438       "formats/mp2t/ts_section_pes.cc",
 439       "formats/mp2t/ts_section_pes.h",
 440       "formats/mp2t/ts_section_pmt.cc",
 441       "formats/mp2t/ts_section_pmt.h",
 442       "formats/mp2t/ts_section_psi.cc",
 443       "formats/mp2t/ts_section_psi.h",
 444       "formats/mp4/aac.cc",
 445       "formats/mp4/aac.h",
 446       "formats/mp4/avc.cc",
 447       "formats/mp4/avc.h",
 448       "formats/mp4/box_definitions.cc",
 449       "formats/mp4/box_definitions.h",
 450       "formats/mp4/box_reader.cc",
 451       "formats/mp4/box_reader.h",
 452       "formats/mp4/cenc.cc",
 453       "formats/mp4/cenc.h",
 454       "formats/mp4/es_descriptor.cc",
 455       "formats/mp4/es_descriptor.h",
 456       "formats/mp4/mp4_stream_parser.cc",
 457       "formats/mp4/mp4_stream_parser.h",
 458       "formats/mp4/sample_to_group_iterator.cc",
 459       "formats/mp4/sample_to_group_iterator.h",
 460       "formats/mp4/track_run_iterator.cc",
 461       "formats/mp4/track_run_iterator.h",
 462       "formats/mpeg/adts_constants.cc",
 463       "formats/mpeg/adts_constants.h",
 464       "formats/mpeg/adts_stream_parser.cc",
 465       "formats/mpeg/adts_stream_parser.h",
 466       "formats/mpeg/mpeg1_audio_stream_parser.cc",
 467       "formats/mpeg/mpeg1_audio_stream_parser.h",
 468       "formats/mpeg/mpeg_audio_stream_parser_base.cc",
 469       "formats/mpeg/mpeg_audio_stream_parser_base.h",
 470     ]
 471   }
 472
 473   public_deps = [
 474     "//media/base",
 475     "//media/audio",
 476   ]
 477
 478   deps += [
 479     ":shared_memory_support",
 480     "//base",
 481     "//base:i18n",
 482     "//base/third_party/dynamic_annotations",
 483     "//crypto",
 484     "//crypto:platform",  # TODO(ajwong): This used to be provided by crypto.gyp via export_dependent_settings
 485     "//gpu/command_buffer/common",
 486     "//skia",
 487     "//third_party/libyuv",
 488     "//third_party/opus",
 489     "//ui/events:events_base",
 490     "//ui/gfx",
 491     "//ui/gfx/geometry",
 492     "//url",
 493   ]
 494 }
 495
 496 # Minimal media component for media/cast on iOS.
 497 if (is_ios) {
 498   component("media_for_cast_ios") {
 499     configs += [
 500       ":media_config",
 501       ":media_implementation",
 502     ]
 503     all_dependent_configs = [ ":media_dependent_config" ]
 504     include_dirs = [ "." ]
 505     libs = [ "CoreVideo.framework" ]
 506
 507     deps = [
 508       ":shared_memory_support",
 509       "//base",
 510       "//gpu/command_buffer/common",
 511       "//media/base:base_for_cast_ios",
 512       "//media/base/mac",
 513       "//ui/gfx/geometry",
 514     ]
 515   }
 516 }
 517
 518 test("media_unittests") {
 519   sources = [
 520     "blink/skcanvas_video_renderer_unittest.cc",
 521     "capture/animated_content_sampler_unittest.cc",
 522     "capture/capture_resolution_chooser_unittest.cc",
 523     "capture/feedback_signal_accumulator_unittest.cc",
 524     "capture/smooth_event_sampler_unittest.cc",
 525     "capture/video_capture_oracle_unittest.cc",
 526     "cdm/aes_decryptor_unittest.cc",
 527     "cdm/json_web_key_unittest.cc",
 528     "filters/audio_clock_unittest.cc",
 529     "filters/audio_decoder_selector_unittest.cc",
 530     "filters/audio_renderer_algorithm_unittest.cc",
 531     "filters/chunk_demuxer_unittest.cc",
 532     "filters/decrypting_audio_decoder_unittest.cc",
 533     "filters/decrypting_demuxer_stream_unittest.cc",
 534     "filters/decrypting_video_decoder_unittest.cc",
 535     "filters/fake_video_decoder.cc",
 536     "filters/fake_video_decoder.h",
 537     "filters/fake_video_decoder_unittest.cc",
 538     "filters/file_data_source_unittest.cc",
 539     "filters/frame_processor_unittest.cc",
 540     "filters/h264_bit_reader_unittest.cc",
 541     "filters/h264_parser_unittest.cc",
 542     "filters/jpeg_parser_unittest.cc",
 543     "filters/source_buffer_stream_unittest.cc",
 544     "filters/video_cadence_estimator_unittest.cc",
 545     "filters/video_decoder_selector_unittest.cc",
 546     "filters/video_frame_stream_unittest.cc",
 547     "filters/video_renderer_algorithm_unittest.cc",
 548     "filters/vp8_bool_decoder_unittest.cc",
 549     "filters/vp8_parser_unittest.cc",
 550     "formats/common/offset_byte_queue_unittest.cc",
 551     "formats/webm/cluster_builder.cc",
 552     "formats/webm/cluster_builder.h",
 553     "formats/webm/opus_packet_builder.cc",
 554     "formats/webm/opus_packet_builder.h",
 555     "formats/webm/tracks_builder.cc",
 556     "formats/webm/tracks_builder.h",
 557     "formats/webm/webm_cluster_parser_unittest.cc",
 558     "formats/webm/webm_content_encodings_client_unittest.cc",
 559     "formats/webm/webm_parser_unittest.cc",
 560     "formats/webm/webm_tracks_parser_unittest.cc",
 561     "formats/webm/webm_webvtt_parser_unittest.cc",
 562     "renderers/audio_renderer_impl_unittest.cc",
 563     "renderers/renderer_impl_unittest.cc",
 564     "renderers/video_renderer_impl_unittest.cc",
 565     "video/capture/fake_video_capture_device_unittest.cc",
 566     "video/capture/video_capture_device_unittest.cc",
 567     "video/h264_poc_unittest.cc",
 568   ]
 569
 570   # TODO(wolenetz): Fix size_t to int trunctaion in win64.
 571   # See http://crbug.com/171009
 572   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 573
 574   deps = [
 575     ":media",
 576     ":test_support",
 577     "//base/allocator",
 578     "//base/test:test_support",
 579     "//media/audio:unittests",
 580     "//media/audio:test_support",
 581     "//media/base:unittests",
 582     "//media/base:test_support",
 583     "//media/test:pipeline_integration_tests",
 584     "//skia",  # Direct dependency required to inherit config.
 585     "//testing/gmock",
 586     "//testing/gtest",
 587     "//third_party/widevine/cdm:version_h",
 588     "//ui/gfx:test_support",
 589     "//url",
 590   ]
 591
 592   if (is_android) {
 593     isolate_file = "media_unittests.isolate"
 594     deps += [
 595       "//media/base/android",
 596       # TODO(GYP)
 597       #"//testing/android/native_test:native_test_native_code"
 598     ]
 599   }
 600
 601   if (media_use_ffmpeg) {
 602     sources += [
 603       "ffmpeg/ffmpeg_common_unittest.cc",
 604       "filters/audio_decoder_unittest.cc",
 605       "filters/audio_file_reader_unittest.cc",
 606       "filters/blocking_url_protocol_unittest.cc",
 607       "filters/ffmpeg_demuxer_unittest.cc",
 608       "filters/ffmpeg_glue_unittest.cc",
 609       "filters/ffmpeg_video_decoder_unittest.cc",
 610       "filters/in_memory_url_protocol_unittest.cc",
 611     ]
 612   }
 613
 614   if (current_cpu != "arm" && is_chromeos) {
 615     sources += [ "filters/h264_bitstream_buffer_unittest.cc" ]
 616   }
 617
 618   if (proprietary_codecs) {
 619     sources += [
 620       "cdm/cenc_utils_unittest.cc",
 621       "filters/h264_to_annex_b_bitstream_converter_unittest.cc",
 622       "formats/common/stream_parser_test_base.cc",
 623       "formats/common/stream_parser_test_base.h",
 624       "formats/mp2t/es_adapter_video_unittest.cc",
 625       "formats/mp2t/es_parser_adts_unittest.cc",
 626       "formats/mp2t/es_parser_h264_unittest.cc",
 627       "formats/mp2t/es_parser_mpeg1audio_unittest.cc",
 628       "formats/mp2t/es_parser_test_base.cc",
 629       "formats/mp2t/es_parser_test_base.h",
 630       "formats/mp2t/mp2t_stream_parser_unittest.cc",
 631       "formats/mp2t/timestamp_unroller_unittest.cc",
 632       "formats/mp4/aac_unittest.cc",
 633       "formats/mp4/avc_unittest.cc",
 634       "formats/mp4/box_reader_unittest.cc",
 635       "formats/mp4/es_descriptor_unittest.cc",
 636       "formats/mp4/mp4_stream_parser_unittest.cc",
 637       "formats/mp4/sample_to_group_iterator_unittest.cc",
 638       "formats/mp4/track_run_iterator_unittest.cc",
 639       "formats/mpeg/adts_stream_parser_unittest.cc",
 640       "formats/mpeg/mpeg1_audio_stream_parser_unittest.cc",
 641     ]
 642     if (media_use_ffmpeg) {
 643       sources += [
 644         "filters/ffmpeg_aac_bitstream_converter_unittest.cc",
 645         "filters/ffmpeg_h264_to_annex_b_bitstream_converter_unittest.cc",
 646       ]
 647     }
 648   }
 649
 650   if (is_mac || is_ios) {
 651     deps += [ "//media/base/mac" ]
 652   }
 653
 654   if (is_mac) {
 655     sources +=
 656         [ "video/capture/mac/video_capture_device_factory_mac_unittest.mm" ]
 657   }
 658
 659   #      include_dirs += [
 660   #        # Needed by media_drm_bridge.cc.
 661   #        target_gen_dir,
 662   #      ],
 663
 664   configs += [ ":media_config" ]
 665
 666   if (media_use_ffmpeg) {
 667     deps += [ "//third_party/ffmpeg" ]  # Direct dependency required to inherit config.
 668   }
 669 }
 670
 671 test("media_perftests") {
 672   configs += [ ":media_config" ]
 673   deps = [
 674     ":media",
 675     ":shared_memory_support",
 676     ":test_support",
 677     "//base/test:test_support",
 678     "//media/audio:test_support",
 679     "//media/base:perftests",
 680     "//media/base:test_support",
 681     "//media/test:pipeline_integration_perftests",
 682     "//testing/gmock",
 683     "//testing/gtest",
 684     "//testing/perf",
 685     "//third_party/widevine/cdm:version_h",
 686     "//ui/gfx:test_support",
 687   ]
 688   if (is_android) {
 689     deps += [ "//ui/gl" ]
 690     isolate_file = "media_perftests.isolate"
 691   }
 692   if (media_use_ffmpeg) {
 693     deps += [ "//third_party/ffmpeg" ]  # Direct dependency required to inherit config.
 694   }
 695 }
 696
 697 # For running the subset of media_unittests that might require audio hardware
 698 # separately on GPU bots. media_unittests includes these too.
 699 test("audio_unittests") {
 700   sources = [
 701     "base/run_all_unittests.cc",
 702   ]
 703   deps = [
 704     ":test_support",
 705     "//base/test:test_support",
 706     "//media/audio:unittests",
 707     "//ui/gfx:test_support",
 708   ]
 709 }
 710
 711 source_set("test_support") {
 712   testonly = true
 713   sources = [
 714     "renderers/mock_gpu_video_accelerator_factories.cc",
 715     "renderers/mock_gpu_video_accelerator_factories.h",
 716     "video/mock_video_decode_accelerator.cc",
 717     "video/mock_video_decode_accelerator.h",
 718   ]
 719   deps = [
 720     ":media",
 721     ":shared_memory_support",
 722     "//base",
 723     "//skia",
 724     "//testing/gmock",
 725     "//testing/gtest",
 726   ]
 727 }
 728
 729 # TODO(dalecurtis): How to split this across audio/base directories??
 730 component("shared_memory_support") {
 731   sources = [
 732     "audio/audio_parameters.cc",
 733     "audio/audio_parameters.h",
 734     "base/audio_bus.cc",
 735     "base/audio_bus.h",
 736     "base/channel_layout.cc",
 737     "base/channel_layout.h",
 738     "base/limits.h",
 739     "base/media_export.h",
 740     "base/vector_math.cc",
 741     "base/vector_math.h",
 742   ]
 743   configs += [
 744     ":media_config",
 745     ":media_implementation",
 746   ]
 747   deps = [
 748     "//base",
 749   ]
 750 }
 751
 752 if (media_use_ffmpeg) {
 753   test("ffmpeg_regression_tests") {
 754     sources = [
 755       "base/run_all_unittests.cc",
 756       "ffmpeg/ffmpeg_regression_tests.cc",
 757     ]
 758
 759     configs += [ "//media:media_config" ]
 760
 761     deps = [
 762       "//base/test:test_support",
 763       "//media",
 764       "//media:test_support",
 765       "//media/audio:test_support",
 766       "//media/base:test_support",
 767       "//media/test:pipeline_integration_tests",
 768       "//testing/gmock",
 769       "//testing/gtest",
 770       "//third_party/ffmpeg",
 771       "//ui/gfx/geometry",
 772       "//ui/gfx:test_support",
 773     ]
 774   }
 775 }