device/usb/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 assert(!is_android && !is_ios)
   6
   7 source_ids = "//third_party/usb_ids/usb.ids"
   8 generated_ids = "$target_gen_dir/usb_ids_gen.cc"
   9
  10 source_set("usb") {
  11   sources = [
  12     "usb_context.cc",
  13     "usb_context.h",
  14     "usb_descriptors.cc",
  15     "usb_descriptors.h",
  16     "usb_device.h",
  17     "usb_device_filter.cc",
  18     "usb_device_filter.h",
  19     "usb_device_handle.h",
  20     "usb_device_handle_impl.cc",
  21     "usb_device_handle_impl.h",
  22     "usb_device_impl.cc",
  23     "usb_device_impl.h",
  24     "usb_error.cc",
  25     "usb_error.h",
  26     "usb_ids.cc",
  27     "usb_ids.h",
  28     "usb_service.cc",
  29     "usb_service.h",
  30     "usb_service_impl.cc",
  31     "usb_service_impl.h",
  32     generated_ids,
  33   ]
  34
  35   deps = [
  36     ":usb_device_ids",
  37     "//base",
  38     "//base/third_party/dynamic_annotations",
  39     "//components/device_event_log",
  40     "//device/core",
  41     "//net",
  42     "//third_party/libusb",
  43   ]
  44
  45   if (is_linux) {
  46     deps += [ "//device/udev_linux" ]
  47   }
  48   if (is_chromeos) {
  49     deps += [ "//chromeos" ]
  50   }
  51 }
  52
  53 action("usb_device_ids") {
  54   script = "//device/usb/tools/usb_ids.py"
  55   inputs = [
  56     source_ids,
  57   ]
  58   outputs = [
  59     generated_ids,
  60   ]
  61   args = [
  62     "-i",
  63     rebase_path(source_ids, root_build_dir),
  64     "-o",
  65     rebase_path(generated_ids, root_build_dir),
  66   ]
  67
  68   # Only the device_usb target can depend on us.
  69   visibility = [ ":usb" ]
  70 }