build/config/sysroot.gni

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 # This header file defines the "sysroot" variable which is the absolute path
   6 # of the sysroot. If no sysroot applies, the variable will be an empty string.
   7
   8 if (is_android) {
   9   import("//build/config/android/config.gni")
  10   if (!is_android_webview_build) {
  11     if (cpu_arch == "x86") {
  12       sysroot = rebase_path("$android_ndk_root/$x86_android_sysroot_subdir")
  13     } else if (cpu_arch == "arm") {
  14       sysroot = rebase_path("$android_ndk_root/$arm_android_sysroot_subdir")
  15     } else if (cpu_arch == "mipsel") {
  16       sysroot = rebase_path("$android_ndk_root/$mips_android_sysroot_subdir")
  17     } else {
  18       sysroot = ""
  19     }
  20   } else {
  21     sysroot = ""
  22   }
  23 } else if (is_linux && is_chrome_branded && is_official_build && !is_chromeos) {
  24   # For official builds, use the sysroot checked into the internal source repo
  25   # so that the builds work on older versions of Linux.
  26   if (cpu_arch == "x64") {
  27     sysroot =
  28         rebase_path("//chrome/installer/linux/debian_wheezy_amd64-sysroot")
  29   } else if (cpu_arch == "x86") {
  30     sysroot = rebase_path("//chrome/installer/linux/debian_wheezy_i386-sysroot")
  31   } else {
  32     # Any other builds don't use a sysroot.
  33     sysroot = ""
  34   }
  35 } else if (is_linux && !is_chromeos) {
  36   if (cpu_arch == "mipsel") {
  37     sysroot = rebase_path("//mipsel-sysroot/sysroot")
  38   } else {
  39     sysroot = ""
  40   }
  41 } else if (is_mac) {
  42   import("//build/config/mac/mac_sdk.gni")
  43
  44   sysroot = mac_sdk_path
  45 } else if (is_ios) {
  46   import("//build/config/ios/ios_sdk.gni")
  47   sysroot = ios_sdk_path
  48 } else {
  49   sysroot = ""
  50 }