remoting/base/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//remoting/remoting_srcs.gni")
   6
   7 source_set("base") {
   8   sources = rebase_path(remoting_srcs_gypi_values.remoting_base_sources,
   9                         ".",
  10                         "//remoting")
  11
  12   configs += [ "//build/config/compiler:wexit_time_destructors" ]
  13
  14   public_deps = [
  15     "//base",
  16     "//net",
  17     "//remoting/proto",
  18     "//third_party/protobuf:protobuf_lite",
  19   ]
  20   deps = [
  21     "//base/third_party/dynamic_annotations",
  22     "//media",
  23     "//media:shared_memory_support",
  24     "//remoting/resources",
  25     "//third_party/libvpx",
  26     "//third_party/libyuv",
  27     "//third_party/webrtc/modules/desktop_capture",
  28     "//ui/base",
  29   ]
  30 }
  31
  32 source_set("breakpad") {
  33   sources = [
  34     "breakpad.h",
  35     "breakpad_linux.cc",
  36     "breakpad_mac.mm",
  37     "breakpad_win.cc",
  38   ]
  39
  40   configs += [ "//build/config/compiler:wexit_time_destructors" ]
  41
  42   deps = [
  43     "//base",
  44   ]
  45
  46   if (is_mac) {
  47     deps += [ "//breakpad" ]
  48   } else if (is_win) {
  49     deps += [ "//breakpad:breakpad_handler" ]
  50   }
  51 }
  52
  53 source_set("unit_tests") {
  54   testonly = true
  55
  56   sources = [
  57     "auto_thread_task_runner_unittest.cc",
  58     "auto_thread_unittest.cc",
  59     "breakpad_win_unittest.cc",
  60     "buffered_socket_writer_unittest.cc",
  61     "capabilities_unittest.cc",
  62     "compound_buffer_unittest.cc",
  63     "rate_counter_unittest.cc",
  64     "rsa_key_pair_unittest.cc",
  65     "run_all_unittests.cc",
  66     "running_average_unittest.cc",
  67     "test_rsa_key_pair.h",
  68     "typed_buffer_unittest.cc",
  69     "util_unittest.cc",
  70   ]
  71
  72   deps = [
  73     ":base",
  74     ":breakpad",
  75     "//base",
  76     "//net:test_support",
  77     "//testing/gmock",
  78     "//testing/gtest",
  79     "//third_party/libyuv",
  80     "//third_party/webrtc/modules/desktop_capture",
  81   ]
  82
  83   if (is_win || is_mac || is_chromeos) {
  84     sources += [ "resources_unittest.cc" ]
  85     deps += [ "//breakpad:client" ]
  86   }
  87
  88   if (is_win) {
  89     libs = [ "rpcrt4.lib" ]  # For UuidCreate in breakpad_win_unittest.cc.
  90   }
  91 }