build/sanitize-mac-build-log.sed

   1 #!/bin/echo Use sanitize-mac-build-log.sh or sed -f
   2
   3 # Copyright (c) 2011 The Chromium Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style license that can be
   5 # found in the LICENSE file.
   6
   7 # Use this sed script to reduce a Mac build log into something readable.
   8
   9 # Drop uninformative lines.
  10 /^distcc/d
  11 /^Check dependencies/d
  12 /^    setenv /d
  13 /^    cd /d
  14 /^make: Nothing to be done/d
  15 /^$/d
  16
  17 # Xcode prints a short "compiling foobar.o" line followed by the lengthy
  18 # full command line.  These deletions drop the command line.
  19 \|^    /Developer/usr/bin/|d
  20 \|^    /Developer/Library/PrivateFrameworks/DevToolsCore.framework/|d
  21 \|^    /Developer/Library/Xcode/Plug-ins/CoreBuildTasks.xcplugin/|d
  22
  23 # Drop any goma command lines as well.
  24 \|^    .*/gomacc |d
  25
  26 # And, if you've overridden something from your own bin directory, remove those
  27 # full command lines, too.
  28 \|^    /Users/[^/]*/bin/|d
  29
  30 # There's already a nice note for bindings, don't need the command line.
  31 \|^python scripts/rule_binding.py|d
  32
  33 # Shorten the "compiling foobar.o" line.
  34 s|^Distributed-CompileC \(.*\) normal i386 c++ com.apple.compilers.gcc.4_2|    CC \1|
  35 s|^CompileC \(.*\) normal i386 c++ com.apple.compilers.gcc.4_2|    CC \1|