extensions/browser/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6 import("//build/config/features.gni")
   7 import("//extensions/extensions.gni")
   8
   9 # GYP version: extensions/extensions.gyp:extensions_browser
  10 source_set("browser") {
  11   sources = []
  12
  13   deps = [
  14     "//components/keyed_service/content",
  15     "//components/keyed_service/core",
  16     "//components/pref_registry",
  17     "//components/sessions:sessions_content",
  18     "//components/ui/zoom:ui_zoom",
  19     "//components/web_cache/browser",
  20     "//components/web_modal",
  21     "//content/public/browser",
  22     "//crypto:platform",
  23     "//extensions/common",
  24     "//extensions/common/api",
  25     "//extensions/common/api:api_registration",
  26     "//extensions/strings",
  27     "//google_apis",
  28     "//skia",
  29     "//third_party/leveldatabase",
  30     "//third_party/re2",
  31   ]
  32
  33   if (enable_extensions) {
  34     # Includes all API implementations and the ExtensionsApiClient
  35     # interface. Moving an API from src/chrome to src/extensions implies
  36     # it can be cleanly disabled with enable_extensions=false.
  37     # TODO: Eventually the entire extensions module should not be built
  38     # when enable_extensions=false.
  39     sources = rebase_path(extensions_gypi_values.extensions_browser_sources,
  40                           ".",
  41                           "//extensions")
  42
  43     deps += [
  44       "//components/onc",
  45       "//components/storage_monitor",
  46       "//components/update_client",
  47       "//crypto:platform",
  48       "//device/bluetooth",
  49       "//device/core",
  50       "//device/hid",
  51       "//device/serial",
  52       "//device/usb",
  53       "//extensions/common/api/cast_channel:cast_channel_proto",
  54     ]
  55
  56     if (is_chromeos) {
  57       deps += [ "//chromeos" ]
  58     }
  59
  60     if (is_chromeos) {
  61       chromeos_sources = rebase_path(
  62               extensions_gypi_values.extensions_browser_sources_chromeos,
  63               ".",
  64               "//extensions")
  65       sources += chromeos_sources
  66     } else {
  67       nonchromeos_sources = rebase_path(
  68               extensions_gypi_values.extensions_browser_sources_nonchromeos,
  69               ".",
  70               "//extensions")
  71       sources += nonchromeos_sources
  72
  73       if (is_linux) {
  74         configs += [ "//build/config/linux:dbus" ]
  75         deps += [ "//dbus" ]
  76         linux_sources = rebase_path(
  77                 extensions_gypi_values.extensions_browser_sources_linux_nonchromeos,
  78                 ".",
  79                 "//extensions")
  80         sources += linux_sources
  81       } else {
  82         nonlinux_sources = rebase_path(
  83                 extensions_gypi_values.extensions_browser_sources_nonlinux,
  84                 ".",
  85                 "//extensions")
  86         sources += nonlinux_sources
  87
  88         if (is_win || is_mac) {
  89           deps += [ "//components/wifi" ]
  90
  91           win_or_mac_sources = rebase_path(
  92                   extensions_gypi_values.extensions_browser_sources_win_or_mac,
  93                   ".",
  94                   "//extensions")
  95           sources += win_or_mac_sources
  96         }
  97       }
  98     }
  99   }
 100
 101   if (is_win) {
 102     cflags = [ "/wd4267" ]  # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 103   }
 104 }