device/BUILD.gn

   1 # Copyright 2015 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//testing/test.gni")
   7
   8 is_linux_without_udev = is_linux && !use_udev
   9 is_linux_without_dbus = is_linux && !use_dbus
  10
  11 test("device_unittests") {
  12   sources = [
  13     "battery/battery_status_manager_win_unittest.cc",
  14     "battery/battery_status_service_unittest.cc",
  15     "bluetooth/bluetooth_adapter_mac_unittest.mm",
  16     "bluetooth/bluetooth_adapter_profile_chromeos_unittest.cc",
  17     "bluetooth/bluetooth_adapter_unittest.cc",
  18     "bluetooth/bluetooth_adapter_win_unittest.cc",
  19     "bluetooth/bluetooth_audio_sink_chromeos_unittest.cc",
  20     "bluetooth/bluetooth_chromeos_unittest.cc",
  21     "bluetooth/bluetooth_device_unittest.cc",
  22     "bluetooth/bluetooth_device_win_unittest.cc",
  23     "bluetooth/bluetooth_gatt_chromeos_unittest.cc",
  24     "bluetooth/bluetooth_low_energy_win_unittest.cc",
  25     "bluetooth/bluetooth_service_record_win_unittest.cc",
  26     "bluetooth/bluetooth_socket_chromeos_unittest.cc",
  27     "bluetooth/bluetooth_task_manager_win_unittest.cc",
  28     "bluetooth/bluetooth_uuid_unittest.cc",
  29     "nfc/nfc_chromeos_unittest.cc",
  30     "nfc/nfc_ndef_record_unittest.cc",
  31     "test/run_all_unittests.cc",
  32   ]
  33
  34   deps = [
  35     "//base/test:test_support",
  36     "//device/battery",
  37     "//device/battery:mojo_bindings",
  38     "//device/bluetooth",
  39     "//device/nfc",
  40     "//mojo/environment:chromium",
  41     "//net",
  42     "//testing/gmock",
  43     "//testing/gtest",
  44     "//third_party/mojo/src/mojo/edk/system",
  45     "//third_party/mojo/src/mojo/public/cpp/bindings",
  46     "//url",
  47   ]
  48
  49   if (!is_linux_without_dbus && !is_chromeos) {
  50     sources += [ "battery/battery_status_manager_linux_unittest.cc" ]
  51   }
  52
  53   # HID and Serial:
  54   # Android doesn't compile.
  55   # Linux, requires udev.
  56   if (!is_linux_without_udev && !is_android) {
  57     sources += [
  58       "hid/hid_connection_unittest.cc",
  59       "hid/hid_device_filter_unittest.cc",
  60       "hid/hid_report_descriptor_unittest.cc",
  61       "hid/input_service_linux_unittest.cc",
  62       "hid/test_report_descriptors.cc",
  63       "hid/test_report_descriptors.h",
  64       "serial/data_sink_unittest.cc",
  65       "serial/data_source_unittest.cc",
  66       "serial/serial_connection_unittest.cc",
  67       "serial/serial_service_unittest.cc",
  68     ]
  69     deps += [
  70       "//device/hid",
  71       "//device/serial",
  72       "//device/serial:test_support",
  73     ]
  74   }
  75
  76   if (use_udev) {
  77     sources += [ "udev_linux/udev_unittest.cc" ]
  78     deps += [ "//device/udev_linux" ]
  79   }
  80
  81   # USB does not compile on mobile platforms.
  82   if (!is_android && !is_ios) {
  83     sources += [
  84       "test/usb_test_gadget_impl.cc",
  85       "usb/usb_context_unittest.cc",
  86       "usb/usb_device_filter_unittest.cc",
  87       "usb/usb_device_handle_unittest.cc",
  88       "usb/usb_ids_unittest.cc",
  89       "usb/usb_service_unittest.cc",
  90     ]
  91     deps += [
  92       "//device/usb",
  93       "//third_party/libusb",
  94     ]
  95   }
  96
  97   if (is_chromeos) {
  98     configs += [ "//build/config/linux:dbus" ]
  99
 100     deps += [
 101       "//chromeos",
 102       "//chromeos:test_support",
 103       "//chromeos:test_support_without_gmock",
 104       "//dbus",
 105     ]
 106   }
 107
 108   if (is_posix && !is_android && !is_mac) {
 109     libs = [ "rt" ]
 110   }
 111
 112   if (is_mac) {
 113     libs = [ "IOBluetooth.framework" ]
 114   }
 115 }