chrome/browser/ui/cocoa/extensions/extension_install_dialog_controller.mm

   1 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #import "chrome/browser/ui/cocoa/extensions/extension_install_dialog_controller.h"
   6
   7 #include "base/bind.h"
   8 #include "base/logging.h"
   9 #include "base/message_loop.h"
  10 #include "chrome/browser/ui/browser.h"
  11 #include "chrome/browser/ui/browser_finder.h"
  12 #import "chrome/browser/ui/cocoa/constrained_window/constrained_window_custom_sheet.h"
  13 #include "chrome/browser/ui/cocoa/constrained_window/constrained_window_custom_window.h"
  14 #import "chrome/browser/ui/cocoa/extensions/extension_install_view_controller.h"
  15 #include "chrome/browser/ui/tabs/tab_strip_model.h"
  16 #include "content/public/browser/web_contents.h"
  17
  18 namespace {
  19
  20 void ShowExtensionInstallDialogImpl(
  21     const ExtensionInstallPrompt::ShowParams& show_params,
  22     ExtensionInstallPrompt::Delegate* delegate,
  23     const ExtensionInstallPrompt::Prompt& prompt) {
  24   if (!show_params.parent_web_contents) {
  25     // TODO(sail): Add support for showing the dialog without a parent window.
  26     NOTIMPLEMENTED();
  27     return;
  28   }
  29
  30   // This object will delete itself when the dialog closes.
  31   new ExtensionInstallDialogController(show_params, delegate, prompt);
  32 }
  33
  34 }  // namespace
  35
  36 ExtensionInstallDialogController::ExtensionInstallDialogController(
  37     const ExtensionInstallPrompt::ShowParams& show_params,
  38     ExtensionInstallPrompt::Delegate* delegate,
  39     const ExtensionInstallPrompt::Prompt& prompt) : delegate_(delegate) {
  40   view_controller_.reset([[ExtensionInstallViewController alloc]
  41       initWithNavigator:show_params.navigator
  42                delegate:this
  43                  prompt:prompt]);
  44
  45   scoped_nsobject<NSWindow> window([[ConstrainedWindowCustomWindow alloc]
  46       initWithContentRect:[[view_controller_ view] bounds]]);
  47   [[window contentView] addSubview:[view_controller_ view]];
  48
  49   scoped_nsobject<CustomConstrainedWindowSheet> sheet(
  50       [[CustomConstrainedWindowSheet alloc]
  51           initWithCustomWindow:window]);
  52   constrained_window_.reset(new ConstrainedWindowMac(
  53       this, show_params.parent_web_contents, sheet));
  54 }
  55
  56 ExtensionInstallDialogController::~ExtensionInstallDialogController() {
  57 }
  58
  59 void ExtensionInstallDialogController::InstallUIProceed() {
  60   delegate_->InstallUIProceed();
  61   delegate_ = NULL;
  62   constrained_window_->CloseConstrainedWindow();
  63 }
  64
  65 void ExtensionInstallDialogController::InstallUIAbort(bool user_initiated) {
  66   delegate_->InstallUIAbort(user_initiated);
  67   delegate_ = NULL;
  68   constrained_window_->CloseConstrainedWindow();
  69 }
  70
  71 void ExtensionInstallDialogController::OnConstrainedWindowClosed(
  72     ConstrainedWindowMac* window) {
  73   if (delegate_)
  74     delegate_->InstallUIAbort(false);
  75   MessageLoop::current()->DeleteSoon(FROM_HERE, this);
  76 }
  77
  78 // static
  79 ExtensionInstallPrompt::ShowDialogCallback
  80 ExtensionInstallPrompt::GetDefaultShowDialogCallback() {
  81   return base::Bind(&ShowExtensionInstallDialogImpl);
  82 }