content/common/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 import("//content/common/common.gni")
   8 import("//third_party/mojo/src/mojo/public/tools/bindings/mojom.gni")
   9
  10 if (is_chromeos && current_cpu != "arm") {
  11   action("libva_generate_stubs") {
  12     extra_header = "gpu/media/va_stub_header.fragment"
  13
  14     script = "../../tools/generate_stubs/generate_stubs.py"
  15     sources = [
  16       "gpu/media/va.sigs",
  17     ]
  18     inputs = [
  19       extra_header,
  20     ]
  21     if (use_x11) {
  22       sources += [ "gpu/media/va_x11.sigs" ]
  23     }
  24     if (use_ozone) {
  25       sources += [ "gpu/media/va_drm.sigs" ]
  26     }
  27     stubs_filename_root = "va_stubs"
  28
  29     outputs = [
  30       "$target_gen_dir/gpu/media/$stubs_filename_root.cc",
  31       "$target_gen_dir/gpu/media/$stubs_filename_root.h",
  32     ]
  33     args = [
  34       "-i",
  35       rebase_path("$target_gen_dir/gpu/media", root_build_dir),
  36       "-o",
  37       rebase_path("$target_gen_dir/gpu/media", root_build_dir),
  38       "-t",
  39       "posix_stubs",
  40       "-e",
  41       rebase_path(extra_header, root_build_dir),
  42       "-s",
  43       stubs_filename_root,
  44       "-p",
  45       "content/common/gpu/media",
  46     ]
  47
  48     args += rebase_path(sources, root_build_dir)
  49   }
  50 }
  51
  52 if (is_chromeos && use_v4lplugin) {
  53   action("libv4l2_generate_stubs") {
  54     extra_header = "gpu/media/v4l2_stub_header.fragment"
  55
  56     script = "../../tools/generate_stubs/generate_stubs.py"
  57     sources = [
  58       "gpu/media/v4l2.sig",
  59     ]
  60     inputs = [
  61       extra_header,
  62     ]
  63     stubs_filename_root = "v4l2_stubs"
  64
  65     outputs = [
  66       "$target_gen_dir/gpu/media/$stubs_filename_root.cc",
  67       "$target_gen_dir/gpu/media/$stubs_filename_root.h",
  68     ]
  69     args = [
  70       "-i",
  71       rebase_path("$target_gen_dir/gpu/media", root_build_dir),
  72       "-o",
  73       rebase_path("$target_gen_dir/gpu/media", root_build_dir),
  74       "-t",
  75       "posix_stubs",
  76       "-e",
  77       rebase_path(extra_header, root_build_dir),
  78       "-s",
  79       stubs_filename_root,
  80       "-p",
  81       "content/common/gpu/media",
  82     ]
  83
  84     args += rebase_path(sources, root_build_dir)
  85   }
  86 }
  87
  88 if (is_mac) {
  89   action("libvt_generate_stubs") {
  90     extra_header = "gpu/media/vt_stubs_header.fragment"
  91
  92     script = "../../tools/generate_stubs/generate_stubs.py"
  93     sources = [
  94       "gpu/media/vt.sig",
  95     ]
  96     inputs = [
  97       extra_header,
  98     ]
  99     stubs_filename_root = "vt_stubs"
 100
 101     outputs = [
 102       "$target_gen_dir/gpu/media/$stubs_filename_root.cc",
 103       "$target_gen_dir/gpu/media/$stubs_filename_root.h",
 104     ]
 105     args = [
 106       "-i",
 107       rebase_path("$target_gen_dir/gpu/media", root_build_dir),
 108       "-o",
 109       rebase_path("$target_gen_dir/gpu/media", root_build_dir),
 110       "-t",
 111       "posix_stubs",
 112       "-e",
 113       rebase_path(extra_header, root_build_dir),
 114       "-s",
 115       stubs_filename_root,
 116       "-p",
 117       "content/common/gpu/media",
 118     ]
 119
 120     args += rebase_path(sources, root_build_dir)
 121   }
 122 }
 123
 124 source_set("common") {
 125   # Only the public target should depend on this. All other targets (even
 126   # internal content ones) should depend on the public one.
 127   visibility = [ "//content/public/common:common_sources" ]
 128
 129   sources = rebase_path(content_common_gypi_values.private_common_sources,
 130                         ".",
 131                         "//content")
 132
 133   configs += [
 134     "//content:content_implementation",
 135     "//build/config/compiler:no_size_t_to_int_warning",
 136   ]
 137
 138   public_deps = [
 139     "//gpu/command_buffer/common",
 140     "//third_party/WebKit/public:blink_headers",
 141   ]
 142   deps = [
 143     "//base",
 144     "//build/util:webkit_version",
 145     "//components/tracing",
 146     "//gpu/command_buffer/client:gles2_interface",
 147     "//gpu/command_buffer/common:gles2_utils",
 148     "//net",
 149     "//skia",
 150     "//third_party/icu",
 151     "//ui/accessibility",
 152     "//ui/base",
 153     "//ui/base/ime",
 154     "//ui/events/ipc",
 155     "//ui/gfx",
 156     "//ui/gfx/geometry",
 157     "//ui/gfx/ipc",
 158     "//ui/shell_dialogs",
 159     "//url",
 160     "//third_party/libjingle",
 161   ]
 162
 163   if (!is_ios) {
 164     deps += [
 165       "//cc",
 166       "//ipc",
 167       "//ipc/mojo",
 168
 169       # TODO: the dependency on gl_in_process_context should be decoupled from
 170       # content and moved to android_webview. See crbug.com/365797.
 171       "//gpu/blink",
 172       "//gpu/command_buffer/client:gl_in_process_context",
 173       "//gpu/command_buffer/client:gles2_c_lib",
 174       "//gpu/command_buffer/client:gles2_cmd_helper",
 175       "//gpu/command_buffer/client:gles2_implementation",
 176       "//gpu/command_buffer/service",
 177       "//gpu/ipc",
 178       "//gpu/skia_bindings",
 179       "//media",
 180       "//media/midi",
 181       "//media:shared_memory_support",
 182       "//mojo/environment:chromium",
 183       "//sandbox",
 184       "//storage/common",
 185       "//third_party/WebKit/public:blink",
 186       "//third_party/mojo/src/mojo/edk/system",
 187       "//third_party/mojo/src/mojo/public/interfaces/application",
 188       "//ui/gl",
 189       "//webkit/common/gpu",
 190     ]
 191   }
 192
 193   defines = []
 194   include_dirs = []
 195   libs = []
 196   ldflags = []
 197
 198   if (is_android && use_seccomp_bpf) {
 199     set_sources_assignment_filter([])
 200     sources += [
 201       "sandbox_linux/sandbox_bpf_base_policy_linux.cc",
 202       "sandbox_linux/sandbox_bpf_base_policy_linux.h",
 203     ]
 204     set_sources_assignment_filter(sources_assignment_filter)
 205   }
 206
 207   if (is_mac) {
 208     sources += [
 209                  "gpu/client/gpu_memory_buffer_impl_io_surface.cc",
 210                  "gpu/client/gpu_memory_buffer_impl_io_surface.h",
 211                  "gpu/gpu_memory_buffer_factory_io_surface.cc",
 212                  "gpu/gpu_memory_buffer_factory_io_surface.h",
 213                  "gpu/media/vt.h",
 214                  "gpu/media/vt_video_decode_accelerator.cc",
 215                  "gpu/media/vt_video_decode_accelerator.h",
 216                ] + get_target_outputs(":libvt_generate_stubs")
 217
 218     sources -= [ "plugin_list_posix.cc" ]
 219
 220     deps += [
 221       ":libvt_generate_stubs",
 222       "//content/app/resources",
 223       "//content:resources",
 224       "//third_party/WebKit/public:image_resources",
 225       "//third_party/WebKit/public:resources",
 226       "//ui/accelerated_widget_mac",
 227     ]
 228     libs += [
 229       "IOSurface.framework",
 230       "OpenGL.framework",
 231       "QuartzCore.framework",
 232     ]
 233   }
 234
 235   if (is_android) {
 236     sources += [
 237       "gpu/client/gpu_memory_buffer_impl_surface_texture.cc",
 238       "gpu/client/gpu_memory_buffer_impl_surface_texture.h",
 239       "gpu/gpu_memory_buffer_factory_surface_texture.cc",
 240       "gpu/gpu_memory_buffer_factory_surface_texture.h",
 241     ]
 242
 243     deps += [
 244       "//content/public/android:jni",
 245       "//content/public/android:common_aidl",
 246     ]
 247
 248     libs += [ "android" ]
 249   }
 250
 251   if (is_debug && !is_component_build) {
 252     # Content depends on the PPAPI message logging stuff; if this isn't here,
 253     # some unit test binaries won't compile. This only worked in release mode
 254     # because logging is disabled there.
 255     deps += [ "//ppapi/proxy:ipc_sources" ]
 256   }
 257
 258   if (is_ios) {
 259     sources -= [ "user_agent.cc" ]
 260     assert(false, "Need to add lots of conditions here")
 261   }
 262
 263   if (use_ozone) {
 264     deps += [
 265       "//ui/ozone:ozone",
 266       "//ui/ozone:ozone_base",
 267       "//ui/ozone/gpu",
 268     ]
 269   } else {
 270     sources -= [
 271       "cursors/webcursor_ozone.cc",
 272       "font_list_ozone.cc",
 273       "gpu/client/gpu_memory_buffer_impl_ozone_native_buffer.cc",
 274       "gpu/client/gpu_memory_buffer_impl_ozone_native_buffer.h",
 275       "gpu/gpu_memory_buffer_factory_ozone_native_buffer.cc",
 276       "gpu/gpu_memory_buffer_factory_ozone_native_buffer.h",
 277     ]
 278   }
 279
 280   if (!use_aura) {
 281     sources -= [ "cursors/webcursor_aura.cc" ]
 282   }
 283
 284   if (!use_aura || !use_x11) {
 285     sources -= [ "cursors/webcursor_aurax11.cc" ]
 286   }
 287
 288   if (use_pango) {
 289     configs += [ "//build/config/linux:pangocairo" ]
 290     if (use_ozone) {
 291       # If we're using pango, never use this ozone file (it was removed in all
 292       # non-ozone cases above).
 293       sources -= [ "font_list_ozone.cc" ]
 294     }
 295   } else {
 296     sources -= [ "font_list_pango.cc" ]
 297   }
 298
 299   if (use_x11) {
 300     configs += [
 301       "//build/config/linux:xcomposite",
 302       "//third_party/khronos:khronos_headers",
 303     ]
 304
 305     if (current_cpu != "arm" || !is_chromeos) {
 306       sources += [ "gpu/x_util.h" ]
 307     }
 308   }
 309
 310   if (enable_plugins) {
 311     deps += [ "//ppapi/shared_impl" ]
 312   } else {
 313     sources -= [
 314       "pepper_file_util.cc",
 315       "pepper_file_util.h",
 316       "pepper_messages.h",
 317       "pepper_plugin_list.cc",
 318       "pepper_plugin_list.h",
 319       "pepper_renderer_instance_data.cc",
 320       "pepper_renderer_instance_data.h",
 321       "plugin_list.cc",
 322       "plugin_list.h",
 323       "plugin_list_posix.cc",
 324       "sandbox_util.cc",
 325     ]
 326   }
 327
 328   if (is_android) {
 329     sources += [
 330       "gpu/media/android_video_decode_accelerator.cc",
 331       "gpu/media/android_video_decode_accelerator.h",
 332     ]
 333
 334     if (enable_webrtc) {
 335       deps += [ "//third_party/libyuv" ]
 336     }
 337   }
 338
 339   if (is_chromeos) {
 340     sources += [
 341       "gpu/media/accelerated_video_decoder.h",
 342       "gpu/media/h264_decoder.cc",
 343       "gpu/media/h264_decoder.h",
 344       "gpu/media/h264_dpb.cc",
 345       "gpu/media/h264_dpb.h",
 346     ]
 347     if (use_v4lplugin) {
 348       defines += [ "USE_LIBV4L2" ]
 349       sources += get_target_outputs(":libv4l2_generate_stubs")
 350       deps += [ ":libv4l2_generate_stubs" ]
 351     }
 352     if (use_v4l2_codec) {
 353       defines += [ "USE_V4L2_CODEC" ]
 354       sources += [
 355         "gpu/media/generic_v4l2_device.cc",
 356         "gpu/media/generic_v4l2_device.h",
 357         "gpu/media/v4l2_device.cc",
 358         "gpu/media/v4l2_device.h",
 359         "gpu/media/v4l2_image_processor.cc",
 360         "gpu/media/v4l2_image_processor.h",
 361         "gpu/media/v4l2_slice_video_decode_accelerator.cc",
 362         "gpu/media/v4l2_slice_video_decode_accelerator.h",
 363         "gpu/media/v4l2_video_decode_accelerator.cc",
 364         "gpu/media/v4l2_video_decode_accelerator.h",
 365         "gpu/media/v4l2_video_encode_accelerator.cc",
 366         "gpu/media/v4l2_video_encode_accelerator.h",
 367         "gpu/media/vp8_decoder.cc",
 368         "gpu/media/vp8_decoder.h",
 369         "gpu/media/vp8_picture.cc",
 370         "gpu/media/vp8_picture.h",
 371       ]
 372       libs = [
 373         "EGL",
 374         "GLESv2",
 375       ]
 376     }
 377     if (current_cpu == "arm") {
 378       sources += [
 379         "gpu/media/tegra_v4l2_device.cc",
 380         "gpu/media/tegra_v4l2_device.h",
 381       ]
 382     }
 383     if (current_cpu != "arm") {
 384       sources += [
 385                    "gpu/media/va_surface.h",
 386                    "gpu/media/vaapi_picture.cc",
 387                    "gpu/media/vaapi_picture.h",
 388                    "gpu/media/vaapi_video_decode_accelerator.cc",
 389                    "gpu/media/vaapi_video_decode_accelerator.h",
 390                    "gpu/media/vaapi_video_encode_accelerator.cc",
 391                    "gpu/media/vaapi_video_encode_accelerator.h",
 392                    "gpu/media/vaapi_wrapper.cc",
 393                    "gpu/media/vaapi_wrapper.h",
 394                  ] + get_target_outputs(":libva_generate_stubs")
 395       configs += [
 396         "//third_party/libva:libva_config",
 397         "//third_party/libyuv:libyuv_config",
 398       ]
 399       deps += [
 400         ":libva_generate_stubs",
 401         "//media",
 402         "//third_party/libyuv",
 403       ]
 404       if (use_x11) {
 405         sources += [
 406           "gpu/media/vaapi_tfp_picture.cc",
 407           "gpu/media/vaapi_tfp_picture.h",
 408         ]
 409       }
 410       if (use_ozone) {
 411         sources += [
 412           "gpu/media/vaapi_drm_picture.cc",
 413           "gpu/media/vaapi_drm_picture.h",
 414         ]
 415       }
 416     }
 417   }
 418
 419   if (is_win) {
 420     sources += [
 421       "gpu/media/dxva_video_decode_accelerator.cc",
 422       "gpu/media/dxva_video_decode_accelerator.h",
 423     ]
 424     configs += [ "//third_party/khronos:khronos_headers" ]
 425     deps += [ "//ui/gl" ]
 426     libs += [
 427       "d3d9.lib",
 428       "d3d11.lib",
 429       "dxva2.lib",
 430       "strmiids.lib",
 431       "mf.lib",
 432       "mfplat.lib",
 433       "mfuuid.lib",
 434     ]
 435     ldflags += [
 436       "/DELAYLOAD:d3d9.dll",
 437       "/DELAYLOAD:d3d11.dll",
 438       "/DELAYLOAD:dxva2.dll",
 439       "/DELAYLOAD:mf.dll",
 440       "/DELAYLOAD:mfplat.dll",
 441     ]
 442
 443     # TODO(GYP): extract_xinput action.
 444   }
 445
 446   if (!is_win || !use_aura) {
 447     sources -= [ "cursors/webcursor_aurawin.cc" ]
 448   }
 449
 450   if (use_seccomp_bpf) {
 451     defines += [ "USE_SECCOMP_BPF" ]
 452   } else {
 453     if (is_linux) {
 454       sources -= [
 455         "sandbox_linux/bpf_cros_arm_gpu_policy_linux.cc",
 456         "sandbox_linux/bpf_cros_arm_gpu_policy_linux.h",
 457         "sandbox_linux/bpf_gpu_policy_linux.cc",
 458         "sandbox_linux/bpf_gpu_policy_linux.h",
 459         "sandbox_linux/bpf_ppapi_policy_linux.cc",
 460         "sandbox_linux/bpf_ppapi_policy_linux.h",
 461         "sandbox_linux/bpf_renderer_policy_linux.cc",
 462         "sandbox_linux/bpf_renderer_policy_linux.h",
 463         "sandbox_linux/bpf_utility_policy_linux.cc",
 464         "sandbox_linux/bpf_utility_policy_linux.h",
 465         "sandbox_linux/sandbox_bpf_base_policy_linux.cc",
 466         "sandbox_linux/sandbox_bpf_base_policy_linux.h",
 467       ]
 468     }
 469     if (is_android) {
 470       sources -= [
 471         "sandbox_linux/android/sandbox_bpf_base_policy_android.cc",
 472         "sandbox_linux/android/sandbox_bpf_base_policy_android.h",
 473       ]
 474     }
 475   }
 476
 477   if (is_win && current_cpu == "x64") {
 478     # TODO(jschuh): Remove this after crbug.com/173851 gets fixed.
 479     cflags = [ "/bigobj" ]
 480   }
 481 }
 482
 483 mojom("mojo_bindings") {
 484   sources = [
 485     "application_setup.mojom",
 486     "background_sync_service.mojom",
 487     "geolocation_service.mojom",
 488     "permission_service.mojom",
 489     "presentation/presentation_service.mojom",
 490     "render_frame_setup.mojom",
 491   ]
 492
 493   deps = [
 494     "//content/public/common:mojo_bindings",
 495     "//third_party/mojo/src/mojo/public/interfaces/application:application",
 496   ]
 497 }