chromeos/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/allocator.gni")
   6 import("//build/config/ui.gni")
   7 import("//third_party/protobuf/proto_library.gni")
   8
   9 assert(is_chromeos, "Non-ChromeOS builds must not depend on //chromeos")
  10
  11 gypi_values = exec_script(
  12     "//build/gypi_to_gn.py",
  13     [ rebase_path("chromeos.gyp") ],
  14     "scope",
  15     [ "chromeos.gyp" ])
  16
  17 component("chromeos") {
  18   configs += [
  19     "//net/third_party/nss/ssl:ssl_config",
  20   ]
  21   public_deps = [ "//dbus" ]
  22   deps = [
  23     "//base",
  24     "//base:prefs",
  25     "//base/third_party/dynamic_annotations",
  26     "//chromeos/ime:gencode",
  27     "//components/policy/proto",
  28     "//components/onc",
  29     "//crypto",
  30     "//google_apis",
  31     "//net/third_party/nss/ssl:libssl",
  32     "//third_party/icu",
  33     "//third_party/libxml",
  34     "//third_party/protobuf:protobuf_lite",
  35     "//ui/accelerometer",
  36     "//url",
  37     ":cryptohome_proto",
  38     ":power_manager_proto"
  39   ]
  40   sources = gypi_values.chromeos_sources
  41   defines = [ "CHROMEOS_IMPLEMENTATION" ]
  42 }
  43
  44 static_library("test_support") {
  45   testonly = true
  46   configs += [
  47     "//build/config/linux:dbus",
  48   ]
  49   deps = [
  50     "//testing/gmock",
  51     ":chromeos",
  52     ":cryptohome_proto",
  53     ":power_manager_proto",
  54     ":test_support_without_gmock",
  55   ]
  56   sources = [
  57     "attestation/mock_attestation_flow.cc",
  58     "attestation/mock_attestation_flow.h",
  59     "chromeos_test_utils.cc",
  60     "chromeos_test_utils.h",
  61     "cryptohome/mock_async_method_caller.cc",
  62     "cryptohome/mock_async_method_caller.h",
  63     "cryptohome/mock_homedir_methods.cc",
  64     "cryptohome/mock_homedir_methods.h",
  65     "dbus/mock_cryptohome_client.cc",
  66     "dbus/mock_cryptohome_client.h",
  67     "dbus/mock_lorgnette_manager_client.cc",
  68     "dbus/mock_lorgnette_manager_client.h",
  69     "dbus/mock_session_manager_client.cc",
  70     "dbus/mock_session_manager_client.h",
  71     "dbus/mock_shill_manager_client.cc",
  72     "dbus/mock_shill_manager_client.h",
  73     "dbus/mock_shill_profile_client.cc",
  74     "dbus/mock_shill_profile_client.h",
  75     "dbus/mock_shill_service_client.cc",
  76     "dbus/mock_shill_service_client.h",
  77     "dbus/services/service_provider_test_helper.cc",
  78     "dbus/services/service_provider_test_helper.h",
  79     "disks/mock_disk_mount_manager.cc",
  80     "disks/mock_disk_mount_manager.h",
  81     "login/auth/mock_auth_attempt_state_resolver.cc",
  82     "login/auth/mock_auth_attempt_state_resolver.h",
  83     "login/auth/mock_auth_status_consumer.cc",
  84     "login/auth/mock_auth_status_consumer.h",
  85     "login/auth/mock_authenticator.cc",
  86     "login/auth/mock_authenticator.h",
  87     "login/auth/mock_url_fetchers.cc",
  88     "login/auth/mock_url_fetchers.h",
  89     "network/fake_network_device_handler.cc",
  90     "network/fake_network_device_handler.h",
  91     "network/mock_managed_network_configuration_handler.cc",
  92     "network/mock_managed_network_configuration_handler.h",
  93     "network/onc/onc_test_utils.cc",
  94     "network/onc/onc_test_utils.h",
  95     "system/fake_statistics_provider.cc",
  96     "system/fake_statistics_provider.h",
  97   ]
  98 }
  99
 100 static_library("test_support_without_gmock") {
 101   testonly = true
 102   configs += [
 103     "//build/config/linux:dbus",
 104   ]
 105   deps = [
 106     "//crypto",
 107     ":chromeos",
 108     ":cryptohome_proto",
 109     ":power_manager_proto",
 110   ]
 111   sources = [
 112     "dbus/fake_cros_disks_client.cc",
 113     "dbus/fake_cros_disks_client.h",
 114     "dbus/fake_power_manager_client.cc",
 115     "dbus/fake_power_manager_client.h",
 116     "dbus/fake_session_manager_client.cc",
 117     "dbus/fake_session_manager_client.h",
 118     "dbus/fake_shill_manager_client.cc",
 119     "dbus/fake_shill_manager_client.h",
 120     "dbus/fake_update_engine_client.cc",
 121     "dbus/fake_update_engine_client.h",
 122   ]
 123 }
 124
 125 test("chromeos_unittests") {
 126   configs += [
 127     "//build/config/linux:dbus",
 128     "//net/third_party/nss/ssl:ssl_config",
 129   ]
 130   deps = [
 131     "//base/test:run_all_unittests",
 132     "//base/test:test_support",
 133     "//components/onc",
 134     "//content/test:test_support",
 135     "//crypto",
 136     "//crypto:test_support",
 137     "//dbus:test_support",
 138     "//google_apis",
 139     "//net",
 140     "//net:test_support",
 141     "//testing/gmock",
 142     "//testing/gtest",
 143     "//url",
 144     ":cryptohome_proto",
 145     ":power_manager_proto",
 146     ":test_support",
 147   ]
 148   sources = gypi_values.chromeos_test_sources
 149   if (use_allocator != "none") {
 150     deps += [ "//base/allocator" ]
 151   }
 152   if (use_x11) {
 153     deps += [ "//ui/gfx/x" ]
 154   }
 155 }
 156
 157 proto_library("power_manager_proto") {
 158   sources = [
 159     "//third_party/cros_system_api/dbus/power_manager/input_event.proto",
 160     "//third_party/cros_system_api/dbus/power_manager/peripheral_battery_status.proto",
 161     "//third_party/cros_system_api/dbus/power_manager/policy.proto",
 162     "//third_party/cros_system_api/dbus/power_manager/power_supply_properties.proto",
 163     "//third_party/cros_system_api/dbus/power_manager/suspend.proto",
 164   ]
 165
 166   proto_out_dir = "chromeos/dbus/power_manager"
 167 }
 168
 169 proto_library("cryptohome_proto") {
 170   sources = [
 171     "//third_party/cros_system_api/dbus/cryptohome/key.proto",
 172     "//third_party/cros_system_api/dbus/cryptohome/rpc.proto",
 173   ]
 174
 175   proto_out_dir = "chromeos/dbus/cryptohome"
 176 }
 177
 178 proto_library("cryptohome_signkey_proto") {
 179   sources = [
 180     "//third_party/cros_system_api/dbus/cryptohome/signed_secret.proto",
 181   ]
 182
 183   proto_out_dir = "chromeos/cryptohome"
 184 }