ui/app_list/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/ui.gni")
   6 import("//testing/test.gni")
   7
   8 component("app_list") {
   9   sources = [
  10     "app_list_constants.cc",
  11     "app_list_constants.h",
  12     "app_list_export.h",
  13     "app_list_folder_item.cc",
  14     "app_list_folder_item.h",
  15     "app_list_item.cc",
  16     "app_list_item.h",
  17     "app_list_item_list.cc",
  18     "app_list_item_list.h",
  19     "app_list_item_list_observer.h",
  20     "app_list_item_observer.h",
  21     "app_list_menu.cc",
  22     "app_list_menu.h",
  23     "app_list_model.cc",
  24     "app_list_model.h",
  25     "app_list_model_observer.h",
  26     "app_list_switches.cc",
  27     "app_list_switches.h",
  28     "app_list_view_delegate.cc",
  29     "app_list_view_delegate.h",
  30     "folder_image.cc",
  31     "folder_image.h",
  32     "pagination_controller.cc",
  33     "pagination_controller.h",
  34     "pagination_model.cc",
  35     "pagination_model.h",
  36     "pagination_model_observer.h",
  37     "search/dictionary_data_store.cc",
  38     "search/dictionary_data_store.h",
  39     "search/history.cc",
  40     "search/history.h",
  41     "search/history_data.cc",
  42     "search/history_data.h",
  43     "search/history_data_store.cc",
  44     "search/history_data_store.h",
  45     "search/history_types.h",
  46     "search/mixer.cc",
  47     "search/mixer.h",
  48     "search/term_break_iterator.cc",
  49     "search/term_break_iterator.h",
  50     "search/tokenized_string.cc",
  51     "search/tokenized_string.h",
  52     "search/tokenized_string_char_iterator.cc",
  53     "search/tokenized_string_char_iterator.h",
  54     "search/tokenized_string_match.cc",
  55     "search/tokenized_string_match.h",
  56     "search_box_model.cc",
  57     "search_box_model.h",
  58     "search_box_model_observer.h",
  59     "search_controller.cc",
  60     "search_controller.h",
  61     "search_provider.cc",
  62     "search_provider.h",
  63     "search_result.cc",
  64     "search_result.h",
  65     "speech_ui_model.cc",
  66     "speech_ui_model.h",
  67     "speech_ui_model_observer.h",
  68   ]
  69
  70   defines = [ "APP_LIST_IMPLEMENTATION" ]
  71
  72   deps = [
  73     "//base",
  74     "//base:i18n",
  75     "//base/third_party/dynamic_annotations",
  76     "//components/keyed_service/core",
  77     "//skia",
  78     "//sync",
  79     "//third_party/icu",
  80     "//ui/accessibility",
  81     "//ui/base",
  82     "//ui/base/ime",
  83     "//ui/compositor",
  84     "//ui/events:events_base",
  85     "//ui/gfx",
  86     "//ui/gfx/geometry",
  87     "//ui/resources",
  88     "//ui/strings",
  89   ]
  90
  91   if (use_aura) {
  92     deps += [
  93       "//ui/aura",
  94       "//ui/wm",
  95     ]
  96   }
  97
  98   if (toolkit_views) {
  99     sources += [
 100       "views/all_apps_tile_item_view.cc",
 101       "views/all_apps_tile_item_view.h",
 102       "views/app_list_background.cc",
 103       "views/app_list_background.h",
 104       "views/app_list_drag_and_drop_host.h",
 105       "views/app_list_folder_view.cc",
 106       "views/app_list_folder_view.h",
 107       "views/app_list_item_view.cc",
 108       "views/app_list_item_view.h",
 109       "views/app_list_main_view.cc",
 110       "views/app_list_main_view.h",
 111       "views/app_list_menu_views.cc",
 112       "views/app_list_menu_views.h",
 113       "views/app_list_page.cc",
 114       "views/app_list_page.h",
 115       "views/app_list_view.cc",
 116       "views/app_list_view.h",
 117       "views/app_list_view_observer.h",
 118       "views/apps_container_view.cc",
 119       "views/apps_container_view.h",
 120       "views/apps_grid_view.cc",
 121       "views/apps_grid_view.h",
 122       "views/apps_grid_view_delegate.h",
 123       "views/apps_grid_view_folder_delegate.h",
 124       "views/cached_label.cc",
 125       "views/cached_label.h",
 126       "views/contents_view.cc",
 127       "views/contents_view.h",
 128       "views/custom_launcher_page_view.cc",
 129       "views/custom_launcher_page_view.h",
 130       "views/folder_background_view.cc",
 131       "views/folder_background_view.h",
 132       "views/folder_header_view.cc",
 133       "views/folder_header_view.h",
 134       "views/folder_header_view_delegate.h",
 135       "views/page_switcher.cc",
 136       "views/page_switcher.h",
 137       "views/progress_bar_view.cc",
 138       "views/progress_bar_view.h",
 139       "views/pulsing_block_view.cc",
 140       "views/pulsing_block_view.h",
 141       "views/search_box_view.cc",
 142       "views/search_box_view.h",
 143       "views/search_box_view_delegate.h",
 144       "views/search_result_actions_view.cc",
 145       "views/search_result_actions_view.h",
 146       "views/search_result_container_view.cc",
 147       "views/search_result_container_view.h",
 148       "views/search_result_list_view.cc",
 149       "views/search_result_list_view.h",
 150       "views/search_result_list_view_delegate.h",
 151       "views/search_result_page_view.cc",
 152       "views/search_result_page_view.h",
 153       "views/search_result_tile_item_list_view.cc",
 154       "views/search_result_tile_item_list_view.h",
 155       "views/search_result_tile_item_view.cc",
 156       "views/search_result_tile_item_view.h",
 157       "views/search_result_view.cc",
 158       "views/search_result_view.h",
 159       "views/speech_view.cc",
 160       "views/speech_view.h",
 161       "views/start_page_view.cc",
 162       "views/start_page_view.h",
 163       "views/tile_item_view.cc",
 164       "views/tile_item_view.h",
 165       "views/top_icon_animation_view.cc",
 166       "views/top_icon_animation_view.h",
 167     ]
 168     deps += [
 169       "//ui/events",
 170       "//ui/views",
 171     ]
 172   }
 173
 174   if (is_mac) {
 175     sources += [
 176       "cocoa/app_list_pager_view.h",
 177       "cocoa/app_list_pager_view.mm",
 178       "cocoa/app_list_view_controller.h",
 179       "cocoa/app_list_view_controller.mm",
 180       "cocoa/app_list_window_controller.h",
 181       "cocoa/app_list_window_controller.mm",
 182       "cocoa/apps_collection_view_drag_manager.h",
 183       "cocoa/apps_collection_view_drag_manager.mm",
 184       "cocoa/apps_grid_controller.h",
 185       "cocoa/apps_grid_controller.mm",
 186       "cocoa/apps_grid_view_item.h",
 187       "cocoa/apps_grid_view_item.mm",
 188       "cocoa/apps_pagination_model_observer.h",
 189       "cocoa/apps_search_box_controller.h",
 190       "cocoa/apps_search_box_controller.mm",
 191       "cocoa/apps_search_results_controller.h",
 192       "cocoa/apps_search_results_controller.mm",
 193       "cocoa/apps_search_results_model_bridge.h",
 194       "cocoa/apps_search_results_model_bridge.mm",
 195       "cocoa/item_drag_controller.h",
 196       "cocoa/item_drag_controller.mm",
 197       "cocoa/scroll_view_with_no_scrollbars.h",
 198       "cocoa/scroll_view_with_no_scrollbars.mm",
 199     ]
 200     deps += [ "//third_party/google_toolbox_for_mac" ]
 201     libs = [ "QuartzCore.framework" ]
 202   }
 203 }
 204
 205 static_library("test_support") {
 206   sources = [
 207     "test/app_list_test_model.cc",
 208     "test/app_list_test_model.h",
 209     "test/app_list_test_view_delegate.cc",
 210     "test/app_list_test_view_delegate.h",
 211     "test/test_search_result.cc",
 212     "test/test_search_result.h",
 213   ]
 214
 215   deps = [
 216     ":app_list",
 217     "//base",
 218     "//ui/gfx",
 219     "//ui/gfx/geometry",
 220     "//ui/resources",
 221   ]
 222 }
 223
 224 if (is_linux && !is_chromeos) {
 225   # TODO(GYP): Figure out which of these work and are needed on other platforms.
 226   if (toolkit_views) {
 227     executable("app_list_demo") {
 228       testonly = true
 229
 230       sources = [
 231         "demo/app_list_demo_views.cc",
 232       ]
 233
 234       deps = [
 235         ":app_list",
 236         ":test_support",
 237         "//base",
 238         "//content",
 239         "//content/public/browser",
 240         "//skia",
 241         "//url",
 242         "//ui/base",
 243         "//ui/events",
 244         "//ui/resources",
 245         "//ui/resources:ui_test_pak",
 246         "//ui/views",
 247         "//ui/views_content_client",
 248         "//ui/views/controls/webview",
 249       ]
 250       if (is_win) {
 251         configs -= [ "//build/config/win:console" ]
 252         configs += [ "//build/config/win:windowed" ]
 253
 254         deps += [
 255           "//sandbox",
 256           "//content:content_startup_helper_win",
 257         ]
 258       }
 259     }
 260   }
 261 }
 262
 263 test("app_list_unittests") {
 264   sources = [
 265     "app_list_item_list_unittest.cc",
 266     "app_list_model_unittest.cc",
 267     "folder_image_unittest.cc",
 268     "pagination_model_unittest.cc",
 269     "search/history_data_store_unittest.cc",
 270     "search/mixer_unittest.cc",
 271     "search/term_break_iterator_unittest.cc",
 272     "search/tokenized_string_char_iterator_unittest.cc",
 273     "search/tokenized_string_match_unittest.cc",
 274     "search/tokenized_string_unittest.cc",
 275     "test/run_all_unittests.cc",
 276   ]
 277
 278   configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
 279
 280   deps = [
 281     ":app_list",
 282     ":test_support",
 283     "//base",
 284     "//base/test:test_support",
 285     "//skia",
 286     "//testing/gtest",
 287     "//ui/base",
 288     "//ui/compositor",
 289     "//ui/events",
 290     "//ui/events:test_support",
 291     "//ui/gl",
 292     "//ui/resources",
 293     "//ui/resources:ui_test_pak",
 294   ]
 295
 296   if (toolkit_views) {
 297     sources += [
 298       "views/app_list_main_view_unittest.cc",
 299       "views/app_list_view_unittest.cc",
 300       "views/apps_grid_view_unittest.cc",
 301       "views/folder_header_view_unittest.cc",
 302       "views/search_box_view_unittest.cc",
 303       "views/search_result_list_view_unittest.cc",
 304       "views/speech_view_unittest.cc",
 305       "views/test/apps_grid_view_test_api.cc",
 306       "views/test/apps_grid_view_test_api.h",
 307     ]
 308     deps += [
 309       "//ui/views",
 310       "//ui/views:test_support",
 311     ]
 312   }
 313
 314   if (is_mac) {
 315     sources += [
 316       "cocoa/app_list_view_controller_unittest.mm",
 317       "cocoa/app_list_window_controller_unittest.mm",
 318       "cocoa/apps_grid_controller_unittest.mm",
 319       "cocoa/apps_search_box_controller_unittest.mm",
 320       "cocoa/apps_search_results_controller_unittest.mm",
 321       "cocoa/test/apps_grid_controller_test_helper.h",
 322       "cocoa/test/apps_grid_controller_test_helper.mm",
 323     ]
 324   }
 325 }