net/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6 import("//build/config/features.gni")
   7 import("//build/config/ui.gni")
   8 import("//url/config.gni")
   9
  10 # TODO(cjhopman): //build/config/android/rules.gni also imports grit_rule.gni.
  11 # Currently, that file can't be imported multiple times.  Make this always
  12 # imported when http://crbug.com/393704 is fixed.
  13 if (!is_android) {
  14   import("//tools/grit/grit_rule.gni")
  15 }
  16
  17 if (is_android) {
  18   import("//build/config/android/config.gni")
  19   import("//build/config/android/rules.gni")
  20 } else if (is_mac) {
  21   import("//build/config/mac/mac_sdk.gni")
  22 }
  23
  24 # The list of net files is kept in net.gypi. Read it.
  25 gypi_values = exec_script(
  26     "//build/gypi_to_gn.py",
  27     [ rebase_path("net.gypi") ],
  28     "scope",
  29     [ "net.gypi" ])
  30
  31 # Disable Kerberos on ChromeOS, Android and iOS, at least for now. It needs
  32 # configuration (krb5.conf and so on).
  33 use_kerberos = !is_chromeos && !is_android && !is_ios
  34
  35 # The way the cache uses mmap() is inefficient on some Android devices. If
  36 # this flag is set, we hackily avoid using mmap() in the disk cache. We are
  37 # pretty confident that mmap-ing the index would not hurt any existing x86
  38 # android devices, but we cannot be so sure about the variety of ARM devices.
  39 # So enable it for x86 only for now.
  40 posix_avoid_mmap = is_android && cpu_arch != "x86"
  41
  42 # WebSockets and socket stream code are used everywhere except iOS.
  43 enable_websockets = !is_ios
  44 use_v8_in_net = !is_ios
  45 enable_built_in_dns = !is_ios
  46 disable_ftp_support = is_ios
  47
  48 declare_args() {
  49   # Disables support for file URLs.  File URL support requires use of icu.
  50   disable_file_support = false
  51 }
  52
  53 config("net_config") {
  54   defines = []
  55   if (posix_avoid_mmap) {
  56     defines += [ "POSIX_AVOID_MMAP" ]
  57   }
  58   if (disable_file_support) {
  59     defines += [ "DISABLE_FILE_SUPPORT" ]
  60   }
  61 }
  62
  63 # Disables Windows warning about size to int truncations.
  64 # TODO(jschuh): crbug.com/167187 fix this and delete this config.
  65 config("net_win_size_truncation") {
  66   if (is_win) {
  67     cflags = [ "/wd4267" ]
  68   }
  69 }
  70
  71 component("net") {
  72   sources =
  73     gypi_values.net_nacl_common_sources +
  74     gypi_values.net_non_nacl_sources
  75
  76   cflags = []
  77   defines = [
  78     # TODO(GYP) Note that he GYP file supports linux_link_kerberos (defaults to
  79     # 0) which implies that we run pkg_config on kerberos and link to that
  80     # rather than setting this define which will dynamically open it. That
  81     # doesn't seem to be set in the regular builds, so we're skipping this
  82     # capability here.
  83     "DLOPEN_KERBEROS",
  84     "NET_IMPLEMENTATION"
  85   ]
  86   configs += [ ":net_win_size_truncation" ]
  87   public_configs = [ ":net_config" ]
  88   include_dirs = []
  89
  90   public_deps = [
  91     "//crypto",
  92     "//crypto:platform"
  93   ]
  94   deps = [
  95    ":net_resources",
  96     "//base",
  97     "//base:i18n",
  98     "//base:prefs",
  99     "//base/third_party/dynamic_annotations",
 100     "//net/base/registry_controlled_domains",
 101     "//sdch",
 102     "//third_party/icu",
 103     "//third_party/zlib",
 104     "//url",
 105   ]
 106
 107   if (use_kerberos) {
 108     defines += [ "USE_KERBEROS" ]
 109     if (is_android) {
 110       include_dirs += [ "/usr/include/kerberosV" ]
 111     }
 112   } else {
 113     sources -= [
 114       "http/http_auth_gssapi_posix.cc",
 115       "http/http_auth_gssapi_posix.h",
 116       "http/http_auth_handler_negotiate.h",
 117       "http/http_auth_handler_negotiate.cc",
 118     ]
 119   }
 120
 121   if (is_posix) {
 122     if (posix_avoid_mmap) {
 123       sources -= [ "disk_cache/blockfile/mapped_file_posix.cc" ]
 124     } else {
 125       sources -= [ "disk_cache/blockfile/mapped_file_avoid_mmap_posix.cc" ]
 126     }
 127   }
 128
 129   if (disable_file_support) {
 130     sources -= [
 131       "base/directory_lister.cc",
 132       "base/directory_lister.h",
 133       "url_request/url_request_file_dir_job.cc",
 134       "url_request/url_request_file_dir_job.h",
 135       "url_request/url_request_file_job.cc",
 136       "url_request/url_request_file_job.h",
 137       "url_request/file_protocol_handler.cc",
 138       "url_request/file_protocol_handler.h",
 139     ]
 140   }
 141
 142   if (disable_ftp_support) {
 143     sources -= [
 144       "ftp/ftp_auth_cache.cc",
 145       "ftp/ftp_auth_cache.h",
 146       "ftp/ftp_ctrl_response_buffer.cc",
 147       "ftp/ftp_ctrl_response_buffer.h",
 148       "ftp/ftp_directory_listing_parser.cc",
 149       "ftp/ftp_directory_listing_parser.h",
 150       "ftp/ftp_directory_listing_parser_ls.cc",
 151       "ftp/ftp_directory_listing_parser_ls.h",
 152       "ftp/ftp_directory_listing_parser_netware.cc",
 153       "ftp/ftp_directory_listing_parser_netware.h",
 154       "ftp/ftp_directory_listing_parser_os2.cc",
 155       "ftp/ftp_directory_listing_parser_os2.h",
 156       "ftp/ftp_directory_listing_parser_vms.cc",
 157       "ftp/ftp_directory_listing_parser_vms.h",
 158       "ftp/ftp_directory_listing_parser_windows.cc",
 159       "ftp/ftp_directory_listing_parser_windows.h",
 160       "ftp/ftp_network_layer.cc",
 161       "ftp/ftp_network_layer.h",
 162       "ftp/ftp_network_session.cc",
 163       "ftp/ftp_network_session.h",
 164       "ftp/ftp_network_transaction.cc",
 165       "ftp/ftp_network_transaction.h",
 166       "ftp/ftp_request_info.h",
 167       "ftp/ftp_response_info.cc",
 168       "ftp/ftp_response_info.h",
 169       "ftp/ftp_server_type_histograms.cc",
 170       "ftp/ftp_server_type_histograms.h",
 171       "ftp/ftp_transaction.h",
 172       "ftp/ftp_transaction_factory.h",
 173       "ftp/ftp_util.cc",
 174       "ftp/ftp_util.h",
 175       "url_request/ftp_protocol_handler.cc",
 176       "url_request/ftp_protocol_handler.h",
 177       "url_request/url_request_ftp_job.cc",
 178       "url_request/url_request_ftp_job.h",
 179     ]
 180   }
 181
 182   if (enable_built_in_dns) {
 183     defines += [ "ENABLE_BUILT_IN_DNS" ]
 184   } else {
 185     sources -= [
 186       "dns/address_sorter_posix.cc",
 187       "dns/address_sorter_posix.h",
 188       "dns/dns_client.cc",
 189     ]
 190   }
 191
 192   if (use_openssl) {
 193     sources -= [
 194       "base/nss_memio.c",
 195       "base/nss_memio.h",
 196       "cert/ct_log_verifier_nss.cc",
 197       "cert/ct_objects_extractor_nss.cc",
 198       "cert/jwk_serializer_nss.cc",
 199       "cert/scoped_nss_types.h",
 200       "cert/test_root_certs_nss.cc",
 201       "cert/x509_util_nss.cc",
 202       "cert/x509_util_nss.h",
 203       "ocsp/nss_ocsp.cc",
 204       "ocsp/nss_ocsp.h",
 205       "quic/crypto/aead_base_decrypter_nss.cc",
 206       "quic/crypto/aead_base_encrypter_nss.cc",
 207       "quic/crypto/aes_128_gcm_12_decrypter_nss.cc",
 208       "quic/crypto/aes_128_gcm_12_encrypter_nss.cc",
 209       "quic/crypto/chacha20_poly1305_decrypter_nss.cc",
 210       "quic/crypto/chacha20_poly1305_encrypter_nss.cc",
 211       "quic/crypto/channel_id_nss.cc",
 212       "quic/crypto/p256_key_exchange_nss.cc",
 213       "socket/nss_ssl_util.cc",
 214       "socket/nss_ssl_util.h",
 215       "socket/ssl_client_socket_nss.cc",
 216       "socket/ssl_client_socket_nss.h",
 217       "socket/ssl_server_socket_nss.cc",
 218       "socket/ssl_server_socket_nss.h",
 219     ]
 220     if (is_chromeos) {
 221       sources -= [
 222         "cert/nss_cert_database_chromeos.cc",
 223         "cert/nss_cert_database_chromeos.h",
 224         "cert/nss_profile_filter_chromeos.cc",
 225         "cert/nss_profile_filter_chromeos.h",
 226       ]
 227     }
 228     if (is_linux) {
 229       # These are always removed for non-Linux cases below.
 230       sources -= [
 231         "base/crypto_module_nss.cc",
 232         "base/keygen_handler_nss.cc",
 233         "cert/cert_database_nss.cc",
 234         "cert/nss_cert_database.cc",
 235         "cert/nss_cert_database.h",
 236         "cert/x509_certificate_nss.cc",
 237         "third_party/mozilla_security_manager/nsKeygenHandler.cpp",
 238         "third_party/mozilla_security_manager/nsKeygenHandler.h",
 239         "third_party/mozilla_security_manager/nsNSSCertificateDB.cpp",
 240         "third_party/mozilla_security_manager/nsNSSCertificateDB.h",
 241         "third_party/mozilla_security_manager/nsPKCS12Blob.cpp",
 242         "third_party/mozilla_security_manager/nsPKCS12Blob.h",
 243       ]
 244     }
 245     if (is_ios) {
 246       # Always removed for !ios below.
 247       sources -= [
 248         "cert/cert_verify_proc_nss.cc",
 249         "cert/cert_verify_proc_nss.h",
 250       ]
 251     }
 252     if (is_win) {
 253       sources -= [
 254         "cert/cert/sha256_legacy_support_nss_win.cc",
 255       ]
 256     }
 257   } else {
 258     sources -= [
 259       "base/crypto_module_openssl.cc",
 260       "cert/ct_log_verifier_openssl.cc",
 261       "cert/ct_objects_extractor_openssl.cc",
 262       "cert/jwk_serializer_openssl.cc",
 263       "cert/x509_util_openssl.cc",
 264       "cert/x509_util_openssl.h",
 265       "quic/crypto/aead_base_decrypter_openssl.cc",
 266       "quic/crypto/aead_base_encrypter_openssl.cc",
 267       "quic/crypto/aes_128_gcm_12_decrypter_openssl.cc",
 268       "quic/crypto/aes_128_gcm_12_encrypter_openssl.cc",
 269       "quic/crypto/chacha20_poly1305_decrypter_openssl.cc",
 270       "quic/crypto/chacha20_poly1305_encrypter_openssl.cc",
 271       "quic/crypto/channel_id_openssl.cc",
 272       "quic/crypto/p256_key_exchange_openssl.cc",
 273       "quic/crypto/scoped_evp_aead_ctx.cc",
 274       "quic/crypto/scoped_evp_aead_ctx.h",
 275       "socket/ssl_client_socket_openssl.cc",
 276       "socket/ssl_client_socket_openssl.h",
 277       "socket/ssl_server_socket_openssl.cc",
 278       "socket/ssl_server_socket_openssl.h",
 279       "socket/ssl_session_cache_openssl.cc",
 280       "socket/ssl_session_cache_openssl.h",
 281       "ssl/openssl_platform_key.h",
 282       "ssl/openssl_ssl_util.cc",
 283       "ssl/openssl_ssl_util.h",
 284     ]
 285     if (is_mac) {
 286       sources -= [
 287         "ssl/openssl_platform_key_mac.cc",
 288       ]
 289     }
 290     if (is_win) {
 291       sources -= [
 292         "cert/sha256_legacy_support_openssl_win.cc",
 293         "ssl/openssl_platform_key_win.cc",
 294       ]
 295     }
 296   }
 297
 298   if (!use_openssl_certs) {
 299     sources -= [
 300       "base/keygen_handler_openssl.cc",
 301       "base/openssl_private_key_store.h",
 302       "base/openssl_private_key_store_memory.cc",
 303       "cert/cert_database_openssl.cc",
 304       "cert/cert_verify_proc_openssl.cc",
 305       "cert/cert_verify_proc_openssl.h",
 306       "cert/test_root_certs_openssl.cc",
 307       "cert/x509_certificate_openssl.cc",
 308       "ssl/openssl_client_key_store.cc",
 309       "ssl/openssl_client_key_store.h",
 310     ]
 311     if (is_android) {
 312       sources -= [
 313         "base/openssl_private_key_store_android.cc",
 314       ]
 315     }
 316   } else if (is_android) {
 317     # Android doesn't use these even when using OpenSSL.
 318     sources -= [
 319       "base/openssl_private_key_store_memory.cc",
 320       "cert/cert_database_openssl.cc",
 321       "cert/cert_verify_proc_openssl.cc",
 322       "cert/test_root_certs_openssl.cc",
 323     ]
 324   }
 325
 326   if (use_glib && !is_chromeos) {
 327     configs += [ "//build/config/linux:gconf" ]
 328     deps += [ "//build/config/linux:gio" ]
 329   }
 330
 331   if (is_linux) {
 332     configs += [ "//build/config/linux:libresolv" ]
 333   } else {
 334     sources -= [
 335       "base/crypto_module_nss.cc",
 336       "base/keygen_handler_nss.cc",
 337       "cert/cert_database_nss.cc",
 338       "cert/nss_cert_database.cc",
 339       "cert/nss_cert_database.h",
 340       "cert/x509_certificate_nss.cc",
 341       "third_party/mozilla_security_manager/nsKeygenHandler.cpp",
 342       "third_party/mozilla_security_manager/nsKeygenHandler.h",
 343       "third_party/mozilla_security_manager/nsNSSCertificateDB.cpp",
 344       "third_party/mozilla_security_manager/nsNSSCertificateDB.h",
 345       "third_party/mozilla_security_manager/nsPKCS12Blob.cpp",
 346       "third_party/mozilla_security_manager/nsPKCS12Blob.h",
 347     ]
 348
 349     if (!is_ios && !use_openssl) {
 350       # These files are part of the partial implementation of NSS on iOS so
 351       # keep them in that case.
 352       sources -= [
 353         "cert/test_root_certs_nss.cc",
 354         "ocsp/nss_ocsp.cc",
 355         "ocsp/nss_ocsp.h",
 356       ]
 357     }
 358   }
 359
 360   if (!use_nss_certs) {
 361     sources -= [
 362       "ssl/client_cert_store_nss.cc",
 363       "ssl/client_cert_store_nss.h",
 364     ]
 365     if (!is_ios) {
 366       # These files are part of the partial implementation of NSS on iOS so
 367       # keep them in that case (even though use_nss_certs is not set).
 368       sources -= [
 369         "cert/cert_verify_proc_nss.cc",
 370         "cert/cert_verify_proc_nss.h",
 371       ]
 372     }
 373     if (is_chromeos) {
 374       # These were already removed on non-ChromeOS.
 375       sources -= [
 376         "ssl/client_cert_store_chromeos.cc",
 377         "ssl/client_cert_store_chromeos.h",
 378       ]
 379     }
 380   }
 381
 382   if (!enable_websockets) {
 383     sources -= [
 384       "websockets/websocket_basic_handshake_stream.cc",
 385       "websockets/websocket_basic_handshake_stream.h",
 386       "websockets/websocket_basic_stream.cc",
 387       "websockets/websocket_basic_stream.h",
 388       "websockets/websocket_channel.cc",
 389       "websockets/websocket_channel.h",
 390       "websockets/websocket_deflate_predictor.h",
 391       "websockets/websocket_deflate_predictor_impl.cc",
 392       "websockets/websocket_deflate_predictor_impl.h",
 393       "websockets/websocket_deflate_stream.cc",
 394       "websockets/websocket_deflate_stream.h",
 395       "websockets/websocket_deflater.cc",
 396       "websockets/websocket_deflater.h",
 397       "websockets/websocket_errors.cc",
 398       "websockets/websocket_errors.h",
 399       "websockets/websocket_extension.cc",
 400       "websockets/websocket_extension.h",
 401       "websockets/websocket_extension_parser.cc",
 402       "websockets/websocket_extension_parser.h",
 403       "websockets/websocket_frame.cc",
 404       "websockets/websocket_frame.h",
 405       "websockets/websocket_frame_parser.cc",
 406       "websockets/websocket_frame_parser.h",
 407       "websockets/websocket_handshake_constants.cc",
 408       "websockets/websocket_handshake_constants.h",
 409       "websockets/websocket_handshake_handler.cc",
 410       "websockets/websocket_handshake_handler.h",
 411       "websockets/websocket_handshake_request_info.cc",
 412       "websockets/websocket_handshake_request_info.h",
 413       "websockets/websocket_handshake_response_info.cc",
 414       "websockets/websocket_handshake_response_info.h",
 415       "websockets/websocket_handshake_stream_base.h",
 416       "websockets/websocket_handshake_stream_create_helper.cc",
 417       "websockets/websocket_handshake_stream_create_helper.h",
 418       "websockets/websocket_inflater.cc",
 419       "websockets/websocket_inflater.h",
 420       "websockets/websocket_mux.h",
 421       "websockets/websocket_stream.cc",
 422       "websockets/websocket_stream.h",
 423     ]
 424   }
 425
 426   if (!enable_mdns) {
 427     sources -= [
 428       "dns/mdns_cache.cc",
 429       "dns/mdns_cache.h",
 430       "dns/mdns_client.cc",
 431       "dns/mdns_client.h",
 432       "dns/mdns_client_impl.cc",
 433       "dns/mdns_client_impl.h",
 434       "dns/record_parsed.cc",
 435       "dns/record_parsed.h",
 436       "dns/record_rdata.cc",
 437       "dns/record_rdata.h",
 438     ]
 439   }
 440
 441   if (is_win) {
 442     sources -= [
 443       "http/http_auth_handler_ntlm_portable.cc",
 444       "socket/socket_libevent.cc",
 445       "socket/socket_libevent.h",
 446       "socket/tcp_socket_libevent.cc",
 447       "socket/tcp_socket_libevent.h",
 448       "udp/udp_socket_libevent.cc",
 449       "udp/udp_socket_libevent.h",
 450     ]
 451   } else {  # !is_win
 452     sources -= [
 453       "base/winsock_init.cc",
 454       "base/winsock_init.h",
 455       "base/winsock_util.cc",
 456       "base/winsock_util.h",
 457       "proxy/proxy_resolver_winhttp.cc",
 458       "proxy/proxy_resolver_winhttp.h",
 459     ]
 460   }
 461
 462   if (is_mac) {
 463     libs = [
 464       "Foundation.framework",
 465       "Security.framework",
 466       "SystemConfiguration.framework",
 467       "resolv",
 468     ]
 469   }
 470
 471   if (is_ios) {
 472     # Add back some sources that were otherwise filtered out. iOS additionally
 473     # doesn't set USE_NSS but needs some of the files.
 474     set_sources_assignment_filter([])
 475     sources += [
 476       "base/network_change_notifier_mac.cc",
 477       "base/network_config_watcher_mac.cc",
 478       "base/platform_mime_util_mac.mm",
 479       "cert/cert_verify_proc_nss.cc",
 480       "cert/cert_verify_proc_nss.h",
 481       "cert/test_root_certs_nss.cc",
 482       "cert/x509_util_nss.cc",
 483       "cert/x509_util_nss.h",
 484       "proxy/proxy_resolver_mac.cc",
 485       "proxy/proxy_server_mac.cc",
 486       "ocsp/nss_ocsp.cc",
 487       "ocsp/nss_ocsp.h",
 488     ]
 489     set_sources_assignment_filter(sources_assignment_filter)
 490
 491     sources -= [ "disk_cache/blockfile/file_posix.cc" ]
 492     libs = [
 493       "CFNetwork.framework",
 494       "MobileCoreServices.framework",
 495       "Security.framework",
 496       "SystemConfiguration.framework",
 497       "resolv",
 498     ]
 499   }
 500
 501   if (is_android) {
 502     # Add some Linux sources that were excluded by the filter, but which
 503     # are needed.
 504     set_sources_assignment_filter([])
 505     sources += [
 506       "base/platform_mime_util_linux.cc",
 507       "base/address_tracker_linux.cc",
 508       "base/address_tracker_linux.h",
 509     ]
 510     set_sources_assignment_filter(sources_assignment_filter)
 511
 512     if (!is_android_webview_build) {
 513       deps += [ ":net_jni_headers" ]
 514     }
 515   }
 516
 517   if (use_icu_alternatives_on_android) {
 518     deps -= [
 519       "//base:i18n",
 520       "//third_party/icu",
 521     ]
 522     sources -= [
 523       "base/filename_util_icu.cc",
 524       "base/net_string_util_icu.cc",
 525       "base/net_util_icu.cc",
 526     ]
 527     sources += [
 528       "base/net_string_util_icu_alternatives_android.cc",
 529       "base/net_string_util_icu_alternatives_android.h",
 530     ]
 531   }
 532 }
 533
 534 grit("net_resources") {
 535   source = "base/net_resources.grd"
 536   use_qualified_include = true
 537   outputs = [
 538     "grit/net_resources.h",
 539     "net_resources.pak",
 540     "net_resources.rc",
 541   ]
 542 }
 543
 544 static_library("extras") {
 545   sources = gypi_values.net_extras_sources
 546   configs += [ "//build/config/compiler:wexit_time_destructors" ]
 547   deps = [
 548     ":net",
 549     "//sql:sql",
 550   ]
 551 }
 552
 553 static_library("http_server") {
 554   sources = [
 555     "server/http_connection.cc",
 556     "server/http_connection.h",
 557     "server/http_server.cc",
 558     "server/http_server.h",
 559     "server/http_server_request_info.cc",
 560     "server/http_server_request_info.h",
 561     "server/http_server_response_info.cc",
 562     "server/http_server_response_info.h",
 563     "server/web_socket.cc",
 564     "server/web_socket.h",
 565   ]
 566   configs += [ "//build/config/compiler:wexit_time_destructors" ]
 567   deps = [
 568     ":net",
 569     "//base",
 570   ]
 571 }
 572
 573 executable("dump_cache") {
 574   testonly = true
 575   sources = [
 576     "tools/dump_cache/cache_dumper.cc",
 577     "tools/dump_cache/cache_dumper.h",
 578     "tools/dump_cache/dump_cache.cc",
 579     "tools/dump_cache/dump_files.cc",
 580     "tools/dump_cache/dump_files.h",
 581     "tools/dump_cache/simple_cache_dumper.cc",
 582     "tools/dump_cache/simple_cache_dumper.h",
 583     "tools/dump_cache/url_to_filename_encoder.cc",
 584     "tools/dump_cache/url_to_filename_encoder.h",
 585     "tools/dump_cache/url_utilities.h",
 586     "tools/dump_cache/url_utilities.cc",
 587   ]
 588
 589   configs += [ ":net_win_size_truncation" ]
 590
 591   deps = [
 592     "//base",
 593     ":net",
 594     ":test_support",
 595   ]
 596 }
 597
 598 source_set("test_support") {
 599   testonly = true
 600   sources = [
 601     "base/capturing_net_log.cc",
 602     "base/capturing_net_log.h",
 603     "base/load_timing_info_test_util.cc",
 604     "base/load_timing_info_test_util.h",
 605     "base/mock_file_stream.cc",
 606     "base/mock_file_stream.h",
 607     "base/test_completion_callback.cc",
 608     "base/test_completion_callback.h",
 609     "base/test_data_directory.cc",
 610     "base/test_data_directory.h",
 611     "cert/mock_cert_verifier.cc",
 612     "cert/mock_cert_verifier.h",
 613     "cookies/cookie_monster_store_test.cc",
 614     "cookies/cookie_monster_store_test.h",
 615     "cookies/cookie_store_test_callbacks.cc",
 616     "cookies/cookie_store_test_callbacks.h",
 617     "cookies/cookie_store_test_helpers.cc",
 618     "cookies/cookie_store_test_helpers.h",
 619     "disk_cache/disk_cache_test_base.cc",
 620     "disk_cache/disk_cache_test_base.h",
 621     "disk_cache/disk_cache_test_util.cc",
 622     "disk_cache/disk_cache_test_util.h",
 623     "dns/dns_test_util.cc",
 624     "dns/dns_test_util.h",
 625     "dns/mock_host_resolver.cc",
 626     "dns/mock_host_resolver.h",
 627     "dns/mock_mdns_socket_factory.cc",
 628     "dns/mock_mdns_socket_factory.h",
 629     "http/http_transaction_test_util.cc",
 630     "http/http_transaction_test_util.h",
 631     "proxy/mock_proxy_resolver.cc",
 632     "proxy/mock_proxy_resolver.h",
 633     "proxy/mock_proxy_script_fetcher.cc",
 634     "proxy/mock_proxy_script_fetcher.h",
 635     "proxy/proxy_config_service_common_unittest.cc",
 636     "proxy/proxy_config_service_common_unittest.h",
 637     "socket/socket_test_util.cc",
 638     "socket/socket_test_util.h",
 639     "test/cert_test_util.cc",
 640     "test/cert_test_util.h",
 641     "test/cert_test_util_nss.cc",
 642     "test/ct_test_util.cc",
 643     "test/ct_test_util.h",
 644     "test/embedded_test_server/embedded_test_server.cc",
 645     "test/embedded_test_server/embedded_test_server.h",
 646     "test/embedded_test_server/http_connection.cc",
 647     "test/embedded_test_server/http_connection.h",
 648     "test/embedded_test_server/http_request.cc",
 649     "test/embedded_test_server/http_request.h",
 650     "test/embedded_test_server/http_response.cc",
 651     "test/embedded_test_server/http_response.h",
 652     "test/net_test_suite.cc",
 653     "test/net_test_suite.h",
 654     "test/python_utils.cc",
 655     "test/python_utils.h",
 656     "test/spawned_test_server/base_test_server.cc",
 657     "test/spawned_test_server/base_test_server.h",
 658     "test/spawned_test_server/local_test_server_posix.cc",
 659     "test/spawned_test_server/local_test_server_win.cc",
 660     "test/spawned_test_server/local_test_server.cc",
 661     "test/spawned_test_server/local_test_server.h",
 662     "test/spawned_test_server/remote_test_server.cc",
 663     "test/spawned_test_server/remote_test_server.h",
 664     "test/spawned_test_server/spawned_test_server.h",
 665     "test/spawned_test_server/spawner_communicator.cc",
 666     "test/spawned_test_server/spawner_communicator.h",
 667     "test/url_request/url_request_failed_job.cc",
 668     "test/url_request/url_request_failed_job.h",
 669     "test/url_request/url_request_mock_http_job.cc",
 670     "test/url_request/url_request_mock_http_job.h",
 671     "url_request/test_url_fetcher_factory.cc",
 672     "url_request/test_url_fetcher_factory.h",
 673     "url_request/test_url_request_interceptor.cc",
 674     "url_request/test_url_request_interceptor.h",
 675     "url_request/url_request_test_util.cc",
 676     "url_request/url_request_test_util.h",
 677   ]
 678
 679   configs += [ ":net_win_size_truncation" ]
 680
 681   public_deps = [
 682     "//base",
 683     "//base/test:test_support",
 684     "//crypto",
 685     "//net",
 686     "//net/tools/tld_cleanup",
 687     "//testing/gmock",
 688     "//testing/gtest",
 689     "//url",
 690   ]
 691
 692   if (!use_openssl && (use_nss_certs || is_ios)) {
 693     public_deps += ["//crypto:platform" ]
 694   }
 695
 696   if (!is_android) {
 697     sources -= [
 698       "test/spawned_test_server/remote_test_server.cc",
 699       "test/spawned_test_server/remote_test_server.h",
 700       "test/spawned_test_server/spawner_communicator.cc",
 701       "test/spawned_test_server/spawner_communicator.h",
 702     ]
 703   }
 704
 705   if (use_v8_in_net) {
 706     public_deps += [ ":net_with_v8" ]
 707   }
 708
 709   if (!enable_mdns) {
 710     sources -= [
 711       "dns/mock_mdns_socket_factory.cc",
 712       "dns/mock_mdns_socket_factory.h",
 713     ]
 714   }
 715
 716   if (!use_nss_certs) {
 717     sources -= [
 718       "test/cert_test_util_nss.cc",
 719     ]
 720   }
 721 }
 722
 723 source_set("balsa") {
 724   sources = [
 725     "tools/balsa/balsa_enums.h",
 726     "tools/balsa/balsa_frame.cc",
 727     "tools/balsa/balsa_frame.h",
 728     "tools/balsa/balsa_headers.cc",
 729     "tools/balsa/balsa_headers.h",
 730     "tools/balsa/balsa_headers_token_utils.cc",
 731     "tools/balsa/balsa_headers_token_utils.h",
 732     "tools/balsa/balsa_visitor_interface.h",
 733     "tools/balsa/http_message_constants.cc",
 734     "tools/balsa/http_message_constants.h",
 735     "tools/balsa/noop_balsa_visitor.h",
 736     "tools/balsa/simple_buffer.cc",
 737     "tools/balsa/simple_buffer.h",
 738     "tools/balsa/split.cc",
 739     "tools/balsa/split.h",
 740     "tools/balsa/string_piece_utils.h",
 741     "tools/quic/spdy_utils.cc",
 742     "tools/quic/spdy_utils.h",
 743   ]
 744   deps = [
 745     ":net",
 746     "//base",
 747     "//url",
 748   ]
 749 }
 750
 751 if (use_v8_in_net) {
 752   component("net_with_v8") {
 753     sources = [
 754       "proxy/proxy_resolver_v8.cc",
 755       "proxy/proxy_resolver_v8.h",
 756       "proxy/proxy_resolver_v8_tracing.cc",
 757       "proxy/proxy_resolver_v8_tracing.h",
 758       "proxy/proxy_service_v8.cc",
 759       "proxy/proxy_service_v8.h",
 760     ]
 761
 762     defines = [ "NET_IMPLEMENTATION" ]
 763     configs += [
 764       ":net_win_size_truncation",
 765       "//build/config/compiler:wexit_time_destructors",
 766     ]
 767
 768     public_deps = [
 769       ":net",
 770     ]
 771     deps = [
 772       "//base",
 773       "//gin",
 774       "//url",
 775       "//v8",
 776     ]
 777   }
 778 }
 779
 780 if (!is_ios && !is_android) {
 781   executable("crash_cache") {
 782     testonly = true
 783     sources = [ "tools/crash_cache/crash_cache.cc" ]
 784     configs += [ ":net_win_size_truncation" ]
 785     deps = [
 786       ":net",
 787       ":test_support",
 788       "//base",
 789     ]
 790   }
 791
 792   executable("crl_set_dump") {
 793     testonly = true
 794     sources = [ "tools/crl_set_dump/crl_set_dump.cc" ]
 795     configs += [ ":net_win_size_truncation" ]
 796     deps = [
 797       ":net",
 798       "//base",
 799     ]
 800   }
 801
 802   executable("dns_fuzz_stub") {
 803     testonly = true
 804     sources = [ "tools/dns_fuzz_stub/dns_fuzz_stub.cc" ]
 805     configs += [ ":net_win_size_truncation" ]
 806     deps = [
 807       ":net",
 808       "//base",
 809     ]
 810   }
 811
 812   executable("gdig") {
 813     testonly = true
 814     sources = [
 815       "tools/gdig/file_net_log.cc",
 816       "tools/gdig/gdig.cc",
 817     ]
 818     deps = [
 819       ":net",
 820       "//base",
 821     ]
 822   }
 823
 824   executable("get_server_time") {
 825     testonly = true
 826     sources = [ "tools/get_server_time/get_server_time.cc" ]
 827     configs += [ ":net_win_size_truncation" ]
 828     deps = [
 829       ":net",
 830       "//base",
 831       "//base:i18n",
 832       "//url",
 833     ]
 834   }
 835
 836   if (use_v8_in_net) {
 837     executable("net_watcher") {
 838       testonly = true
 839       sources = [ "tools/net_watcher/net_watcher.cc" ]
 840       deps = [
 841         ":net",
 842         ":net_with_v8",
 843         "//base",
 844       ]
 845
 846       if (is_desktop_linux) {
 847         configs += [
 848           "//build/config/linux:gconf",
 849           "//build/config/linux:glib",
 850         ]
 851         deps += [ "//build/config/linux:gio" ]
 852       }
 853     }
 854   }
 855
 856   executable("run_testserver") {
 857     testonly = true
 858     sources = [ "tools/testserver/run_testserver.cc" ]
 859     deps = [
 860       ":net",  # TODO(brettw) bug 363749: this shouldn't be necessary. It's not
 861                # in the GYP build, and can be removed when the bug is fixed.
 862       ":test_support",
 863       "//base",
 864       "//base/test:test_support",
 865       "//testing/gtest",
 866     ]
 867   }
 868
 869   executable("stress_cache") {
 870     testonly = true
 871     sources = [ "disk_cache/blockfile/stress_cache.cc" ]
 872     configs += [ ":net_win_size_truncation" ]
 873     deps = [
 874       ":net",
 875       ":test_support",
 876       "//base",
 877     ]
 878   }
 879
 880   executable("tld_cleanup") {
 881     sources = [ "tools/tld_cleanup/tld_cleanup.cc" ]
 882     configs += [ ":net_win_size_truncation" ]
 883     deps = [
 884       "//base",
 885       "//base:i18n",
 886       "//net/tools/tld_cleanup",
 887     ]
 888   }
 889 }
 890
 891 if (is_linux) {
 892   static_library("epoll_server") {
 893     sources = [
 894       "tools/epoll_server/epoll_server.cc",
 895       "tools/epoll_server/epoll_server.h",
 896     ]
 897     deps = [
 898       ":net",
 899       "//base",
 900     ]
 901   }
 902
 903   static_library("flip_in_mem_edsm_server_base") {
 904     testonly = true
 905     sources = [
 906       "tools/dump_cache/url_to_filename_encoder.cc",
 907       "tools/dump_cache/url_to_filename_encoder.h",
 908       "tools/dump_cache/url_utilities.h",
 909       "tools/dump_cache/url_utilities.cc",
 910       "tools/flip_server/acceptor_thread.h",
 911       "tools/flip_server/acceptor_thread.cc",
 912       "tools/flip_server/create_listener.cc",
 913       "tools/flip_server/create_listener.h",
 914       "tools/flip_server/constants.h",
 915       "tools/flip_server/flip_config.cc",
 916       "tools/flip_server/flip_config.h",
 917       "tools/flip_server/http_interface.cc",
 918       "tools/flip_server/http_interface.h",
 919       "tools/flip_server/loadtime_measurement.h",
 920       "tools/flip_server/mem_cache.h",
 921       "tools/flip_server/mem_cache.cc",
 922       "tools/flip_server/output_ordering.cc",
 923       "tools/flip_server/output_ordering.h",
 924       "tools/flip_server/ring_buffer.cc",
 925       "tools/flip_server/ring_buffer.h",
 926       "tools/flip_server/sm_connection.cc",
 927       "tools/flip_server/sm_connection.h",
 928       "tools/flip_server/sm_interface.h",
 929       "tools/flip_server/spdy_ssl.cc",
 930       "tools/flip_server/spdy_ssl.h",
 931       "tools/flip_server/spdy_interface.cc",
 932       "tools/flip_server/spdy_interface.h",
 933       "tools/flip_server/spdy_util.cc",
 934       "tools/flip_server/spdy_util.h",
 935       "tools/flip_server/streamer_interface.cc",
 936       "tools/flip_server/streamer_interface.h",
 937     ]
 938     deps = [
 939       ":balsa",
 940       ":epoll_server",
 941       ":net",
 942       "//base",
 943       "//third_party/boringssl",
 944     ]
 945   }
 946
 947   executable("flip_in_mem_edsm_server_unittests") {
 948     testonly = true
 949     sources = [
 950       "tools/flip_server/flip_test_utils.cc",
 951       "tools/flip_server/flip_test_utils.h",
 952       "tools/flip_server/http_interface_test.cc",
 953       "tools/flip_server/mem_cache_test.cc",
 954       "tools/flip_server/run_all_tests.cc",
 955       "tools/flip_server/spdy_interface_test.cc",
 956     ]
 957     deps = [
 958       ":flip_in_mem_edsm_server_base",
 959       ":net",
 960       ":test_support",
 961       "//testing/gtest",
 962       "//testing/gmock",
 963       "//third_party/boringssl",
 964     ]
 965   }
 966
 967   executable("flip_in_mem_edsm_server") {
 968     testonly = true
 969     sources = [ "tools/flip_server/flip_in_mem_edsm_server.cc" ]
 970     deps = [
 971       ":flip_in_mem_edsm_server_base",
 972       ":net",
 973       "//base",
 974     ]
 975   }
 976
 977   source_set("quic_base") {
 978     sources = [
 979       "tools/quic/quic_client.cc",
 980       "tools/quic/quic_client.h",
 981       "tools/quic/quic_client_session.cc",
 982       "tools/quic/quic_client_session.h",
 983       "tools/quic/quic_default_packet_writer.cc",
 984       "tools/quic/quic_default_packet_writer.h",
 985       "tools/quic/quic_dispatcher.h",
 986       "tools/quic/quic_dispatcher.cc",
 987       "tools/quic/quic_epoll_clock.cc",
 988       "tools/quic/quic_epoll_clock.h",
 989       "tools/quic/quic_epoll_connection_helper.cc",
 990       "tools/quic/quic_epoll_connection_helper.h",
 991       "tools/quic/quic_in_memory_cache.cc",
 992       "tools/quic/quic_in_memory_cache.h",
 993       "tools/quic/quic_packet_writer_wrapper.cc",
 994       "tools/quic/quic_packet_writer_wrapper.h",
 995       "tools/quic/quic_per_connection_packet_writer.cc",
 996       "tools/quic/quic_per_connection_packet_writer.h",
 997       "tools/quic/quic_server.cc",
 998       "tools/quic/quic_server.h",
 999       "tools/quic/quic_server_session.cc",
1000       "tools/quic/quic_server_session.h",
1001       "tools/quic/quic_socket_utils.cc",
1002       "tools/quic/quic_socket_utils.h",
1003       "tools/quic/quic_spdy_client_stream.cc",
1004       "tools/quic/quic_spdy_client_stream.h",
1005       "tools/quic/quic_spdy_server_stream.cc",
1006       "tools/quic/quic_spdy_server_stream.h",
1007       "tools/quic/quic_time_wait_list_manager.h",
1008       "tools/quic/quic_time_wait_list_manager.cc",
1009     ]
1010     deps = [
1011       ":balsa",
1012       ":epoll_server",
1013       ":net",
1014       "//base",
1015       "//base/third_party/dynamic_annotations",
1016       "//crypto",
1017       "//third_party/boringssl",
1018       "//url",
1019     ]
1020   }
1021
1022   executable("quic_client") {
1023     sources = [ "tools/quic/quic_client_bin.cc" ]
1024     deps = [
1025       ":quic_base",
1026       ":net",
1027       "//base",
1028       "//third_party/boringssl",
1029     ]
1030   }
1031 }
1032
1033 if (is_android) {
1034   generate_jni("net_jni_headers") {
1035     sources = [
1036       "android/java/src/org/chromium/net/AndroidCertVerifyResult.java",
1037       "android/java/src/org/chromium/net/AndroidKeyStore.java",
1038       "android/java/src/org/chromium/net/AndroidNetworkLibrary.java",
1039       "android/java/src/org/chromium/net/AndroidPrivateKey.java",
1040       "android/java/src/org/chromium/net/GURLUtils.java",
1041       "android/java/src/org/chromium/net/NetworkChangeNotifier.java",
1042       "android/java/src/org/chromium/net/ProxyChangeListener.java",
1043       "android/java/src/org/chromium/net/X509Util.java",
1044     ]
1045     jni_package = "net"
1046   }
1047   generate_jni("net_test_jni_headers") {
1048     sources = [
1049       "android/javatests/src/org/chromium/net/AndroidKeyStoreTestUtil.java",
1050     ]
1051     jni_package = "net"
1052   }
1053 }
1054
1055 if (is_android || is_linux) {
1056   executable("disk_cache_memory_test") {
1057     testonly = true
1058     sources = [ "tools/disk_cache_memory_test/disk_cache_memory_test.cc" ]
1059     deps = [
1060       ":net",
1061       "//base",
1062     ]
1063   }
1064 }
1065
1066 # TODO(GYP) make this compile on Android, we need some native test deps done.
1067 # TODO(GYP) Also doesn't work on Windows; dependency on boringssl is wrong.
1068 # TODO(GYP) Also doesn't work on Mac, need to figure out why not.
1069 if (!is_android && !is_win && !is_mac) {
1070
1071 source_set("quic_tools") {
1072   sources = [
1073     "quic/quic_dispatcher.cc",
1074     "quic/quic_dispatcher.h",
1075     "quic/quic_in_memory_cache.cc",
1076     "quic/quic_in_memory_cache.h",
1077     "quic/quic_per_connection_packet_writer.cc",
1078     "quic/quic_per_connection_packet_writer.h",
1079     "quic/quic_server.cc",
1080     "quic/quic_server.h",
1081     "quic/quic_server_packet_writer.cc",
1082     "quic/quic_server_packet_writer.h",
1083     "quic/quic_server_session.cc",
1084     "quic/quic_server_session.h",
1085     "quic/quic_spdy_server_stream.cc",
1086     "quic/quic_spdy_server_stream.h",
1087     "quic/quic_time_wait_list_manager.cc",
1088     "quic/quic_time_wait_list_manager.h",
1089   ]
1090   deps = [
1091     ":net",
1092     "//base",
1093     "//base/third_party/dynamic_annotations",
1094     "//url",
1095   ]
1096 }
1097
1098 test("net_unittests") {
1099   sources = gypi_values.net_test_sources
1100
1101   configs += [ ":net_win_size_truncation" ]
1102   defines = []
1103
1104   deps = [
1105     ":extras",
1106     ":http_server",
1107     ":net",
1108     ":quic_tools",
1109     ":test_support",
1110     "//base",
1111     "//base:i18n",
1112     "//base:prefs_test_support",
1113     "//base/allocator",
1114     "//base/third_party/dynamic_annotations",
1115     "//crypto",
1116     "//crypto:platform",
1117     "//crypto:test_support",
1118     "//net/base/registry_controlled_domains",
1119     "//testing/gmock",
1120     "//testing/gtest",
1121     "//third_party/zlib",
1122     "//url",
1123   ]
1124
1125   if (is_linux) {
1126     sources += gypi_values.net_linux_test_sources
1127     deps += [
1128       ":balsa",
1129       ":epoll_server",
1130       ":flip_in_mem_edsm_server_base",
1131       ":quic_base",
1132     ]
1133   }
1134
1135   if (is_chromeos) {
1136     sources -= [
1137       "proxy/proxy_config_service_linux_unittest.cc",
1138     ]
1139   }
1140
1141   if (is_android) {
1142     sources -= [
1143       # See bug http://crbug.com/344533.
1144       "disk_cache/blockfile/index_table_v3_unittest.cc",
1145       # No res_ninit() et al on Android, so this doesn't make a lot of
1146       # sense.
1147       "dns/dns_config_service_posix_unittest.cc",
1148     ]
1149     deps += [
1150       ":net_javatests",  # FIXME(brettw)
1151       ":net_test_jni_headers",
1152     ]
1153   }
1154
1155   if (!use_nss_certs) {
1156     sources -= [
1157       "ssl/client_cert_store_nss_unittest.cc",
1158     ]
1159     if (is_chromeos) {  # Already removed for all non-ChromeOS builds.
1160       sources -= [
1161         "ssl/client_cert_store_chromeos_unittest.cc",
1162       ]
1163     }
1164   }
1165
1166   if (use_openssl) {
1167     # When building for OpenSSL, we need to exclude NSS specific tests
1168     # or functionality not supported by OpenSSL yet.
1169     # TODO(bulach): Add equivalent tests when the underlying
1170     #               functionality is ported to OpenSSL.
1171     sources -= [
1172       "cert/nss_cert_database_unittest.cc",
1173       "cert/x509_util_nss_unittest.cc",
1174       "quic/test_tools/crypto_test_utils_nss.cc",
1175     ]
1176     if (is_chromeos) {
1177       # These were already removed in the non-ChromeOS case.
1178       sources -= [
1179         "cert/nss_cert_database_chromeos_unittest.cc",
1180         "cert/nss_profile_filter_chromeos_unittest.cc",
1181       ]
1182     }
1183   } else {
1184     sources -= [
1185       "cert/x509_util_openssl_unittest.cc",
1186       "quic/test_tools/crypto_test_utils_openssl.cc",
1187       "socket/ssl_client_socket_openssl_unittest.cc",
1188       "socket/ssl_session_cache_openssl_unittest.cc",
1189     ]
1190     if (!is_desktop_linux && !is_chromeos) {
1191       sources -= [ "cert/nss_cert_database_unittest.cc" ]
1192     }
1193   }
1194
1195   if (use_kerberos) {
1196     defines += [ "USE_KERBEROS" ]
1197   } else {
1198     sources -= [
1199       "http/http_auth_gssapi_posix_unittest.cc",
1200       "http/http_auth_handler_negotiate_unittest.cc",
1201       "http/mock_gssapi_library_posix.cc",
1202       "http/mock_gssapi_library_posix.h",
1203     ]
1204   }
1205
1206   if (use_openssl || (!is_desktop_linux && !is_chromeos && !is_ios)) {
1207     # Only include this test when on Posix and using NSS for
1208     # cert verification or on iOS (which also uses NSS for certs).
1209     sources -= [ "ocsp/nss_ocsp_unittest.cc" ]
1210   }
1211
1212   if (!use_openssl_certs) {
1213     sources -= [ "ssl/openssl_client_key_store_unittest.cc" ]
1214   }
1215
1216   if (!enable_websockets) {
1217     sources -= [
1218       "websockets/websocket_basic_stream_test.cc",
1219       "websockets/websocket_channel_test.cc",
1220       "websockets/websocket_deflate_predictor_impl_test.cc",
1221       "websockets/websocket_deflate_stream_test.cc",
1222       "websockets/websocket_deflater_test.cc",
1223       "websockets/websocket_errors_test.cc",
1224       "websockets/websocket_extension_parser_test.cc",
1225       "websockets/websocket_frame_parser_test.cc",
1226       "websockets/websocket_frame_test.cc",
1227       "websockets/websocket_handshake_handler_spdy_test.cc",
1228       "websockets/websocket_handshake_handler_test.cc",
1229       "websockets/websocket_handshake_stream_create_helper_test.cc",
1230       "websockets/websocket_inflater_test.cc",
1231       "websockets/websocket_stream_test.cc",
1232       "websockets/websocket_test_util.cc",
1233       "websockets/websocket_test_util.h",
1234     ]
1235   }
1236
1237   if (disable_file_support) {
1238     sources -= [
1239       "base/directory_lister_unittest.cc",
1240       "url_request/url_request_file_job_unittest.cc",
1241     ]
1242   }
1243
1244   if (disable_ftp_support) {
1245     sources -= [
1246       "ftp/ftp_auth_cache_unittest.cc",
1247       "ftp/ftp_ctrl_response_buffer_unittest.cc",
1248       "ftp/ftp_directory_listing_parser_ls_unittest.cc",
1249       "ftp/ftp_directory_listing_parser_netware_unittest.cc",
1250       "ftp/ftp_directory_listing_parser_os2_unittest.cc",
1251       "ftp/ftp_directory_listing_parser_unittest.cc",
1252       "ftp/ftp_directory_listing_parser_unittest.h",
1253       "ftp/ftp_directory_listing_parser_vms_unittest.cc",
1254       "ftp/ftp_directory_listing_parser_windows_unittest.cc",
1255       "ftp/ftp_network_transaction_unittest.cc",
1256       "ftp/ftp_util_unittest.cc",
1257       "url_request/url_request_ftp_job_unittest.cc",
1258     ]
1259   }
1260
1261   if (!enable_built_in_dns) {
1262     sources -= [
1263       "dns/address_sorter_posix_unittest.cc",
1264       "dns/address_sorter_unittest.cc",
1265     ]
1266   }
1267
1268   # Always need use_v8_in_net to be 1 to run on Android, so just remove
1269   # net_unittest's dependency on v8 when using icu alternatives instead of
1270   # setting use_v8_in_net to 0.
1271   if (use_v8_in_net && !use_icu_alternatives_on_android) {
1272     deps += [ ":net_with_v8" ]
1273   } else {
1274     sources -= [
1275       "proxy/proxy_resolver_v8_unittest.cc",
1276       "proxy/proxy_resolver_v8_tracing_unittest.cc",
1277     ]
1278   }
1279
1280   if (!enable_mdns) {
1281     sources -= [
1282       "dns/mdns_cache_unittest.cc",
1283       "dns/mdns_client_unittest.cc",
1284       "dns/record_parsed_unittest.cc",
1285       "dns/record_rdata_unittest.cc",
1286     ]
1287   }
1288
1289   if (is_ios) {
1290     # TODO(GYP)
1291     #  'actions': [
1292     #    {
1293     #      'action_name': 'copy_test_data',
1294     #      'variables': {
1295     #        'test_data_files': [
1296     #          'data/ssl/certificates/',
1297     #          'data/test.html',
1298     #          'data/url_request_unittest/',
1299     #        ],
1300     #        'test_data_prefix': 'net',
1301     #      },
1302     #      'includes': [ '../build/copy_test_data_ios.gypi' ],
1303     #    },
1304     #  ],
1305     sources -= [
1306       # TODO(droger): The following tests are disabled because the
1307       # implementation is missing or incomplete.
1308       # KeygenHandler::GenKeyAndSignChallenge() is not ported to iOS.
1309       "base/keygen_handler_unittest.cc",
1310       "disk_cache/backend_unittest.cc",
1311       "disk_cache/blockfile/block_files_unittest.cc",
1312       # Need to read input data files.
1313       "filter/gzip_filter_unittest.cc",
1314       "socket/ssl_server_socket_unittest.cc",
1315       "spdy/fuzzing/hpack_fuzz_util_test.cc",
1316       # Need TestServer.
1317       "proxy/proxy_script_fetcher_impl_unittest.cc",
1318       "socket/ssl_client_socket_unittest.cc",
1319       "url_request/url_fetcher_impl_unittest.cc",
1320       "url_request/url_request_context_builder_unittest.cc",
1321       # Needs GetAppOutput().
1322       "test/python_utils_unittest.cc",
1323
1324       # The following tests are disabled because they don't apply to
1325       # iOS.
1326       # OS is not "linux" or "freebsd" or "openbsd".
1327       "socket/unix_domain_client_socket_posix_unittest.cc",
1328       "socket/unix_domain_listen_socket_posix_unittest.cc",
1329       "socket/unix_domain_server_socket_posix_unittest.cc",
1330
1331       # See bug http://crbug.com/344533.
1332       "disk_cache/blockfile/index_table_v3_unittest.cc",
1333     ]
1334   }
1335
1336   if (is_android) {
1337     sources -= [
1338       "dns/dns_config_service_posix_unittest.cc",
1339     ]
1340     # TODO(GYP)
1341     # # TODO(mmenke):  This depends on test_support_base, which depends on
1342     # #                icu.  Figure out a way to remove that dependency.
1343     # 'dependencies': [
1344     #   '../testing/android/native_test.gyp:native_test_native_code',
1345     # ]
1346
1347     set_sources_assignment_filter([])
1348     sources += [ "base/address_tracker_linux_unittest.cc" ]
1349     set_sources_assignment_filter(sources_assignment_filter)
1350   }
1351
1352   if (use_icu_alternatives_on_android) {
1353     sources -= [
1354       "base/filename_util_unittest.cc",
1355       "base/net_util_icu_unittest.cc",
1356     ]
1357     deps -= [ "//base:i18n" ]
1358   }
1359 }
1360
1361 executable("quic_server") {
1362   sources = [ "quic/quic_server_bin.cc" ]
1363   deps = [
1364     ":quic_tools",
1365     ":net",
1366     "//base",
1367     "//third_party/boringssl",
1368   ]
1369 }
1370
1371 }  # !is_android && !is_win && !is_mac