net/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6 import("//build/config/features.gni")
   7 import("//build/config/ui.gni")
   8 import("//url/config.gni")
   9
  10 # TODO(cjhopman): //build/config/android/rules.gni also imports grit_rule.gni.
  11 # Currently, that file can't be imported multiple times.  Make this always
  12 # imported when http://crbug.com/393704 is fixed.
  13 if (!is_android) {
  14   import("//tools/grit/grit_rule.gni")
  15 }
  16
  17 if (is_android) {
  18   import("//build/config/android/config.gni")
  19   import("//build/config/android/rules.gni")
  20 } else if (is_mac) {
  21   import("//build/config/mac/mac_sdk.gni")
  22 }
  23
  24 # The list of net files is kept in net.gypi. Read it.
  25 gypi_values = exec_script(
  26     "//build/gypi_to_gn.py",
  27     [ rebase_path("net.gypi") ],
  28     "scope",
  29     [ "net.gypi" ])
  30
  31 # Disable Kerberos on ChromeOS, Android and iOS, at least for now. It needs
  32 # configuration (krb5.conf and so on).
  33 use_kerberos = !is_chromeos && !is_android && !is_ios
  34
  35 # The way the cache uses mmap() is inefficient on some Android devices. If
  36 # this flag is set, we hackily avoid using mmap() in the disk cache. We are
  37 # pretty confident that mmap-ing the index would not hurt any existing x86
  38 # android devices, but we cannot be so sure about the variety of ARM devices.
  39 # So enable it for x86 only for now.
  40 posix_avoid_mmap = is_android && cpu_arch != "x86"
  41
  42 # WebSockets and socket stream code are used everywhere except iOS.
  43 enable_websockets = !is_ios
  44 use_v8_in_net = !is_ios
  45 enable_built_in_dns = !is_ios
  46 disable_ftp_support = is_ios
  47
  48 declare_args() {
  49   # Disables support for file URLs.  File URL support requires use of icu.
  50   disable_file_support = false
  51 }
  52
  53 config("net_config") {
  54   defines = []
  55   if (posix_avoid_mmap) {
  56     defines += [ "POSIX_AVOID_MMAP" ]
  57   }
  58   if (disable_file_support) {
  59     defines += [ "DISABLE_FILE_SUPPORT" ]
  60   }
  61 }
  62
  63 # Disables Windows warning about size to int truncations.
  64 # TODO(jschuh): crbug.com/167187 fix this and delete this config.
  65 config("net_win_size_truncation") {
  66   if (is_win) {
  67     cflags = [ "/wd4267" ]
  68   }
  69 }
  70
  71 component("net") {
  72   sources =
  73     gypi_values.net_nacl_common_sources +
  74     gypi_values.net_non_nacl_sources
  75
  76   cflags = []
  77   defines = [
  78     # TODO(GYP) Note that he GYP file supports linux_link_kerberos (defaults to
  79     # 0) which implies that we run pkg_config on kerberos and link to that
  80     # rather than setting this define which will dynamically open it. That
  81     # doesn't seem to be set in the regular builds, so we're skipping this
  82     # capability here.
  83     "DLOPEN_KERBEROS",
  84     "NET_IMPLEMENTATION"
  85   ]
  86   configs += [ ":net_win_size_truncation" ]
  87   direct_dependent_configs = [ ":net_config" ]
  88   include_dirs = []
  89
  90   deps = [
  91    ":net_resources",
  92     "//base",
  93     "//base:i18n",
  94     "//base:prefs",
  95     "//base/third_party/dynamic_annotations",
  96     "//crypto",
  97     "//crypto:platform",
  98     "//net/base/registry_controlled_domains",
  99     "//sdch",
 100     "//third_party/icu",
 101     "//third_party/zlib",
 102     "//url",
 103   ]
 104   forward_dependent_configs_from = [
 105     "//crypto",
 106     "//crypto:platform"
 107   ]
 108
 109   if (use_kerberos) {
 110     defines += [ "USE_KERBEROS" ]
 111     if (is_android) {
 112       include_dirs += [ "/usr/include/kerberosV" ]
 113     }
 114   } else {
 115     sources -= [
 116       "http/http_auth_gssapi_posix.cc",
 117       "http/http_auth_gssapi_posix.h",
 118       "http/http_auth_handler_negotiate.h",
 119       "http/http_auth_handler_negotiate.cc",
 120     ]
 121   }
 122
 123   if (is_posix) {
 124     if (posix_avoid_mmap) {
 125       sources -= [ "disk_cache/blockfile/mapped_file_posix.cc" ]
 126     } else {
 127       sources -= [ "disk_cache/blockfile/mapped_file_avoid_mmap_posix.cc" ]
 128     }
 129   }
 130
 131   if (disable_file_support) {
 132     sources -= [
 133       "base/directory_lister.cc",
 134       "base/directory_lister.h",
 135       "url_request/url_request_file_dir_job.cc",
 136       "url_request/url_request_file_dir_job.h",
 137       "url_request/url_request_file_job.cc",
 138       "url_request/url_request_file_job.h",
 139       "url_request/file_protocol_handler.cc",
 140       "url_request/file_protocol_handler.h",
 141     ]
 142   }
 143
 144   if (disable_ftp_support) {
 145     sources -= [
 146       "ftp/ftp_auth_cache.cc",
 147       "ftp/ftp_auth_cache.h",
 148       "ftp/ftp_ctrl_response_buffer.cc",
 149       "ftp/ftp_ctrl_response_buffer.h",
 150       "ftp/ftp_directory_listing_parser.cc",
 151       "ftp/ftp_directory_listing_parser.h",
 152       "ftp/ftp_directory_listing_parser_ls.cc",
 153       "ftp/ftp_directory_listing_parser_ls.h",
 154       "ftp/ftp_directory_listing_parser_netware.cc",
 155       "ftp/ftp_directory_listing_parser_netware.h",
 156       "ftp/ftp_directory_listing_parser_os2.cc",
 157       "ftp/ftp_directory_listing_parser_os2.h",
 158       "ftp/ftp_directory_listing_parser_vms.cc",
 159       "ftp/ftp_directory_listing_parser_vms.h",
 160       "ftp/ftp_directory_listing_parser_windows.cc",
 161       "ftp/ftp_directory_listing_parser_windows.h",
 162       "ftp/ftp_network_layer.cc",
 163       "ftp/ftp_network_layer.h",
 164       "ftp/ftp_network_session.cc",
 165       "ftp/ftp_network_session.h",
 166       "ftp/ftp_network_transaction.cc",
 167       "ftp/ftp_network_transaction.h",
 168       "ftp/ftp_request_info.h",
 169       "ftp/ftp_response_info.cc",
 170       "ftp/ftp_response_info.h",
 171       "ftp/ftp_server_type_histograms.cc",
 172       "ftp/ftp_server_type_histograms.h",
 173       "ftp/ftp_transaction.h",
 174       "ftp/ftp_transaction_factory.h",
 175       "ftp/ftp_util.cc",
 176       "ftp/ftp_util.h",
 177       "url_request/ftp_protocol_handler.cc",
 178       "url_request/ftp_protocol_handler.h",
 179       "url_request/url_request_ftp_job.cc",
 180       "url_request/url_request_ftp_job.h",
 181     ]
 182   }
 183
 184   if (enable_built_in_dns) {
 185     defines += [ "ENABLE_BUILT_IN_DNS" ]
 186   } else {
 187     sources -= [
 188       "dns/address_sorter_posix.cc",
 189       "dns/address_sorter_posix.h",
 190       "dns/dns_client.cc",
 191     ]
 192   }
 193
 194   if (use_openssl) {
 195     sources -= [
 196       "base/nss_memio.c",
 197       "base/nss_memio.h",
 198       "cert/ct_log_verifier_nss.cc",
 199       "cert/ct_objects_extractor_nss.cc",
 200       "cert/jwk_serializer_nss.cc",
 201       "cert/scoped_nss_types.h",
 202       "cert/x509_util_nss.cc",
 203       "cert/x509_util_nss.h",
 204       "quic/crypto/aead_base_decrypter_nss.cc",
 205       "quic/crypto/aead_base_encrypter_nss.cc",
 206       "quic/crypto/aes_128_gcm_12_decrypter_nss.cc",
 207       "quic/crypto/aes_128_gcm_12_encrypter_nss.cc",
 208       "quic/crypto/chacha20_poly1305_decrypter_nss.cc",
 209       "quic/crypto/chacha20_poly1305_encrypter_nss.cc",
 210       "quic/crypto/channel_id_nss.cc",
 211       "quic/crypto/p256_key_exchange_nss.cc",
 212       "socket/nss_ssl_util.cc",
 213       "socket/nss_ssl_util.h",
 214       "socket/ssl_client_socket_nss.cc",
 215       "socket/ssl_client_socket_nss.h",
 216       "socket/ssl_server_socket_nss.cc",
 217       "socket/ssl_server_socket_nss.h",
 218     ]
 219     if (is_chromeos) {
 220       sources -= [
 221         "cert/nss_cert_database_chromeos.cc",
 222         "cert/nss_cert_database_chromeos.h",
 223         "cert/nss_profile_filter_chromeos.cc",
 224         "cert/nss_profile_filter_chromeos.h",
 225       ]
 226     }
 227     if (is_linux) {
 228       # These are always removed for non-Linux cases below.
 229       sources -= [
 230         "base/crypto_module_nss.cc",
 231         "base/keygen_handler_nss.cc",
 232         "cert/cert_database_nss.cc",
 233         "cert/nss_cert_database.cc",
 234         "cert/nss_cert_database.h",
 235         "cert/x509_certificate_nss.cc",
 236         "third_party/mozilla_security_manager/nsKeygenHandler.cpp",
 237         "third_party/mozilla_security_manager/nsKeygenHandler.h",
 238         "third_party/mozilla_security_manager/nsNSSCertificateDB.cpp",
 239         "third_party/mozilla_security_manager/nsNSSCertificateDB.h",
 240         "third_party/mozilla_security_manager/nsPKCS12Blob.cpp",
 241         "third_party/mozilla_security_manager/nsPKCS12Blob.h",
 242       ]
 243     }
 244     if (is_ios) {
 245       # Always removed for !ios below.
 246       sources -= [
 247         "cert/cert_verify_proc_nss.cc",
 248         "cert/cert_verify_proc_nss.h",
 249         "cert/test_root_certs_nss.cc",
 250         "ocsp/nss_ocsp.cc",
 251         "ocsp/nss_ocsp.h",
 252       ]
 253     }
 254   } else {
 255     sources -= [
 256       "base/crypto_module_openssl.cc",
 257       "base/keygen_handler_openssl.cc",
 258       "cert/ct_log_verifier_openssl.cc",
 259       "cert/ct_objects_extractor_openssl.cc",
 260       "cert/jwk_serializer_openssl.cc",
 261       "cert/x509_util_openssl.cc",
 262       "cert/x509_util_openssl.h",
 263       "quic/crypto/aead_base_decrypter_openssl.cc",
 264       "quic/crypto/aead_base_encrypter_openssl.cc",
 265       "quic/crypto/aes_128_gcm_12_decrypter_openssl.cc",
 266       "quic/crypto/aes_128_gcm_12_encrypter_openssl.cc",
 267       "quic/crypto/chacha20_poly1305_decrypter_openssl.cc",
 268       "quic/crypto/chacha20_poly1305_encrypter_openssl.cc",
 269       "quic/crypto/channel_id_openssl.cc",
 270       "quic/crypto/p256_key_exchange_openssl.cc",
 271       "quic/crypto/scoped_evp_aead_ctx.cc",
 272       "quic/crypto/scoped_evp_aead_ctx.h",
 273       "socket/ssl_client_socket_openssl.cc",
 274       "socket/ssl_client_socket_openssl.h",
 275       "socket/ssl_server_socket_openssl.cc",
 276       "socket/ssl_server_socket_openssl.h",
 277       "socket/ssl_session_cache_openssl.cc",
 278       "socket/ssl_session_cache_openssl.h",
 279       "ssl/openssl_platform_key.h",
 280       "ssl/openssl_ssl_util.cc",
 281       "ssl/openssl_ssl_util.h",
 282     ]
 283     if (is_mac) {
 284       sources -= [
 285         "ssl/openssl_platform_key_mac.cc",
 286       ]
 287     }
 288     if (is_win) {
 289       sources -= [
 290         "ssl/openssl_platform_key_win.cc",
 291       ]
 292     }
 293   }
 294
 295   if (!use_openssl_certs) {
 296     sources -= [
 297       "base/openssl_private_key_store.h",
 298       "base/openssl_private_key_store_memory.cc",
 299       "cert/cert_database_openssl.cc",
 300       "cert/cert_verify_proc_openssl.cc",
 301       "cert/cert_verify_proc_openssl.h",
 302       "cert/test_root_certs_openssl.cc",
 303       "cert/x509_certificate_openssl.cc",
 304       "ssl/openssl_client_key_store.cc",
 305       "ssl/openssl_client_key_store.h",
 306     ]
 307     if (is_android) {
 308       sources -= [
 309         "base/openssl_private_key_store_android.cc",
 310       ]
 311     }
 312   } else if (is_android) {
 313     # Android doesn't use these even when using OpenSSL.
 314     sources -= [
 315       "base/openssl_private_key_store_memory.cc",
 316       "cert/cert_database_openssl.cc",
 317       "cert/cert_verify_proc_openssl.cc",
 318       "cert/test_root_certs_openssl.cc",
 319     ]
 320   }
 321
 322   if (use_glib) {
 323     configs += [ "//build/config/linux:gconf" ]
 324     deps += [ "//build/config/linux:gio" ]
 325   }
 326
 327   if (is_linux) {
 328     configs += [ "//build/config/linux:libresolv" ]
 329   } else {
 330     sources -= [
 331       "base/crypto_module_nss.cc",
 332       "base/keygen_handler_nss.cc",
 333       "cert/cert_database_nss.cc",
 334       "cert/nss_cert_database.cc",
 335       "cert/nss_cert_database.h",
 336       "cert/x509_certificate_nss.cc",
 337       "third_party/mozilla_security_manager/nsKeygenHandler.cpp",
 338       "third_party/mozilla_security_manager/nsKeygenHandler.h",
 339       "third_party/mozilla_security_manager/nsNSSCertificateDB.cpp",
 340       "third_party/mozilla_security_manager/nsNSSCertificateDB.h",
 341       "third_party/mozilla_security_manager/nsPKCS12Blob.cpp",
 342       "third_party/mozilla_security_manager/nsPKCS12Blob.h",
 343     ]
 344
 345     if (!is_ios) {
 346       # These files are part of the partial implementation of NSS on iOS so
 347       # keep them in that case.
 348       sources -= [
 349         "cert/test_root_certs_nss.cc",
 350         "ocsp/nss_ocsp.cc",
 351         "ocsp/nss_ocsp.h",
 352       ]
 353     }
 354   }
 355
 356   if (!use_nss_certs) {
 357     sources -= [
 358       "ssl/client_cert_store_nss.cc",
 359       "ssl/client_cert_store_nss.h",
 360     ]
 361     if (!is_ios) {
 362       # These files are part of the partial implementation of NSS on iOS so
 363       # keep them in that case (even though use_nss_certs is not set).
 364       sources -= [
 365         "cert/cert_verify_proc_nss.cc",
 366         "cert/cert_verify_proc_nss.h",
 367       ]
 368     }
 369     if (is_chromeos) {
 370       # These were already removed on non-ChromeOS.
 371       sources -= [
 372         "ssl/client_cert_store_chromeos.cc",
 373         "ssl/client_cert_store_chromeos.h",
 374       ]
 375     }
 376   }
 377
 378   if (!enable_websockets) {
 379     sources -= [
 380       "socket_stream/socket_stream.cc",
 381       "socket_stream/socket_stream.h",
 382       "socket_stream/socket_stream_job.cc",
 383       "socket_stream/socket_stream_job.h",
 384       "socket_stream/socket_stream_job_manager.cc",
 385       "socket_stream/socket_stream_job_manager.h",
 386       "socket_stream/socket_stream_metrics.cc",
 387       "socket_stream/socket_stream_metrics.h",
 388       "spdy/spdy_websocket_stream.cc",
 389       "spdy/spdy_websocket_stream.h",
 390       "websockets/websocket_basic_handshake_stream.cc",
 391       "websockets/websocket_basic_handshake_stream.h",
 392       "websockets/websocket_basic_stream.cc",
 393       "websockets/websocket_basic_stream.h",
 394       "websockets/websocket_channel.cc",
 395       "websockets/websocket_channel.h",
 396       "websockets/websocket_deflate_predictor.h",
 397       "websockets/websocket_deflate_predictor_impl.cc",
 398       "websockets/websocket_deflate_predictor_impl.h",
 399       "websockets/websocket_deflate_stream.cc",
 400       "websockets/websocket_deflate_stream.h",
 401       "websockets/websocket_deflater.cc",
 402       "websockets/websocket_deflater.h",
 403       "websockets/websocket_errors.cc",
 404       "websockets/websocket_errors.h",
 405       "websockets/websocket_extension.cc",
 406       "websockets/websocket_extension.h",
 407       "websockets/websocket_extension_parser.cc",
 408       "websockets/websocket_extension_parser.h",
 409       "websockets/websocket_frame.cc",
 410       "websockets/websocket_frame.h",
 411       "websockets/websocket_frame_parser.cc",
 412       "websockets/websocket_frame_parser.h",
 413       "websockets/websocket_handshake_constants.cc",
 414       "websockets/websocket_handshake_constants.h",
 415       "websockets/websocket_handshake_handler.cc",
 416       "websockets/websocket_handshake_handler.h",
 417       "websockets/websocket_handshake_request_info.cc",
 418       "websockets/websocket_handshake_request_info.h",
 419       "websockets/websocket_handshake_response_info.cc",
 420       "websockets/websocket_handshake_response_info.h",
 421       "websockets/websocket_handshake_stream_base.h",
 422       "websockets/websocket_handshake_stream_create_helper.cc",
 423       "websockets/websocket_handshake_stream_create_helper.h",
 424       "websockets/websocket_inflater.cc",
 425       "websockets/websocket_inflater.h",
 426       "websockets/websocket_job.cc",
 427       "websockets/websocket_job.h",
 428       "websockets/websocket_mux.h",
 429       "websockets/websocket_net_log_params.cc",
 430       "websockets/websocket_net_log_params.h",
 431       "websockets/websocket_stream.cc",
 432       "websockets/websocket_stream.h",
 433       "websockets/websocket_throttle.cc",
 434       "websockets/websocket_throttle.h",
 435     ]
 436   }
 437
 438   if (!enable_mdns) {
 439     sources -= [
 440       "dns/mdns_cache.cc",
 441       "dns/mdns_cache.h",
 442       "dns/mdns_client.cc",
 443       "dns/mdns_client.h",
 444       "dns/mdns_client_impl.cc",
 445       "dns/mdns_client_impl.h",
 446       "dns/record_parsed.cc",
 447       "dns/record_parsed.h",
 448       "dns/record_rdata.cc",
 449       "dns/record_rdata.h",
 450     ]
 451   }
 452
 453   if (is_win) {
 454     sources -= [
 455       "http/http_auth_handler_ntlm_portable.cc",
 456       "socket/socket_libevent.cc",
 457       "socket/socket_libevent.h",
 458       "socket/tcp_socket_libevent.cc",
 459       "socket/tcp_socket_libevent.h",
 460       "udp/udp_socket_libevent.cc",
 461       "udp/udp_socket_libevent.h",
 462     ]
 463     deps += [
 464       "//third_party/nss:nspr",
 465       "//third_party/nss",
 466     ]
 467   } else {  # !is_win
 468     sources -= [
 469       "base/winsock_init.cc",
 470       "base/winsock_init.h",
 471       "base/winsock_util.cc",
 472       "base/winsock_util.h",
 473       "proxy/proxy_resolver_winhttp.cc",
 474       "proxy/proxy_resolver_winhttp.h",
 475     ]
 476   }
 477
 478   if (is_mac) {
 479     deps += [
 480       "//third_party/nss:nspr",
 481       "//third_party/nss",
 482     ]
 483     libs = [
 484       "Foundation.framework",
 485       "Security.framework",
 486       "SystemConfiguration.framework",
 487       "resolv",
 488     ]
 489   }
 490
 491   if (is_ios) {
 492     # Add back some sources that were otherwise filtered out. iOS additionally
 493     # doesn't set USE_NSS but needs some of the files.
 494     set_sources_assignment_filter([])
 495     sources += [
 496       "base/network_change_notifier_mac.cc",
 497       "base/network_config_watcher_mac.cc",
 498       "base/platform_mime_util_mac.mm",
 499       "cert/cert_verify_proc_nss.cc",
 500       "cert/cert_verify_proc_nss.h",
 501       "cert/test_root_certs_nss.cc",
 502       "cert/x509_util_nss.cc",
 503       "cert/x509_util_nss.h",
 504       "proxy/proxy_resolver_mac.cc",
 505       "proxy/proxy_server_mac.cc",
 506       "ocsp/nss_ocsp.cc",
 507       "ocsp/nss_ocsp.h",
 508     ]
 509     set_sources_assignment_filter(sources_assignment_filter)
 510
 511     sources -= [ "disk_cache/blockfile/file_posix.cc" ]
 512     deps += [
 513       "//third_party/nss",
 514     ]
 515     libs = [
 516       "CFNetwork.framework",
 517       "MobileCoreServices.framework",
 518       "Security.framework",
 519       "SystemConfiguration.framework",
 520       "resolv",
 521     ]
 522   }
 523
 524   if (is_android) {
 525     # Add some Linux sources that were excluded by the filter, but which
 526     # are needed.
 527     set_sources_assignment_filter([])
 528     sources += [
 529       "base/platform_mime_util_linux.cc",
 530       "base/address_tracker_linux.cc",
 531       "base/address_tracker_linux.h",
 532     ]
 533     set_sources_assignment_filter(sources_assignment_filter)
 534
 535     if (!is_android_webview_build) {
 536       deps += [ ":net_jni_headers" ]
 537     }
 538   }
 539
 540   if (use_icu_alternatives_on_android) {
 541     deps -= [
 542       "//base:i18n",
 543       "//third_party/icu",
 544     ]
 545     sources -= [
 546       "base/filename_util_icu.cc",
 547       "base/net_string_util_icu.cc",
 548       "base/net_util_icu.cc",
 549     ]
 550     sources += [
 551       "base/net_string_util_icu_alternatives_android.cc",
 552       "base/net_string_util_icu_alternatives_android.h",
 553     ]
 554   }
 555 }
 556
 557 grit("net_resources") {
 558   source = "base/net_resources.grd"
 559   outputs = [
 560     "grit/net_resources.h",
 561     "net_resources.pak",
 562     "net_resources.rc",
 563   ]
 564 }
 565
 566 static_library("http_server") {
 567   sources = [
 568     "server/http_connection.cc",
 569     "server/http_connection.h",
 570     "server/http_server.cc",
 571     "server/http_server.h",
 572     "server/http_server_request_info.cc",
 573     "server/http_server_request_info.h",
 574     "server/http_server_response_info.cc",
 575     "server/http_server_response_info.h",
 576     "server/web_socket.cc",
 577     "server/web_socket.h",
 578   ]
 579   configs += [ "//build/config/compiler:wexit_time_destructors" ]
 580   deps = [
 581     ":net",
 582     "//base",
 583   ]
 584 }
 585
 586 executable("dump_cache") {
 587   sources = [
 588     "tools/dump_cache/cache_dumper.cc",
 589     "tools/dump_cache/cache_dumper.h",
 590     "tools/dump_cache/dump_cache.cc",
 591     "tools/dump_cache/dump_files.cc",
 592     "tools/dump_cache/dump_files.h",
 593     "tools/dump_cache/simple_cache_dumper.cc",
 594     "tools/dump_cache/simple_cache_dumper.h",
 595     "tools/dump_cache/upgrade_win.cc",
 596     "tools/dump_cache/upgrade_win.h",
 597     "tools/dump_cache/url_to_filename_encoder.cc",
 598     "tools/dump_cache/url_to_filename_encoder.h",
 599     "tools/dump_cache/url_utilities.h",
 600     "tools/dump_cache/url_utilities.cc",
 601   ]
 602
 603   configs += [ ":net_win_size_truncation" ]
 604
 605   deps = [
 606     "//base",
 607     ":net",
 608     ":test_support",
 609   ]
 610 }
 611
 612 source_set("test_support") {
 613   sources = [
 614     "base/capturing_net_log.cc",
 615     "base/capturing_net_log.h",
 616     "base/load_timing_info_test_util.cc",
 617     "base/load_timing_info_test_util.h",
 618     "base/mock_file_stream.cc",
 619     "base/mock_file_stream.h",
 620     "base/test_completion_callback.cc",
 621     "base/test_completion_callback.h",
 622     "base/test_data_directory.cc",
 623     "base/test_data_directory.h",
 624     "cert/mock_cert_verifier.cc",
 625     "cert/mock_cert_verifier.h",
 626     "cookies/cookie_monster_store_test.cc",
 627     "cookies/cookie_monster_store_test.h",
 628     "cookies/cookie_store_test_callbacks.cc",
 629     "cookies/cookie_store_test_callbacks.h",
 630     "cookies/cookie_store_test_helpers.cc",
 631     "cookies/cookie_store_test_helpers.h",
 632     "disk_cache/disk_cache_test_base.cc",
 633     "disk_cache/disk_cache_test_base.h",
 634     "disk_cache/disk_cache_test_util.cc",
 635     "disk_cache/disk_cache_test_util.h",
 636     "dns/dns_test_util.cc",
 637     "dns/dns_test_util.h",
 638     "dns/mock_host_resolver.cc",
 639     "dns/mock_host_resolver.h",
 640     "dns/mock_mdns_socket_factory.cc",
 641     "dns/mock_mdns_socket_factory.h",
 642     "http/http_transaction_test_util.cc",
 643     "http/http_transaction_test_util.h",
 644     "proxy/mock_proxy_resolver.cc",
 645     "proxy/mock_proxy_resolver.h",
 646     "proxy/mock_proxy_script_fetcher.cc",
 647     "proxy/mock_proxy_script_fetcher.h",
 648     "proxy/proxy_config_service_common_unittest.cc",
 649     "proxy/proxy_config_service_common_unittest.h",
 650     "socket/socket_test_util.cc",
 651     "socket/socket_test_util.h",
 652     "test/cert_test_util.cc",
 653     "test/cert_test_util.h",
 654     "test/cert_test_util_nss.cc",
 655     "test/ct_test_util.cc",
 656     "test/ct_test_util.h",
 657     "test/embedded_test_server/embedded_test_server.cc",
 658     "test/embedded_test_server/embedded_test_server.h",
 659     "test/embedded_test_server/http_connection.cc",
 660     "test/embedded_test_server/http_connection.h",
 661     "test/embedded_test_server/http_request.cc",
 662     "test/embedded_test_server/http_request.h",
 663     "test/embedded_test_server/http_response.cc",
 664     "test/embedded_test_server/http_response.h",
 665     "test/net_test_suite.cc",
 666     "test/net_test_suite.h",
 667     "test/python_utils.cc",
 668     "test/python_utils.h",
 669     "test/spawned_test_server/base_test_server.cc",
 670     "test/spawned_test_server/base_test_server.h",
 671     "test/spawned_test_server/local_test_server_posix.cc",
 672     "test/spawned_test_server/local_test_server_win.cc",
 673     "test/spawned_test_server/local_test_server.cc",
 674     "test/spawned_test_server/local_test_server.h",
 675     "test/spawned_test_server/remote_test_server.cc",
 676     "test/spawned_test_server/remote_test_server.h",
 677     "test/spawned_test_server/spawned_test_server.h",
 678     "test/spawned_test_server/spawner_communicator.cc",
 679     "test/spawned_test_server/spawner_communicator.h",
 680     "url_request/test_url_fetcher_factory.cc",
 681     "url_request/test_url_fetcher_factory.h",
 682     "url_request/url_request_test_util.cc",
 683     "url_request/url_request_test_util.h",
 684   ]
 685
 686   configs += [ ":net_win_size_truncation" ]
 687
 688   deps = [
 689     "//base",
 690     "//base/test:test_support",
 691     "//crypto",
 692     "//net",
 693     "//net/tools/tld_cleanup",
 694     "//testing/gmock",
 695     "//testing/gtest",
 696     "//url",
 697   ]
 698
 699   if (is_ios) {
 700     deps += [ "//third_party/nss" ]
 701   }
 702
 703   if (!is_android) {
 704     sources -= [
 705       "test/spawned_test_server/remote_test_server.cc",
 706       "test/spawned_test_server/remote_test_server.h",
 707       "test/spawned_test_server/spawner_communicator.cc",
 708       "test/spawned_test_server/spawner_communicator.h",
 709     ]
 710   }
 711
 712   if (use_v8_in_net) {
 713     deps += [ ":net_with_v8" ]
 714   }
 715
 716   if (!enable_mdns) {
 717     sources -= [
 718       "dns/mock_mdns_socket_factory.cc",
 719       "dns/mock_mdns_socket_factory.h",
 720     ]
 721   }
 722
 723   if (use_nss_certs) {
 724     deps += ["//crypto:platform" ]
 725   } else {
 726     sources -= [
 727       "test/cert_test_util_nss.cc",
 728     ]
 729   }
 730
 731   forward_dependent_configs_from = deps
 732 }
 733
 734 source_set("balsa") {
 735   sources = [
 736     "tools/balsa/balsa_enums.h",
 737     "tools/balsa/balsa_frame.cc",
 738     "tools/balsa/balsa_frame.h",
 739     "tools/balsa/balsa_headers.cc",
 740     "tools/balsa/balsa_headers.h",
 741     "tools/balsa/balsa_headers_token_utils.cc",
 742     "tools/balsa/balsa_headers_token_utils.h",
 743     "tools/balsa/balsa_visitor_interface.h",
 744     "tools/balsa/http_message_constants.cc",
 745     "tools/balsa/http_message_constants.h",
 746     "tools/balsa/noop_balsa_visitor.h",
 747     "tools/balsa/simple_buffer.cc",
 748     "tools/balsa/simple_buffer.h",
 749     "tools/balsa/split.cc",
 750     "tools/balsa/split.h",
 751     "tools/balsa/string_piece_utils.h",
 752     "tools/quic/spdy_utils.cc",
 753     "tools/quic/spdy_utils.h",
 754   ]
 755   deps = [
 756     ":net",
 757     "//base",
 758     "//url",
 759   ]
 760 }
 761
 762 if (use_v8_in_net) {
 763   component("net_with_v8") {
 764     sources = [
 765       "proxy/proxy_resolver_v8.cc",
 766       "proxy/proxy_resolver_v8.h",
 767       "proxy/proxy_resolver_v8_tracing.cc",
 768       "proxy/proxy_resolver_v8_tracing.h",
 769       "proxy/proxy_service_v8.cc",
 770       "proxy/proxy_service_v8.h",
 771     ]
 772
 773     defines = [ "NET_IMPLEMENTATION" ]
 774     configs += [
 775       ":net_win_size_truncation",
 776       "//build/config/compiler:wexit_time_destructors",
 777     ]
 778
 779     deps = [
 780       ":net",
 781       "//base",
 782       "//gin",
 783       "//url",
 784       "//v8",
 785     ]
 786
 787     forward_dependent_configs_from = [ ":net" ]
 788   }
 789 }
 790
 791 if (!is_ios && !is_android) {
 792   executable("crash_cache") {
 793     sources = [ "tools/crash_cache/crash_cache.cc" ]
 794     configs += [ ":net_win_size_truncation" ]
 795     deps = [
 796       ":net",
 797       ":test_support",
 798       "//base",
 799     ]
 800   }
 801
 802   executable("crl_set_dump") {
 803     sources = [ "tools/crl_set_dump/crl_set_dump.cc" ]
 804     configs += [ ":net_win_size_truncation" ]
 805     deps = [
 806       ":net",
 807       "//base",
 808     ]
 809   }
 810
 811   executable("dns_fuzz_stub") {
 812     sources = [ "tools/dns_fuzz_stub/dns_fuzz_stub.cc" ]
 813     configs += [ ":net_win_size_truncation" ]
 814     deps = [
 815       ":net",
 816       "//base",
 817     ]
 818   }
 819
 820   executable("gdig") {
 821     sources = [
 822       "tools/gdig/file_net_log.cc",
 823       "tools/gdig/gdig.cc",
 824     ]
 825     deps = [
 826       ":net",
 827       "//base",
 828     ]
 829   }
 830
 831   executable("get_server_time") {
 832     sources = [ "tools/get_server_time/get_server_time.cc" ]
 833     configs += [ ":net_win_size_truncation" ]
 834     deps = [
 835       ":net",
 836       "//base",
 837       "//base:i18n",
 838       "//url",
 839     ]
 840   }
 841
 842   if (use_v8_in_net) {
 843     executable("net_watcher") {
 844       sources = [ "tools/net_watcher/net_watcher.cc" ]
 845       deps = [
 846         ":net",
 847         ":net_with_v8",
 848         "//base",
 849       ]
 850
 851       if (is_linux) {
 852         configs += [
 853           "//build/config/linux:gconf",
 854           "//build/config/linux:glib",
 855         ]
 856         deps += [ "//build/config/linux:gio" ]
 857       }
 858     }
 859   }
 860
 861   executable("run_testserver") {
 862     sources = [ "tools/testserver/run_testserver.cc" ]
 863     deps = [
 864       ":net",  # TODO(brettw) bug 363749: this shouldn't be necessary. It's not
 865                # in the GYP build, and can be removed when the bug is fixed.
 866       ":test_support",
 867       "//base",
 868       "//base/test:test_support",
 869       "//testing/gtest",
 870     ]
 871   }
 872
 873   executable("stress_cache") {
 874     sources = [ "disk_cache/blockfile/stress_cache.cc" ]
 875     configs += [ ":net_win_size_truncation" ]
 876     deps = [
 877       ":net",
 878       ":test_support",
 879       "//base",
 880     ]
 881   }
 882
 883   executable("tld_cleanup") {
 884     sources = [ "tools/tld_cleanup/tld_cleanup.cc" ]
 885     configs += [ ":net_win_size_truncation" ]
 886     deps = [
 887       "//base",
 888       "//base:i18n",
 889       "//net/tools/tld_cleanup",
 890     ]
 891   }
 892 }
 893
 894 if (is_linux) {
 895   static_library("epoll_server") {
 896     sources = [
 897       "tools/epoll_server/epoll_server.cc",
 898       "tools/epoll_server/epoll_server.h",
 899     ]
 900     deps = [
 901       ":net",
 902       "//base",
 903     ]
 904   }
 905
 906   static_library("flip_in_mem_edsm_server_base") {
 907     sources = [
 908       "tools/dump_cache/url_to_filename_encoder.cc",
 909       "tools/dump_cache/url_to_filename_encoder.h",
 910       "tools/dump_cache/url_utilities.h",
 911       "tools/dump_cache/url_utilities.cc",
 912       "tools/flip_server/acceptor_thread.h",
 913       "tools/flip_server/acceptor_thread.cc",
 914       "tools/flip_server/create_listener.cc",
 915       "tools/flip_server/create_listener.h",
 916       "tools/flip_server/constants.h",
 917       "tools/flip_server/flip_config.cc",
 918       "tools/flip_server/flip_config.h",
 919       "tools/flip_server/http_interface.cc",
 920       "tools/flip_server/http_interface.h",
 921       "tools/flip_server/loadtime_measurement.h",
 922       "tools/flip_server/mem_cache.h",
 923       "tools/flip_server/mem_cache.cc",
 924       "tools/flip_server/output_ordering.cc",
 925       "tools/flip_server/output_ordering.h",
 926       "tools/flip_server/ring_buffer.cc",
 927       "tools/flip_server/ring_buffer.h",
 928       "tools/flip_server/sm_connection.cc",
 929       "tools/flip_server/sm_connection.h",
 930       "tools/flip_server/sm_interface.h",
 931       "tools/flip_server/spdy_ssl.cc",
 932       "tools/flip_server/spdy_ssl.h",
 933       "tools/flip_server/spdy_interface.cc",
 934       "tools/flip_server/spdy_interface.h",
 935       "tools/flip_server/spdy_util.cc",
 936       "tools/flip_server/spdy_util.h",
 937       "tools/flip_server/streamer_interface.cc",
 938       "tools/flip_server/streamer_interface.h",
 939     ]
 940     deps = [
 941       ":balsa",
 942       ":epoll_server",
 943       ":net",
 944       "//base",
 945       "//third_party/boringssl",
 946     ]
 947   }
 948
 949   executable("flip_in_mem_edsm_server_unittests") {
 950     sources = [
 951       "tools/flip_server/flip_test_utils.cc",
 952       "tools/flip_server/flip_test_utils.h",
 953       "tools/flip_server/http_interface_test.cc",
 954       "tools/flip_server/mem_cache_test.cc",
 955       "tools/flip_server/run_all_tests.cc",
 956       "tools/flip_server/spdy_interface_test.cc",
 957     ]
 958     deps = [
 959       ":flip_in_mem_edsm_server_base",
 960       ":net",
 961       ":test_support",
 962       "//testing/gtest",
 963       "//testing/gmock",
 964       "//third_party/boringssl",
 965     ]
 966   }
 967
 968   executable("flip_in_mem_edsm_server") {
 969     sources = [ "tools/flip_server/flip_in_mem_edsm_server.cc" ]
 970     deps = [
 971       ":flip_in_mem_edsm_server_base",
 972       ":net",
 973       "//base",
 974     ]
 975   }
 976
 977   source_set("quic_base") {
 978     sources = [
 979       "tools/quic/quic_client.cc",
 980       "tools/quic/quic_client.h",
 981       "tools/quic/quic_client_session.cc",
 982       "tools/quic/quic_client_session.h",
 983       "tools/quic/quic_default_packet_writer.cc",
 984       "tools/quic/quic_default_packet_writer.h",
 985       "tools/quic/quic_dispatcher.h",
 986       "tools/quic/quic_dispatcher.cc",
 987       "tools/quic/quic_epoll_clock.cc",
 988       "tools/quic/quic_epoll_clock.h",
 989       "tools/quic/quic_epoll_connection_helper.cc",
 990       "tools/quic/quic_epoll_connection_helper.h",
 991       "tools/quic/quic_in_memory_cache.cc",
 992       "tools/quic/quic_in_memory_cache.h",
 993       "tools/quic/quic_packet_writer_wrapper.cc",
 994       "tools/quic/quic_packet_writer_wrapper.h",
 995       "tools/quic/quic_server.cc",
 996       "tools/quic/quic_server.h",
 997       "tools/quic/quic_server_session.cc",
 998       "tools/quic/quic_server_session.h",
 999       "tools/quic/quic_socket_utils.cc",
1000       "tools/quic/quic_socket_utils.h",
1001       "tools/quic/quic_spdy_client_stream.cc",
1002       "tools/quic/quic_spdy_client_stream.h",
1003       "tools/quic/quic_spdy_server_stream.cc",
1004       "tools/quic/quic_spdy_server_stream.h",
1005       "tools/quic/quic_time_wait_list_manager.h",
1006       "tools/quic/quic_time_wait_list_manager.cc",
1007     ]
1008     deps = [
1009       ":balsa",
1010       ":epoll_server",
1011       ":net",
1012       "//base",
1013       "//base/third_party/dynamic_annotations",
1014       "//crypto",
1015       "//third_party/boringssl",
1016       "//url",
1017     ]
1018   }
1019
1020   executable("quic_client") {
1021     sources = [ "tools/quic/quic_client_bin.cc" ]
1022     deps = [
1023       ":quic_base",
1024       ":net",
1025       "//base",
1026       "//third_party/boringssl",
1027     ]
1028   }
1029 }
1030
1031 if (is_android) {
1032   generate_jni("net_jni_headers") {
1033     sources = [
1034       "android/java/src/org/chromium/net/AndroidCertVerifyResult.java",
1035       "android/java/src/org/chromium/net/AndroidKeyStore.java",
1036       "android/java/src/org/chromium/net/AndroidNetworkLibrary.java",
1037       "android/java/src/org/chromium/net/AndroidPrivateKey.java",
1038       "android/java/src/org/chromium/net/GURLUtils.java",
1039       "android/java/src/org/chromium/net/NetworkChangeNotifier.java",
1040       "android/java/src/org/chromium/net/ProxyChangeListener.java",
1041       "android/java/src/org/chromium/net/X509Util.java",
1042     ]
1043     jni_package = "net"
1044   }
1045 }
1046
1047 if (is_android || is_linux) {
1048   executable("disk_cache_memory_test") {
1049     sources = [ "tools/disk_cache_memory_test/disk_cache_memory_test.cc" ]
1050     deps = [
1051       ":net",
1052       "//base",
1053     ]
1054   }
1055 }
1056
1057 # TODO(GYP) make this compile on Android, we need some native test deps done.
1058 # TODO(GYP) Also doesn't work on Windows; dependency on boringssl is wrong.
1059 if (!is_android && !is_win) {
1060
1061 source_set("quic_tools") {
1062   sources = [
1063     "quic/quic_dispatcher.cc",
1064     "quic/quic_dispatcher.h",
1065     "quic/quic_in_memory_cache.cc",
1066     "quic/quic_in_memory_cache.h",
1067     "quic/quic_per_connection_packet_writer.cc",
1068     "quic/quic_per_connection_packet_writer.h",
1069     "quic/quic_server.cc",
1070     "quic/quic_server.h",
1071     "quic/quic_server_packet_writer.cc",
1072     "quic/quic_server_packet_writer.h",
1073     "quic/quic_server_session.cc",
1074     "quic/quic_server_session.h",
1075     "quic/quic_spdy_server_stream.cc",
1076     "quic/quic_spdy_server_stream.h",
1077     "quic/quic_time_wait_list_manager.cc",
1078     "quic/quic_time_wait_list_manager.h",
1079   ]
1080   deps = [
1081     ":net",
1082     "//base",
1083     "//base/third_party/dynamic_annotations",
1084     "//url",
1085   ]
1086 }
1087
1088 test("net_unittests") {
1089   sources = gypi_values.net_test_sources
1090
1091   configs += [ ":net_win_size_truncation" ]
1092   defines = []
1093
1094   deps = [
1095     ":http_server",
1096     ":net",
1097     ":quic_tools",
1098     ":test_support",
1099     "//base",
1100     "//base:i18n",
1101     "//base:prefs_test_support",
1102     "//base/allocator",
1103     "//base/third_party/dynamic_annotations",
1104     "//crypto",
1105     "//crypto:platform",
1106     "//crypto:test_support",
1107     "//net/base/registry_controlled_domains",
1108     "//testing/gmock",
1109     "//testing/gtest",
1110     "//third_party/zlib",
1111     "//url",
1112   ]
1113
1114   if (is_linux) {
1115     sources += gypi_values.net_linux_test_sources
1116     deps += [
1117       ":balsa",
1118       ":epoll_server",
1119       ":flip_in_mem_edsm_server_base",
1120       ":quic_base",
1121     ]
1122   }
1123
1124   if (is_chromeos) {
1125     sources -= [
1126       "proxy/proxy_config_service_linux_unittest.cc",
1127     ]
1128   }
1129
1130   if (is_android) {
1131     sources -= [
1132       # See bug http://crbug.com/344533.
1133       "disk_cache/blockfile/index_table_v3_unittest.cc",
1134       # No res_ninit() et al on Android, so this doesn't make a lot of
1135       # sense.
1136       "dns/dns_config_service_posix_unittest.cc",
1137     ]
1138     deps += [
1139       ":net_javatests",  # FIXME(brettw)
1140       ":net_test_jni_headers",
1141     ]
1142   }
1143
1144   if (!use_nss_certs) {
1145     sources -= [
1146       "ssl/client_cert_store_nss_unittest.cc",
1147     ]
1148     if (is_chromeos) {  # Already removed for all non-ChromeOS builds.
1149       sources -= [
1150         "ssl/client_cert_store_chromeos_unittest.cc",
1151       ]
1152     }
1153   }
1154
1155   if (use_openssl) {
1156     # When building for OpenSSL, we need to exclude NSS specific tests
1157     # or functionality not supported by OpenSSL yet.
1158     # TODO(bulach): Add equivalent tests when the underlying
1159     #               functionality is ported to OpenSSL.
1160     sources -= [
1161       "cert/ct_objects_extractor_unittest.cc",
1162       "cert/multi_log_ct_verifier_unittest.cc",
1163       "cert/nss_cert_database_unittest.cc",
1164       "cert/nss_cert_database_chromeos_unittest.cc",
1165       "cert/nss_profile_filter_chromeos_unittest.cc",
1166       "cert/x509_util_nss_unittest.cc",
1167       "quic/test_tools/crypto_test_utils_nss.cc",
1168     ]
1169   } else {
1170     sources -= [
1171       "cert/x509_util_openssl_unittest.cc",
1172       "quic/test_tools/crypto_test_utils_openssl.cc",
1173       "socket/ssl_client_socket_openssl_unittest.cc",
1174       "socket/ssl_session_cache_openssl_unittest.cc",
1175     ]
1176     if (!is_desktop_linux && !is_chromeos) {
1177       sources -= [ "cert/nss_cert_database_unittest.cc" ]
1178     }
1179   }
1180
1181   if (use_kerberos) {
1182     defines += [ "USE_KERBEROS" ]
1183   } else {
1184     sources -= [
1185       "http/http_auth_gssapi_posix_unittest.cc",
1186       "http/http_auth_handler_negotiate_unittest.cc",
1187       "http/mock_gssapi_library_posix.cc",
1188       "http/mock_gssapi_library_posix.h",
1189     ]
1190   }
1191
1192   if (use_openssl || (!is_desktop_linux && !is_chromeos && !is_ios)) {
1193     # Only include this test when on Posix and using NSS for
1194     # cert verification or on iOS (which also uses NSS for certs).
1195     sources -= [ "ocsp/nss_ocsp_unittest.cc" ]
1196   }
1197
1198   if (!use_openssl_certs) {
1199     sources -= [ "ssl/openssl_client_key_store_unittest.cc" ]
1200   }
1201
1202   if (!enable_websockets) {
1203     sources -= [
1204       "socket_stream/socket_stream_metrics_unittest.cc",
1205       "socket_stream/socket_stream_unittest.cc",
1206       "spdy/spdy_websocket_stream_unittest.cc",
1207       "websockets/websocket_basic_stream_test.cc",
1208       "websockets/websocket_channel_test.cc",
1209       "websockets/websocket_deflate_predictor_impl_test.cc",
1210       "websockets/websocket_deflate_stream_test.cc",
1211       "websockets/websocket_deflater_test.cc",
1212       "websockets/websocket_errors_test.cc",
1213       "websockets/websocket_extension_parser_test.cc",
1214       "websockets/websocket_frame_parser_test.cc",
1215       "websockets/websocket_frame_test.cc",
1216       "websockets/websocket_handshake_handler_spdy_test.cc",
1217       "websockets/websocket_handshake_handler_test.cc",
1218       "websockets/websocket_handshake_stream_create_helper_test.cc",
1219       "websockets/websocket_inflater_test.cc",
1220       "websockets/websocket_job_test.cc",
1221       "websockets/websocket_net_log_params_test.cc",
1222       "websockets/websocket_stream_test.cc",
1223       "websockets/websocket_test_util.cc",
1224       "websockets/websocket_test_util.h",
1225       "websockets/websocket_throttle_test.cc",
1226     ]
1227   }
1228
1229   if (disable_file_support) {
1230     sources -= [
1231       "base/directory_lister_unittest.cc",
1232       "url_request/url_request_file_job_unittest.cc",
1233     ]
1234   }
1235
1236   if (disable_ftp_support) {
1237     sources -= [
1238       "ftp/ftp_auth_cache_unittest.cc",
1239       "ftp/ftp_ctrl_response_buffer_unittest.cc",
1240       "ftp/ftp_directory_listing_parser_ls_unittest.cc",
1241       "ftp/ftp_directory_listing_parser_netware_unittest.cc",
1242       "ftp/ftp_directory_listing_parser_os2_unittest.cc",
1243       "ftp/ftp_directory_listing_parser_unittest.cc",
1244       "ftp/ftp_directory_listing_parser_unittest.h",
1245       "ftp/ftp_directory_listing_parser_vms_unittest.cc",
1246       "ftp/ftp_directory_listing_parser_windows_unittest.cc",
1247       "ftp/ftp_network_transaction_unittest.cc",
1248       "ftp/ftp_util_unittest.cc",
1249       "url_request/url_request_ftp_job_unittest.cc",
1250     ]
1251   }
1252
1253   if (!enable_built_in_dns) {
1254     sources -= [
1255       "dns/address_sorter_posix_unittest.cc",
1256       "dns/address_sorter_unittest.cc",
1257     ]
1258   }
1259
1260   # Always need use_v8_in_net to be 1 to run on Android, so just remove
1261   # net_unittest's dependency on v8 when using icu alternatives instead of
1262   # setting use_v8_in_net to 0.
1263   if (use_v8_in_net && !use_icu_alternatives_on_android) {
1264     deps += [ ":net_with_v8" ]
1265   } else {
1266     sources -= [
1267       "proxy/proxy_resolver_v8_unittest.cc",
1268       "proxy/proxy_resolver_v8_tracing_unittest.cc",
1269     ]
1270   }
1271
1272   if (!enable_mdns) {
1273     sources -= [
1274       "dns/mdns_cache_unittest.cc",
1275       "dns/mdns_client_unittest.cc",
1276       "dns/record_parsed_unittest.cc",
1277       "dns/record_rdata_unittest.cc",
1278     ]
1279   }
1280
1281   if (is_ios) {
1282     # TODO(GYP)
1283     #  'actions': [
1284     #    {
1285     #      'action_name': 'copy_test_data',
1286     #      'variables': {
1287     #        'test_data_files': [
1288     #          'data/ssl/certificates/',
1289     #          'data/test.html',
1290     #          'data/url_request_unittest/',
1291     #        ],
1292     #        'test_data_prefix': 'net',
1293     #      },
1294     #      'includes': [ '../build/copy_test_data_ios.gypi' ],
1295     #    },
1296     #  ],
1297     sources -= [
1298       # TODO(droger): The following tests are disabled because the
1299       # implementation is missing or incomplete.
1300       # KeygenHandler::GenKeyAndSignChallenge() is not ported to iOS.
1301       "base/keygen_handler_unittest.cc",
1302       "disk_cache/backend_unittest.cc",
1303       "disk_cache/blockfile/block_files_unittest.cc",
1304       # Need to read input data files.
1305       "filter/gzip_filter_unittest.cc",
1306       "socket/ssl_server_socket_unittest.cc",
1307       "spdy/fuzzing/hpack_fuzz_util_test.cc",
1308       # Need TestServer.
1309       "proxy/proxy_script_fetcher_impl_unittest.cc",
1310       "socket/ssl_client_socket_unittest.cc",
1311       "url_request/url_fetcher_impl_unittest.cc",
1312       "url_request/url_request_context_builder_unittest.cc",
1313       # Needs GetAppOutput().
1314       "test/python_utils_unittest.cc",
1315
1316       # The following tests are disabled because they don't apply to
1317       # iOS.
1318       # OS is not "linux" or "freebsd" or "openbsd".
1319       "socket/unix_domain_client_socket_posix_unittest.cc",
1320       "socket/unix_domain_listen_socket_posix_unittest.cc",
1321       "socket/unix_domain_server_socket_posix_unittest.cc",
1322
1323       # See bug http://crbug.com/344533.
1324       "disk_cache/blockfile/index_table_v3_unittest.cc",
1325     ]
1326   }
1327
1328   if (is_android) {
1329     sources -= [
1330       "dns/dns_config_service_posix_unittest.cc",
1331     ]
1332     # TODO(GYP)
1333     # # TODO(mmenke):  This depends on test_support_base, which depends on
1334     # #                icu.  Figure out a way to remove that dependency.
1335     # 'dependencies': [
1336     #   '../testing/android/native_test.gyp:native_test_native_code',
1337     # ]
1338
1339     set_sources_assignment_filter([])
1340     sources += [ "base/address_tracker_linux_unittest.cc" ]
1341     set_sources_assignment_filter(sources_assignment_filter)
1342   }
1343
1344   if (use_icu_alternatives_on_android) {
1345     sources -= [
1346       "base/filename_util_unittest.cc",
1347       "base/net_util_icu_unittest.cc",
1348     ]
1349     deps -= [ "//base:i18n" ]
1350   }
1351 }
1352
1353 executable("quic_server") {
1354   sources = [ "quic/quic_server_bin.cc" ]
1355   deps = [
1356     ":quic_tools",
1357     ":net",
1358     "//base",
1359     "//third_party/boringssl",
1360   ]
1361 }
1362
1363 }  # !is_android