app/l10n_util_mac.mm

   1 // Copyright (c) 2010 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #import <Foundation/Foundation.h>
   6
   7 #include "app/l10n_util.h"
   8 #include "app/l10n_util_mac.h"
   9 #include "base/sys_string_conversions.h"
  10 #include "base/lazy_instance.h"
  11 #include "base/logging.h"
  12
  13 namespace {
  14
  15 class OverrideLocaleHolder {
  16  public:
  17   OverrideLocaleHolder() {}
  18   const std::string& value() const { return value_; }
  19   void set_value(const std::string override_value) { value_ = override_value; }
  20  private:
  21   DISALLOW_COPY_AND_ASSIGN(OverrideLocaleHolder);
  22   std::string value_;
  23 };
  24
  25 base::LazyInstance<OverrideLocaleHolder>
  26     override_locale_holder(base::LINKER_INITIALIZED);
  27
  28 }  // namespace
  29
  30 namespace l10n_util {
  31
  32 const std::string& GetLocaleOverride() {
  33   return override_locale_holder.Get().value();
  34 }
  35
  36 void OverrideLocaleWithCocoaLocale() {
  37   // NSBundle really should only be called on the main thread.
  38   DCHECK([NSThread isMainThread]);
  39
  40   // Chrome really only has one concept of locale, but Mac OS X has locale and
  41   // language that can be set independently.  After talking with Chrome UX folks
  42   // (Cole), the best path from an experience point of view is to map the Mac OS
  43   // X language into the Chrome locale.  This way strings like "Yesterday" and
  44   // "Today" are in the same language as raw dates like "March 20, 1999" (Chrome
  45   // strings resources vs ICU generated strings).  This also makes the Mac acts
  46   // like other Chrome platforms.
  47   NSArray* languageList = [[NSBundle mainBundle] preferredLocalizations];
  48   NSString* firstLocale = [languageList objectAtIndex:0];
  49   // Mac OS X uses "_" instead of "-", so swap to get a real locale value.
  50   std::string locale_value =
  51       [[firstLocale stringByReplacingOccurrencesOfString:@"_"
  52                                               withString:@"-"] UTF8String];
  53
  54   // On disk the "en-US" resources are just "en" (http://crbug.com/25578), so
  55   // the reverse mapping is done here to continue to feed Chrome the same values
  56   // in all cases on all platforms.  (l10n_util maps en to en-US if it gets
  57   // passed this on the command line)
  58   if (locale_value == "en")
  59     locale_value = "en-US";
  60
  61   override_locale_holder.Get().set_value(locale_value);
  62 }
  63
  64 // Remove the Windows-style accelerator marker and change "..." into an
  65 // ellipsis.  Returns the result in an autoreleased NSString.
  66 NSString* FixUpWindowsStyleLabel(const string16& label) {
  67   const char16 kEllipsisUTF16 = 0x2026;
  68   string16 ret;
  69   size_t label_len = label.length();
  70   ret.reserve(label_len);
  71   for (size_t i = 0; i < label_len; ++i) {
  72     char16 c = label[i];
  73     if (c == '&') {
  74       if (i + 1 < label_len && label[i + 1] == '&') {
  75         ret.push_back(c);
  76         ++i;
  77       }
  78     } else if (c == '.' && i + 2 < label_len && label[i + 1] == '.'
  79                && label[i + 2] == '.') {
  80       ret.push_back(kEllipsisUTF16);
  81       i += 2;
  82     } else {
  83       ret.push_back(c);
  84     }
  85   }
  86
  87   return base::SysUTF16ToNSString(ret);
  88 }
  89
  90 NSString* GetNSString(int message_id) {
  91   return base::SysUTF16ToNSString(l10n_util::GetStringUTF16(message_id));
  92 }
  93
  94 NSString* GetNSStringF(int message_id,
  95                        const string16& a) {
  96   return base::SysUTF16ToNSString(l10n_util::GetStringFUTF16(message_id,
  97                                                              a));
  98 }
  99
 100 NSString* GetNSStringF(int message_id,
 101                        const string16& a,
 102                        const string16& b) {
 103   return base::SysUTF16ToNSString(l10n_util::GetStringFUTF16(message_id,
 104                                                              a, b));
 105 }
 106
 107 NSString* GetNSStringF(int message_id,
 108                        const string16& a,
 109                        const string16& b,
 110                        const string16& c) {
 111   return base::SysUTF16ToNSString(l10n_util::GetStringFUTF16(message_id,
 112                                                              a, b, c));
 113 }
 114
 115 NSString* GetNSStringF(int message_id,
 116                        const string16& a,
 117                        const string16& b,
 118                        const string16& c,
 119                        const string16& d) {
 120   return base::SysUTF16ToNSString(l10n_util::GetStringFUTF16(message_id,
 121                                                              a, b, c, d));
 122 }
 123
 124 NSString* GetNSStringF(int message_id,
 125                        const string16& a,
 126                        const string16& b,
 127                        std::vector<size_t>* offsets) {
 128   return base::SysUTF16ToNSString(l10n_util::GetStringFUTF16(message_id,
 129                                                              a, b, offsets));
 130 }
 131
 132 NSString* GetNSStringWithFixup(int message_id) {
 133   return FixUpWindowsStyleLabel(l10n_util::GetStringUTF16(message_id));
 134 }
 135
 136 NSString* GetNSStringFWithFixup(int message_id,
 137                                 const string16& a) {
 138   return FixUpWindowsStyleLabel(l10n_util::GetStringFUTF16(message_id,
 139                                                            a));
 140 }
 141
 142 NSString* GetNSStringFWithFixup(int message_id,
 143                                 const string16& a,
 144                                 const string16& b) {
 145   return FixUpWindowsStyleLabel(l10n_util::GetStringFUTF16(message_id,
 146                                                            a, b));
 147 }
 148
 149 NSString* GetNSStringFWithFixup(int message_id,
 150                                 const string16& a,
 151                                 const string16& b,
 152                                 const string16& c) {
 153   return FixUpWindowsStyleLabel(l10n_util::GetStringFUTF16(message_id,
 154                                                            a, b, c));
 155 }
 156
 157 NSString* GetNSStringFWithFixup(int message_id,
 158                                 const string16& a,
 159                                 const string16& b,
 160                                 const string16& c,
 161                                 const string16& d) {
 162   return FixUpWindowsStyleLabel(l10n_util::GetStringFUTF16(message_id,
 163                                                            a, b, c, d));
 164 }
 165
 166
 167 }  // namespace l10n_util