url/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//testing/test.gni")
   6 import("//url/config.gni")
   7
   8 # Sets the USE_ICU_ALTERNATIVES_ON_ANDROID define based on the build flag.
   9 config("url_icu_config") {
  10   if (use_icu_alternatives_on_android) {
  11     defines = [ "USE_ICU_ALTERNATIVES_ON_ANDROID=1" ]
  12   }
  13 }
  14
  15 component("url") {
  16   if (is_win) {
  17     # Don't conflict with Windows' "url.dll".
  18     output_name = "url_lib"
  19   }
  20   sources = [
  21     "android/url_jni_registrar.cc",
  22     "android/url_jni_registrar.h",
  23     "gurl.cc",
  24     "gurl.h",
  25     "origin.cc",
  26     "origin.h",
  27     "third_party/mozilla/url_parse.cc",
  28     "third_party/mozilla/url_parse.h",
  29     "url_canon.h",
  30     "url_canon_etc.cc",
  31     "url_canon_filesystemurl.cc",
  32     "url_canon_fileurl.cc",
  33     "url_canon_host.cc",
  34     "url_canon_icu.cc",
  35     "url_canon_icu.h",
  36     "url_canon_internal.cc",
  37     "url_canon_internal.h",
  38     "url_canon_internal_file.h",
  39     "url_canon_ip.cc",
  40     "url_canon_ip.h",
  41     "url_canon_mailtourl.cc",
  42     "url_canon_path.cc",
  43     "url_canon_pathurl.cc",
  44     "url_canon_query.cc",
  45     "url_canon_relative.cc",
  46     "url_canon_stdstring.cc",
  47     "url_canon_stdstring.h",
  48     "url_canon_stdurl.cc",
  49     "url_constants.cc",
  50     "url_constants.h",
  51     "url_export.h",
  52     "url_file.h",
  53     "url_parse_file.cc",
  54     "url_parse_internal.h",
  55     "url_util.cc",
  56     "url_util.h",
  57   ]
  58
  59   defines = [ "URL_IMPLEMENTATION" ]
  60
  61   configs += [ ":url_icu_config" ]
  62
  63   if (is_win) {
  64     cflags = [ "/wd4267" ]  # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
  65   }
  66
  67   deps = [
  68     "//base",
  69     "//base/third_party/dynamic_annotations",
  70     "//third_party/icu:icudata",
  71     "//third_party/icu",
  72   ]
  73
  74   if (use_icu_alternatives_on_android) {
  75     sources -= [
  76       "url_canon_icu.cc",
  77       "url_canon_icu.h",
  78     ]
  79     deps -= [
  80       "//third_party/icu:icudata",
  81       "//third_party/icu",
  82     ]
  83
  84     sources += [
  85       "url_canon_icu_alternatives_android.cc",
  86       "url_canon_icu_alternatives_android.h",
  87     ]
  88   }
  89 }
  90
  91 # TODO(dpranke): crbug.com/360936. Get this to build and run on Android.
  92 if (!is_android) {
  93   test("url_unittests") {
  94     sources = [
  95       "gurl_unittest.cc",
  96       "origin_unittest.cc",
  97       "url_canon_icu_unittest.cc",
  98       "url_canon_unittest.cc",
  99       "url_parse_unittest.cc",
 100       "url_test_utils.h",
 101       "url_util_unittest.cc",
 102     ]
 103
 104     #if (is_posix && !is_mac && !is_ios) {
 105     #  if (use_allocator!="none") {
 106     #    deps += "//base/allocator"
 107     #  }
 108     #}
 109
 110     if (is_win) {
 111       cflags = [
 112         # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 113         "/wd4267",
 114       ]
 115     }
 116
 117     deps = [
 118       ":url",
 119       "//base",
 120       "//base/test:run_all_unittests",
 121       "//testing/gtest",
 122       "//third_party/icu:icuuc",
 123     ]
 124
 125     if (use_icu_alternatives_on_android) {
 126       sources -= [ "url_canon_icu_unittest.cc" ]
 127       deps -= [ "//third_party/icu:icuuc" ]
 128     }
 129   }
 130 }