ui/aura/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/ui.gni")
   6 import("//testing/test.gni")
   7
   8 component("aura") {
   9   sources = [
  10     "client/aura_constants.cc",
  11     "client/aura_constants.h",
  12     "client/capture_client.cc",
  13     "client/capture_client.h",
  14     "client/capture_delegate.h",
  15     "client/cursor_client.cc",
  16     "client/cursor_client.h",
  17     "client/cursor_client_observer.h",
  18     "client/cursor_client_observer.cc",
  19     "client/default_capture_client.cc",
  20     "client/default_capture_client.h",
  21     "client/event_client.cc",
  22     "client/event_client.h",
  23     "client/focus_change_observer.cc",
  24     "client/focus_change_observer.h",
  25     "client/focus_client.cc",
  26     "client/focus_client.h",
  27     "client/screen_position_client.cc",
  28     "client/screen_position_client.h",
  29     "client/visibility_client.cc",
  30     "client/visibility_client.h",
  31     "client/window_stacking_client.cc",
  32     "client/window_stacking_client.h",
  33     "client/window_tree_client.cc",
  34     "client/window_tree_client.h",
  35     "env.cc",
  36     "env.h",
  37     "env_observer.h",
  38     "input_state_lookup.cc",
  39     "input_state_lookup.h",
  40     "input_state_lookup_win.cc",
  41     "input_state_lookup_win.h",
  42     "layout_manager.cc",
  43     "layout_manager.h",
  44     "remote_window_tree_host_win.cc",
  45     "remote_window_tree_host_win.h",
  46     "scoped_window_targeter.cc",
  47     "scoped_window_targeter.h",
  48     "window.cc",
  49     "window.h",
  50     "window_event_dispatcher.cc",
  51     "window_event_dispatcher.h",
  52     "window_delegate.h",
  53     "window_layer_type.h",
  54     "window_observer.cc",
  55     "window_observer.h",
  56     "window_targeter.cc",
  57     "window_targeter.h",
  58     "window_tracker.cc",
  59     "window_tracker.h",
  60     "window_tree_host.cc",
  61     "window_tree_host.h",
  62     "window_tree_host_mac.mm",
  63     "window_tree_host_mac.h",
  64     "window_tree_host_observer.h",
  65     "window_tree_host_win.cc",
  66     "window_tree_host_win.h",
  67     "window_tree_host_x11.cc",
  68     "window_tree_host_x11.h",
  69     "../wm/public/activation_change_observer.h",
  70     "../wm/public/activation_change_observer.cc",
  71     "../wm/public/activation_client.cc",
  72     "../wm/public/activation_client.h",
  73     "../wm/public/activation_delegate.cc",
  74     "../wm/public/activation_delegate.h",
  75     "../wm/public/animation_host.cc",
  76     "../wm/public/animation_host.h",
  77     "../wm/public/dispatcher_client.cc",
  78     "../wm/public/dispatcher_client.h",
  79     "../wm/public/drag_drop_client.cc",
  80     "../wm/public/drag_drop_client.h",
  81     "../wm/public/drag_drop_delegate.cc",
  82     "../wm/public/drag_drop_delegate.h",
  83     "../wm/public/scoped_tooltip_disabler.cc",
  84     "../wm/public/scoped_tooltip_disabler.h",
  85     "../wm/public/tooltip_client.cc",
  86     "../wm/public/tooltip_client.h",
  87     "../wm/public/transient_window_client.cc",
  88     "../wm/public/transient_window_client.h",
  89     "../wm/public/window_move_client.cc",
  90     "../wm/public/window_move_client.h",
  91     "../wm/public/window_types.h",
  92   ]
  93
  94   defines = [ "AURA_IMPLEMENTATION" ]
  95
  96   deps = [
  97     "//base",
  98     "//base:i18n",
  99     "//base/third_party/dynamic_annotations",
 100     "//skia",
 101     "//ui/base",
 102     "//ui/base/ime",
 103     "//ui/compositor",
 104     "//ui/events",
 105     "//ui/events/platform",
 106     "//ui/gfx",
 107     "//ui/gfx/geometry",
 108   ]
 109
 110   if (use_x11) {
 111     configs += [
 112       "//build/config/linux:x11",
 113       "//build/config/linux:xrandr",
 114     ]
 115     deps += [
 116       "//ui/events:events_base",
 117       "//ui/events/devices",
 118       "//ui/events/platform/x11",
 119       "//ui/gfx/x",
 120     ]
 121   } else {
 122     sources -= [
 123       "window_tree_host_x11.cc",
 124       "window_tree_host_x11.h",
 125     ]
 126   }
 127
 128   if (is_win) {
 129     sources -= [ "input_state_lookup.cc" ]
 130
 131     deps += [
 132       "//ipc",
 133       "//ui/metro_viewer",
 134       "//ui/platform_window/win:win_window",
 135     ]
 136   }
 137
 138   if (use_ozone) {
 139     sources += [
 140       "window_tree_host_ozone.cc",
 141       "window_tree_host_ozone.h",
 142     ]
 143
 144     deps += [ "//ui/ozone" ]
 145   }
 146 }
 147
 148 source_set("test_support") {
 149   testonly = true
 150   sources = [
 151     "test/aura_test_base.cc",
 152     "test/aura_test_base.h",
 153     "test/aura_test_helper.cc",
 154     "test/aura_test_helper.h",
 155     "test/aura_test_utils.cc",
 156     "test/aura_test_utils.h",
 157     "test/env_test_helper.h",
 158     "test/event_generator_delegate_aura.cc",
 159     "test/event_generator_delegate_aura.h",
 160     "test/test_cursor_client.cc",
 161     "test/test_cursor_client.h",
 162     "test/test_focus_client.cc",
 163     "test/test_focus_client.h",
 164     "test/test_screen.cc",
 165     "test/test_screen.h",
 166     "test/test_window_tree_client.cc",
 167     "test/test_window_tree_client.h",
 168     "test/test_windows.cc",
 169     "test/test_windows.h",
 170     "test/test_window_delegate.cc",
 171     "test/test_window_delegate.h",
 172     "test/ui_controls_factory_aura.h",
 173     "test/window_event_dispatcher_test_api.cc",
 174     "test/window_event_dispatcher_test_api.h",
 175     "test/window_test_api.cc",
 176     "test/window_test_api.h",
 177   ]
 178
 179   public_deps = [
 180     ":aura",
 181   ]
 182   deps = [
 183     "//skia",
 184     "//testing/gtest",
 185     "//ui/base:test_support",
 186     "//ui/compositor:test_support",
 187     "//ui/events",
 188     "//ui/events:events_base",
 189     "//ui/events:test_support",
 190     "//ui/gfx",
 191     "//ui/gfx/geometry",
 192     "//ui/wm",
 193   ]
 194
 195   if (is_win) {
 196     sources += [ "test/ui_controls_factory_aurawin.cc" ]
 197
 198     cflags = [ "/wd4267" ]  # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 199   }
 200
 201   if (use_x11) {
 202     sources += [
 203       "test/ui_controls_factory_aurax11.cc",
 204       "test/x11_event_sender.cc",
 205       "test/x11_event_sender.h",
 206     ]
 207
 208     deps += [ "//ui/gfx/x" ]
 209   }
 210
 211   if (use_ozone) {
 212     sources += [ "test/ui_controls_factory_ozone.cc" ]
 213   }
 214 }
 215
 216 executable("demo") {
 217   output_name = "aura_demo"
 218   testonly = true
 219
 220   sources = [
 221     "demo/demo_main.cc",
 222   ]
 223
 224   deps = [
 225     ":aura",
 226     ":test_support",
 227     "//base",
 228     "//base:i18n",
 229     "//skia",
 230     "//third_party/icu",
 231     "//ui/base",
 232     "//ui/compositor",
 233     "//ui/compositor:test_support",
 234     "//ui/events",
 235     "//ui/gfx",
 236     "//ui/gfx/geometry",
 237     "//ui/gl",
 238   ]
 239
 240   if (use_x11) {
 241     deps += [ "//ui/gfx/x" ]
 242   }
 243 }
 244
 245 if (!is_win || link_chrome_on_windows) {
 246   executable("bench") {
 247     output_name = "aura_bench"
 248     testonly = true
 249
 250     sources = [
 251       "bench/bench_main.cc",
 252     ]
 253
 254     deps = [
 255       ":test_support",
 256       "//base",
 257       "//base:i18n",
 258       "//cc",
 259       "//gpu/command_buffer/client:gles2_interface",
 260       "//skia",
 261       "//third_party/icu",
 262       "//ui/base",
 263       "//ui/compositor",
 264       "//ui/compositor:test_support",
 265       "//ui/events",
 266       "//ui/gfx",
 267       "//ui/gfx/geometry",
 268       "//ui/gl",
 269     ]
 270
 271     if (use_x11) {
 272       deps += [ "//ui/gfx/x" ]
 273     }
 274   }
 275
 276   test("aura_unittests") {
 277     sources = [
 278       "gestures/gesture_recognizer_unittest.cc",
 279       "test/run_all_unittests.cc",
 280       "window_event_dispatcher_unittest.cc",
 281       "window_targeter_unittest.cc",
 282       "window_unittest.cc",
 283     ]
 284
 285     deps = [
 286       ":test_support",
 287       "//base/allocator",
 288       "//base/test:test_support",
 289       "//skia",
 290       "//testing/gtest",
 291       "//ui/base:test_support",
 292       "//ui/compositor:test_support",
 293       "//ui/events:test_support",
 294       "//ui/events:gesture_detection",
 295       "//ui/gfx",
 296       "//ui/gfx/geometry",
 297       "//ui/gl",
 298     ]
 299
 300     if (is_linux) {
 301       deps += [ "//third_party/mesa" ]
 302     }
 303   }
 304 }