ui/gfx/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/ui.gni")
   6
   7 if (is_android) {
   8   import("//build/config/android/config.gni")
   9   import("//build/config/android/rules.gni")
  10 }
  11
  12 # Several targets want to include this header file, and some of them are
  13 # child dependencies of "gfx". Therefore, we separate it out here so multiple
  14 # targets can all have a dependency for header checking purposes without
  15 # creating circular dependencies.
  16 source_set("gfx_export") {
  17   sources = [
  18     "gfx_export.h",
  19   ]
  20 }
  21
  22 component("gfx") {
  23   sources = [
  24     "android/device_display_info.cc",
  25     "android/device_display_info.h",
  26     "android/gfx_jni_registrar.cc",
  27     "android/gfx_jni_registrar.h",
  28     "android/java_bitmap.cc",
  29     "android/java_bitmap.h",
  30     "android/shared_device_display_info.cc",
  31     "android/shared_device_display_info.h",
  32     "android/view_configuration.cc",
  33     "android/view_configuration.h",
  34     "animation/animation.cc",
  35     "animation/animation.h",
  36     "animation/animation_container.cc",
  37     "animation/animation_container.h",
  38     "animation/animation_container_element.h",
  39     "animation/animation_container_observer.h",
  40     "animation/animation_delegate.h",
  41     "animation/linear_animation.cc",
  42     "animation/linear_animation.h",
  43     "animation/multi_animation.cc",
  44     "animation/multi_animation.h",
  45     "animation/slide_animation.cc",
  46     "animation/slide_animation.h",
  47     "animation/throb_animation.cc",
  48     "animation/throb_animation.h",
  49     "animation/tween.cc",
  50     "animation/tween.h",
  51     "blit.cc",
  52     "blit.h",
  53     "break_list.h",
  54     "canvas.cc",
  55     "canvas.h",
  56     "canvas_notimplemented.cc",
  57     "canvas_paint_mac.h",
  58     "canvas_paint_mac.mm",
  59     "canvas_paint_win.cc",
  60     "canvas_paint_win.h",
  61     "canvas_skia.cc",
  62     "canvas_skia_paint.h",
  63     "codec/jpeg_codec.cc",
  64     "codec/jpeg_codec.h",
  65     "codec/png_codec.cc",
  66     "codec/png_codec.h",
  67     "color_analysis.cc",
  68     "color_analysis.h",
  69     "color_profile.cc",
  70     "color_profile.h",
  71     "color_profile_mac.mm",
  72     "color_profile_win.cc",
  73     "color_utils.cc",
  74     "color_utils.h",
  75     "display.cc",
  76     "display.h",
  77     "display_change_notifier.cc",
  78     "display_change_notifier.h",
  79     "display_observer.cc",
  80     "display_observer.h",
  81     "favicon_size.cc",
  82     "favicon_size.h",
  83     "font.cc",
  84     "font.h",
  85     "font_fallback.h",
  86     "font_fallback_linux.cc",
  87     "font_fallback_mac.cc",
  88     "font_fallback_win.cc",
  89     "font_fallback_win.h",
  90     "font_list.cc",
  91     "font_list.h",
  92     "font_list_impl.cc",
  93     "font_list_impl.h",
  94     "font_render_params.cc",
  95     "font_render_params.h",
  96     "font_render_params_android.cc",
  97     "font_render_params_linux.cc",
  98     "font_render_params_mac.cc",
  99     "font_render_params_win.cc",
 100     "frame_time.h",
 101     "gdi_util.cc",
 102     "gdi_util.h",
 103     "gfx_paths.cc",
 104     "gfx_paths.h",
 105     "gpu_memory_buffer.cc",
 106     "gpu_memory_buffer.h",
 107     "icon_util.cc",
 108     "icon_util.h",
 109     "image/canvas_image_source.cc",
 110     "image/canvas_image_source.h",
 111     "image/image.cc",
 112     "image/image.h",
 113     "image/image_family.cc",
 114     "image/image_family.h",
 115     "image/image_ios.mm",
 116     "image/image_mac.mm",
 117     "image/image_png_rep.cc",
 118     "image/image_png_rep.h",
 119     "image/image_skia.cc",
 120     "image/image_skia.h",
 121     "image/image_skia_operations.cc",
 122     "image/image_skia_operations.h",
 123     "image/image_skia_rep.cc",
 124     "image/image_skia_rep.h",
 125     "image/image_skia_source.h",
 126     "image/image_skia_util_ios.h",
 127     "image/image_skia_util_ios.mm",
 128     "image/image_skia_util_mac.h",
 129     "image/image_skia_util_mac.mm",
 130     "image/image_util.cc",
 131     "image/image_util.h",
 132     "image/image_util_ios.mm",
 133     "interpolated_transform.cc",
 134     "interpolated_transform.h",
 135     "linux_font_delegate.cc",
 136     "linux_font_delegate.h",
 137     "mac/coordinate_conversion.h",
 138     "mac/coordinate_conversion.mm",
 139     "mac/scoped_ns_disable_screen_updates.h",
 140     "native_widget_types.h",
 141     "nine_image_painter.cc",
 142     "nine_image_painter.h",
 143     "path.cc",
 144     "path.h",
 145     "path_aura.cc",
 146     "path_win.cc",
 147     "path_win.h",
 148     "path_x11.cc",
 149     "path_x11.h",
 150     "platform_font.h",
 151     "platform_font_android.cc",
 152     "platform_font_ios.h",
 153     "platform_font_ios.mm",
 154     "platform_font_mac.h",
 155     "platform_font_mac.mm",
 156     "platform_font_win.cc",
 157     "platform_font_win.h",
 158     "range/range.cc",
 159     "range/range.h",
 160     "range/range_mac.mm",
 161     "range/range_win.cc",
 162     "scoped_canvas.h",
 163     "scoped_cg_context_save_gstate_mac.h",
 164     "scoped_ns_graphics_context_save_gstate_mac.h",
 165     "scoped_ns_graphics_context_save_gstate_mac.mm",
 166     "scoped_ui_graphics_push_context_ios.h",
 167     "scoped_ui_graphics_push_context_ios.mm",
 168     "screen.cc",
 169     "screen.h",
 170     "screen_android.cc",
 171     "screen_aura.cc",
 172     "screen_ios.mm",
 173     "screen_mac.mm",
 174     "screen_win.cc",
 175     "screen_win.h",
 176     "scrollbar_size.cc",
 177     "scrollbar_size.h",
 178     "selection_model.cc",
 179     "selection_model.h",
 180     "sequential_id_generator.cc",
 181     "sequential_id_generator.h",
 182     "shadow_value.cc",
 183     "shadow_value.h",
 184     "skbitmap_operations.cc",
 185     "skbitmap_operations.h",
 186     "skia_util.cc",
 187     "skia_util.h",
 188     "switches.cc",
 189     "switches.h",
 190     "sys_color_change_listener.cc",
 191     "sys_color_change_listener.h",
 192     "text_constants.h",
 193     "text_elider.cc",
 194     "text_elider.h",
 195     "text_utils.cc",
 196     "text_utils.h",
 197     "text_utils_android.cc",
 198     "text_utils_ios.mm",
 199     "transform.cc",
 200     "transform.h",
 201     "transform_util.cc",
 202     "transform_util.h",
 203     "ui_gfx_exports.cc",
 204     "utf16_indexing.cc",
 205     "utf16_indexing.h",
 206     "vsync_provider.h",
 207     "win/direct_write.cc",
 208     "win/direct_write.h",
 209     "win/dpi.cc",
 210     "win/dpi.h",
 211     "win/hwnd_util.cc",
 212     "win/hwnd_util.h",
 213     "win/scoped_set_map_mode.h",
 214     "win/singleton_hwnd.cc",
 215     "win/singleton_hwnd.h",
 216     "win/window_impl.cc",
 217     "win/window_impl.h",
 218   ]
 219
 220   defines = [ "GFX_IMPLEMENTATION" ]
 221
 222   deps = [
 223     ":gfx_export",
 224     "//base:i18n",
 225     "//base:base_static",
 226     "//base/third_party/dynamic_annotations",
 227     "//skia",
 228     "//third_party/harfbuzz-ng",
 229     "//third_party/libpng",
 230     "//third_party/zlib",
 231     "//ui/gfx/geometry",
 232   ]
 233   public_deps = [
 234     "//base",
 235     "//skia",
 236     "//third_party/icu",
 237   ]
 238
 239   # Text rendering conditions (complicated so separated out).
 240   if (is_android || is_ios) {
 241     # We don't support RenderText on these platforms.
 242   } else {
 243     # These text rendering files are supported everywhere text rendering is.
 244     sources += [
 245       "render_text.cc",
 246       "render_text.h",
 247       "render_text_harfbuzz.cc",
 248       "render_text_harfbuzz.h",
 249       "text_utils_skia.cc",
 250     ]
 251
 252     # These are the "native" rendering routines, only one should apply.
 253     if (is_win) {
 254       sources += [ "render_text_win.cc" ]
 255     } else if (is_mac) {
 256       sources += [ "render_text_mac.cc" ]
 257     } else if (use_pango) {
 258       sources += [ "render_text_pango.cc" ]
 259     } else if (use_ozone) {
 260       sources += [ "render_text_ozone.cc" ]
 261     }
 262   }
 263
 264   # iOS.
 265   if (is_ios) {
 266     sources -= [
 267       "codec/jpeg_codec.cc",
 268       "codec/jpeg_codec.h",
 269     ]
 270   } else {
 271     deps += [ "//third_party:jpeg" ]
 272   }
 273
 274   # Android.
 275   if (is_android) {
 276     sources -= [
 277       "animation/throb_animation.cc",
 278       "canvas_skia.cc",
 279       "selection_model.cc",
 280     ]
 281
 282     if (use_aura) {
 283       sources -= [ "screen_android.cc" ]
 284     } else {
 285       sources -= [ "path.cc" ]
 286     }
 287
 288     # TODO(GYP) re-enable when base_java exists.
 289     #if (!is_android_webview_build) {
 290     #  deps += [ "//base:base_java" ]
 291     #}
 292
 293     if (!is_debug) {
 294       configs -= [ "//build/config/compiler:optimize" ]
 295       configs += [ "//build/config/compiler:optimize_max" ]
 296     }
 297
 298     deps += [ ":gfx_jni_headers" ]
 299     libs = [
 300       "android",
 301       "jnigraphics",
 302     ]
 303   } else {
 304     sources -= [ "canvas_notimplemented.cc" ]
 305   }
 306
 307   # Windows.
 308   if (is_win) {
 309     cflags = [
 310       "/wd4267",  # TODO(jschuh): C4267: http://crbug.com/167187 size_t -> int.
 311       "/wd4324",  # Structure was padded due to __declspec(align()), which is
 312                   # uninteresting.
 313     ]
 314   } else {
 315     sources -= [
 316       "gdi_util.cc",
 317       "gdi_util.h",
 318       "icon_util.cc",
 319       "icon_util.h",
 320     ]
 321   }
 322
 323   # Linux.
 324   if (is_linux) {
 325     configs += [ "//build/config/linux:fontconfig" ]
 326   }
 327
 328   # Ozone stuff.
 329   if (use_ozone) {
 330     sources += [ "platform_font_ozone.cc" ]
 331   }
 332
 333   if (!use_aura) {
 334     sources -= [
 335       "nine_image_painter.cc",
 336       "nine_image_painter.h",
 337       "path_aura.cc",
 338       "screen_aura.cc",
 339     ]
 340   }
 341
 342   if (use_x11) {
 343     deps += [ "//ui/gfx/x" ]
 344     configs += [ "//build/config/linux:x11" ]
 345   } else {
 346     sources -= [ "path_x11.cc" ]
 347   }
 348
 349   if (use_pango) {
 350     sources += [
 351       "pango_util.cc",
 352       "pango_util.h",
 353       "platform_font_pango.cc",
 354       "platform_font_pango.h",
 355     ]
 356     configs += [ "//build/config/linux:pangocairo" ]
 357   }
 358   if (use_pango && use_ozone) {
 359     sources -= [ "platform_font_ozone.cc" ]
 360   }
 361 }
 362
 363 # Looking for gfx_geometry? It's //ui/gfx/geometry:geometry
 364
 365 source_set("test_support") {
 366   testonly = true
 367   sources = [
 368     "image/image_unittest_util.cc",
 369     "image/image_unittest_util.h",
 370     "image/image_unittest_util_ios.mm",
 371     "image/image_unittest_util_mac.mm",
 372     "test/fontconfig_util_linux.cc",
 373     "test/fontconfig_util_linux.h",
 374     "test/gfx_util.cc",
 375     "test/gfx_util.h",
 376     "test/ui_cocoa_test_helper.h",
 377     "test/ui_cocoa_test_helper.mm",
 378   ]
 379
 380   public_deps = [
 381     ":gfx",
 382   ]
 383
 384   deps = [
 385     "//base",
 386     "//base/test:test_support",
 387     "//skia",
 388     "//testing/gtest",
 389     "//ui/gfx/geometry",
 390   ]
 391
 392   if (is_ios) {
 393     # The cocoa files don't apply to iOS.
 394     sources -= [
 395       "test/ui_cocoa_test_helper.h",
 396       "test/ui_cocoa_test_helper.mm",
 397     ]
 398   }
 399   if (is_linux) {
 400     configs += [ "//build/config/linux:fontconfig" ]
 401   }
 402 }
 403
 404 test("gfx_unittests") {
 405   sources = [
 406     "font_unittest.cc",
 407     "image/image_family_unittest.cc",
 408     "image/image_ios_unittest.mm",
 409     "image/image_skia_unittest.cc",
 410     "image/image_unittest.cc",
 411     "screen_unittest.cc",
 412     "test/run_all_unittests.cc",
 413     "text_elider_unittest.cc",
 414     "text_utils_unittest.cc",
 415   ]
 416
 417   if (!is_ios) {
 418     sources += [
 419       "animation/animation_container_unittest.cc",
 420       "animation/animation_unittest.cc",
 421       "animation/multi_animation_unittest.cc",
 422       "animation/slide_animation_unittest.cc",
 423       "animation/tween_unittest.cc",
 424       "blit_unittest.cc",
 425       "break_list_unittest.cc",
 426       "canvas_unittest.cc",
 427       "canvas_unittest_mac.mm",
 428       "codec/jpeg_codec_unittest.cc",
 429       "codec/png_codec_unittest.cc",
 430       "color_analysis_unittest.cc",
 431       "color_profile_mac_unittest.mm",
 432       "color_utils_unittest.cc",
 433       "display_change_notifier_unittest.cc",
 434       "display_unittest.cc",
 435       "font_list_unittest.cc",
 436       "geometry/box_unittest.cc",
 437       "geometry/cubic_bezier_unittest.cc",
 438       "geometry/insets_unittest.cc",
 439       "geometry/matrix3_unittest.cc",
 440       "geometry/point_unittest.cc",
 441       "geometry/point3_unittest.cc",
 442       "geometry/quad_unittest.cc",
 443       "geometry/r_tree_unittest.cc",
 444       "geometry/rect_unittest.cc",
 445       "geometry/safe_integer_conversions_unittest.cc",
 446       "geometry/scroll_offset_unittest.cc",
 447       "geometry/size_unittest.cc",
 448       "geometry/vector2d_unittest.cc",
 449       "geometry/vector3d_unittest.cc",
 450       "image/image_mac_unittest.mm",
 451       "image/image_util_unittest.cc",
 452       "mac/coordinate_conversion_unittest.mm",
 453       "platform_font_mac_unittest.mm",
 454       "range/range_mac_unittest.mm",
 455       "range/range_unittest.cc",
 456       "range/range_win_unittest.cc",
 457       "render_text_unittest.cc",
 458       "sequential_id_generator_unittest.cc",
 459       "shadow_value_unittest.cc",
 460       "skbitmap_operations_unittest.cc",
 461       "skrect_conversion_unittest.cc",
 462       "transform_util_unittest.cc",
 463       "utf16_indexing_unittest.cc",
 464     ]
 465   }
 466
 467   deps = [
 468     ":gfx",
 469     ":test_support",
 470     "//base",
 471     "//base/test:test_support",
 472     "//skia",
 473     "//third_party/icu:icuuc",
 474     "//third_party/libpng",
 475     "//third_party/zlib",
 476     "//testing/gtest",
 477     "//ui/base",
 478     "//ui/gfx/geometry",
 479     "//ui/resources:ui_test_pak",
 480   ]
 481
 482   if (use_pango) {
 483     sources += [
 484       "font_render_params_linux_unittest.cc",
 485       "platform_font_pango_unittest.cc",
 486     ]
 487     configs += [
 488       "//build/config/linux:pangocairo",
 489       "//build/config/linux:pangoft2",
 490     ]
 491   }
 492
 493   if (!is_mac && !is_ios) {
 494     sources += [
 495       "transform_unittest.cc",
 496       "interpolated_transform_unittest.cc",
 497     ]
 498   }
 499
 500   if (use_ozone && !use_pango) {
 501     sources -= [
 502       "canvas_unittest.cc",
 503       "font_list_unittest.cc",
 504       "font_unittest.cc",
 505       "render_text_unittest.cc",
 506       "text_elider_unittest.cc",
 507     ]
 508   }
 509
 510   if (is_android) {
 511     sources -= [
 512       # Do not run display_change_notifier_unittest.cc on Android because it
 513       # does not compile display_observer.cc
 514       "display_change_notifier_unittest.cc",
 515     ]
 516
 517     deps += [
 518       #'../../testing/android/native_test.gyp:native_test_native_code', TODO(GYP)
 519     ]
 520   }
 521
 522   if (is_android || is_ios) {
 523     sources -= [ "render_text_unittest.cc" ]
 524   }
 525
 526   if (use_aura) {
 527     sources -= [ "screen_unittest.cc" ]
 528   }
 529
 530   if (is_win) {
 531     sources += [
 532       "color_profile_win_unittest.cc",
 533       "font_fallback_win_unittest.cc",
 534       "icon_util_unittest.cc",
 535       "icon_util_unittests.rc",
 536       "path_win_unittest.cc",
 537       "platform_font_win_unittest.cc",
 538     ]
 539
 540     ldflags = [
 541       "/DELAYLOAD:d2d1.dll",
 542       "/DELAYLOAD:d3d10_1.dll",
 543     ]
 544
 545     libs = [
 546       "d2d1.lib",
 547       "d3d10_1.lib",
 548       "imm32.lib",
 549       "oleacc.lib",
 550     ]
 551
 552     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 553     cflags = [ "/wd4267" ]
 554   }
 555 }
 556
 557 if (is_android) {
 558   generate_jni("gfx_jni_headers") {
 559     sources = [
 560       "../android/java/src/org/chromium/ui/gfx/BitmapHelper.java",
 561       "../android/java/src/org/chromium/ui/gfx/DeviceDisplayInfo.java",
 562       "../android/java/src/org/chromium/ui/gfx/ViewConfigurationHelper.java",
 563     ]
 564     jni_package = "gfx"
 565   }
 566 }