skia/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 import("//testing/test.gni")
   8 if (current_cpu == "arm") {
   9   import("//build/config/arm.gni")
  10 }
  11 if (current_cpu == "mipsel" || current_cpu == "mips64el") {
  12   import("//build/config/mips.gni")
  13 }
  14
  15 skia_support_gpu = !is_ios
  16 skia_support_pdf = !is_ios && (enable_basic_printing || enable_print_preview)
  17
  18 # The list of Skia defines that are to be set for blink.
  19 gypi_blink_skia_defines =
  20     exec_script("//build/gypi_to_gn.py",
  21                 [
  22                   rebase_path(
  23                       "//third_party/WebKit/public/blink_skia_config.gypi"),
  24                   "--replace=<(skia_include_path)=//third_party/skia/include",
  25                   "--replace=<(skia_src_path)=//third_party/skia/src",
  26                 ],
  27                 "scope",
  28                 [ "//third_party/WebKit/public/blink_skia_config.gypi" ])
  29
  30 # The list of Skia defines that are to be set for chromium.
  31 gypi_skia_defines =
  32     exec_script("//build/gypi_to_gn.py",
  33                 [
  34                   rebase_path(
  35                       "//third_party/skia/gyp/skia_for_chromium_defines.gypi"),
  36                   "--replace=<(skia_include_path)=//third_party/skia/include",
  37                   "--replace=<(skia_src_path)=//third_party/skia/src",
  38                 ],
  39                 "scope",
  40                 [ "//third_party/skia/gyp/skia_for_chromium_defines.gypi" ])
  41
  42 # The list of Skia core sources that are to be set for chromium.
  43 gypi_skia_core =
  44     exec_script("//build/gypi_to_gn.py",
  45                 [
  46                   rebase_path("//third_party/skia/gyp/core.gypi"),
  47                   "--replace=<(skia_include_path)=//third_party/skia/include",
  48                   "--replace=<(skia_src_path)=//third_party/skia/src",
  49                 ],
  50                 "scope",
  51                 [ "//third_party/skia/gyp/core.gypi" ])
  52
  53 # The list of Skia gpu sources that are to be set for chromium.
  54 if (skia_support_gpu) {
  55   gypi_skia_gpu =
  56       exec_script("//build/gypi_to_gn.py",
  57                   [
  58                     rebase_path("//third_party/skia/gyp/gpu.gypi"),
  59                     "--replace=<(skia_include_path)=//third_party/skia/include",
  60                     "--replace=<(skia_src_path)=//third_party/skia/src",
  61                   ],
  62                   "scope",
  63                   [ "//third_party/skia/gyp/gpu.gypi" ])
  64 }
  65
  66 # The list of Skia pdf sources that are to be set for chromium.
  67 if (skia_support_pdf) {
  68   gypi_skia_pdf =
  69       exec_script("//build/gypi_to_gn.py",
  70                   [
  71                     rebase_path("//third_party/skia/gyp/pdf.gypi"),
  72                     "--replace=<(skia_include_path)=//third_party/skia/include",
  73                     "--replace=<(skia_src_path)=//third_party/skia/src",
  74                   ],
  75                   "scope",
  76                   [ "//third_party/skia/gyp/pdf.gypi" ])
  77 }
  78
  79 # The list of Skia effects that are to be set for chromium.
  80 gypi_skia_effects =
  81     exec_script("//build/gypi_to_gn.py",
  82                 [
  83                   rebase_path("//third_party/skia/gyp/effects.gypi"),
  84                   "--replace=<(skia_include_path)=//third_party/skia/include",
  85                   "--replace=<(skia_src_path)=//third_party/skia/src",
  86                 ],
  87                 "scope",
  88                 [ "//third_party/skia/gyp/effects.gypi" ])
  89
  90 # The list of Skia utils that are to be set for chromium.
  91 gypi_skia_utils =
  92     exec_script("//build/gypi_to_gn.py",
  93                 [
  94                   rebase_path("//third_party/skia/gyp/utils.gypi"),
  95                   "--replace=<(skia_include_path)=//third_party/skia/include",
  96                   "--replace=<(skia_src_path)=//third_party/skia/src",
  97                 ],
  98                 "scope",
  99                 [ "//third_party/skia/gyp/utils.gypi" ])
 100
 101 gypi_skia_opts =
 102     exec_script("//build/gypi_to_gn.py",
 103                 [
 104                   rebase_path("//third_party/skia/gyp/opts.gypi"),
 105                   "--replace=<(skia_include_path)=//third_party/skia/include",
 106                   "--replace=<(skia_src_path)=//third_party/skia/src",
 107                 ],
 108                 "scope",
 109                 [ "//third_party/skia/gyp/opts.gypi" ])
 110
 111 # The list of Skia files is kept in skia_gn_files.gypi. Read it.
 112 gypi_values =
 113     exec_script("//build/gypi_to_gn.py",
 114                 [
 115                   rebase_path("skia_gn_files.gypi"),
 116                   "--replace=<(skia_include_path)=//third_party/skia/include",
 117                   "--replace=<(skia_src_path)=//third_party/skia/src",
 118                 ],
 119                 "scope",
 120                 [ "skia_gn_files.gypi" ])
 121
 122 # External-facing config for dependent code.
 123 config("skia_config") {
 124   include_dirs = [
 125     "config",
 126     "ext",
 127     "//third_party/skia/include/c",
 128     "//third_party/skia/include/config",
 129     "//third_party/skia/include/core",
 130     "//third_party/skia/include/effects",
 131     "//third_party/skia/include/images",
 132     "//third_party/skia/include/lazy",
 133     "//third_party/skia/include/pathops",
 134     "//third_party/skia/include/pdf",
 135     "//third_party/skia/include/pipe",
 136     "//third_party/skia/include/ports",
 137     "//third_party/skia/include/utils",
 138   ]
 139
 140   defines = gypi_blink_skia_defines.blink_skia_defines
 141   defines += gypi_skia_defines.skia_for_chromium_defines
 142
 143   defines += []
 144
 145   if (is_component_build) {
 146     defines += [
 147       "SKIA_DLL",
 148       "GR_GL_IGNORE_ES3_MSAA=0",
 149     ]
 150   }
 151
 152   if (skia_support_gpu) {
 153     include_dirs += [
 154       "//third_party/skia/include/gpu",
 155       "//third_party/skia/src/gpu",
 156     ]
 157     defines += [ "SK_SUPPORT_GPU=1" ]
 158   } else {
 159     defines += [ "SK_SUPPORT_GPU=0" ]
 160   }
 161
 162   if (is_android) {
 163     defines += [
 164       "SK_BUILD_FOR_ANDROID",
 165       "USE_CHROMIUM_SKIA",
 166     ]
 167   }
 168
 169   if (is_mac) {
 170     defines += [ "SK_BUILD_FOR_MAC" ]
 171   }
 172
 173   if (is_win) {
 174     defines += [ "GR_GL_FUNCTION_TYPE=__stdcall" ]
 175   }
 176 }
 177
 178 # Internal-facing config for Skia library code.
 179 config("skia_library_config") {
 180   # These include directories are only included for Skia code and are not
 181   # exported to dependents. It's not clear if this is on purpose, but this
 182   # matches the GYP build.
 183   include_dirs = [
 184     "//third_party/skia/include/private",
 185     "//third_party/skia/src/core",
 186     "//third_party/skia/src/image",
 187     "//third_party/skia/src/opts",
 188     "//third_party/skia/src/pdf",
 189     "//third_party/skia/src/ports",
 190     "//third_party/skia/src/sfnt",
 191     "//third_party/skia/src/utils",
 192     "//third_party/skia/src/lazy",
 193   ]
 194   if (is_mac || is_ios) {
 195     include_dirs += [ "//third_party/skia/include/utils/mac" ]
 196   }
 197   if (is_mac) {
 198     include_dirs += [ "//third_party/skia/include/utils/ios" ]
 199   }
 200
 201   defines = []
 202
 203   if (is_component_build) {
 204     defines += [ "SKIA_IMPLEMENTATION=1" ]
 205   }
 206
 207   if (current_cpu == "arm") {
 208     if (arm_use_neon) {
 209       defines += [ "SK_ARM_HAS_NEON" ]
 210     } else if (arm_optionally_use_neon) {
 211       defines += [ "SK_ARM_HAS_OPTIONAL_NEON" ]
 212     }
 213   }
 214
 215   # Settings for text blitting, chosen to approximate the system browser.
 216   if (is_linux) {
 217     defines += [
 218       "SK_GAMMA_EXPONENT=1.2",
 219       "SK_GAMMA_CONTRAST=0.2",
 220     ]
 221   } else if (is_android) {
 222     defines += [
 223       "SK_GAMMA_APPLY_TO_A8",
 224       "SK_GAMMA_EXPONENT=1.4",
 225       "SK_GAMMA_CONTRAST=0.0",
 226     ]
 227   } else if (is_win) {
 228     defines += [
 229       "SK_GAMMA_SRGB",
 230       "SK_GAMMA_CONTRAST=0.5",
 231     ]
 232   } else if (is_mac) {
 233     defines += [
 234       "SK_GAMMA_SRGB",
 235       "SK_GAMMA_CONTRAST=0.0",
 236     ]
 237   }
 238
 239   if (is_android) {
 240     defines += [
 241       # Android devices are typically more memory constrained, so default to a
 242       # smaller glyph cache (it may be overriden at runtime when the renderer
 243       # starts up, depending on the actual device memory).
 244       "SK_DEFAULT_FONT_CACHE_LIMIT=1048576",  # 1024 * 1024
 245     ]
 246   } else {
 247     defines += [ "SK_DEFAULT_FONT_CACHE_LIMIT=20971520" ]  # 20 * 1024 * 1024
 248   }
 249
 250   if (is_win) {
 251     include_dirs += [
 252       "//third_party/skia/include/utils/win",
 253       "//third_party/skia/src/utils/win",
 254     ]
 255
 256     defines += [
 257       # On windows, GDI handles are a scarse system-wide resource so we have to
 258       # keep the glyph cache, which holds up to 4 GDI handles per entry, to a
 259       # fairly small size. http://crbug.com/314387
 260       "SK_DEFAULT_FONT_CACHE_COUNT_LIMIT=256",
 261     ]
 262
 263     cflags = [
 264       "/wd4244",  # conversion from 'type1( __int64)' to 'type2 (unsigned int)'
 265       "/wd4267",  # conversion from 'size_t' (64 bit) to 'type'(32 bit).
 266       "/wd4341",  # signed value is out of range for enum constant.
 267       "/wd4345",  # Object is default-initialized if initialization is omitted.
 268       "/wd4390",  # ';'empty statement found in looping;is it what was intended?
 269       "/wd4554",  # 'operator' : check operator precedence for possible error
 270       "/wd4748",  # compiler will disable optimizations if a function has inline
 271                   # assembly code contains flow control(jmp or jcc) statements.
 272
 273       "/wd4800",  # forcing value to bool 'true/false'(assigning int to bool).
 274     ]
 275   }
 276 }
 277
 278 component("skia") {
 279   sources = [
 280     # Chrome sources.
 281     "ext/SkDiscardableMemory_chrome.cc",
 282     "ext/SkMemory_new_handler.cpp",
 283     "ext/SkTraceMemoryDump_chrome.cc",
 284     "ext/analysis_canvas.cc",
 285     "ext/benchmarking_canvas.cc",
 286     "ext/convolver.cc",
 287     "ext/discardable_image_utils.cc",
 288     "ext/event_tracer_impl.cc",
 289     "ext/fontmgr_default_win.cc",
 290     "ext/google_logging.cc",
 291     "ext/image_operations.cc",
 292     "ext/opacity_filter_canvas.cc",
 293     "ext/platform_device.cc",
 294     "ext/platform_device_linux.cc",
 295     "ext/platform_device_mac.cc",
 296     "ext/platform_device_win.cc",
 297     "ext/recursive_gaussian_convolution.cc",
 298     "ext/skia_memory_dump_provider.cc",
 299     "ext/skia_utils_base.cc",
 300     "ext/skia_utils_ios.mm",
 301     "ext/skia_utils_mac.mm",
 302     "ext/skia_utils_win.cc",
 303   ]
 304
 305   if (!is_ios) {
 306     sources += [ "ext/platform_canvas.cc" ]
 307   }
 308   if (!is_ios && (current_cpu == "x86" || current_cpu == "x64")) {
 309     sources += [ "ext/convolver_SSE2.cc" ]
 310   } else if (current_cpu == "mipsel" && mips_dsp_rev >= 2) {
 311     sources += [ "ext/convolver_mips_dspr2.cc" ]
 312   }
 313
 314   # The skia gypi values are relative to the skia_dir, so we need to rebase.
 315   sources += gypi_skia_core.sources
 316   sources += gypi_skia_effects.sources
 317   sources += gypi_skia_utils.sources
 318   sources += gypi_values.skia_library_sources
 319
 320   # This and skia_opts are really the same conceptual target so share headers.
 321   allow_circular_includes_from = [ ":skia_opts" ]
 322
 323   if (current_cpu == "arm") {
 324     sources += [ "//third_party/skia/src/core/SkUtilsArm.cpp" ]
 325   }
 326
 327   # GPU
 328   if (skia_support_gpu) {
 329     sources += gypi_skia_gpu.skgpu_sources
 330     sources += gypi_skia_gpu.skgpu_null_gl_sources
 331   }
 332
 333   # Remove unused util files include in utils.gypi
 334   sources -= [
 335     "//third_party/skia/src/utils/SkBitmapHasher.cpp",
 336     "//third_party/skia/src/utils/SkBoundaryPatch.cpp",
 337     "//third_party/skia/src/utils/SkCamera.cpp",
 338     "//third_party/skia/src/utils/SkCubicInterval.cpp",
 339     "//third_party/skia/src/utils/SkCullPoints.cpp",
 340     "//third_party/skia/src/utils/SkDumpCanvas.cpp",
 341     "//third_party/skia/src/utils/SkFrontBufferedStream.cpp",
 342     "//third_party/skia/src/utils/SkInterpolator.cpp",
 343     "//third_party/skia/src/utils/SkLayer.cpp",
 344     "//third_party/skia/src/utils/SkMD5.cpp",
 345     "//third_party/skia/src/utils/SkMeshUtils.cpp",
 346     "//third_party/skia/src/utils/SkNinePatch.cpp",
 347     "//third_party/skia/src/utils/SkOSFile.cpp",
 348     "//third_party/skia/src/utils/SkParsePath.cpp",
 349     "//third_party/skia/src/utils/SkSHA1.cpp",
 350
 351     # We don't currently need to change thread affinity, so leave out this complexity for now.
 352     "//third_party/skia/src/utils/SkThreadUtils_pthread_linux.cpp",
 353     "//third_party/skia/src/utils/SkThreadUtils_pthread_mach.cpp",
 354
 355     #testing
 356     "//third_party/skia/src/fonts/SkGScalerContext.cpp",
 357   ]
 358
 359   if (is_win) {
 360     sources -= [
 361       # Keeping _win.cpp
 362       "//third_party/skia/src/utils/SkThreadUtils_pthread.cpp",
 363       "//third_party/skia/src/utils/SkThreadUtils_pthread_other.cpp",
 364     ]
 365   } else {
 366     sources -= [
 367       # Keeping _pthread.cpp and _pthread_other.cpp.
 368       "//third_party/skia/src/utils/SkThreadUtils_win.cpp",
 369     ]
 370   }
 371
 372   # need separate win section to handle chromes auto gn filter
 373   # (build/config/BUILDCONFIG.gn)
 374   if (is_win) {
 375     sources -= [
 376       #windows
 377       "//third_party/skia/src/utils/win/SkAutoCoInitialize.cpp",
 378       "//third_party/skia/src/utils/win/SkIStream.cpp",
 379       "//third_party/skia/src/utils/win/SkWGL_win.cpp",
 380     ]
 381   }
 382
 383   if (is_android && (!enable_basic_printing && !enable_print_preview)) {
 384     sources -= [ "ext/skia_utils_base.cc" ]
 385   }
 386
 387   # Fixup skia library sources.
 388   if (is_win) {
 389     sources -= [
 390       "//third_party/skia/src/ports/SkOSFile_posix.cpp",
 391       "//third_party/skia/src/ports/SkTLS_pthread.cpp",
 392       "//third_party/skia/src/ports/SkTime_Unix.cpp",
 393     ]
 394   } else {
 395     sources -= [
 396       "//third_party/skia/src/ports/SkFontHost_win.cpp",
 397       "//third_party/skia/src/ports/SkFontMgr_win_dw.cpp",
 398       "//third_party/skia/src/ports/SkOSFile_win.cpp",
 399       "//third_party/skia/src/ports/SkRemotableFontMgr_win_dw.cpp",
 400       "//third_party/skia/src/ports/SkScalerContext_win_dw.cpp",
 401       "//third_party/skia/src/ports/SkTLS_win.cpp",
 402       "//third_party/skia/src/ports/SkTypeface_win_dw.cpp",
 403     ]
 404   }
 405   if (!is_android) {
 406     sources -= [
 407       "//third_party/skia/src/ports/SkFontMgr_android.cpp",
 408       "//third_party/skia/src/ports/SkFontMgr_android_factory.cpp",
 409       "//third_party/skia/src/ports/SkFontMgr_android_parser.cpp",
 410     ]
 411   }
 412   if (!is_mac) {
 413     sources -= [ "//third_party/skia/src/ports/SkFontHost_mac.cpp" ]
 414   }
 415
 416   if (!is_linux) {
 417     sources -= [
 418       "//third_party/skia/src/fonts/SkFontMgr_fontconfig.cpp",
 419       "//third_party/skia/src/ports/SkFontConfigInterface_direct.cpp",
 420       "//third_party/skia/src/ports/SkFontHost_fontconfig.cpp",
 421     ]
 422   }
 423
 424   if (!is_linux && !is_android) {
 425     sources -= [
 426       "//third_party/skia/src/ports/SkFontHost_FreeType.cpp",
 427       "//third_party/skia/src/ports/SkFontHost_FreeType_common.cpp",
 428     ]
 429   }
 430
 431   # Select the right BitmapPlatformDevice.
 432   if (is_win) {
 433     sources += [ "ext/bitmap_platform_device_win.cc" ]
 434   } else if (is_mac) {
 435     sources += [ "ext/bitmap_platform_device_mac.cc" ]
 436   } else if (use_cairo) {
 437     sources += [ "ext/bitmap_platform_device_cairo.cc" ]
 438   } else if (!is_ios) {
 439     sources += [ "ext/bitmap_platform_device_skia.cc" ]
 440   }
 441
 442   if (is_clang) {
 443     # Skia won't compile with some of the more strict clang warnings.
 444     # e.g. it does:
 445     #  SkASSERT(!"sk_out_of_memory");
 446     configs -= [ "//build/config/clang:extra_warnings" ]
 447   }
 448
 449   configs -= [ "//build/config/compiler:chromium_code" ]
 450   configs += [
 451     ":skia_library_config",
 452     "//build/config:precompiled_headers",
 453     "//build/config/compiler:no_chromium_code",
 454   ]
 455   public_configs = [ ":skia_config" ]
 456
 457   deps = [
 458     ":skia_opts",
 459     "//base",
 460     "//base/third_party/dynamic_annotations",
 461     "//third_party/zlib",
 462   ]
 463
 464   if (is_linux) {
 465     configs += [
 466       "//build/config/linux:fontconfig",
 467       "//build/config/linux:freetype2",
 468     ]
 469     if (use_pango) {
 470       configs += [ "//build/config/linux:pangocairo" ]
 471     }
 472     deps += [ "//third_party/icu:icuuc" ]
 473   }
 474
 475   if (is_android) {
 476     set_sources_assignment_filter([])
 477     sources += [ "ext/platform_device_linux.cc" ]
 478     set_sources_assignment_filter(sources_assignment_filter)
 479     deps += [
 480       "//third_party/expat",
 481       "//third_party/freetype-android:freetype",
 482       "//third_party/android_tools:cpu_features",
 483     ]
 484   }
 485
 486   if (skia_support_pdf) {
 487     deps += [ "//third_party/sfntly" ]
 488     sources += gypi_skia_pdf.sources
 489   }
 490
 491   if (is_android && !is_debug) {
 492     configs -= [ "//build/config/compiler:optimize" ]
 493     configs += [ "//build/config/compiler:optimize_max" ]
 494   }
 495
 496   if (is_ios) {
 497     libs = [ "ImageIO.framework" ]
 498     set_sources_assignment_filter([])
 499     sources += [
 500       "//third_party/skia/src/ports/SkFontHost_mac.cpp",
 501       "//third_party/skia/src/utils/mac/SkCreateCGImageRef.cpp",
 502       "//third_party/skia/src/utils/mac/SkStream_mac.cpp",
 503     ]
 504     set_sources_assignment_filter(sources_assignment_filter)
 505
 506     # To disable warning "CGContextSelectFont' is deprecated"
 507     cflags = [ "-Wno-deprecated-declarations" ]
 508   }
 509 }
 510
 511 # Separated out so it can be compiled with different flags for SSE.
 512 if (current_cpu == "x86" || current_cpu == "x64") {
 513   source_set("skia_opts_sse3") {
 514     sources = gypi_skia_opts.ssse3_sources
 515     if (!is_win || is_clang) {
 516       cflags = [ "-mssse3" ]
 517     }
 518     if (is_win) {
 519       defines = [ "SK_CPU_SSE_LEVEL=31" ]
 520     }
 521     visibility = [ ":skia_opts" ]
 522     configs -= [ "//build/config/compiler:chromium_code" ]
 523     configs += [
 524       ":skia_config",
 525       ":skia_library_config",
 526       "//build/config/compiler:no_chromium_code",
 527     ]
 528   }
 529   source_set("skia_opts_sse4") {
 530     sources = gypi_skia_opts.sse41_sources
 531     if (!is_win || is_clang) {
 532       cflags = [ "-msse4.1" ]
 533     }
 534     if (is_win) {
 535       defines = [ "SK_CPU_SSE_LEVEL=41" ]
 536     }
 537     visibility = [ ":skia_opts" ]
 538     configs -= [ "//build/config/compiler:chromium_code" ]
 539     configs += [
 540       ":skia_config",
 541       ":skia_library_config",
 542       "//build/config/compiler:no_chromium_code",
 543     ]
 544   }
 545 }
 546 source_set("skia_opts") {
 547   cflags = []
 548   defines = []
 549
 550   deps = [
 551     "//base",
 552   ]
 553
 554   if (current_cpu == "x86" || current_cpu == "x64") {
 555     sources = gypi_skia_opts.sse2_sources
 556     deps += [
 557       ":skia_opts_sse3",
 558       ":skia_opts_sse4",
 559     ]
 560   } else if (current_cpu == "arm") {
 561     # The assembly uses the frame pointer register (r7 in Thumb/r11 in
 562     # ARM), the compiler doesn't like that.
 563     cflags += [ "-fomit-frame-pointer" ]
 564
 565     if (arm_version >= 7) {
 566       sources = gypi_skia_opts.armv7_sources
 567       if (arm_use_neon || arm_optionally_use_neon) {
 568         sources += gypi_skia_opts.neon_sources
 569
 570         # Root build config sets -mfpu=$arm_fpu, which we expect to be neon
 571         # when running this.
 572         if (!arm_use_neon) {
 573           configs -= [ "//build/config/compiler:compiler_arm_fpu" ]
 574           cflags += [ "-mfpu=neon" ]
 575         }
 576       }
 577     } else {
 578       sources = gypi_skia_opts.none_sourcees
 579     }
 580   } else if (current_cpu == "mipsel") {
 581     cflags += [ "-fomit-frame-pointer" ]
 582
 583     if (mips_dsp_rev >= 1) {
 584       sources = gypi_skia_opts.mips_dsp_sources
 585     } else {
 586       sources = gypi_skia_opts.none_sources
 587     }
 588   } else {
 589     assert(false, "Need to port cpu specific stuff from skia_library_opts.gyp")
 590   }
 591
 592   if (is_android && !is_debug) {
 593     configs -= [ "//build/config/compiler:optimize" ]
 594     configs += [ "//build/config/compiler:optimize_max" ]
 595   }
 596
 597   configs -= [ "//build/config/compiler:chromium_code" ]
 598   configs += [
 599     ":skia_config",
 600     ":skia_library_config",
 601     "//build/config/compiler:no_chromium_code",
 602   ]
 603
 604   visibility = [ ":skia" ]
 605 }
 606
 607 # TODO(GYP): Delete this after we've converted everything to GN.
 608 # The _run targets exist only for compatibility w/ GYP.
 609 group("skia_unittests_run") {
 610   testonly = true
 611   deps = [
 612     ":skia_unittests",
 613   ]
 614 }
 615
 616 test("skia_unittests") {
 617   sources = [
 618     "ext/analysis_canvas_unittest.cc",
 619     "ext/bitmap_platform_device_mac_unittest.cc",
 620     "ext/convolver_unittest.cc",
 621     "ext/image_operations_unittest.cc",
 622     "ext/platform_canvas_unittest.cc",
 623     "ext/recursive_gaussian_convolution_unittest.cc",
 624     "ext/refptr_unittest.cc",
 625     "ext/skia_memory_dump_provider_unittest.cc",
 626     "ext/skia_utils_ios_unittest.mm",
 627     "ext/skia_utils_mac_unittest.mm",
 628   ]
 629
 630   if (!is_win && !is_mac) {
 631     sources -= [ "ext/platform_canvas_unittest.cc" ]
 632   }
 633
 634   deps = [
 635     ":skia",
 636     "//base",
 637     "//base/test:run_all_unittests",
 638     "//testing/gtest",
 639     "//ui/gfx",
 640     "//ui/gfx/geometry",
 641   ]
 642
 643   if (!is_ios) {
 644     deps += [ "//cc:test_support" ]  # TODO: Fix this test to not depend on cc.
 645   }
 646 }
 647
 648 if (is_linux && !is_chromeos) {
 649   # TODO(GYP): Figure out which of these work and are needed on other platforms.
 650   executable("image_operations_bench") {
 651     sources = [
 652       "ext/image_operations_bench.cc",
 653     ]
 654
 655     deps = [
 656       ":skia",
 657       "//base",
 658       "//build/config/sanitizers:deps",
 659     ]
 660   }
 661
 662   executable("filter_fuzz_stub") {
 663     testonly = true
 664     sources = [
 665       "tools/filter_fuzz_stub/filter_fuzz_stub.cc",
 666     ]
 667
 668     deps = [
 669       ":skia",
 670       "//base",
 671       "//base/test:test_support",
 672       "//build/config/sanitizers:deps",
 673     ]
 674   }
 675 }