skia/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 if (cpu_arch == "arm") {
   8   import("//build/config/arm.gni")
   9 }
  10
  11 skia_support_gpu = !is_ios
  12 skia_support_pdf = !is_ios && enable_printing != 0
  13
  14 # The list of Skia defines that are to be set for chromium.
  15 gypi_skia_defines = exec_script(
  16     "//build/gypi_to_gn.py",
  17     [ rebase_path("//third_party/skia/gyp/skia_for_chromium_defines.gypi"),
  18       "--replace=<(skia_include_path)=//third_party/skia/include",
  19       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  20     "scope",
  21     [ "//third_party/skia/gyp/skia_for_chromium_defines.gypi" ])
  22
  23 # The list of Skia core sources that are to be set for chromium.
  24 gypi_skia_core = exec_script(
  25     "//build/gypi_to_gn.py",
  26     [ rebase_path("//third_party/skia/gyp/core.gypi"),
  27       "--replace=<(skia_include_path)=//third_party/skia/include",
  28       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  29     "scope",
  30     [ "//third_party/skia/gyp/core.gypi" ])
  31
  32 # The list of Skia gpu sources that are to be set for chromium.
  33 gypi_skia_gpu = exec_script(
  34     "//build/gypi_to_gn.py",
  35     [ rebase_path("//third_party/skia/gyp/gpu.gypi"),
  36       "--replace=<(skia_include_path)=//third_party/skia/include",
  37       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  38     "scope",
  39     [ "//third_party/skia/gyp/gpu.gypi" ])
  40
  41 # The list of Skia pdf sources that are to be set for chromium.
  42 gypi_skia_pdf = exec_script(
  43     "//build/gypi_to_gn.py",
  44     [ rebase_path("//third_party/skia/gyp/pdf.gypi"),
  45       "--replace=<(skia_include_path)=//third_party/skia/include",
  46       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  47     "scope",
  48     [ "//third_party/skia/gyp/pdf.gypi" ])
  49
  50 # The list of Skia effects that are to be set for chromium.
  51 gypi_skia_effects = exec_script(
  52     "//build/gypi_to_gn.py",
  53     [ rebase_path("//third_party/skia/gyp/effects.gypi"),
  54       "--replace=<(skia_include_path)=//third_party/skia/include",
  55       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  56     "scope",
  57     [ "//third_party/skia/gyp/effects.gypi" ])
  58
  59 # The list of Skia utilss that are to be set for chromium.
  60 gypi_skia_utils = exec_script(
  61     "//build/gypi_to_gn.py",
  62     [ rebase_path("//third_party/skia/gyp/utils.gypi"),
  63       "--replace=<(skia_include_path)=//third_party/skia/include",
  64       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  65     "scope",
  66     [ "//third_party/skia/gyp/utils.gypi" ])
  67
  68 # The list of Skia files is kept in skia_gn_files.gypi. Read it.
  69 gypi_values = exec_script(
  70     "//build/gypi_to_gn.py",
  71     [ rebase_path("skia_gn_files.gypi"),
  72       "--replace=<(skia_include_path)=//third_party/skia/include",
  73       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  74     "scope",
  75     [ "skia_gn_files.gypi" ])
  76
  77 # External-facing config for dependent code.
  78 config("skia_config") {
  79   include_dirs = [
  80     "config",
  81     "ext",
  82     "//third_party/skia/include/config",
  83     "//third_party/skia/include/core",
  84     "//third_party/skia/include/effects",
  85     "//third_party/skia/include/images",
  86     "//third_party/skia/include/lazy",
  87     "//third_party/skia/include/pathops",
  88     "//third_party/skia/include/pdf",
  89     "//third_party/skia/include/pipe",
  90     "//third_party/skia/include/ports",
  91     "//third_party/skia/include/utils",
  92     "//third_party/skia/src/core",
  93     "//third_party/skia/src/image",
  94     "//third_party/skia/src/opts",
  95     "//third_party/skia/src/ports",
  96     "//third_party/skia/src/sfnt",
  97     "//third_party/skia/src/utils",
  98     "//third_party/skia/src/lazy",
  99   ]
 100
 101   defines = gypi_skia_defines.skia_for_chromium_defines
 102
 103   defines += [
 104     "SK_ENABLE_INST_COUNT=0",
 105     "GR_GL_CUSTOM_SETUP_HEADER=\"GrGLConfig_chrome.h\"",
 106     "SK_ENABLE_LEGACY_API_ALIASING=1",
 107     "SK_ATTR_DEPRECATED=SK_NOTHING_ARG1",
 108     "GR_GL_IGNORE_ES3_MSAA=0",
 109     "SK_WILL_NEVER_DRAW_PERSPECTIVE_TEXT",
 110     "SK_SUPPORT_LEGACY_GETTOTALCLIP",
 111   ]
 112
 113   if (component_mode == "shared_library") {
 114     defines += [ "SKIA_DLL" ]
 115   }
 116
 117   if (skia_support_gpu) {
 118     include_dirs += [
 119       "//third_party/skia/include/gpu",
 120       "//third_party/skia/src/gpu",
 121     ]
 122     defines += [ "SK_SUPPORT_GPU=1" ]
 123   } else {
 124     defines += [ "SK_SUPPORT_GPU=0" ]
 125   }
 126
 127   # For POSIX platforms, prefer the Mutex implementation provided by Skia
 128   # since it does not generate static initializers.
 129   if (is_posix) {
 130     defines += [ "SK_USE_POSIX_THREADS" ]
 131   }
 132
 133   if (is_android) {
 134     defines += [
 135       "SK_BUILD_FOR_ANDROID",
 136       "USE_CHROMIUM_SKIA",
 137     ]
 138   }
 139 }
 140
 141 # Internal-facing config for Skia library code.
 142 config("skia_library_config") {
 143   # These include directories are only included for Skia code and are not
 144   # exported to dependents. It's not clear if this is on purpose, but this
 145   # matches the GYP build.
 146   include_dirs = []
 147   if (is_mac || is_ios) {
 148     include_dirs += [ "//third_party/skia/include/utils/mac" ]
 149   }
 150   if (is_mac) {
 151     include_dirs += [ "//third_party/skia/include/utils/ios" ]
 152   }
 153
 154   defines = [
 155     #skia_export_defines ???) TODO
 156
 157     # skia uses static initializers to initialize the serialization logic
 158     # of its "pictures" library. This is currently not used in chrome; if
 159     # it ever gets used the processes that use it need to call
 160     # SkGraphics::Init().
 161     "SK_ALLOW_STATIC_GLOBAL_INITIALIZERS=0",
 162
 163     # Forcing the unoptimized path for the offset image filter in skia until
 164     # all filters used in Blink support the optimized path properly
 165     "SK_DISABLE_OFFSETIMAGEFILTER_OPTIMIZATION",
 166
 167     # Disable this check because it is too strict for some Chromium-specific
 168     # subclasses of SkPixelRef. See bug: crbug.com/171776.
 169     "SK_DISABLE_PIXELREF_LOCKCOUNT_BALANCE_CHECK",
 170
 171     "IGNORE_ROT_AA_RECT_OPT",
 172
 173     "SK_IGNORE_BLURRED_RRECT_OPT",
 174
 175     "SK_IGNORE_QUAD_RR_CORNERS_OPT",
 176
 177     # this flag forces Skia not to use typographic metrics with GDI.
 178     "SK_GDI_ALWAYS_USE_TEXTMETRICS_FOR_FONT_METRICS",
 179
 180     "SK_USE_DISCARDABLE_SCALEDIMAGECACHE",
 181   ]
 182
 183   # Settings for text blitting, chosen to approximate the system browser.
 184   if (is_linux) {
 185     defines += [
 186       "SK_GAMMA_EXPONENT=1.2",
 187       "SK_GAMMA_CONTRAST=0.2",
 188       "SK_HIGH_QUALITY_IS_LANCZOS",
 189     ]
 190   } else if (is_android) {
 191     defines += [
 192       "SK_GAMMA_APPLY_TO_A8",
 193       "SK_GAMMA_EXPONENT=1.4",
 194       "SK_GAMMA_CONTRAST=0.0",
 195     ]
 196   } else if (is_win) {
 197     defines += [
 198       "SK_GAMMA_SRGB",
 199       "SK_GAMMA_CONTRAST=0.5",
 200       "SK_HIGH_QUALITY_IS_LANCZOS",
 201     ]
 202   } else if (is_mac) {
 203     defines += [
 204       "SK_GAMMA_SRGB",
 205       "SK_GAMMA_CONTRAST=0.0",
 206       "SK_HIGH_QUALITY_IS_LANCZOS",
 207     ]
 208   }
 209
 210   if (is_android) {
 211     defines += [
 212       # Android devices are typically more memory constrained, so default to a
 213       # smaller glyph cache (it may be overriden at runtime when the renderer
 214       # starts up, depending on the actual device memory).
 215       "SK_DEFAULT_FONT_CACHE_LIMIT=1048576"  # 1024 * 1024
 216     ]
 217   } else {
 218     defines += [ "SK_DEFAULT_FONT_CACHE_LIMIT=20971520" ]  # 20 * 1024 * 1024
 219   }
 220
 221   if (is_win) {
 222     include_dirs = [
 223       "//third_party/skia/include/utils/win",
 224       "//third_party/skia/src/utils/win",
 225     ]
 226
 227     defines += [ "SK_FONTHOST_USES_FONTMGR" ]
 228
 229     cflags = [
 230       # TODO(brettw) comment what these are.
 231       "/wd4244",
 232       "/wd4267",
 233       "/wd4341",
 234       "/wd4345",
 235       "/wd4390",
 236       "/wd4554",
 237       "/wd4748",
 238       "/wd4800",
 239     ]
 240   }
 241 }
 242
 243 component("skia") {
 244   sources = [
 245     # Chrome sources.
 246     "ext/analysis_canvas.cc",
 247     "ext/analysis_canvas.h",
 248     "ext/benchmarking_canvas.cc",
 249     "ext/benchmarking_canvas.h",
 250     "ext/bitmap_platform_device.h",
 251     "ext/bitmap_platform_device_cairo.cc",
 252     "ext/bitmap_platform_device_cairo.h",
 253     "ext/bitmap_platform_device_mac.cc",
 254     "ext/bitmap_platform_device_mac.h",
 255     #"ext/bitmap_platform_device_skia.cc",
 256     #"ext/bitmap_platform_device_skia.h",
 257     "ext/bitmap_platform_device_win.cc",
 258     "ext/bitmap_platform_device_win.h",
 259     "ext/convolver.cc",
 260     "ext/convolver.h",
 261     "ext/event_tracer_impl.cc",
 262     "ext/event_tracer_impl.h",
 263     "ext/fontmgr_default_win.cc",
 264     "ext/fontmgr_default_win.h",
 265     "ext/google_logging.cc",
 266     "ext/image_operations.cc",
 267     "ext/image_operations.h",
 268     "ext/lazy_pixel_ref.cc",
 269     "ext/lazy_pixel_ref.h",
 270     "ext/SkThread_chrome.cc",
 271     "ext/opacity_draw_filter.cc",
 272     "ext/opacity_draw_filter.h",
 273     "ext/paint_simplifier.cc",
 274     "ext/paint_simplifier.h",
 275     "ext/pixel_ref_utils.cc",
 276     "ext/pixel_ref_utils.h",
 277     "ext/platform_canvas.cc",
 278     "ext/platform_canvas.h",
 279     "ext/platform_device.cc",
 280     "ext/platform_device.h",
 281     "ext/platform_device_linux.cc",
 282     "ext/platform_device_mac.cc",
 283     "ext/platform_device_win.cc",
 284     "ext/recursive_gaussian_convolution.cc",
 285     "ext/recursive_gaussian_convolution.h",
 286     "ext/refptr.h",
 287     "ext/SkDiscardableMemory_chrome.h",
 288     "ext/SkDiscardableMemory_chrome.cc",
 289     "ext/SkMemory_new_handler.cpp",
 290     "ext/skia_trace_shim.h",
 291     "ext/skia_utils_base.cc",
 292     "ext/skia_utils_base.h",
 293     "ext/skia_utils_ios.mm",
 294     "ext/skia_utils_ios.h",
 295     "ext/skia_utils_mac.mm",
 296     "ext/skia_utils_mac.h",
 297     "ext/skia_utils_win.cc",
 298     "ext/skia_utils_win.h",
 299     "ext/vector_canvas.h",
 300     "ext/vector_platform_device_emf_win.cc",
 301     "ext/vector_platform_device_emf_win.h",
 302     "ext/vector_platform_device_skia.cc",
 303     "ext/vector_platform_device_skia.h",
 304   ]
 305
 306   # The skia gypi values are relative to the skia_dir, so we need to rebase.
 307   sources += gypi_skia_core.sources
 308   sources += gypi_skia_effects.sources
 309   sources += gypi_skia_utils.sources
 310   sources += gypi_skia_pdf.sources
 311   sources += gypi_values.skia_library_sources
 312
 313   # GPU
 314   if (skia_support_gpu) {
 315     sources += gypi_skia_gpu.skgpu_sources
 316     sources += gypi_skia_gpu.skgpu_null_gl_sources
 317   }
 318
 319   # Remove unused util files include in utils.gypi
 320   sources -= [
 321   "//third_party/skia/include/utils/SkCondVar.h",
 322   "//third_party/skia/include/utils/SkCountdown.h",
 323   "//third_party/skia/include/utils/SkRunnable.h",
 324   "//third_party/skia/include/utils/SkThreadPool.h",
 325   "//third_party/skia/src/utils/SkCondVar.cpp",
 326   "//third_party/skia/src/utils/SkCountdown.cpp",
 327
 328   "//third_party/skia/include/utils/SkBoundaryPatch.h",
 329   "//third_party/skia/include/utils/SkFrontBufferedStream.h",
 330   "//third_party/skia/include/utils/SkCamera.h",
 331   "//third_party/skia/include/utils/SkCanvasStateUtils.h",
 332   "//third_party/skia/include/utils/SkCubicInterval.h",
 333   "//third_party/skia/include/utils/SkCullPoints.h",
 334   "//third_party/skia/include/utils/SkDebugUtils.h",
 335   "//third_party/skia/include/utils/SkDumpCanvas.h",
 336   "//third_party/skia/include/utils/SkEventTracer.h",
 337   "//third_party/skia/include/utils/SkInterpolator.h",
 338   "//third_party/skia/include/utils/SkLayer.h",
 339   "//third_party/skia/include/utils/SkMeshUtils.h",
 340   "//third_party/skia/include/utils/SkNinePatch.h",
 341   "//third_party/skia/include/utils/SkParse.h",
 342   "//third_party/skia/include/utils/SkParsePaint.h",
 343   "//third_party/skia/include/utils/SkParsePath.h",
 344   "//third_party/skia/include/utils/SkRandom.h",
 345   "//third_party/skia/include/utils/SkWGL.h",
 346
 347   "//third_party/skia/src/utils/SkBitmapHasher.cpp",
 348   "//third_party/skia/src/utils/SkBitmapHasher.h",
 349   "//third_party/skia/src/utils/SkBoundaryPatch.cpp",
 350   "//third_party/skia/src/utils/SkFrontBufferedStream.cpp",
 351   "//third_party/skia/src/utils/SkCamera.cpp",
 352   "//third_party/skia/src/utils/SkCanvasStack.h",
 353   "//third_party/skia/src/utils/SkCubicInterval.cpp",
 354   "//third_party/skia/src/utils/SkCullPoints.cpp",
 355   "//third_party/skia/src/utils/SkDumpCanvas.cpp",
 356   "//third_party/skia/src/utils/SkFloatUtils.h",
 357   "//third_party/skia/src/utils/SkGatherPixelRefsAndRects.cpp",
 358   "//third_party/skia/src/utils/SkGatherPixelRefsAndRects.h",
 359   "//third_party/skia/src/utils/SkInterpolator.cpp",
 360   "//third_party/skia/src/utils/SkLayer.cpp",
 361   "//third_party/skia/src/utils/SkMD5.cpp",
 362   "//third_party/skia/src/utils/SkMD5.h",
 363   "//third_party/skia/src/utils/SkMeshUtils.cpp",
 364   "//third_party/skia/src/utils/SkNinePatch.cpp",
 365   "//third_party/skia/src/utils/SkOSFile.cpp",
 366   "//third_party/skia/src/utils/SkParse.cpp",
 367   "//third_party/skia/src/utils/SkParseColor.cpp",
 368   "//third_party/skia/src/utils/SkParsePath.cpp",
 369   "//third_party/skia/src/utils/SkPathUtils.cpp",
 370   "//third_party/skia/src/utils/SkSHA1.cpp",
 371   "//third_party/skia/src/utils/SkSHA1.h",
 372   "//third_party/skia/src/utils/SkThreadUtils.h",
 373   "//third_party/skia/src/utils/SkThreadUtils_pthread.cpp",
 374   "//third_party/skia/src/utils/SkThreadUtils_pthread.h",
 375   "//third_party/skia/src/utils/SkThreadUtils_pthread_linux.cpp",
 376   "//third_party/skia/src/utils/SkThreadUtils_pthread_mach.cpp",
 377   "//third_party/skia/src/utils/SkThreadUtils_pthread_other.cpp",
 378   "//third_party/skia/src/utils/SkThreadUtils_win.cpp",
 379   "//third_party/skia/src/utils/SkTFitsIn.h",
 380   "//third_party/skia/src/utils/SkTLogic.h",
 381
 382   #testing
 383   "//third_party/skia/src/fonts/SkGScalerContext.cpp",
 384   "//third_party/skia/src/fonts/SkGScalerContext.h",
 385   ]
 386
 387   # need separate win section to handle chromes auto gn filter (build/config/BUILDCONFIG.gn)
 388   if (is_win) {
 389     sources -= [
 390       "//third_party/skia/src/utils/SkThreadUtils_win.h",
 391
 392       #windows
 393       "//third_party/skia/include/utils/win/SkAutoCoInitialize.h",
 394       "//third_party/skia/include/utils/win/SkHRESULT.h",
 395       "//third_party/skia/include/utils/win/SkIStream.h",
 396       "//third_party/skia/include/utils/win/SkTScopedComPtr.h",
 397       "//third_party/skia/src/utils/win/SkAutoCoInitialize.cpp",
 398       "//third_party/skia/src/utils/win/SkIStream.cpp",
 399       "//third_party/skia/src/utils/win/SkWGL_win.cpp",
 400     ]
 401   }
 402
 403   # Fixup Chrome sources.
 404   if (is_posix) {
 405     sources -= [ "ext/SkThread_chrome.cc" ]
 406   }
 407   if (is_ios) {
 408     sources -= [ "ext/vector_platform_device_skia.cc" ]
 409   }
 410   if (is_win) {
 411     sources -= [ "ext/SkThread_chrome.cc" ]
 412   }
 413   if (is_android && enable_printing == 0) {
 414     sources -= [
 415       "ext/skia_utils_base.cc",
 416       "ext/vector_platform_device_skia.cc"
 417     ]
 418   }
 419
 420   # Fixup skia library sources.
 421   if (is_win) {
 422     sources -= [
 423       "//third_party/skia/src/ports/SkOSFile_posix.cpp",
 424       "//third_party/skia/src/ports/SkTime_Unix.cpp",
 425       "//third_party/skia/src/ports/SkTLS_pthread.cpp",
 426     ]
 427   } else {
 428     sources -= [
 429       "//third_party/skia/src/ports/SkFontHost_win.cpp",
 430       "//third_party/skia/src/ports/SkFontMgr_win_dw.cpp",
 431       "//third_party/skia/src/ports/SkOSFile_win.cpp",
 432       "//third_party/skia/src/ports/SkRemotableFontMgr_win_dw.cpp",
 433       "//third_party/skia/src/ports/SkScalerContext_win_dw.cpp",
 434       "//third_party/skia/src/ports/SkScalerContext_win_dw.h",
 435       "//third_party/skia/src/ports/SkTLS_win.cpp",
 436       "//third_party/skia/src/ports/SkTypeface_win_dw.cpp",
 437       "//third_party/skia/src/ports/SkTypeface_win_dw.h",
 438     ]
 439   }
 440   if (!is_android) {
 441     sources -= [
 442       "//third_party/skia/src/ports/SkFontConfigInterface_android.cpp",
 443       "//third_party/skia/src/ports/SkFontConfigParser_android.cpp",
 444     ]
 445   }
 446   if (!is_mac) {
 447     sources -= [
 448       "//third_party/skia/src/ports/SkFontHost_mac.cpp",
 449     ]
 450   }
 451
 452   if (!is_linux) {
 453     sources -= [
 454       "//third_party/skia/src/fonts/SkFontMgr_fontconfig.cpp",
 455       "//third_party/skia/src/ports/SkFontConfigInterface_direct.cpp",
 456       "//third_party/skia/src/ports/SkFontHost_fontconfig.cpp",
 457       "//third_party/skia/src/ports/SkFontHost_FreeType_common.cpp",
 458       "//third_party/skia/src/ports/SkFontHost_FreeType.cpp",
 459     ]
 460   }
 461
 462   if (!use_cairo) {
 463     sources -= [
 464       "ext/bitmap_platform_device_cairo.cc",
 465       "ext/bitmap_platform_device_cairo.h",
 466     ]
 467   }
 468
 469   if (is_clang) {
 470     # Skia won't compile with some of the more strict clang warnings.
 471     # e.g. it does:
 472     #  SkASSERT(!"sk_out_of_memory");
 473     configs -= [ "//build/config/clang:extra_warnings" ]
 474   }
 475
 476   configs -= [ "//build/config/compiler:chromium_code" ]
 477   configs += [
 478     ":skia_library_config",
 479     "//build/config/compiler:no_chromium_code"
 480   ]
 481   direct_dependent_configs = [ ":skia_config" ]
 482
 483   deps = [
 484     ":skia_opts",
 485     "//base",
 486     "//base/third_party/dynamic_annotations",
 487     "//third_party/zlib",
 488   ]
 489
 490   if (component_mode == "shared_library") {
 491     defines = [ "SKIA_IMPLEMENTATION=1" ]
 492   }
 493
 494   if (is_win) {
 495     configs -= [
 496       # Some files define WIN32_LEAN_AND_MEAN and we want to avoid a duplicate
 497       # definition warning.
 498       "//build/config/win:lean_and_mean",
 499     ]
 500   }
 501
 502   if (is_linux) {
 503     configs += [
 504       "//build/config/linux:fontconfig",
 505       "//build/config/linux:freetype2",
 506       "//build/config/linux:pangocairo",
 507     ]
 508     deps += [
 509       "//third_party/icu:icuuc",
 510     ]
 511   }
 512
 513   if (is_android) {
 514     deps += [
 515       "//third_party/expat",
 516       "//third_party/freetype",
 517     ]
 518   }
 519
 520   if (skia_support_pdf) {
 521     deps += [ "//third_party/sfntly" ]
 522   }
 523 }
 524
 525 # Separated out so it can be compiled with different flags for SSE.
 526 source_set("skia_opts") {
 527   cflags = []
 528   defines = []
 529
 530   if (cpu_arch == "x86" || cpu_arch == "x64") {
 531     sources = [
 532       # SSE 2
 533       "//third_party/skia/src/opts/opts_check_x86.cpp",
 534       "//third_party/skia/src/opts/SkBitmapFilter_opts_SSE2.cpp",
 535       "//third_party/skia/src/opts/SkBitmapProcState_opts_SSE2.cpp",
 536       "//third_party/skia/src/opts/SkBlitRect_opts_SSE2.cpp",
 537       "//third_party/skia/src/opts/SkBlitRow_opts_SSE2.cpp",
 538       "//third_party/skia/src/opts/SkBlurImage_opts_SSE2.cpp",
 539       "//third_party/skia/src/opts/SkMorphology_opts_SSE2.cpp",
 540       "//third_party/skia/src/opts/SkUtils_opts_SSE2.cpp",
 541       "//third_party/skia/src/opts/SkXfermode_opts_SSE2.cpp",
 542
 543       # SSE 3
 544       "//third_party/skia/src/opts/SkBitmapProcState_opts_SSSE3.cpp",
 545
 546       # Chrome-specific.
 547       "ext/convolver_SSE2.cc",
 548
 549       # These are header files used by this target from the skia one above.
 550       "ext/convolver.h",
 551       "//third_party/skia/include/core/SkTypes.h",
 552     ]
 553
 554     if (is_linux || is_mac) {
 555       cflags += [ "-mssse3" ]  # Note third 's'.
 556     }
 557   } else if (cpu_arch == "arm") {
 558     sources = [
 559       "//third_party/skia/src/opts/SkBitmapProcState_opts_arm.cpp",
 560     ]
 561
 562     # The assembly uses the frame pointer register (r7 in Thumb/r11 in
 563     # ARM), the compiler doesn't like that.
 564     cflags += [ "-fomit-frame-pointer" ]
 565
 566     if (arm_version >= 7) {
 567       if (arm_use_neon || arm_optionally_use_neon) {
 568         sources += [
 569           "//third_party/skia/src/opts/memset16_neon.S",
 570           "//third_party/skia/src/opts/memset32_neon.S",
 571           "//third_party/skia/src/opts/SkBitmapProcState_arm_neon.cpp",
 572           "//third_party/skia/src/opts/SkBitmapProcState_matrixProcs_neon.cpp",
 573           "//third_party/skia/src/opts/SkBitmapProcState_matrix_clamp_neon.h",
 574           "//third_party/skia/src/opts/SkBitmapProcState_matrix_repeat_neon.h",
 575           "//third_party/skia/src/opts/SkBlitMask_opts_arm_neon.cpp",
 576           "//third_party/skia/src/opts/SkBlitRow_opts_arm_neon.cpp",
 577           "//third_party/skia/src/opts/SkXfermode_opts_arm_neon.cpp",
 578           "//third_party/skia/src/opts/SkBlurImage_opts_neon.cpp",
 579           "//third_party/skia/src/opts/SkMorphology_opts_neon.cpp",
 580         ]
 581
 582         cflags += [
 583           # The neon assembly contains conditional instructions which aren't
 584           # enclosed in an IT block. The assembler complains without this
 585           # option. See #86592.
 586           "-Wa,-mimplicit-it=always",
 587         ]
 588
 589         # Root build config sets -mfpu=$arm_fpu, which we expect to be neon
 590         # when running this.
 591         assert(arm_fpu == "neon")
 592
 593         #ldflags = [
 594         #  "-march=armv7-a",
 595         #  "-Wl,--fix-cortex-a8",
 596         #]
 597       }
 598
 599       if (arm_use_neon) {
 600         defines += [ "__ARM_HAVE_NEON" ]
 601       }
 602       if (arm_optionally_use_neon) {
 603         defines += [ "__ARM_HAVE_OPTIONAL_NEON_SUPPORT" ]
 604       }
 605     }
 606
 607     # Non-Neon ARM code.
 608     if (arm_version < 7 || (!arm_use_neon && arm_optionally_use_neon)) {
 609       sources += [ "//third_party/skia/src/opts/memset.arm.S" ]
 610     }
 611
 612     if (arm_version < 6) {
 613       sources += [
 614         "//third_party/skia/src/opts/SkBlitMask_opts_none.cpp",
 615         "//third_party/skia/src/opts/SkBlitRow_opts_none.cpp",
 616         "//third_party/skia/src/opts/SkUtils_opts_none.cpp",
 617         "//third_party/skia/src/opts/SkXfermode_opts_none.cpp",
 618         "//third_party/skia/src/opts/SkMorphology_opts_none.cpp",
 619         "//third_party/skia/src/opts/SkBlurImage_opts_none.cpp",
 620       ]
 621     } else {
 622       # arm version >= 6.
 623       sources += [
 624         "//third_party/skia/src/opts/SkBlitMask_opts_arm.cpp",
 625         "//third_party/skia/src/opts/SkBlitRow_opts_arm.cpp",
 626         "//third_party/skia/src/opts/SkBlitRow_opts_arm.h",
 627         "//third_party/skia/src/opts/SkBlurImage_opts_arm.cpp",
 628         "//third_party/skia/src/opts/SkMorphology_opts_arm.cpp",
 629         "//third_party/skia/src/opts/SkUtils_opts_arm.cpp",
 630         "//third_party/skia/src/opts/SkXfermode_opts_none.cpp",
 631       ]
 632     }
 633
 634   } else if (cpu_arch == "mipsel") {
 635     cflags += [ "-fomit-frame-pointer" ]
 636     sources = [
 637       "//third_party/skia/src/opts/SkBitmapProcState_opts_none.cpp",
 638       "//third_party/skia/src/opts/SkBlitMask_opts_none.cpp",
 639       "//third_party/skia/src/opts/SkBlitRow_opts_none.cpp",
 640       "//third_party/skia/src/opts/SkUtils_opts_none.cpp",
 641       "//third_party/skia/src/opts/SkXfermode_opts_none.cpp",
 642       "//third_party/skia/src/opts/SkMorphology_opts_none.cpp",
 643       "//third_party/skia/src/opts/SkBlurImage_opts_none.cpp",
 644     ]
 645   } else {
 646     assert(false, "Need to port cpu specific stuff from skia_library_opts.gyp")
 647   }
 648
 649   configs -= [ "//build/config/compiler:chromium_code" ]
 650   configs += [
 651     ":skia_config",
 652     "//build/config/compiler:no_chromium_code"
 653   ]
 654
 655   deps = [
 656     "//base",
 657   ]
 658
 659   visibility = ":skia"
 660 }