skia/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 if (cpu_arch == "arm") {
   8   import("//build/config/arm.gni")
   9 }
  10
  11 skia_support_gpu = !is_ios
  12 skia_support_pdf = !is_ios && printing_mode != 0
  13
  14 # The list of Skia defines that are to be set for chromium.
  15 gypi_skia_defines = exec_script(
  16     "//build/gypi_to_gn.py",
  17     [ rebase_path("//third_party/skia/gyp/skia_for_chromium_defines.gypi"),
  18       "--replace=<(skia_include_path)=//third_party/skia/include",
  19       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  20     "scope",
  21     [ "//third_party/skia/gyp/skia_for_chromium_defines.gypi" ])
  22
  23 # The list of Skia core sources that are to be set for chromium.
  24 gypi_skia_core = exec_script(
  25     "//build/gypi_to_gn.py",
  26     [ rebase_path("//third_party/skia/gyp/core.gypi"),
  27       "--replace=<(skia_include_path)=//third_party/skia/include",
  28       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  29     "scope",
  30     [ "//third_party/skia/gyp/core.gypi" ])
  31
  32 # The list of Skia gpu sources that are to be set for chromium.
  33 gypi_skia_gpu = exec_script(
  34     "//build/gypi_to_gn.py",
  35     [ rebase_path("//third_party/skia/gyp/gpu.gypi"),
  36       "--replace=<(skia_include_path)=//third_party/skia/include",
  37       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  38     "scope",
  39     [ "//third_party/skia/gyp/gpu.gypi" ])
  40
  41 # The list of Skia pdf sources that are to be set for chromium.
  42 gypi_skia_pdf = exec_script(
  43     "//build/gypi_to_gn.py",
  44     [ rebase_path("//third_party/skia/gyp/pdf.gypi"),
  45       "--replace=<(skia_include_path)=//third_party/skia/include",
  46       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  47     "scope",
  48     [ "//third_party/skia/gyp/pdf.gypi" ])
  49
  50 # The list of Skia effects that are to be set for chromium.
  51 gypi_skia_effects = exec_script(
  52     "//build/gypi_to_gn.py",
  53     [ rebase_path("//third_party/skia/gyp/effects.gypi"),
  54       "--replace=<(skia_include_path)=//third_party/skia/include",
  55       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  56     "scope",
  57     [ "//third_party/skia/gyp/effects.gypi" ])
  58
  59 # The list of Skia utilss that are to be set for chromium.
  60 gypi_skia_utils = exec_script(
  61     "//build/gypi_to_gn.py",
  62     [ rebase_path("//third_party/skia/gyp/utils.gypi"),
  63       "--replace=<(skia_include_path)=//third_party/skia/include",
  64       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  65     "scope",
  66     [ "//third_party/skia/gyp/utils.gypi" ])
  67
  68 # The list of Skia files is kept in skia_gn_files.gypi. Read it.
  69 gypi_values = exec_script(
  70     "//build/gypi_to_gn.py",
  71     [ rebase_path("skia_gn_files.gypi"),
  72       "--replace=<(skia_include_path)=//third_party/skia/include",
  73       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  74     "scope",
  75     [ "skia_gn_files.gypi" ])
  76
  77 # External-facing config for dependent code.
  78 config("skia_config") {
  79   include_dirs = [
  80     "config",
  81     "ext",
  82     "//third_party/skia/include/config",
  83     "//third_party/skia/include/core",
  84     "//third_party/skia/include/effects",
  85     "//third_party/skia/include/images",
  86     "//third_party/skia/include/lazy",
  87     "//third_party/skia/include/pathops",
  88     "//third_party/skia/include/pdf",
  89     "//third_party/skia/include/pipe",
  90     "//third_party/skia/include/ports",
  91     "//third_party/skia/include/utils",
  92     "//third_party/skia/src/core",
  93     "//third_party/skia/src/image",
  94     "//third_party/skia/src/opts",
  95     "//third_party/skia/src/ports",
  96     "//third_party/skia/src/sfnt",
  97     "//third_party/skia/src/utils",
  98     "//third_party/skia/src/lazy",
  99   ]
 100
 101   defines = gypi_skia_defines.skia_for_chromium_defines
 102
 103   defines += [
 104     "SK_ENABLE_INST_COUNT=0",
 105     "GR_GL_CUSTOM_SETUP_HEADER=\"GrGLConfig_chrome.h\"",
 106     "SK_ENABLE_LEGACY_API_ALIASING=1",
 107     "SK_ATTR_DEPRECATED=SK_NOTHING_ARG1",
 108     "GR_GL_IGNORE_ES3_MSAA=0",
 109     "SK_WILL_NEVER_DRAW_PERSPECTIVE_TEXT",
 110     "SK_SUPPORT_LEGACY_GETTOTALCLIP",
 111   ]
 112
 113   if (component_mode == "shared_library") {
 114     defines += [ "SKIA_DLL" ]
 115   }
 116
 117   if (skia_support_gpu) {
 118     include_dirs += [
 119       "//third_party/skia/include/gpu",
 120       "//third_party/skia/src/gpu",
 121     ]
 122     defines += [ "SK_SUPPORT_GPU=1" ]
 123   } else {
 124     defines += [ "SK_SUPPORT_GPU=0" ]
 125   }
 126
 127   # For POSIX platforms, prefer the Mutex implementation provided by Skia
 128   # since it does not generate static initializers.
 129   if (is_posix) {
 130     defines += [ "SK_USE_POSIX_THREADS" ]
 131   }
 132
 133   if (is_android) {
 134     defines += [
 135       "SK_BUILD_FOR_ANDROID",
 136       "USE_CHROMIUM_SKIA",
 137     ]
 138   }
 139
 140   if (is_mac) {
 141     defines += [ "SK_BUILD_FOR_MAC" ]
 142   }
 143 }
 144
 145 # Internal-facing config for Skia library code.
 146 config("skia_library_config") {
 147   # These include directories are only included for Skia code and are not
 148   # exported to dependents. It's not clear if this is on purpose, but this
 149   # matches the GYP build.
 150   include_dirs = []
 151   if (is_mac || is_ios) {
 152     include_dirs += [ "//third_party/skia/include/utils/mac" ]
 153   }
 154   if (is_mac) {
 155     include_dirs += [ "//third_party/skia/include/utils/ios" ]
 156   }
 157
 158   defines = [
 159     #skia_export_defines ???) TODO
 160
 161     # skia uses static initializers to initialize the serialization logic
 162     # of its "pictures" library. This is currently not used in chrome; if
 163     # it ever gets used the processes that use it need to call
 164     # SkGraphics::Init().
 165     "SK_ALLOW_STATIC_GLOBAL_INITIALIZERS=0",
 166
 167     # Forcing the unoptimized path for the offset image filter in skia until
 168     # all filters used in Blink support the optimized path properly
 169     "SK_DISABLE_OFFSETIMAGEFILTER_OPTIMIZATION",
 170
 171     "IGNORE_ROT_AA_RECT_OPT",
 172
 173     "SK_IGNORE_BLURRED_RRECT_OPT",
 174
 175     # this flag forces Skia not to use typographic metrics with GDI.
 176     "SK_GDI_ALWAYS_USE_TEXTMETRICS_FOR_FONT_METRICS",
 177
 178     "SK_USE_DISCARDABLE_SCALEDIMAGECACHE",
 179   ]
 180
 181   if (component_mode == "shared_library") {
 182     defines += [ "SKIA_IMPLEMENTATION=1" ]
 183   }
 184
 185   if (cpu_arch == "arm") {
 186     if (arm_use_neon) {
 187       defines += [ "SK_ARM_HAS_NEON" ]
 188     }
 189     if (arm_optionally_use_neon) {
 190       defines += [ "SK_ARM_HAS_OPTIONAL_NEON" ]
 191     }
 192   }
 193
 194   # Settings for text blitting, chosen to approximate the system browser.
 195   if (is_linux) {
 196     defines += [
 197       "SK_GAMMA_EXPONENT=1.2",
 198       "SK_GAMMA_CONTRAST=0.2",
 199       "SK_HIGH_QUALITY_IS_LANCZOS",
 200     ]
 201   } else if (is_android) {
 202     defines += [
 203       "SK_GAMMA_APPLY_TO_A8",
 204       "SK_GAMMA_EXPONENT=1.4",
 205       "SK_GAMMA_CONTRAST=0.0",
 206     ]
 207   } else if (is_win) {
 208     defines += [
 209       "SK_GAMMA_SRGB",
 210       "SK_GAMMA_CONTRAST=0.5",
 211       "SK_HIGH_QUALITY_IS_LANCZOS",
 212     ]
 213   } else if (is_mac) {
 214     defines += [
 215       "SK_GAMMA_SRGB",
 216       "SK_GAMMA_CONTRAST=0.0",
 217       "SK_HIGH_QUALITY_IS_LANCZOS",
 218     ]
 219   }
 220
 221   if (is_android) {
 222     defines += [
 223       # Android devices are typically more memory constrained, so default to a
 224       # smaller glyph cache (it may be overriden at runtime when the renderer
 225       # starts up, depending on the actual device memory).
 226       "SK_DEFAULT_FONT_CACHE_LIMIT=1048576"  # 1024 * 1024
 227     ]
 228   } else {
 229     defines += [ "SK_DEFAULT_FONT_CACHE_LIMIT=20971520" ]  # 20 * 1024 * 1024
 230   }
 231
 232   if (is_win) {
 233     include_dirs = [
 234       "//third_party/skia/include/utils/win",
 235       "//third_party/skia/src/utils/win",
 236     ]
 237
 238     defines += [ "SK_FONTHOST_USES_FONTMGR" ]
 239
 240     cflags = [
 241       "/wd4244", # conversion from 'type1( __int64)' to 'type2 (unsigned int)'
 242       "/wd4267", # conversion from 'size_t' (64 bit) to 'type'(32 bit).
 243       "/wd4341", # signed value is out of range for enum constant.
 244       "/wd4345", # Object is default-initialized if initialization is omitted.
 245       "/wd4390", # ';'empty statement found in looping;is it what was intended?
 246       "/wd4554", # 'operator' : check operator precedence for possible error
 247       "/wd4748", # compiler will disable optimizations if a function has inline
 248                  # assembly code contains flow control(jmp or jcc) statements.
 249       "/wd4800", # forcing value to bool 'true/false'(assigning int to bool).
 250     ]
 251   }
 252 }
 253
 254 component("skia") {
 255   sources = [
 256     # Chrome sources.
 257     "config/SkUserConfig.h",
 258     "ext/analysis_canvas.cc",
 259     "ext/analysis_canvas.h",
 260     "ext/benchmarking_canvas.cc",
 261     "ext/benchmarking_canvas.h",
 262     "ext/bitmap_platform_device.h",
 263     "ext/convolver.cc",
 264     "ext/convolver.h",
 265     "ext/event_tracer_impl.cc",
 266     "ext/event_tracer_impl.h",
 267     "ext/fontmgr_default_win.cc",
 268     "ext/fontmgr_default_win.h",
 269     "ext/google_logging.cc",
 270     "ext/image_operations.cc",
 271     "ext/image_operations.h",
 272     "ext/lazy_pixel_ref.cc",
 273     "ext/lazy_pixel_ref.h",
 274     "ext/SkThread_chrome.cc",
 275     "ext/opacity_draw_filter.cc",
 276     "ext/opacity_draw_filter.h",
 277     "ext/pixel_ref_utils.cc",
 278     "ext/pixel_ref_utils.h",
 279     "ext/platform_canvas.cc",
 280     "ext/platform_canvas.h",
 281     "ext/platform_device.cc",
 282     "ext/platform_device.h",
 283     "ext/platform_device_linux.cc",
 284     "ext/platform_device_mac.cc",
 285     "ext/platform_device_win.cc",
 286     "ext/recursive_gaussian_convolution.cc",
 287     "ext/recursive_gaussian_convolution.h",
 288     "ext/refptr.h",
 289     "ext/SkDiscardableMemory_chrome.h",
 290     "ext/SkDiscardableMemory_chrome.cc",
 291     "ext/SkMemory_new_handler.cpp",
 292     "ext/skia_trace_shim.h",
 293     "ext/skia_utils_base.cc",
 294     "ext/skia_utils_base.h",
 295     "ext/skia_utils_ios.mm",
 296     "ext/skia_utils_ios.h",
 297     "ext/skia_utils_mac.mm",
 298     "ext/skia_utils_mac.h",
 299     "ext/skia_utils_win.cc",
 300     "ext/skia_utils_win.h",
 301     "ext/vector_canvas.h",
 302     "ext/vector_platform_device_emf_win.cc",
 303     "ext/vector_platform_device_emf_win.h",
 304     "ext/vector_platform_device_skia.cc",
 305     "ext/vector_platform_device_skia.h",
 306   ]
 307
 308   # The skia gypi values are relative to the skia_dir, so we need to rebase.
 309   sources += gypi_skia_core.sources
 310   sources += gypi_skia_effects.sources
 311   sources += gypi_skia_utils.sources
 312   sources += gypi_skia_pdf.sources
 313   sources += gypi_values.skia_library_sources
 314
 315   if (cpu_arch == "arm") {
 316     sources += [
 317       "//third_party/skia/src/core/SkUtilsArm.cpp",
 318       "//third_party/skia/src/core/SkUtilsArm.h",
 319     ]
 320   }
 321
 322   # GPU
 323   if (skia_support_gpu) {
 324     sources += gypi_skia_gpu.skgpu_sources
 325     sources += gypi_skia_gpu.skgpu_null_gl_sources
 326   }
 327
 328   # Remove unused util files include in utils.gypi
 329   sources -= [
 330   "//third_party/skia/src/utils/SkCondVar.cpp",
 331   "//third_party/skia/src/utils/SkCondVar.h",
 332   "//third_party/skia/src/utils/SkRunnable.h",
 333
 334   "//third_party/skia/include/utils/SkBoundaryPatch.h",
 335   "//third_party/skia/include/utils/SkFrontBufferedStream.h",
 336   "//third_party/skia/include/utils/SkCamera.h",
 337   "//third_party/skia/include/utils/SkCanvasStateUtils.h",
 338   "//third_party/skia/include/utils/SkCubicInterval.h",
 339   "//third_party/skia/include/utils/SkCullPoints.h",
 340   "//third_party/skia/include/utils/SkDebugUtils.h",
 341   "//third_party/skia/include/utils/SkDumpCanvas.h",
 342   "//third_party/skia/include/utils/SkEventTracer.h",
 343   "//third_party/skia/include/utils/SkInterpolator.h",
 344   "//third_party/skia/include/utils/SkLayer.h",
 345   "//third_party/skia/include/utils/SkMeshUtils.h",
 346   "//third_party/skia/include/utils/SkNinePatch.h",
 347   "//third_party/skia/include/utils/SkParse.h",
 348   "//third_party/skia/include/utils/SkParsePaint.h",
 349   "//third_party/skia/include/utils/SkParsePath.h",
 350   "//third_party/skia/include/utils/SkRandom.h",
 351   "//third_party/skia/include/utils/SkWGL.h",
 352
 353   "//third_party/skia/src/utils/SkBitmapHasher.cpp",
 354   "//third_party/skia/src/utils/SkBitmapHasher.h",
 355   "//third_party/skia/src/utils/SkBoundaryPatch.cpp",
 356   "//third_party/skia/src/utils/SkFrontBufferedStream.cpp",
 357   "//third_party/skia/src/utils/SkCamera.cpp",
 358   "//third_party/skia/src/utils/SkCanvasStack.h",
 359   "//third_party/skia/src/utils/SkCubicInterval.cpp",
 360   "//third_party/skia/src/utils/SkCullPoints.cpp",
 361   "//third_party/skia/src/utils/SkDumpCanvas.cpp",
 362   "//third_party/skia/src/utils/SkFloatUtils.h",
 363   "//third_party/skia/src/utils/SkGatherPixelRefsAndRects.cpp",
 364   "//third_party/skia/src/utils/SkGatherPixelRefsAndRects.h",
 365   "//third_party/skia/src/utils/SkInterpolator.cpp",
 366   "//third_party/skia/src/utils/SkLayer.cpp",
 367   "//third_party/skia/src/utils/SkMD5.cpp",
 368   "//third_party/skia/src/utils/SkMD5.h",
 369   "//third_party/skia/src/utils/SkMeshUtils.cpp",
 370   "//third_party/skia/src/utils/SkNinePatch.cpp",
 371   "//third_party/skia/src/utils/SkOSFile.cpp",
 372   "//third_party/skia/src/utils/SkParse.cpp",
 373   "//third_party/skia/src/utils/SkParseColor.cpp",
 374   "//third_party/skia/src/utils/SkParsePath.cpp",
 375   "//third_party/skia/src/utils/SkPathUtils.cpp",
 376   "//third_party/skia/src/utils/SkSHA1.cpp",
 377   "//third_party/skia/src/utils/SkSHA1.h",
 378   "//third_party/skia/src/utils/SkThreadUtils.h",
 379   "//third_party/skia/src/utils/SkThreadUtils_pthread.cpp",
 380   "//third_party/skia/src/utils/SkThreadUtils_pthread.h",
 381   "//third_party/skia/src/utils/SkThreadUtils_pthread_linux.cpp",
 382   "//third_party/skia/src/utils/SkThreadUtils_pthread_mach.cpp",
 383   "//third_party/skia/src/utils/SkThreadUtils_pthread_other.cpp",
 384   "//third_party/skia/src/utils/SkThreadUtils_win.cpp",
 385   "//third_party/skia/src/utils/SkTFitsIn.h",
 386   "//third_party/skia/src/utils/SkTLogic.h",
 387
 388   #testing
 389   "//third_party/skia/src/fonts/SkGScalerContext.cpp",
 390   "//third_party/skia/src/fonts/SkGScalerContext.h",
 391   ]
 392
 393   # need separate win section to handle chromes auto gn filter
 394   # (build/config/BUILDCONFIG.gn)
 395   if (is_win) {
 396     sources -= [
 397       "//third_party/skia/src/utils/SkThreadUtils_win.h",
 398
 399       #windows
 400       "//third_party/skia/include/utils/win/SkAutoCoInitialize.h",
 401       "//third_party/skia/include/utils/win/SkHRESULT.h",
 402       "//third_party/skia/include/utils/win/SkIStream.h",
 403       "//third_party/skia/include/utils/win/SkTScopedComPtr.h",
 404       "//third_party/skia/src/utils/win/SkAutoCoInitialize.cpp",
 405       "//third_party/skia/src/utils/win/SkIStream.cpp",
 406       "//third_party/skia/src/utils/win/SkWGL_win.cpp",
 407     ]
 408   }
 409
 410   # Fixup Chrome sources.
 411   if (is_posix) {
 412     sources -= [ "ext/SkThread_chrome.cc" ]
 413   }
 414   if (is_ios) {
 415     sources -= [ "ext/vector_platform_device_skia.cc" ]
 416   }
 417   if (is_win) {
 418     sources -= [ "ext/SkThread_chrome.cc" ]
 419   }
 420   if (is_android && printing_mode == 0) {
 421     sources -= [
 422       "ext/skia_utils_base.cc",
 423       "ext/vector_platform_device_skia.cc"
 424     ]
 425   }
 426
 427   # Fixup skia library sources.
 428   if (is_win) {
 429     sources -= [
 430       "//third_party/skia/src/ports/SkOSFile_posix.cpp",
 431       "//third_party/skia/src/ports/SkTime_Unix.cpp",
 432       "//third_party/skia/src/ports/SkTLS_pthread.cpp",
 433     ]
 434   } else {
 435     sources -= [
 436       "//third_party/skia/src/ports/SkFontHost_win.cpp",
 437       "//third_party/skia/src/ports/SkFontMgr_win_dw.cpp",
 438       "//third_party/skia/src/ports/SkOSFile_win.cpp",
 439       "//third_party/skia/src/ports/SkRemotableFontMgr_win_dw.cpp",
 440       "//third_party/skia/src/ports/SkScalerContext_win_dw.cpp",
 441       "//third_party/skia/src/ports/SkScalerContext_win_dw.h",
 442       "//third_party/skia/src/ports/SkTLS_win.cpp",
 443       "//third_party/skia/src/ports/SkTypeface_win_dw.cpp",
 444       "//third_party/skia/src/ports/SkTypeface_win_dw.h",
 445     ]
 446   }
 447   if (!is_android) {
 448     sources -= [
 449       "//third_party/skia/src/ports/SkFontConfigParser_android.cpp",
 450       "//third_party/skia/src/ports/SkFontMgr_android.cpp",
 451     ]
 452   }
 453   if (!is_mac) {
 454     sources -= [
 455       "//third_party/skia/src/ports/SkFontHost_mac.cpp",
 456     ]
 457   }
 458
 459   if (!is_linux) {
 460     sources -= [
 461       "//third_party/skia/src/ports/SkFontHost_fontconfig.cpp",
 462       "//third_party/skia/src/fonts/SkFontMgr_fontconfig.cpp",
 463       "//third_party/skia/src/ports/SkFontConfigInterface_direct.cpp",
 464     ]
 465   }
 466
 467   if (!is_linux && !is_android) {
 468     sources -= [
 469       "//third_party/skia/src/ports/SkFontHost_FreeType_common.cpp",
 470       "//third_party/skia/src/ports/SkFontHost_FreeType.cpp",
 471     ]
 472   }
 473
 474   # Select the right BitmapPlatformDevice.
 475   if (is_win) {
 476     sources += [
 477       "ext/bitmap_platform_device_win.cc",
 478       "ext/bitmap_platform_device_win.h",
 479     ]
 480   } else if (is_mac) {
 481     sources += [
 482       "ext/bitmap_platform_device_mac.cc",
 483       "ext/bitmap_platform_device_mac.h",
 484     ]
 485   } else if (use_cairo) {
 486     sources += [
 487       "ext/bitmap_platform_device_cairo.cc",
 488       "ext/bitmap_platform_device_cairo.h",
 489     ]
 490   } else {
 491     sources += [
 492       "ext/bitmap_platform_device_skia.cc",
 493       "ext/bitmap_platform_device_skia.h",
 494     ]
 495   }
 496
 497   if (is_clang) {
 498     # Skia won't compile with some of the more strict clang warnings.
 499     # e.g. it does:
 500     #  SkASSERT(!"sk_out_of_memory");
 501     configs -= [ "//build/config/clang:extra_warnings" ]
 502   }
 503
 504   configs -= [ "//build/config/compiler:chromium_code" ]
 505   configs += [
 506     ":skia_library_config",
 507     "//build/config/compiler:no_chromium_code"
 508   ]
 509   public_configs = [ ":skia_config" ]
 510
 511   deps = [
 512     ":skia_opts",
 513     "//base",
 514     "//base/third_party/dynamic_annotations",
 515     "//third_party/zlib",
 516   ]
 517
 518   if (is_win) {
 519     configs -= [
 520       # Some files define WIN32_LEAN_AND_MEAN and we want to avoid a duplicate
 521       # definition warning.
 522       "//build/config/win:lean_and_mean",
 523     ]
 524   }
 525
 526   if (is_linux) {
 527     configs += [
 528       "//build/config/linux:fontconfig",
 529       "//build/config/linux:freetype2",
 530       "//build/config/linux:pangocairo",
 531     ]
 532     deps += [
 533       "//third_party/icu:icuuc",
 534     ]
 535   }
 536
 537   if (is_android) {
 538     set_sources_assignment_filter([])
 539     sources += [
 540       "ext/platform_device_linux.cc",
 541     ]
 542     set_sources_assignment_filter(sources_assignment_filter)
 543     deps += [
 544       "//third_party/expat",
 545       "//third_party/freetype",
 546       "//third_party/android_tools:cpu_features",
 547     ]
 548   }
 549
 550   if (skia_support_pdf) {
 551     deps += [ "//third_party/sfntly" ]
 552   }
 553
 554   if (is_android && !is_debug) {
 555     configs -= [ "//build/config/compiler:optimize" ]
 556     configs += [ "//build/config/compiler:optimize_max" ]
 557   }
 558 }
 559
 560 # Separated out so it can be compiled with different flags for SSE.
 561 source_set("skia_opts") {
 562   cflags = []
 563   defines = []
 564
 565   if (cpu_arch == "x86" || cpu_arch == "x64") {
 566     sources = [
 567       "//third_party/skia/src/opts/SkTextureCompression_opts_none.cpp",
 568
 569       # SSE 2
 570       "//third_party/skia/src/opts/opts_check_x86.cpp",
 571       "//third_party/skia/src/opts/SkBitmapFilter_opts_SSE2.cpp",
 572       "//third_party/skia/src/opts/SkBitmapProcState_opts_SSE2.cpp",
 573       "//third_party/skia/src/opts/SkBlitRect_opts_SSE2.cpp",
 574       "//third_party/skia/src/opts/SkBlitRow_opts_SSE2.cpp",
 575       "//third_party/skia/src/opts/SkBlurImage_opts_SSE2.cpp",
 576       "//third_party/skia/src/opts/SkMorphology_opts_SSE2.cpp",
 577       "//third_party/skia/src/opts/SkUtils_opts_SSE2.cpp",
 578       "//third_party/skia/src/opts/SkXfermode_opts_SSE2.cpp",
 579
 580       # SSSE 3
 581       "//third_party/skia/src/opts/SkBitmapProcState_opts_SSSE3.cpp",
 582
 583       # SSE 4
 584       "//third_party/skia/src/opts/SkBlurImage_opts_SSE4.cpp",
 585
 586       # Chrome-specific.
 587       "ext/convolver_SSE2.cc",
 588
 589       # These are header files used by this target from the skia one above.
 590       "ext/convolver.h",
 591       "//third_party/skia/include/core/SkTypes.h",
 592     ]
 593
 594     if (!is_win) {
 595       # SSE 4
 596       if (cpu_arch == "x86") {
 597         sources += [ "//third_party/skia/src/opts/SkBlitRow_opts_SSE4_asm.S" ]
 598       } else {  # x64
 599         sources += [
 600           "//third_party/skia/src/opts/SkBlitRow_opts_SSE4_x64_asm.S"
 601         ]
 602       }
 603     }
 604
 605     if (is_linux || is_mac) {
 606       cflags += [ "-msse4.1" ]
 607     }
 608   } else if (cpu_arch == "arm") {
 609     sources = [
 610       "//third_party/skia/src/opts/SkBitmapProcState_opts_arm.cpp",
 611     ]
 612
 613     # The assembly uses the frame pointer register (r7 in Thumb/r11 in
 614     # ARM), the compiler doesn't like that.
 615     cflags += [ "-fomit-frame-pointer" ]
 616
 617     if (arm_version >= 7) {
 618       if (arm_use_neon || arm_optionally_use_neon) {
 619         sources += [
 620           "//third_party/skia/src/opts/SkBitmapProcState_arm_neon.cpp",
 621           "//third_party/skia/src/opts/SkBitmapProcState_matrixProcs_neon.cpp",
 622           "//third_party/skia/src/opts/SkBitmapProcState_matrix_clamp_neon.h",
 623           "//third_party/skia/src/opts/SkBitmapProcState_matrix_repeat_neon.h",
 624           "//third_party/skia/src/opts/SkBlitMask_opts_arm_neon.cpp",
 625           "//third_party/skia/src/opts/SkBlitRow_opts_arm_neon.cpp",
 626           "//third_party/skia/src/opts/SkBlurImage_opts_neon.cpp",
 627           "//third_party/skia/src/opts/SkMorphology_opts_neon.cpp",
 628           "//third_party/skia/src/opts/SkTextureCompression_opts_neon.cpp",
 629           "//third_party/skia/src/opts/SkXfermode_opts_arm_neon.cpp",
 630           "//third_party/skia/src/opts/memset16_neon.S",
 631           "//third_party/skia/src/opts/memset32_neon.S",
 632         ]
 633
 634         # Root build config sets -mfpu=$arm_fpu, which we expect to be neon
 635         # when running this.
 636         if (!arm_use_neon) {
 637           configs -= [ "//build/config/compiler:compiler_arm_fpu" ]
 638           cflags += [
 639             "-mfpu=neon"
 640           ]
 641         }
 642
 643         #ldflags = [
 644         #  "-march=armv7-a",
 645         #  "-Wl,--fix-cortex-a8",
 646         #]
 647       }
 648     }
 649
 650     # Non-Neon ARM code.
 651     if (arm_version < 7 || !arm_use_neon) {
 652       sources += [ "//third_party/skia/src/opts/memset.arm.S" ]
 653     }
 654
 655     if (arm_version < 6) {
 656       sources += [
 657         "//third_party/skia/src/opts/SkBlitMask_opts_none.cpp",
 658         "//third_party/skia/src/opts/SkBlitRow_opts_none.cpp",
 659         "//third_party/skia/src/opts/SkBlurImage_opts_none.cpp",
 660         "//third_party/skia/src/opts/SkMorphology_opts_none.cpp",
 661         "//third_party/skia/src/opts/SkTextureCompression_opts_none.cpp",
 662         "//third_party/skia/src/opts/SkUtils_opts_none.cpp",
 663         "//third_party/skia/src/opts/SkXfermode_opts_none.cpp",
 664       ]
 665     } else {
 666       # arm version >= 6.
 667       sources += [
 668         "//third_party/skia/src/opts/SkBlitMask_opts_arm.cpp",
 669         "//third_party/skia/src/opts/SkBlitRow_opts_arm.cpp",
 670         "//third_party/skia/src/opts/SkBlitRow_opts_arm.h",
 671         "//third_party/skia/src/opts/SkBlurImage_opts_arm.cpp",
 672         "//third_party/skia/src/opts/SkMorphology_opts_arm.cpp",
 673         "//third_party/skia/src/opts/SkTextureCompression_opts_arm.cpp",
 674         "//third_party/skia/src/opts/SkUtils_opts_arm.cpp",
 675         "//third_party/skia/src/opts/SkXfermode_opts_none.cpp",
 676       ]
 677     }
 678
 679   } else if (cpu_arch == "mipsel") {
 680     cflags += [ "-fomit-frame-pointer" ]
 681     sources = [
 682       "//third_party/skia/src/opts/SkBitmapProcState_opts_none.cpp",
 683       "//third_party/skia/src/opts/SkBlitMask_opts_none.cpp",
 684       "//third_party/skia/src/opts/SkBlitRow_opts_none.cpp",
 685       "//third_party/skia/src/opts/SkBlurImage_opts_none.cpp",
 686       "//third_party/skia/src/opts/SkMorphology_opts_none.cpp",
 687       "//third_party/skia/src/opts/SkTextureCompression_opts_none.cpp",
 688       "//third_party/skia/src/opts/SkUtils_opts_none.cpp",
 689       "//third_party/skia/src/opts/SkXfermode_opts_none.cpp",
 690     ]
 691   } else {
 692     assert(false, "Need to port cpu specific stuff from skia_library_opts.gyp")
 693   }
 694
 695   if (is_android && !is_debug) {
 696     configs -= [ "//build/config/compiler:optimize" ]
 697     configs += [ "//build/config/compiler:optimize_max" ]
 698   }
 699
 700   configs -= [ "//build/config/compiler:chromium_code" ]
 701   configs += [
 702     ":skia_config",
 703     ":skia_library_config",
 704     "//build/config/compiler:no_chromium_code"
 705   ]
 706
 707   deps = [
 708     "//base",
 709   ]
 710
 711   visibility = [ ":skia" ]
 712 }