configure.in

   1 AC_INIT(Chocolate Doom, 1.2.1, fraggle@gmail.com, chocolate-doom)
   2
   3 AC_CONFIG_AUX_DIR(autotools)
   4
   5 orig_CFLAGS="$CFLAGS"
   6
   7 AC_PROG_CC
   8 AC_PROG_RANLIB
   9 AC_CHECK_PROG(HAVE_PYTHON, python, true, false)
  10
  11 OPT_LEVEL=2
  12
  13 # Engine room, we need more speed!
  14
  15 AC_ARG_ENABLE(penis-extension,
  16 [  --enable-penis-extension   Enable counterproductive compiler optimisations ],
  17 [ OPT_LEVEL=3 ])
  18
  19 # If this is gcc, we have some options we'd like to turn on.  Turn on
  20 # optimisation and debugging symbols.
  21
  22 if test "$GCC" = "yes"
  23 then
  24         CFLAGS="-O$OPT_LEVEL -g -Wall $orig_CFLAGS"
  25 fi
  26
  27 dnl Search for SDL ...
  28
  29 AM_PATH_SDL(1.1.3)
  30
  31 # Add the SDL compiler flags to the default compiler flag variables.
  32 # It is important to do this now, before checking for headers and
  33 # library functions.  The reason being that on Windows, sdl-config
  34 # sets the -mno-cygwin compiler option in order to generate MinGW
  35 # executables.  If we don't do this now, we might end up discovering
  36 # header files that are not actually available to us when we come
  37 # to compile.
  38
  39 CFLAGS="$CFLAGS $SDL_CFLAGS"
  40 LDFLAGS="$LDFLAGS $SDL_LIBS"
  41
  42 # On some platforms, SDL renames main() to SDL_main() using a #define,
  43 # so that its own main, stored in the SDLmain library, can be run first.
  44 # Unfortunately, this causes problems for autoconf, which builds
  45 # test programs to probe the system.  All library/header/symbol checks
  46 # must be run in this block, that performs a workaround for the problem.
  47
  48 AC_SDL_MAIN_WORKAROUND([
  49
  50     # Check for SDL_mixer.
  51
  52     AC_CHECK_LIB(SDL_mixer,Mix_LoadMUS,[
  53         SDLMIXER_LIBS="$SDLMIXER_LIBS -lSDL_mixer"
  54     ],[
  55         echo "*** Could not find SDL_mixer.  Please install it."
  56         exit -1
  57     ])
  58
  59     # Check for SDL_net.
  60
  61     AC_CHECK_LIB(SDL_net,SDLNet_UDP_Send,[
  62         SDLNET_LIBS="$SDLNET_LIBS -lSDL_net"
  63     ],[
  64         echo "*** Could not find SDL_net.  Please install it."
  65         exit -1
  66     ])
  67
  68     # Check for libsamplerate.
  69
  70     AC_CHECK_LIB(samplerate, src_new)
  71
  72     AC_CHECK_HEADERS([linux/kd.h dev/isa/spkrio.h dev/speaker/speaker.h])
  73     AC_CHECK_FUNCS(mmap sched_setaffinity)
  74 ])
  75
  76 AC_CHECK_TOOL(WINDRES, windres, )
  77
  78 # Windows CE build?
  79
  80 WINDOWS_CE=false
  81
  82 case "$host" in
  83     *mingw32ce*|*cegcc*|*wince*)
  84         CFLAGS="-I../wince $CFLAGS"
  85         WINDOWS_CE=true
  86         ;;
  87     *)
  88         ;;
  89 esac
  90
  91 AM_CONDITIONAL(WINDOWS_CE, $WINDOWS_CE)
  92 AM_CONDITIONAL(HAVE_WINDRES, test "$WINDRES" != "")
  93 AM_CONDITIONAL(HAVE_PYTHON, $HAVE_PYTHON)
  94
  95 dnl Automake v1.8.0 is required, please upgrade!
  96
  97 AM_INIT_AUTOMAKE([1.8.0])
  98
  99 WINDOWS_RC_VERSION=`echo $PACKAGE_VERSION.0 | sed 's/\./, /g' `
 100
 101 AM_CONFIG_HEADER(config.h:config.hin)
 102
 103 AC_SUBST(WINDOWS_RC_VERSION)
 104 AC_SUBST(SDLMIXER_CFLAGS)
 105 AC_SUBST(SDLMIXER_LIBS)
 106
 107 AC_SUBST(SDLNET_CFLAGS)
 108 AC_SUBST(SDLNET_LIBS)
 109
 110 AC_SUBST(ac_aux_dir)
 111
 112 dnl Shut up the datarootdir warnings.
 113 AC_DEFUN([AC_DATAROOTDIR_CHECKED])
 114
 115 AC_OUTPUT([
 116 Makefile
 117 wince/Makefile
 118 textscreen/Makefile
 119 textscreen/examples/Makefile
 120 setup/Makefile
 121 man/Makefile
 122 src/Makefile
 123 pcsound/Makefile
 124 pkg/Makefile
 125 pkg/wince/GNUmakefile
 126 src/resource.rc
 127 src/doom-screensaver.desktop
 128 setup/setup-res.rc
 129 ])
 130