configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.64])
   3 AC_INIT([cheese],
   4         [3.5.1],
   5         [https://bugzilla.gnome.org/enter_bug.cgi?product=cheese],
   6         [cheese],
   7         [http://projects.gnome.org/cheese/])
   8
   9 AC_CONFIG_AUX_DIR([build-aux])
  10 AC_CONFIG_HEADERS([cheese-config.h])
  11 AC_CONFIG_SRCDIR([configure.ac])
  12 AC_CONFIG_MACRO_DIR([m4])
  13
  14 AM_INIT_AUTOMAKE([1.11 -Wall -Wno-portability dist-xz no-define no-dist-gzip nostdinc subdir-objects])
  15 AM_MAINTAINER_MODE([enable])
  16 AM_SILENT_RULES([yes])
  17
  18 # Check for programs
  19 AC_PROG_CC
  20 AM_PROG_CC_C_O
  21 AM_PROG_VALAC([0.13.2])
  22
  23 # Initialize libtool
  24 LT_PREREQ([2.2])
  25 LT_INIT([disable-static])
  26
  27 PKG_PROG_PKG_CONFIG([0.24])
  28
  29 AC_SUBST([CHEESE_WFLAGS], ["-Wall -DGSEAL_ENABLE"])
  30
  31 GNOME_MAINTAINER_MODE_DEFINES
  32 GNOME_COMPILE_WARNINGS([maximum])
  33
  34 #*******************************************************************************
  35 # Libraries
  36 #*******************************************************************************
  37 # Before making a release, the CHEESE_LT_VERSION string should be modified.
  38 # The string is of the form C:R:A.
  39 # - If interfaces have been changed or added, but binary compatibility has
  40 #   been preserved, change to C+1:0:A+1
  41 # - If binary compatibility has been broken (eg removed or changed interfaces)
  42 #   change to C+1:0:0
  43 # - If the interface is the same as the previous version, change to C:R+1:A
  44 AC_SUBST([LIBCHEESE_LT_VERSION], [6:0:3])
  45 AC_SUBST([LIBCHEESE_GTK_LT_VERSION], [22:4:1])
  46
  47 #*******************************************************************************
  48 # Internationalization
  49 #*******************************************************************************
  50 AC_SUBST([GETTEXT_PACKAGE], [$PACKAGE_TARNAME])
  51 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], ["$GETTEXT_PACKAGE"], [GETTEXT package name])
  52
  53 IT_PROG_INTLTOOL([0.40.0])
  54
  55 #*******************************************************************************
  56 # Check required libraries
  57 #*******************************************************************************
  58
  59
  60 GLIB_REQUIRED="glib-2.0 >= 2.28.0"
  61 GOBJECT_REQUIRED="gobject-2.0 >= 2.28.0"
  62 GIO_REQUIRED="gio-2.0 >= 2.28.0"
  63 GTK_REQUIRED="gtk+-3.0 >= 2.99.4"
  64 GDK_REQUIRED="gdk-3.0 >= 3.3.6"
  65 GDK_PIXBUF_REQUIRED="gdk-pixbuf-2.0"
  66 LIBGNOMEDESKTOP_REQUIRED="gnome-desktop-3.0 >= 2.91.6"
  67 GSTREAMER_VERSION=0.10.32
  68 GSTREAMER_REQUIRED="gstreamer-plugins-base-0.10 >= $GSTREAMER_VERSION gstreamer-0.10 >= $GSTREAMER_VERSION"
  69 CAIRO_REQUIRED="cairo >= 1.10.0"
  70 PANGOCAIRO_REQUIRED="pangocairo >= 1.28.0"
  71 LIBRSVG_REQUIRED="librsvg-2.0 >= 2.32.0"
  72 CLUTTER_REQUIRED="clutter-1.0 >= 1.6.1"
  73 CLUTTERGTK_REQUIRED="clutter-gtk-1.0 >= 0.91.8"
  74 CLUTTERGST_REQUIRED="clutter-gst-1.0 >= 1.0.0"
  75 GEE_REQUIRED="gee-1.0 >= 0.6.0"
  76 LIBCANBERRA_REQUIRED="libcanberra-gtk3 >= 0.26"
  77 MX_REQUIRED="mx-1.0"
  78 X11_REQUIRED="x11"
  79 GNOME_VIDEO_EFFECTS_REQUIRED="gnome-video-effects"
  80
  81 # Libtool requires this, but it is only expanded once anyway.
  82 AC_CANONICAL_HOST
  83
  84 AC_MSG_CHECKING([host operating system])
  85 AS_CASE([$host_os],
  86   [*linux-*], [AC_MSG_RESULT([Linux])
  87     UDEV_REQUIRED="gudev-1.0"],
  88   [AC_MSG_RESULT([unsupported operating system])])
  89
  90 AC_MSG_CHECKING([for gudev-1.0])
  91 AS_IF([test -n "$UDEV_REQUIRED"],
  92   [PKG_CHECK_EXISTS([$UDEV_REQUIRED],
  93     [AC_MSG_RESULT([found])
  94      AC_DEFINE([HAVE_UDEV], [], [Enable gudev support])],
  95     [AC_MSG_ERROR([$UDEV_REQUIRED not found])])],
  96   [AC_MSG_RESULT([not needed])])
  97
  98 AC_CHECK_HEADERS([sys/videoio.h])
  99
 100 AC_CHECK_HEADER([X11/extensions/XTest.h],
 101   [AC_CHECK_LIB([Xtst], [XTestFakeKeyEvent],
 102     [AC_SUBST([XTEST_LIBS], ["-lX11 -lXtst"])])])
 103 AM_CONDITIONAL([HAVE_XTEST], test "x$ac_cv_lib_Xtst_XTestFakeKeyEvent" = "xyes")
 104
 105 PKG_CHECK_MODULES([CHEESE],
 106   [$GLIB_REQUIRED
 107   $GIO_REQUIRED
 108   $X11_REQUIRED
 109   $GOBJECT_REQUIRED
 110   $GDK_PIXBUF_REQUIRED
 111   $GSTREAMER_REQUIRED
 112   $CAIRO_REQUIRED
 113   $PANGOCAIRO_REQUIRED
 114   $CLUTTER_REQUIRED
 115   $CLUTTERGST_REQUIRED
 116   $MX_REQUIRED
 117   $UDEV_REQUIRED])
 118 CHEESE_LIBS="$CHEESE_LIBS -lgstinterfaces-0.10"
 119
 120 PKG_CHECK_MODULES([CHEESE_GTK],
 121   [$GIO_REQUIRED
 122    $GTK_REQUIRED
 123    $GDK_REQUIRED
 124    $LIBGNOMEDESKTOP_REQUIRED
 125    $LIBRSVG_REQUIRED
 126    $CLUTTERGTK_REQUIRED
 127    $GEE_REQUIRED
 128    $LIBCANBERRA_REQUIRED
 129    $UDEV_REQUIRED
 130    $GNOME_VIDEO_EFFECTS_REQUIRED])
 131
 132 # Recommend some runtime GStreamer plugins.
 133 AC_PATH_PROGS([GST_INSPECT], [gst-inspect-0.10 gst-inspect], [notfound])
 134 AS_IF([test "x$GST_INSPECT" = "xnotfound"],
 135   [AC_MSG_WARN([unable to check for runtime GStreamer plugin dependencies])],
 136   [GST_RUNTIME_PLUGINS="camerabin vp8enc webmmux"
 137    for gst_runtime_plugin in $GST_RUNTIME_PLUGINS
 138    do
 139      AC_MSG_CHECKING([for $gst_runtime_plugin GStreamer plugin])
 140      AS_IF([$GST_INSPECT $gst_runtime_plugin >&AS_MESSAGE_LOG_FD],
 141        [AC_MSG_RESULT([found])],
 142        [AC_MSG_RESULT([not found])
 143         AC_MSG_WARN([$gst_runtime_plugin was not found. It needs to be installed before Cheese is run])])
 144    done])
 145
 146 # Check for nautilus-sendto runtime dependency.
 147 NAUTILUS_SENDTO_DEP_MSG="This is a runtime dependency just needed for using the sharing functionality in Cheese."
 148 NAUTILUS_SENDTO_REQUIRED=2.91.0
 149 AC_PATH_PROGS([NAUTILUS_SENDTO], [nautilus-sendto], [notfound])
 150 AS_IF([test "x$NAUTILUS_SENDTO" = "xnotfound"],
 151   [AC_MSG_WARN([Unable to find nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED in the path. $NAUTILUS_SENDTO_DEP_MSG])],
 152   [NAUTILUS_SENDTO_SYSTEM=`nautilus-sendto --version 2>/dev/null | $SED 's/nautilus-sendto //'`
 153    AS_IF([echo $NAUTILUS_SENDTO_SYSTEM | $GREP 'version' >/dev/null],
 154      [AC_MSG_WARN([Unable to check the version of nautilus-sendto, it is \
 155 probably too old. At least $NAUTILUS_SENDTO_REQUIRED is required. \
 156 $NAUTILUS_SENDTO_DEP_MSG])],
 157       [AS_VERSION_COMPARE([$NAUTILUS_SENDTO_SYSTEM], [$NAUTILUS_SENDTO_REQUIRED],
 158          [NS_VERSION_COMPARE=0], [NS_VERSION_COMPARE=1], [NS_VERSION_COMPARE=1])
 159        AS_IF([test $NS_VERSION_COMPARE = 0],
 160          [AC_MSG_WARN([Unable to find nautilus-sendto >= \
 161 $NAUTILUS_SENDTO_REQUIRED in the path. The current installed version is \
 162 $NAUTILUS_SENDTO_SYSTEM. $NAUTILUS_SENDTO_DEP_MSG])])])])
 163
 164 # Check for GLib testing utilities.
 165 AC_PATH_PROG([GTESTER], [gtester], [notfound])
 166 AC_PATH_PROG([GTESTER_REPORT], [gtester-report], [notfound])
 167 AS_IF([test "x$GTESTER" = "xnotfound" -o "x$GTESTER_REPORT" = "xnotfound"],
 168   [AC_MSG_WARN([testing disabled as the required utilities were not found])],
 169   [CHEESE_ENABLE_TESTS=true
 170    AC_SUBST([GTESTER])
 171    AC_SUBST([GTESTER_REPORT])])
 172 AM_CONDITIONAL([CHEESE_ENABLE_TESTS], [test "x$CHEESE_ENABLE_TESTS" = "xtrue"])
 173
 174 # Check for lcov.
 175 AC_ARG_ENABLE([lcov],
 176   [AS_HELP_STRING([--disable-lcov], [Disable lcov code coverage testing])])
 177
 178 AS_IF([test "x$enable_lcov" != "xno"],
 179   [AC_PATH_PROG([LCOV], [lcov], [notfound])
 180    AC_PATH_PROG([LCOV_GENHTML], [genhtml], [notfound])
 181    AS_IF([test "x$LCOV" = "xnotfound" -o "x$LCOV_GENHTML" = "xnotfound"],
 182      [have_lcov=no],
 183      [have_lcov=yes])],
 184   [have_lcov=no])
 185
 186 AS_IF([test "x$have_lcov" = "xyes"],
 187   [AC_SUBST([LCOV])
 188    AC_SUBST([LCOV_GENHTML])
 189    CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
 190    LDFLAGS="$LDFLAGS -lgcov"],
 191   [AS_IF([test "x$enable_lcov" = "xyes"],
 192      [AC_MSG_ERROR([lcov code coverage reporting requested but not found])])])
 193
 194 AM_CONDITIONAL([CHEESE_ENABLE_LCOV], [test "x$have_lcov" = "xyes"])
 195
 196 AC_MSG_CHECKING([for glib-mkenums script])
 197 GLIB_MKENUMS=`$PKG_CONFIG --variable=glib_mkenums glib-2.0`
 198 AS_IF([test "x$GLIB_MKENUMS" = "x"],
 199   [AC_MSG_ERROR([glib-mkenums not listed in glib-2.0 pkg-config file])],
 200   [AC_SUBST([GLIB_MKENUMS])
 201    AC_MSG_RESULT([$GLIB_MKENUMS])])
 202
 203 GOBJECT_INTROSPECTION_CHECK([0.6.7])
 204
 205 # API documentation
 206 GTK_DOC_CHECK([1.14], [--flavour no-tmpl])
 207
 208 # Manpage, generated with gtk-doc and xsltproc from DocBook XML.
 209 AC_ARG_ENABLE([man],
 210   [AS_HELP_STRING([--disable-man], [Disable building the man page])])
 211
 212 AS_IF([test "x$enable_man" != "xno"],
 213   [AC_CHECK_PROG([have_xsltproc], [xsltproc], [yes], [no])
 214    JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.3//EN],
 215      [DocBook XML DTD V4.3], [have_docbookdtd=yes], [have_docbookdtd=no])
 216    JH_CHECK_XML_CATALOG(
 217      [http://docbook.sourceforge.net/release/xsl/current/html/refentry.xsl],
 218      [DocBook XSL Stylesheets], [have_docbookxsl=yes], [have_docbookxsl=no])
 219    AS_IF([test "x$have_xsltproc" = "xyes" -a "x$have_docbookdtd" = "xyes" \
 220      -a "x$have_docbookxsl" = "xyes"],
 221      [have_manutils=yes],
 222      [AS_IF([test "x$enable_man" = "xyes"],
 223        [AC_MSG_ERROR(
 224          [manpage generation requested but required utilities were not found])])
 225       have_manutils=no])],
 226   [have_manutils=no])
 227
 228 AM_CONDITIONAL([ENABLE_MAN], [test "x$have_manutils" = "xyes"])
 229
 230 # Mallard help
 231 YELP_HELP_INIT
 232
 233 GLIB_GSETTINGS
 234 #*******************************************************************************
 235
 236 AC_CONFIG_FILES([
 237 Makefile
 238 docs/reference/Makefile
 239 docs/reference/version.xml
 240 data/cheese.pc
 241 data/cheese-gtk.pc
 242 data/cheese.desktop.in
 243 help/Makefile
 244 po/Makefile.in
 245 ])
 246 AC_OUTPUT
 247
 248 #**************************************************************************