configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ([2.64])
   3 AC_INIT([Cheese],
   4         [3.7.5],
   5         [https://bugzilla.gnome.org/enter_bug.cgi?product=cheese],
   6         [cheese],
   7         [http://projects.gnome.org/cheese/])
   8
   9 AC_CONFIG_AUX_DIR([build-aux])
  10 AC_CONFIG_HEADERS([cheese-config.h])
  11 AC_CONFIG_SRCDIR([configure.ac])
  12 AC_CONFIG_MACRO_DIR([m4])
  13
  14 AM_INIT_AUTOMAKE([1.11 -Wall -Wno-portability dist-xz no-define no-dist-gzip nostdinc subdir-objects])
  15 AM_MAINTAINER_MODE([enable])
  16 AM_SILENT_RULES([yes])
  17
  18 # Check for programs
  19 AC_PROG_CC
  20 AM_PROG_CC_C_O
  21 AM_PROG_VALAC([0.16.0])
  22
  23 # Initialize libtool
  24 LT_PREREQ([2.2])
  25 LT_INIT([disable-static])
  26
  27 PKG_PROG_PKG_CONFIG([0.24])
  28
  29 AC_SUBST([CHEESE_WFLAGS], ["-Wall -DGSEAL_ENABLE"])
  30
  31 GNOME_MAINTAINER_MODE_DEFINES
  32 GNOME_COMPILE_WARNINGS([maximum])
  33
  34 #*******************************************************************************
  35 # Libraries
  36 #*******************************************************************************
  37 # Before making a release, the CHEESE_LT_VERSION string should be modified.
  38 # The string is of the form C:R:A.
  39 # - If interfaces have been changed or added, but binary compatibility has
  40 #   been preserved, change to C+1:0:A+1
  41 # - If binary compatibility has been broken (eg removed or changed interfaces)
  42 #   change to C+1:0:0
  43 # - If the interface is the same as the previous version, change to C:R+1:A
  44 AC_SUBST([LIBCHEESE_LT_VERSION], [7:3:0])
  45 AC_SUBST([LIBCHEESE_GTK_LT_VERSION], [23:3:0])
  46
  47 #*******************************************************************************
  48 # Internationalization
  49 #*******************************************************************************
  50 AC_SUBST([GETTEXT_PACKAGE], [$PACKAGE_TARNAME])
  51 AC_DEFINE_UNQUOTED([GETTEXT_PACKAGE], ["$GETTEXT_PACKAGE"], [GETTEXT package name])
  52 IT_PROG_INTLTOOL([0.50.0])
  53
  54 #*******************************************************************************
  55 # Check required libraries
  56 #*******************************************************************************
  57
  58
  59 GLIB_REQUIRED="glib-2.0 >= 2.28.0"
  60 GOBJECT_REQUIRED="gobject-2.0 >= 2.28.0"
  61 GIO_REQUIRED="gio-2.0 >= 2.28.0"
  62 GTK_REQUIRED="gtk+-3.0 >= 3.4.4"
  63 GDK_REQUIRED="gdk-3.0 >= 3.3.6"
  64 GDK_PIXBUF_REQUIRED="gdk-pixbuf-2.0"
  65 LIBGNOMEDESKTOP_REQUIRED="gnome-desktop-3.0 >= 2.91.6"
  66 GSTREAMER_VERSION=0.11.0
  67 GSTREAMER_REQUIRED="gstreamer-plugins-base-1.0 >= $GSTREAMER_VERSION gstreamer-1.0 >= $GSTREAMER_VERSION gstreamer-pbutils-1.0 >= $GSTREAMER_VERSION"
  68 GSTREAMER_PLUGINS_BAD_VERSION=0.11.0
  69 GSTREAMER_PLUGINS_BAD_REQUIRED="gstreamer-plugins-bad-1.0 >= $GSTREAMER_PLUGINS_BAD_VERSION"
  70 CAIRO_REQUIRED="cairo >= 1.10.0"
  71 PANGOCAIRO_REQUIRED="pangocairo >= 1.28.0"
  72 LIBRSVG_REQUIRED="librsvg-2.0 >= 2.32.0"
  73 CLUTTER_REQUIRED="clutter-1.0 >= 1.10.0"
  74 CLUTTERGTK_REQUIRED="clutter-gtk-1.0 >= 0.91.8"
  75 CLUTTERGST_REQUIRED="clutter-gst-2.0 >= 1.9.0"
  76 LIBCANBERRA_REQUIRED="libcanberra-gtk3 >= 0.26"
  77 X11_REQUIRED="x11"
  78 GNOME_VIDEO_EFFECTS_REQUIRED="gnome-video-effects"
  79
  80 # Libtool requires this, but it is only expanded once anyway.
  81 AC_CANONICAL_HOST
  82
  83 AC_MSG_CHECKING([host operating system])
  84 AS_CASE([$host_os],
  85   [*linux-*], [AC_MSG_RESULT([Linux])
  86     UDEV_REQUIRED="gudev-1.0"],
  87   [AC_MSG_RESULT([unsupported operating system])])
  88
  89 AC_MSG_CHECKING([for gudev-1.0])
  90 AS_IF([test -n "$UDEV_REQUIRED"],
  91   [PKG_CHECK_EXISTS([$UDEV_REQUIRED],
  92     [AC_MSG_RESULT([found])
  93      AC_DEFINE([HAVE_UDEV], [], [Enable gudev support])],
  94     [AC_MSG_ERROR([$UDEV_REQUIRED not found])])],
  95   [AC_MSG_RESULT([not needed])])
  96
  97 AC_CHECK_HEADERS([sys/videoio.h])
  98
  99 AC_CHECK_HEADER([X11/extensions/XTest.h],
 100   [AC_CHECK_LIB([Xtst], [XTestFakeKeyEvent],
 101     [AC_SUBST([XTEST_LIBS], ["-lX11 -lXtst"])])])
 102 AM_CONDITIONAL([HAVE_XTEST], test "x$ac_cv_lib_Xtst_XTestFakeKeyEvent" = "xyes")
 103
 104 PKG_CHECK_MODULES([CHEESE],
 105   [$GLIB_REQUIRED
 106   $GIO_REQUIRED
 107   $X11_REQUIRED
 108   $GOBJECT_REQUIRED
 109   $GDK_PIXBUF_REQUIRED
 110   $GSTREAMER_REQUIRED
 111   $GSTREAMER_PLUGINS_BAD_REQUIRED
 112   $CAIRO_REQUIRED
 113   $PANGOCAIRO_REQUIRED
 114   $CLUTTER_REQUIRED
 115   $CLUTTERGST_REQUIRED
 116   $UDEV_REQUIRED])
 117
 118 PKG_CHECK_MODULES([CHEESE_GTK],
 119   [$GIO_REQUIRED
 120    $GTK_REQUIRED
 121    $GDK_REQUIRED
 122    $LIBGNOMEDESKTOP_REQUIRED
 123    $LIBRSVG_REQUIRED
 124    $CLUTTERGTK_REQUIRED
 125    $LIBCANBERRA_REQUIRED
 126    $UDEV_REQUIRED
 127    $GNOME_VIDEO_EFFECTS_REQUIRED])
 128
 129 # Recommend some runtime GStreamer plugins.
 130 AC_PATH_PROGS([GST_INSPECT], [gst-inspect-1.0], [notfound])
 131 AS_IF([test "x$GST_INSPECT" = "xnotfound"],
 132   [AC_MSG_WARN([unable to check for runtime GStreamer plugin dependencies])],
 133   [GST_RUNTIME_PLUGINS="camerabin vp8enc webmmux"
 134    for gst_runtime_plugin in $GST_RUNTIME_PLUGINS
 135    do
 136      AC_MSG_CHECKING([for $gst_runtime_plugin GStreamer plugin])
 137      AS_IF([$GST_INSPECT $gst_runtime_plugin >&AS_MESSAGE_LOG_FD],
 138        [AC_MSG_RESULT([found])],
 139        [AC_MSG_RESULT([not found])
 140         AC_MSG_WARN([$gst_runtime_plugin was not found. It needs to be installed before Cheese is run])])
 141    done])
 142
 143 # Check for nautilus-sendto runtime dependency.
 144 NAUTILUS_SENDTO_DEP_MSG="This is a runtime dependency just needed for using the sharing functionality in Cheese."
 145 NAUTILUS_SENDTO_REQUIRED=2.91.0
 146 AC_PATH_PROGS([NAUTILUS_SENDTO], [nautilus-sendto], [notfound])
 147 AS_IF([test "x$NAUTILUS_SENDTO" = "xnotfound"],
 148   [AC_MSG_WARN([Unable to find nautilus-sendto >= $NAUTILUS_SENDTO_REQUIRED in the path. $NAUTILUS_SENDTO_DEP_MSG])],
 149   [NAUTILUS_SENDTO_SYSTEM=`nautilus-sendto --version 2>/dev/null | $SED 's/nautilus-sendto //'`
 150    AS_IF([echo $NAUTILUS_SENDTO_SYSTEM | $GREP 'version' >/dev/null],
 151      [AC_MSG_WARN([Unable to check the version of nautilus-sendto, it is \
 152 probably too old. At least $NAUTILUS_SENDTO_REQUIRED is required. \
 153 $NAUTILUS_SENDTO_DEP_MSG])],
 154       [AS_VERSION_COMPARE([$NAUTILUS_SENDTO_SYSTEM], [$NAUTILUS_SENDTO_REQUIRED],
 155          [NS_VERSION_COMPARE=0], [NS_VERSION_COMPARE=1], [NS_VERSION_COMPARE=1])
 156        AS_IF([test $NS_VERSION_COMPARE = 0],
 157          [AC_MSG_WARN([Unable to find nautilus-sendto >= \
 158 $NAUTILUS_SENDTO_REQUIRED in the path. The current installed version is \
 159 $NAUTILUS_SENDTO_SYSTEM. $NAUTILUS_SENDTO_DEP_MSG])])])])
 160
 161 # Check for GLib testing utilities.
 162 AC_PATH_PROG([GTESTER], [gtester], [notfound])
 163 AC_PATH_PROG([GTESTER_REPORT], [gtester-report], [notfound])
 164 AS_IF([test "x$GTESTER" = "xnotfound" -o "x$GTESTER_REPORT" = "xnotfound"],
 165   [AC_MSG_WARN([testing disabled as the required utilities were not found])],
 166   [CHEESE_ENABLE_TESTS=true
 167    AC_SUBST([GTESTER])
 168    AC_SUBST([GTESTER_REPORT])])
 169 AM_CONDITIONAL([CHEESE_ENABLE_TESTS], [test "x$CHEESE_ENABLE_TESTS" = "xtrue"])
 170
 171 # Check for lcov.
 172 AC_ARG_ENABLE([lcov],
 173   [AS_HELP_STRING([--disable-lcov], [Disable lcov code coverage testing])])
 174
 175 AS_IF([test "x$enable_lcov" != "xno"],
 176   [AC_PATH_PROG([LCOV], [lcov], [notfound])
 177    AC_PATH_PROG([LCOV_GENHTML], [genhtml], [notfound])
 178    AS_IF([test "x$LCOV" = "xnotfound" -o "x$LCOV_GENHTML" = "xnotfound"],
 179      [have_lcov=no],
 180      [have_lcov=yes])],
 181   [have_lcov=no])
 182
 183 AS_IF([test "x$have_lcov" = "xyes"],
 184   [AC_SUBST([LCOV])
 185    AC_SUBST([LCOV_GENHTML])
 186    CFLAGS="$CFLAGS -O0 -fprofile-arcs -ftest-coverage"
 187    LDFLAGS="$LDFLAGS -lgcov"],
 188   [AS_IF([test "x$enable_lcov" = "xyes"],
 189      [AC_MSG_ERROR([lcov code coverage reporting requested but not found])])])
 190
 191 AM_CONDITIONAL([CHEESE_ENABLE_LCOV], [test "x$have_lcov" = "xyes"])
 192
 193 AC_MSG_CHECKING([for glib-mkenums script])
 194 GLIB_MKENUMS=`$PKG_CONFIG --variable=glib_mkenums glib-2.0`
 195 AS_IF([test "x$GLIB_MKENUMS" = "x"],
 196   [AC_MSG_ERROR([glib-mkenums not listed in glib-2.0 pkg-config file])],
 197   [AC_SUBST([GLIB_MKENUMS])
 198    AC_MSG_RESULT([$GLIB_MKENUMS])])
 199
 200 GOBJECT_INTROSPECTION_CHECK([0.6.7])
 201
 202 # API documentation
 203 GTK_DOC_CHECK([1.14], [--flavour no-tmpl])
 204
 205 # Manpage, generated with gtk-doc and xsltproc from DocBook XML.
 206 AC_ARG_ENABLE([man],
 207   [AS_HELP_STRING([--disable-man], [Disable building the man page])])
 208
 209 AS_IF([test "x$enable_man" != "xno"],
 210   [AC_CHECK_PROG([have_xsltproc], [xsltproc], [yes], [no])
 211    JH_CHECK_XML_CATALOG([-//OASIS//DTD DocBook XML V4.3//EN],
 212      [DocBook XML DTD V4.3], [have_docbookdtd=yes], [have_docbookdtd=no])
 213    JH_CHECK_XML_CATALOG(
 214      [http://docbook.sourceforge.net/release/xsl/current/html/refentry.xsl],
 215      [DocBook XSL Stylesheets], [have_docbookxsl=yes], [have_docbookxsl=no])
 216    AS_IF([test "x$have_xsltproc" = "xyes" -a "x$have_docbookdtd" = "xyes" \
 217      -a "x$have_docbookxsl" = "xyes"],
 218      [have_manutils=yes],
 219      [AS_IF([test "x$enable_man" = "xyes"],
 220        [AC_MSG_ERROR(
 221          [manpage generation requested but required utilities were not found])])
 222       have_manutils=no])],
 223   [have_manutils=no])
 224
 225 AM_CONDITIONAL([ENABLE_MAN], [test "x$have_manutils" = "xyes"])
 226
 227 # Mallard help
 228 YELP_HELP_INIT
 229
 230 GLIB_GSETTINGS
 231 #*******************************************************************************
 232
 233 AC_CONFIG_FILES([
 234 Makefile
 235 docs/reference/Makefile
 236 docs/reference/version.xml
 237 data/cheese.pc
 238 data/cheese-gtk.pc
 239 data/cheese.desktop.in
 240 help/Makefile
 241 po/Makefile.in
 242 ])
 243 AC_OUTPUT
 244
 245 #**************************************************************************