configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.67])
   5
   6 AC_INIT([cclive], m4_esyscmd([./gen-ver.sh -c | tr -d '\n']),
   7         [http://cclive.sf.net/bugs/],[],[http://cclive.sf.net/])
   8
   9 AC_CONFIG_SRCDIR([src/cc/application.cpp])
  10 AC_CONFIG_HEADERS([config.h])
  11 AC_CONFIG_AUX_DIR([config.aux])
  12 AC_CONFIG_MACRO_DIR([m4])
  13
  14 AC_CANONICAL_TARGET
  15 AC_USE_SYSTEM_EXTENSIONS
  16
  17 AC_DEFINE_UNQUOTED([CANONICAL_TARGET], "$target", [...])
  18 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [...])
  19
  20 AM_INIT_AUTOMAKE([1.11.1 -Wall -Werror dist-xz no-dist-gzip tar-ustar])
  21 AM_SILENT_RULES([yes])
  22
  23 # GNU Automake 1.12 requires this macro. Earlier versions do not
  24 # recognize this macro. Work around this.
  25 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  26
  27 LT_INIT([disable-static])
  28 LT_PREREQ([2.2.6])
  29
  30 # Checks for programs.
  31 AC_PROG_CXX
  32 AC_PROG_CC
  33 AC_PROG_CPP
  34 AC_PROG_LN_S
  35
  36 AC_PATH_PROG([DATE], [date], [no])
  37 AS_IF([test "$DATE" != x"$xno"], [build_time=`$DATE +"%F %T %z"`])
  38 AC_DEFINE_UNQUOTED([BUILD_TIME], ["$build_time"], [We have build time])
  39
  40 AC_PATH_PROG([A2X], [a2x], [no])
  41 AM_CONDITIONAL([HAVE_A2X], [test x"$A2X" != "xno"])
  42 AC_SUBST([A2X])
  43
  44 # Checks for libraries.
  45
  46 have_libquvi_0_9=
  47 PKG_CHECK_MODULES([libquvi], [libquvi-0.9 >= 0.9],
  48   [
  49     AC_DEFINE([HAVE_LIBQUVI_0_9], [1], [We have libquvi 0.9])
  50     have_libquvi_0_9=yes
  51   ],
  52   [PKG_CHECK_MODULES([libquvi], [libquvi >= 0.4])])
  53 AM_CONDITIONAL([HAVE_LIBQUVI_0_9], [test x"$have_libquvi_0_9" = "xyes"])
  54
  55 PKG_CHECK_MODULES([libcurl], [libcurl >= 7.18.0])
  56 PKG_CHECK_MODULES([libpcre], [libpcre >= 8.02])
  57 PKG_CHECK_MODULES([libpcrecpp], [libpcrecpp >= 8.02])
  58 PKG_CHECK_MODULES([glib], [glib-2.0 >= 2.24])
  59
  60 BOOST_REQUIRE([1.42.0])
  61 # Boost: Header-only libs
  62 BOOST_FOREACH
  63 BOOST_FORMAT
  64 # Boost: Libs requiring linking
  65 BOOST_DATE_TIME
  66 BOOST_PROGRAM_OPTIONS
  67 BOOST_IOSTREAMS
  68 BOOST_FILESYSTEM
  69 BOOST_SYSTEM
  70
  71 # Checks for header files.
  72 AC_CHECK_HEADERS([sys/ioctl.h unistd.h sys/types.h sys/stat.h signal.h])
  73
  74 # Checks for typedefs, structures, and compiler characteristics.
  75 AC_HEADER_STDBOOL
  76 AC_TYPE_SIZE_T
  77 AC_TYPE_PID_T
  78 AC_C_INLINE
  79
  80 # Checks for library functions.
  81 AC_CHECK_FUNCS([strerror strstr getpid signal memset setlocale])
  82 AC_FUNC_ERROR_AT_LINE
  83 AC_FUNC_STRERROR_R
  84 AC_FUNC_FORK
  85
  86 # Version.
  87 VN=`$srcdir/gen-ver.sh`
  88 AC_DEFINE_UNQUOTED([VN],["$VN"], [We have version number from gen-ver.sh])
  89
  90 # --with-manual
  91 AC_ARG_WITH([manual],
  92   [AS_HELP_STRING([--with-manual],
  93     [Install manual page(s) @<:@default=yes@:>@])],
  94   [],
  95   [with_manual=yes])
  96 AM_CONDITIONAL([WITH_MANUAL], [test x"$with_manual" != "xno"])
  97
  98 # --enable-ccl
  99 AC_ARG_ENABLE([ccl],
 100   [AS_HELP_STRING([--enable-ccl],
 101     [Symlink from 'cclive' executable to 'ccl' @<:@default=yes@:>@])],
 102   [],
 103   [enable_ccl=yes])
 104 AM_CONDITIONAL([ENABLE_CCL], [test x"$enable_ccl" = "xyes"])
 105
 106 AC_CONFIG_FILES([
 107   Makefile
 108   doc/Makefile
 109   doc/man1/Makefile
 110   src/Makefile
 111 ])
 112
 113 AC_OUTPUT
 114
 115 AC_MSG_NOTICE([
 116   version:    ${VERSION}
 117   prefix:     ${prefix}
 118   compiler:   ${CXX}
 119   flags:      ${CXXFLAGS}
 120 System types:
 121   target      ${target}
 122   build       ${build}
 123   host        ${host}
 124 Options:
 125   add ccl symlink: ${enable_ccl}
 126   install manual : ${with_manual}])
 127
 128 # vim: set ts=2 sw=2 tw=72 expandtab: