m4/inttypes-pri.m4

   1 # inttypes-pri.m4 serial 7 (gettext-0.18.2)
   2 dnl Copyright (C) 1997-2002, 2006, 2008-2016 Free Software Foundation, Inc.
   3 dnl This file is free software; the Free Software Foundation
   4 dnl gives unlimited permission to copy and/or distribute it,
   5 dnl with or without modifications, as long as this notice is preserved.
   6
   7 dnl From Bruno Haible.
   8
   9 AC_PREREQ([2.53])
  10
  11 # Define PRI_MACROS_BROKEN if <inttypes.h> exists and defines the PRI*
  12 # macros to non-string values.  This is the case on AIX 4.3.3.
  13
  14 AC_DEFUN([gt_INTTYPES_PRI],
  15 [
  16   AC_CHECK_HEADERS([inttypes.h])
  17   if test $ac_cv_header_inttypes_h = yes; then
  18     AC_CACHE_CHECK([whether the inttypes.h PRIxNN macros are broken],
  19       [gt_cv_inttypes_pri_broken],
  20       [
  21         AC_COMPILE_IFELSE(
  22           [AC_LANG_PROGRAM(
  23              [[
  24 #include <inttypes.h>
  25 #ifdef PRId32
  26 char *p = PRId32;
  27 #endif
  28              ]],
  29              [[]])],
  30           [gt_cv_inttypes_pri_broken=no],
  31           [gt_cv_inttypes_pri_broken=yes])
  32       ])
  33   fi
  34   if test "$gt_cv_inttypes_pri_broken" = yes; then
  35     AC_DEFINE_UNQUOTED([PRI_MACROS_BROKEN], [1],
  36       [Define if <inttypes.h> exists and defines unusable PRI* macros.])
  37     PRI_MACROS_BROKEN=1
  38   else
  39     PRI_MACROS_BROKEN=0
  40   fi
  41   AC_SUBST([PRI_MACROS_BROKEN])
  42 ])