workbench/libs/openurl/distrib/OpenURL/Install

   1 ; $VER: Install OpenURL 6.3 (17.4.2005)
   2 ;
   3
   4 (set #exitmsg "\n\nIf you are a developer and wish to use\nopenurl.library, check out the included\ndocumentation and source code.")
   5
   6 ; Welcome screen
   7
   8 (welcome "\nThis installer script will install openurl.library and tools.\nopenurl.library is a universal URL display and browser launcher library.")
   9
  10 ; Copy openurl.library
  11
  12 (copylib
  13     (prompt "Installing the library")
  14     (help @copyfiles-help)
  15     (source "libs/openurl.library")
  16     (dest "Libs:")
  17 )
  18
  19 ; Copy OpenURL preferences program
  20
  21 (copyfiles
  22         (prompt "Installing the preference program")
  23         (help @copyfiles-help)
  24         (source "Prefs/OpenURL")
  25         (dest "SYS:Prefs")
  26 )
  27
  28 (copyfiles
  29         (prompt "Installing the preference program")
  30         (help @copyfiles-help)
  31         (source "Prefs/OpenURL.info")
  32         (dest "SYS:Prefs")
  33         (infos)
  34         (noposition)
  35 )
  36
  37 ; Copy catalogs
  38
  39 (set #catSourceDir (tackon "Catalogs" @language))
  40 (set #catDestDir (tackon "Locale:" (tackon "Catalogs" @language)))
  41 (if (= (and (= (exists (#catSourceDir)) 2) (= (exists (#catDestDir)) 2)) 1)
  42     (foreach #catSourceDir "#?"
  43         (copylib
  44             (source (tackon #catSourceDir @each-name))
  45             (dest #catDestDir)
  46         )
  47     )
  48 )
  49
  50 ; Copy OpenURL command
  51
  52 (copyfiles
  53         (prompt "Installing the optional commandline tool")
  54         (help "This is a small tool that allows you to open URLs from the commandline.")
  55         (source "C/OpenURL")
  56         (dest "C:")
  57         (confirm)
  58 )
  59
  60 ; Set environment variable
  61
  62 (run "Echo SYS:Prefs/OpenURL >ENV:OpenURL_Prefs_Path")
  63 (run "Echo SYS:Prefs/OpenURL >ENVARC:OpenURL_Prefs_Path")
  64
  65 ; Flush
  66
  67 (message "Before proceeding, you must quit all programs using openurl.library, so that the old version can be flushed from memory.")
  68 (run "Avail FLUSH")
  69
  70 ; Ask whether to run prefs program
  71
  72 (if
  73         (=
  74                 (askbool
  75                         (prompt "You should run the preferences program now to set your browser path(s) and other preferences. Would you like me to launch it?")
  76                         (help "")
  77                         (default 1)
  78                 )
  79
  80                 1
  81         )
  82
  83         (run "SYS:Prefs/OpenURL")
  84 )
  85
  86 ; Exit
  87
  88 (exit #exitmsg (quiet))