src/impl-allegro.lisp

   1 ;;;; -*- indent-tabs-mode: nil -*-
   2
   3 #|
   4 Copyright 2006, 2007 Greg Pfeil
   5
   6 Distributed under the MIT license (see LICENSE file)
   7 |#
   8
   9 (in-package #:bordeaux-threads)
  10
  11 ;;; documentation on the Allegro Multiprocessing interface can be found at
  12 ;;; http://www.franz.com/support/documentation/8.1/doc/multiprocessing.htm
  13
  14 ;;; Resource contention: locks and recursive locks
  15
  16 (defun make-lock (&optional name)
  17   (mp:make-process-lock :name (or name "Anonymous lock")))
  18
  19 (defun make-recursive-lock (&optional name)
  20   (mp:make-process-lock :name (or name "Anonymous recursive lock")))
  21
  22 (defun acquire-lock (lock &optional (wait-p t))
  23   (mp:process-lock lock mp:*current-process* "Lock" (if wait-p nil 0)))
  24
  25 (defun release-lock (lock)
  26   (mp:process-unlock lock))
  27
  28 (defmacro with-lock-held ((place) &body body)
  29   `(mp:with-process-lock (,place :norecursive t)
  30      ,@body))
  31
  32 (defmacro with-recursive-lock-held ((place &key timeout) &body body)
  33   `(mp:with-process-lock (,place :timeout ,timeout)
  34      ,@body))
  35
  36 ;;; Resource contention: condition variables
  37
  38 (defun make-condition-variable (&key name)
  39   (mp:make-condition-variable :name name))
  40
  41 (defun condition-wait (condition-variable lock)
  42   (mp:condition-variable-wait condition-variable lock))
  43
  44 (defun condition-notify (condition-variable)
  45   (mp:condition-variable-signal condition-variable))
  46
  47 (defun thread-yield ()
  48   (mp:process-allow-schedule))
  49
  50 (deftype thread ()
  51   'mp:process)
  52
  53 ;;; Thread Creation
  54
  55 (defun start-multiprocessing ()
  56   (mp:start-scheduler))
  57
  58 (defvar *thread-results* (make-hash-table :weak-keys t))
  59
  60 (defvar *thread-join-lock* (make-lock "Bordeaux threads join lock"))
  61
  62 (defun %make-thread (function name)
  63   (mp:process-run-function
  64    name
  65    (lambda ()
  66      (let ((result (funcall function)))
  67        (with-lock-held (*thread-join-lock*)
  68          (setf (gethash (current-thread) *thread-results*)
  69                result))))))
  70
  71 (defun current-thread ()
  72   mp:*current-process*)
  73
  74 (defun threadp (object)
  75   (typep object 'mp:process))
  76
  77 (defun thread-name (thread)
  78   (mp:process-name thread))
  79
  80 ;;; Timeouts
  81
  82 (defmacro with-timeout ((timeout) &body body)
  83   (once-only (timeout)
  84     `(mp:with-timeout (,timeout (error 'timeout :length ,timeout))
  85        ,@body)))
  86
  87 ;;; Introspection/debugging
  88
  89 (defun all-threads ()
  90   mp:*all-processes*)
  91
  92 (defun interrupt-thread (thread function &rest args)
  93   (apply #'mp:process-interrupt thread function args))
  94
  95 (defun destroy-thread (thread)
  96   (signal-error-if-current-thread thread)
  97   (mp:process-kill thread))
  98
  99 (defun thread-alive-p (thread)
 100   (mp:process-alive-p thread))
 101
 102 (defun join-thread (thread)
 103   (mp:process-wait (format nil "Waiting for thread ~A to complete" thread)
 104                    (complement #'mp:process-alive-p)
 105                    thread)
 106   (with-lock-held (*thread-join-lock*)
 107     (prog1
 108         (gethash thread *thread-results*)
 109       (remhash thread *thread-results*))))
 110
 111 (mark-supported)