src/cmu.lisp

   1 #|
   2 Copyright 2006, 2007 Greg Pfeil
   3
   4 Distributed under the MIT license (see LICENSE file)
   5 |#
   6
   7 (in-package #:bordeaux-threads)
   8
   9 ;;; Thread Creation
  10
  11 (defun make-thread (function &key name)
  12   (mp:make-process function :name name))
  13
  14 (defun current-thread ()
  15   mp:*current-process*)
  16
  17 (defmethod threadp (object)
  18   (mp:processp object))
  19
  20 (defun thread-name (thread)
  21   (mp:process-name thread))
  22
  23 ;;; Resource contention: locks and recursive locks
  24
  25 (defun make-lock (&optional name)
  26   (mp:make-lock name))
  27
  28 (defun acquire-lock (lock &optional (wait-p t))
  29   (if wait-p
  30       (mp::lock-wait lock "Lock")
  31       (mp::lock-wait-with-timeout lock "Lock" 0)))
  32
  33 (defun release-lock (lock)
  34   (setf (mp::lock-process lock) nil))
  35
  36 (defmacro with-lock-held ((place) &body body)
  37   `(mp:with-lock-held (,place) ,@body))
  38
  39 (defmacro with-recursive-lock-held ((place &key timeout) &body body)
  40   `(mp:with-lock-held (,place "Lock Wait" :timeout ,timeout) ,@body))
  41
  42 ;;; Note that the locks _are_ recursive, but not "balanced", and only
  43 ;;; checked if they are being held by the same process by with-lock-held.
  44 ;;; The default with-lock-held in bordeaux-mp.lisp sort of works, in that
  45 ;;; it will wait for recursive locks by the same process as well.
  46
  47 ;;; Resource contention: condition variables
  48
  49 ;;; There's some stuff in x86-vm.lisp that might be worth investigating
  50 ;;; whether to build on. There's also process-wait and friends.
  51
  52 (defstruct condition-var
  53   "CMUCL doesn't have conditions, so we need to create our own type."
  54   lock
  55   active)
  56
  57 (defun make-condition-variable ()
  58   (make-condition-var :lock (make-lock)))
  59
  60 (defun condition-wait (condition-variable lock)
  61   (check-type condition-variable condition-var)
  62   (with-lock-held ((condition-var-lock condition-variable))
  63     (setf (condition-var-active condition-variable) nil))
  64   (release-lock lock)
  65   (mp:process-wait "Condition Wait"
  66                    #'(lambda () (condition-var-active condition-variable)))
  67   (acquire-lock lock)
  68   t)
  69
  70 (defun condition-notify (condition-variable)
  71   (check-type condition-variable condition-var)
  72   (with-lock-held ((condition-var-lock condition-variable))
  73     (setf (condition-var-active condition-variable) t))
  74   (thread-yield))
  75
  76 (defun thread-yield ()
  77   (mp:process-yield))
  78
  79 ;;; Timeouts
  80
  81 (defmacro with-timeout ((timeout) &body body)
  82   `(mp:with-timeout (,timeout)
  83      ,@body))
  84
  85 ;;; Introspection/debugging
  86
  87 (defun all-threads ()
  88   (mp:all-processes))
  89
  90 (defun interrupt-thread (thread function)
  91   (mp:process-interrupt thread function))
  92
  93 (defun destroy-thread (thread)
  94   (signal-error-if-current-thread thread)
  95   (mp:destroy-process thread))
  96
  97 (defun thread-alive-p (thread)
  98   (mp:process-active-p thread))
  99
 100 (mark-supported)