CMakeLists.txt

   1 # CMake build for CompilerRT.
   2 #
   3 # This build assumes that CompilerRT is checked out into the
   4 # 'projects/compiler-rt' inside of an LLVM tree, it is not a stand-alone build
   5 # system.
   6 #
   7 # An important constraint of the build is that it only produces libraries
   8 # based on the ability of the host toolchain to target various platforms.
   9
  10 include(LLVMParseArguments)
  11
  12 # The CompilerRT build system requires CMake version 2.8.8 or higher in order
  13 # to use its support for building convenience "libraries" as a collection of
  14 # .o files. This is particularly useful in producing larger, more complex
  15 # runtime libraries.
  16 cmake_minimum_required(VERSION 2.8.8)
  17
  18 # Top level target used to build all compiler-rt libraries.
  19 add_custom_target(compiler-rt)
  20
  21 # Compute the Clang version from the LLVM version.
  22 # FIXME: We should be able to reuse CLANG_VERSION variable calculated
  23 #        in Clang cmake files, instead of copying the rules here.
  24 string(REGEX MATCH "[0-9]+\\.[0-9]+(\\.[0-9]+)?" CLANG_VERSION
  25        ${PACKAGE_VERSION})
  26 # Setup the paths where compiler-rt runtimes and headers should be stored.
  27 set(LIBCLANG_INSTALL_PATH lib${LLVM_LIBDIR_SUFFIX}/clang/${CLANG_VERSION})
  28 string(TOLOWER ${CMAKE_SYSTEM_NAME} LIBCLANG_OS_DIR)
  29 set(CLANG_RESOURCE_DIR ${LLVM_BINARY_DIR}/lib/clang/${CLANG_VERSION})
  30 set(COMPILER_RT_LIBRARY_OUTPUT_DIR ${CLANG_RESOURCE_DIR}/lib/${LIBCLANG_OS_DIR})
  31 set(COMPILER_RT_LIBRARY_INSTALL_DIR
  32   ${LIBCLANG_INSTALL_PATH}/lib/${LIBCLANG_OS_DIR})
  33
  34 # Add path for custom modules
  35 set(CMAKE_MODULE_PATH
  36   ${CMAKE_MODULE_PATH}
  37   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules"
  38   )
  39 include(AddCompilerRT)
  40
  41 set(COMPILER_RT_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  42 set(COMPILER_RT_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
  43 # Setup custom SDK sysroots.
  44 set(COMPILER_RT_DARWIN_SDK_SYSROOT ${COMPILER_RT_SOURCE_DIR}/SDKs/darwin)
  45 set(COMPILER_RT_LINUX_SDK_SYSROOT ${COMPILER_RT_SOURCE_DIR}/SDKs/linux)
  46 include(SanitizerUtils)
  47
  48 # Detect whether the current target platform is 32-bit or 64-bit, and setup
  49 # the correct commandline flags needed to attempt to target 32-bit and 64-bit.
  50 if (NOT CMAKE_SIZEOF_VOID_P EQUAL 4 AND
  51     NOT CMAKE_SIZEOF_VOID_P EQUAL 8)
  52   message(FATAL_ERROR "Please use architecture with 4 or 8 byte pointers.")
  53 endif()
  54 if (NOT MSVC)
  55   set(TARGET_64_BIT_CFLAGS "-m64")
  56   set(TARGET_32_BIT_CFLAGS "-m32")
  57 else()
  58   set(TARGET_64_BIT_CFLAGS "")
  59   set(TARGET_32_BIT_CFLAGS "")
  60 endif()
  61
  62 # List of architectures we can target.
  63 set(COMPILER_RT_SUPPORTED_ARCH)
  64
  65 function(get_target_flags_for_arch arch out_var)
  66   list(FIND COMPILER_RT_SUPPORTED_ARCH ${arch} ARCH_INDEX)
  67   if(ARCH_INDEX EQUAL -1)
  68     message(FATAL_ERROR "Unsupported architecture: ${arch}")
  69   else()
  70     set(${out_var} ${TARGET_${arch}_CFLAGS} PARENT_SCOPE)
  71   endif()
  72 endfunction()
  73
  74 # Try to compile a very simple source file to ensure we can target the given
  75 # platform. We use the results of these tests to build only the various target
  76 # runtime libraries supported by our current compilers cross-compiling
  77 # abilities.
  78 set(SIMPLE_SOURCE ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/simple.c)
  79 file(WRITE ${SIMPLE_SOURCE} "#include <stdlib.h>\nint main() {}")
  80
  81 # test_target_arch(<arch> <target flags...>)
  82 # Sets the target flags for a given architecture and determines if this
  83 # architecture is supported by trying to build a simple file.
  84 macro(test_target_arch arch)
  85   set(TARGET_${arch}_CFLAGS ${ARGN})
  86   try_compile(CAN_TARGET_${arch} ${CMAKE_BINARY_DIR} ${SIMPLE_SOURCE}
  87               COMPILE_DEFINITIONS "${TARGET_${arch}_CFLAGS}"
  88               CMAKE_FLAGS "-DCMAKE_EXE_LINKER_FLAGS:STRING=${TARGET_${arch}_CFLAGS}")
  89   if(${CAN_TARGET_${arch}})
  90     list(APPEND COMPILER_RT_SUPPORTED_ARCH ${arch})
  91   endif()
  92 endmacro()
  93
  94 if("${LLVM_NATIVE_ARCH}" STREQUAL "X86")
  95   if (NOT MSVC)
  96     test_target_arch(x86_64 ${TARGET_64_BIT_CFLAGS})
  97   endif()
  98   test_target_arch(i386 ${TARGET_32_BIT_CFLAGS})
  99 elseif("${LLVM_NATIVE_ARCH}" STREQUAL "PowerPC")
 100   test_target_arch(powerpc64 ${TARGET_64_BIT_CFLAGS})
 101 endif()
 102
 103 # We only support running instrumented tests when we're not cross compiling
 104 # and target a unix-like system. On Android we define the rules for building
 105 # unit tests, but don't execute them.
 106 if("${CMAKE_HOST_SYSTEM}" STREQUAL "${CMAKE_SYSTEM}" AND UNIX AND NOT ANDROID)
 107   option(COMPILER_RT_CAN_EXECUTE_TESTS "Can we execute instrumented tests" ON)
 108 else()
 109   option(COMPILER_RT_CAN_EXECUTE_TESTS "Can we execute instrumented tests" OFF)
 110 endif()
 111
 112 # Check if compiler-rt is built with libc++.
 113 find_flag_in_string("${CMAKE_CXX_FLAGS}" "-stdlib=libc++"
 114                     COMPILER_RT_USES_LIBCXX)
 115
 116 function(filter_available_targets out_var)
 117   set(archs)
 118   foreach(arch ${ARGN})
 119     list(FIND COMPILER_RT_SUPPORTED_ARCH ${arch} ARCH_INDEX)
 120     if(NOT (ARCH_INDEX EQUAL -1) AND CAN_TARGET_${arch})
 121       list(APPEND archs ${arch})
 122     endif()
 123   endforeach()
 124   set(${out_var} ${archs} PARENT_SCOPE)
 125 endfunction()
 126
 127 option(COMPILER_RT_DEBUG "Build runtimes with full debug info" OFF)
 128
 129 # COMPILER_RT_DEBUG_PYBOOL is used by lit.common.configured.in.
 130 pythonize_bool(COMPILER_RT_DEBUG)
 131
 132 # Provide some common commmandline flags for Sanitizer runtimes.
 133 if (NOT MSVC)
 134   set(SANITIZER_COMMON_CFLAGS
 135     -fPIC
 136     -fno-builtin
 137     -fno-exceptions
 138     -fomit-frame-pointer
 139     -funwind-tables
 140     -fno-stack-protector
 141     -Wno-gnu  # Variadic macros with 0 arguments for ...
 142     -fvisibility=hidden
 143     )
 144   if (NOT COMPILER_RT_DEBUG)
 145     list(APPEND SANITIZER_COMMON_CFLAGS -O3)
 146   endif()
 147 else()
 148   set(SANITIZER_COMMON_CFLAGS
 149     /MT
 150     /Zi
 151     /Oy-
 152     /GS-
 153     /wd4722
 154     )
 155 endif()
 156 # Build sanitizer runtimes with debug info. (MSVC gets /Zi above)
 157 if (NOT MSVC)
 158   check_cxx_compiler_flag(-gline-tables-only SUPPORTS_GLINE_TABLES_ONLY_FLAG)
 159   if(SUPPORTS_GLINE_TABLES_ONLY_FLAG AND NOT COMPILER_RT_DEBUG)
 160     list(APPEND SANITIZER_COMMON_CFLAGS -gline-tables-only)
 161   else()
 162     list(APPEND SANITIZER_COMMON_CFLAGS -g)
 163   endif()
 164 endif()
 165 # Warnings suppressions.
 166 check_cxx_compiler_flag(-Wno-variadic-macros SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 167 if(SUPPORTS_NO_VARIADIC_MACROS_FLAG)
 168   list(APPEND SANITIZER_COMMON_CFLAGS -Wno-variadic-macros)
 169 endif()
 170 check_cxx_compiler_flag(-Wno-c99-extensions SUPPORTS_NO_C99_EXTENSIONS_FLAG)
 171 if(SUPPORTS_NO_C99_EXTENSIONS_FLAG)
 172   list(APPEND SANITIZER_COMMON_CFLAGS -Wno-c99-extensions)
 173 endif()
 174 # Sanitizer may not have libstdc++, so we can have problems with virtual
 175 # destructors.
 176 check_cxx_compiler_flag(-Wno-non-virtual-dtor SUPPORTS_NO_NON_VIRTUAL_DTOR_FLAG)
 177 if (SUPPORTS_NO_NON_VIRTUAL_DTOR_FLAG)
 178   list(APPEND SANITIZER_COMMON_CFLAGS -Wno-non-virtual-dtor)
 179 endif()
 180 check_cxx_compiler_flag(-Wglobal-constructors SUPPORTS_GLOBAL_CONSTRUCTORS_FLAG)
 181 # Not all sanitizers forbid global constructors.
 182
 183 if(APPLE)
 184   # Obtain the iOS Simulator SDK path from xcodebuild.
 185   execute_process(
 186     COMMAND xcodebuild -version -sdk iphonesimulator Path
 187     OUTPUT_VARIABLE IOSSIM_SDK_DIR
 188     OUTPUT_STRIP_TRAILING_WHITESPACE
 189   )
 190   set(SANITIZER_COMMON_SUPPORTED_DARWIN_OS osx)
 191   if (IOSSIM_SDK_DIR)
 192     list(APPEND SANITIZER_COMMON_SUPPORTED_DARWIN_OS iossim)
 193   endif()
 194
 195   if(COMPILER_RT_USES_LIBCXX)
 196     set(SANITIZER_MIN_OSX_VERSION 10.7)
 197   else()
 198     set(SANITIZER_MIN_OSX_VERSION 10.6)
 199   endif()
 200   set(DARWIN_osx_CFLAGS -mmacosx-version-min=${SANITIZER_MIN_OSX_VERSION})
 201   set(DARWIN_iossim_CFLAGS
 202     -mios-simulator-version-min=7.0 -isysroot ${IOSSIM_SDK_DIR})
 203   set(DARWIN_osx_LINKFLAGS)
 204   set(DARWIN_iossim_LINKFLAGS
 205     -Wl,-ios_simulator_version_min,7.0.0
 206     -mios-simulator-version-min=7.0
 207     -isysroot ${IOSSIM_SDK_DIR})
 208 endif()
 209
 210 # Architectures supported by Sanitizer runtimes. Specific sanitizers may
 211 # support only subset of these (e.g. TSan works on x86_64 only).
 212 filter_available_targets(SANITIZER_COMMON_SUPPORTED_ARCH
 213   x86_64 i386 powerpc64)
 214
 215 add_subdirectory(include)
 216
 217 set(SANITIZER_COMMON_LIT_TEST_DEPS
 218   clang clang-headers FileCheck count not llvm-nm llvm-symbolizer
 219   compiler-rt-headers)
 220 # Check code style when running lit tests for sanitizers.
 221 if(UNIX)
 222   list(APPEND SANITIZER_COMMON_LIT_TEST_DEPS SanitizerLintCheck)
 223 endif()
 224
 225 add_subdirectory(lib)
 226
 227 if(LLVM_INCLUDE_TESTS)
 228   # Currently the tests have not been ported to CMake, so disable this
 229   # directory.
 230   #
 231   #add_subdirectory(test)
 232 endif()