CMakeLists.txt

   1 # CMake build for CompilerRT.
   2 #
   3 # This build assumes that CompilerRT is checked out into the
   4 # 'projects/compiler-rt' inside of an LLVM tree.
   5 # Standalone build system for CompilerRT is not yet ready.
   6 #
   7 # An important constraint of the build is that it only produces libraries
   8 # based on the ability of the host toolchain to target various platforms.
   9
  10 # Check if compiler-rt is built as a standalone project.
  11 if (CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
  12   project(CompilerRT)
  13   set(COMPILER_RT_STANDALONE_BUILD TRUE)
  14 else()
  15   set(COMPILER_RT_STANDALONE_BUILD FALSE)
  16 endif()
  17
  18 # The CompilerRT build system requires CMake version 2.8.8 or higher in order
  19 # to use its support for building convenience "libraries" as a collection of
  20 # .o files. This is particularly useful in producing larger, more complex
  21 # runtime libraries.
  22 if (NOT MSVC)
  23   cmake_minimum_required(VERSION 2.8.8)
  24 else()
  25   # Version 2.8.12.1 is required to build with Visual Studion 2013.
  26   cmake_minimum_required(VERSION 2.8.12.1)
  27 endif()
  28
  29 # FIXME: It may be removed when we use 2.8.12.
  30 if(CMAKE_VERSION VERSION_LESS 2.8.12)
  31   # Invalidate a couple of keywords.
  32   set(cmake_2_8_12_INTERFACE)
  33   set(cmake_2_8_12_PRIVATE)
  34 else()
  35   # Use ${cmake_2_8_12_KEYWORD} intead of KEYWORD in target_link_libraries().
  36   set(cmake_2_8_12_INTERFACE INTERFACE)
  37   set(cmake_2_8_12_PRIVATE PRIVATE)
  38   if(POLICY CMP0022)
  39     cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  40   endif()
  41 endif()
  42
  43 # Top level target used to build all compiler-rt libraries.
  44 add_custom_target(compiler-rt ALL)
  45
  46 if (NOT COMPILER_RT_STANDALONE_BUILD)
  47   # Compute the Clang version from the LLVM version.
  48   # FIXME: We should be able to reuse CLANG_VERSION variable calculated
  49   #        in Clang cmake files, instead of copying the rules here.
  50   string(REGEX MATCH "[0-9]+\\.[0-9]+(\\.[0-9]+)?" CLANG_VERSION
  51          ${PACKAGE_VERSION})
  52   # Setup the paths where compiler-rt runtimes and headers should be stored.
  53   set(COMPILER_RT_OUTPUT_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR}/clang/${CLANG_VERSION})
  54   set(COMPILER_RT_EXEC_OUTPUT_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
  55   set(COMPILER_RT_INSTALL_PATH lib${LLVM_LIBDIR_SUFFIX}/clang/${CLANG_VERSION})
  56   option(COMPILER_RT_INCLUDE_TESTS "Generate and build compiler-rt unit tests."
  57          ${LLVM_INCLUDE_TESTS})
  58  option(COMPILER_RT_ENABLE_WERROR "Fail and stop if warning is triggered"
  59         ${LLVM_ENABLE_WERROR})
  60   # Use just-built Clang to compile/link tests on all platforms, except for
  61   # Windows where we need to use clang-cl instead.
  62   if(NOT MSVC)
  63     set(COMPILER_RT_TEST_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/clang)
  64     set(COMPILER_RT_TEST_COMPILER_EXE "-o")
  65     set(COMPILER_RT_TEST_COMPILER_OBJ "-o")
  66   else()
  67     set(COMPILER_RT_TEST_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/clang-cl.exe)
  68     set(COMPILER_RT_TEST_COMPILER_EXE "-Fe")
  69     set(COMPILER_RT_TEST_COMPILER_OBJ "-Fo")
  70   endif()
  71 else()
  72   # Take output dir and install path from the user.
  73   set(COMPILER_RT_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR} CACHE PATH
  74     "Path where built compiler-rt libraries should be stored.")
  75   set(COMPILER_RT_EXEC_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/bin CACHE PATH
  76     "Path where built compiler-rt executables should be stored.")
  77   set(COMPILER_RT_INSTALL_PATH ${CMAKE_INSTALL_PREFIX} CACHE PATH
  78     "Path where built compiler-rt libraries should be installed.")
  79   option(COMPILER_RT_INCLUDE_TESTS "Generate and build compiler-rt unit tests." OFF)
  80   option(COMPILER_RT_ENABLE_WERROR "Fail and stop if warning is triggered" OFF)
  81   # Use a host compiler to compile/link tests.
  82   set(COMPILER_RT_TEST_COMPILER ${CMAKE_C_COMPILER} CACHE PATH "Compiler to use for testing")
  83
  84   if (NOT LLVM_CONFIG_PATH)
  85     find_program(LLVM_CONFIG_PATH "llvm-config"
  86                  DOC "Path to llvm-config binary")
  87     if (NOT LLVM_CONFIG_PATH)
  88       message(FATAL_ERROR "llvm-config not found: specify LLVM_CONFIG_PATH")
  89     endif()
  90   endif()
  91   execute_process(
  92     COMMAND ${LLVM_CONFIG_PATH} "--obj-root" "--bindir" "--libdir" "--src-root"
  93     RESULT_VARIABLE HAD_ERROR
  94     OUTPUT_VARIABLE CONFIG_OUTPUT)
  95   if (HAD_ERROR)
  96     message(FATAL_ERROR "llvm-config failed with status ${HAD_ERROR}")
  97   endif()
  98   string(REGEX REPLACE "[ \t]*[\r\n]+[ \t]*" ";" CONFIG_OUTPUT ${CONFIG_OUTPUT})
  99   list(GET CONFIG_OUTPUT 0 LLVM_BINARY_DIR)
 100   list(GET CONFIG_OUTPUT 1 LLVM_TOOLS_BINARY_DIR)
 101   list(GET CONFIG_OUTPUT 2 LLVM_LIBRARY_DIR)
 102   list(GET CONFIG_OUTPUT 3 LLVM_MAIN_SRC_DIR)
 103
 104   # Make use of LLVM CMake modules.
 105   file(TO_CMAKE_PATH ${LLVM_BINARY_DIR} LLVM_BINARY_DIR_CMAKE_STYLE)
 106   set(LLVM_CMAKE_PATH "${LLVM_BINARY_DIR_CMAKE_STYLE}/share/llvm/cmake")
 107   list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_PATH}")
 108   # Get some LLVM variables from LLVMConfig.
 109   include("${LLVM_CMAKE_PATH}/LLVMConfig.cmake")
 110
 111   set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib)
 112
 113   # Find Python interpreter.
 114   set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
 115   include(FindPythonInterp)
 116   if(NOT PYTHONINTERP_FOUND)
 117     message(FATAL_ERROR "
 118       Unable to find Python interpreter required testing. Please install Python
 119       or specify the PYTHON_EXECUTABLE CMake variable.")
 120   endif()
 121
 122   # Define default arguments to lit.
 123   set(LIT_ARGS_DEFAULT "-sv")
 124   if (MSVC OR XCODE)
 125     set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 126   endif()
 127   set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 128 endif()
 129
 130 if("${COMPILER_RT_TEST_COMPILER}" MATCHES "clang[+]*$")
 131   set(COMPILER_RT_TEST_COMPILER_ID Clang)
 132 else()
 133   set(COMPILER_RT_TEST_COMPILER_ID GNU)
 134 endif()
 135
 136 string(TOLOWER ${CMAKE_SYSTEM_NAME} COMPILER_RT_OS_DIR)
 137 set(COMPILER_RT_LIBRARY_OUTPUT_DIR
 138   ${COMPILER_RT_OUTPUT_DIR}/lib/${COMPILER_RT_OS_DIR})
 139 set(COMPILER_RT_LIBRARY_INSTALL_DIR
 140   ${COMPILER_RT_INSTALL_PATH}/lib/${COMPILER_RT_OS_DIR})
 141
 142 # Add path for custom compiler-rt modules.
 143 set(CMAKE_MODULE_PATH
 144   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 145   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules"
 146   ${CMAKE_MODULE_PATH}
 147   )
 148 include(CompilerRTUtils)
 149
 150 set(COMPILER_RT_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 151 set(COMPILER_RT_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 152 # Setup custom SDK sysroots.
 153 set(COMPILER_RT_DARWIN_SDK_SYSROOT ${COMPILER_RT_SOURCE_DIR}/SDKs/darwin)
 154 set(COMPILER_RT_LINUX_SDK_SYSROOT ${COMPILER_RT_SOURCE_DIR}/SDKs/linux)
 155
 156 set(COMPILER_RT_EXTRA_ANDROID_HEADERS ${COMPILER_RT_SOURCE_DIR}/android/include)
 157
 158 # Detect whether the current target platform is 32-bit or 64-bit, and setup
 159 # the correct commandline flags needed to attempt to target 32-bit and 64-bit.
 160 if (NOT CMAKE_SIZEOF_VOID_P EQUAL 4 AND
 161     NOT CMAKE_SIZEOF_VOID_P EQUAL 8)
 162   message(FATAL_ERROR "Please use architecture with 4 or 8 byte pointers.")
 163 endif()
 164 if (NOT MSVC)
 165   set(TARGET_64_BIT_CFLAGS "-m64")
 166   set(TARGET_32_BIT_CFLAGS "-m32")
 167 else()
 168   set(TARGET_64_BIT_CFLAGS "")
 169   set(TARGET_32_BIT_CFLAGS "")
 170 endif()
 171
 172 # List of architectures we can target.
 173 set(COMPILER_RT_SUPPORTED_ARCH)
 174
 175 function(get_target_flags_for_arch arch out_var)
 176   list(FIND COMPILER_RT_SUPPORTED_ARCH ${arch} ARCH_INDEX)
 177   if(ARCH_INDEX EQUAL -1)
 178     message(FATAL_ERROR "Unsupported architecture: ${arch}")
 179   else()
 180     set(${out_var} ${TARGET_${arch}_CFLAGS} PARENT_SCOPE)
 181   endif()
 182 endfunction()
 183
 184 # Try to compile a very simple source file to ensure we can target the given
 185 # platform. We use the results of these tests to build only the various target
 186 # runtime libraries supported by our current compilers cross-compiling
 187 # abilities.
 188 set(SIMPLE_SOURCE ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/simple.cc)
 189 file(WRITE ${SIMPLE_SOURCE} "#include <stdlib.h>\n#include <limits>\nint main() {}\n")
 190
 191 # test_target_arch(<arch> <target flags...>)
 192 # Sets the target flags for a given architecture and determines if this
 193 # architecture is supported by trying to build a simple file.
 194 macro(test_target_arch arch)
 195   set(TARGET_${arch}_CFLAGS ${ARGN})
 196   try_compile(CAN_TARGET_${arch} ${CMAKE_BINARY_DIR} ${SIMPLE_SOURCE}
 197               COMPILE_DEFINITIONS "${TARGET_${arch}_CFLAGS}"
 198               CMAKE_FLAGS "-DCMAKE_EXE_LINKER_FLAGS:STRING=${TARGET_${arch}_CFLAGS}")
 199   if(${CAN_TARGET_${arch}})
 200     list(APPEND COMPILER_RT_SUPPORTED_ARCH ${arch})
 201   endif()
 202 endmacro()
 203
 204 if(ANDROID_COMMON_FLAGS)
 205   test_target_arch(arm_android "${ANDROID_COMMON_FLAGS}")
 206 else()
 207   if("${LLVM_NATIVE_ARCH}" STREQUAL "X86")
 208     if (NOT MSVC)
 209       test_target_arch(x86_64 ${TARGET_64_BIT_CFLAGS})
 210     endif()
 211     test_target_arch(i386 ${TARGET_32_BIT_CFLAGS})
 212   elseif("${LLVM_NATIVE_ARCH}" STREQUAL "PowerPC")
 213     test_target_arch(powerpc64 ${TARGET_64_BIT_CFLAGS})
 214   elseif("${LLVM_NATIVE_ARCH}" STREQUAL "ARM")
 215     test_target_arch(arm "")
 216   endif()
 217 endif()
 218
 219 # We only support running instrumented tests when we're not cross compiling
 220 # and target a unix-like system. We can run tests on Android even when we are
 221 # cross-compiling.
 222 if(("${CMAKE_HOST_SYSTEM}" STREQUAL "${CMAKE_SYSTEM}" AND UNIX) OR ANDROID)
 223   option(COMPILER_RT_CAN_EXECUTE_TESTS "Can we execute instrumented tests" ON)
 224 else()
 225   option(COMPILER_RT_CAN_EXECUTE_TESTS "Can we execute instrumented tests" OFF)
 226 endif()
 227
 228 # Check if compiler-rt is built with libc++.
 229 find_flag_in_string("${CMAKE_CXX_FLAGS}" "-stdlib=libc++"
 230                     COMPILER_RT_USES_LIBCXX)
 231
 232 function(filter_available_targets out_var)
 233   set(archs)
 234   foreach(arch ${ARGN})
 235     list(FIND COMPILER_RT_SUPPORTED_ARCH ${arch} ARCH_INDEX)
 236     if(NOT (ARCH_INDEX EQUAL -1) AND CAN_TARGET_${arch})
 237       list(APPEND archs ${arch})
 238     endif()
 239   endforeach()
 240   set(${out_var} ${archs} PARENT_SCOPE)
 241 endfunction()
 242
 243 option(COMPILER_RT_DEBUG "Build runtimes with full debug info" OFF)
 244 # COMPILER_RT_DEBUG_PYBOOL is used by lit.common.configured.in.
 245 pythonize_bool(COMPILER_RT_DEBUG)
 246
 247 option(COMPILER_RT_BUILD_SHARED_ASAN "Build shared version of AddressSanitizer runtime" OFF)
 248
 249 #================================
 250 # Setup Compiler Flags
 251 #================================
 252 include(config-ix)
 253
 254 if(MSVC)
 255   append_string_if(COMPILER_RT_HAS_W3_FLAG /W3 CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 256 else()
 257   append_string_if(COMPILER_RT_HAS_WALL_FLAG -Wall CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 258 endif()
 259 if(COMPILER_RT_ENABLE_WERROR)
 260   append_string_if(COMPILER_RT_HAS_WERROR_FLAG -Werror CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 261   append_string_if(COMPILER_RT_HAS_WX_FLAG /WX CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 262 endif()
 263
 264 append_string_if(COMPILER_RT_HAS_STD_CXX11_FLAG -std=c++11 CMAKE_CXX_FLAGS)
 265
 266 # Emulate C99 and C++11's __func__ for MSVC prior to 2013 CTP.
 267 if(NOT COMPILER_RT_HAS_FUNC_SYMBOL)
 268   add_definitions(-D__func__=__FUNCTION__)
 269 endif()
 270
 271 # Provide some common commmandline flags for Sanitizer runtimes.
 272 append_if(COMPILER_RT_HAS_FPIC_FLAG -fPIC SANITIZER_COMMON_CFLAGS)
 273 append_if(COMPILER_RT_HAS_FNO_BUILTIN_FLAG -fno-builtin SANITIZER_COMMON_CFLAGS)
 274 append_if(COMPILER_RT_HAS_FNO_EXCEPTIONS_FLAG -fno-exceptions SANITIZER_COMMON_CFLAGS)
 275 append_if(COMPILER_RT_HAS_FOMIT_FRAME_POINTER_FLAG -fomit-frame-pointer SANITIZER_COMMON_CFLAGS)
 276 append_if(COMPILER_RT_HAS_FUNWIND_TABLES_FLAG -funwind-tables SANITIZER_COMMON_CFLAGS)
 277 append_if(COMPILER_RT_HAS_FNO_STACK_PROTECTOR_FLAG -fno-stack-protector SANITIZER_COMMON_CFLAGS)
 278 append_if(COMPILER_RT_HAS_FVISIBILITY_HIDDEN_FLAG -fvisibility=hidden SANITIZER_COMMON_CFLAGS)
 279 append_if(COMPILER_RT_HAS_FNO_FUNCTION_SECTIONS_FLAG -fno-function-sections SANITIZER_COMMON_CFLAGS)
 280
 281 if(MSVC)
 282   # Remove /MD flag so that it doesn't conflict with /MT.
 283   if(COMPILER_RT_HAS_MT_FLAG)
 284     string(REGEX REPLACE "(^| ) */MDd? *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 285     list(APPEND SANITIZER_COMMON_CFLAGS /MT)
 286   endif()
 287   append_if(COMPILER_RT_HAS_Oy_FLAG /Oy- SANITIZER_COMMON_CFLAGS)
 288   append_if(COMPILER_RT_HAS_GS_FLAG /GS- SANITIZER_COMMON_CFLAGS)
 289 endif()
 290
 291 # Build with optimization, unless we're in debug mode. If we're using MSVC,
 292 # always respect the optimization flags set by CMAKE_BUILD_TYPE instead.
 293 if(NOT COMPILER_RT_DEBUG AND NOT MSVC)
 294   list(APPEND SANITIZER_COMMON_CFLAGS -O3)
 295 endif()
 296
 297 # Build sanitizer runtimes with debug info.
 298 if(COMPILER_RT_HAS_GLINE_TABLES_ONLY_FLAG)
 299   list(APPEND SANITIZER_COMMON_CFLAGS -gline-tables-only)
 300 elseif(COMPILER_RT_HAS_G_FLAG)
 301   list(APPEND SANITIZER_COMMON_CFLAGS -g)
 302 elseif(COMPILER_RT_HAS_Zi_FLAG)
 303   list(APPEND SANITIZER_COMMON_CFLAGS /Zi)
 304 endif()
 305
 306 # Turn off several warnings.
 307 append_if(COMPILER_RT_HAS_WNO_GNU_FLAG -Wno-gnu SANITIZER_COMMON_CFLAGS)
 308 append_if(COMPILER_RT_HAS_WNO_VARIADIC_MACROS_FLAG -Wno-variadic-macros SANITIZER_COMMON_CFLAGS)
 309 append_if(COMPILER_RT_HAS_WNO_C99_EXTENSIONS_FLAG -Wno-c99-extensions SANITIZER_COMMON_CFLAGS)
 310 append_if(COMPILER_RT_HAS_WNO_NON_VIRTUAL_DTOR_FLAG -Wno-non-virtual-dtor SANITIZER_COMMON_CFLAGS)
 311 append_if(COMPILER_RT_HAS_WD4722_FLAG /wd4722 SANITIZER_COMMON_CFLAGS)
 312
 313 if(APPLE)
 314   # Obtain the iOS Simulator SDK path from xcodebuild.
 315   execute_process(
 316     COMMAND xcodebuild -version -sdk iphonesimulator Path
 317     OUTPUT_VARIABLE IOSSIM_SDK_DIR
 318     OUTPUT_STRIP_TRAILING_WHITESPACE
 319   )
 320   string(REGEX MATCH "-mmacosx-version-min="
 321          MACOSX_VERSION_MIN_FLAG "${CMAKE_CXX_FLAGS}")
 322   set(SANITIZER_COMMON_SUPPORTED_DARWIN_OS osx)
 323   if (IOSSIM_SDK_DIR AND NOT MACOSX_VERSION_MIN_FLAG)
 324     list(APPEND SANITIZER_COMMON_SUPPORTED_DARWIN_OS iossim)
 325   endif()
 326
 327   if(COMPILER_RT_USES_LIBCXX)
 328     set(SANITIZER_MIN_OSX_VERSION 10.7)
 329   else()
 330     set(SANITIZER_MIN_OSX_VERSION 10.6)
 331   endif()
 332   set(DARWIN_osx_CFLAGS -mmacosx-version-min=${SANITIZER_MIN_OSX_VERSION})
 333   set(DARWIN_iossim_CFLAGS
 334     -mios-simulator-version-min=7.0 -isysroot ${IOSSIM_SDK_DIR})
 335   set(DARWIN_osx_LINKFLAGS)
 336   set(DARWIN_iossim_LINKFLAGS
 337     -Wl,-ios_simulator_version_min,7.0.0
 338     -mios-simulator-version-min=7.0
 339     -isysroot ${IOSSIM_SDK_DIR})
 340 endif()
 341
 342 # Architectures supported by Sanitizer runtimes. Specific sanitizers may
 343 # support only subset of these (e.g. TSan works on x86_64 only).
 344 filter_available_targets(SANITIZER_COMMON_SUPPORTED_ARCH
 345   x86_64 i386 powerpc64 arm)
 346 filter_available_targets(ASAN_SUPPORTED_ARCH x86_64 i386 powerpc64)
 347 filter_available_targets(DFSAN_SUPPORTED_ARCH x86_64)
 348 filter_available_targets(LSAN_SUPPORTED_ARCH x86_64)
 349 filter_available_targets(MSAN_SUPPORTED_ARCH x86_64)
 350 filter_available_targets(PROFILE_SUPPORTED_ARCH x86_64 i386 arm)
 351 filter_available_targets(TSAN_SUPPORTED_ARCH x86_64)
 352 filter_available_targets(UBSAN_SUPPORTED_ARCH x86_64 i386)
 353
 354 add_subdirectory(include)
 355
 356 set(COMPILER_RT_LIBCXX_PATH ${LLVM_MAIN_SRC_DIR}/projects/libcxx)
 357 if(EXISTS ${COMPILER_RT_LIBCXX_PATH}/)
 358   set(COMPILER_RT_HAS_LIBCXX_SOURCES TRUE)
 359 else()
 360   set(COMPILER_RT_HAS_LIBCXX_SOURCES FALSE)
 361 endif()
 362
 363 add_subdirectory(lib)
 364
 365 if(COMPILER_RT_INCLUDE_TESTS)
 366   add_subdirectory(unittests)
 367 endif()
 368 add_subdirectory(test)