CMakeLists.txt

   1 # CMake build for CompilerRT.
   2 #
   3 # This build assumes that CompilerRT is checked out into the
   4 # 'projects/compiler-rt' inside of an LLVM tree.
   5 # Standalone build system for CompilerRT is not yet ready.
   6 #
   7 # An important constraint of the build is that it only produces libraries
   8 # based on the ability of the host toolchain to target various platforms.
   9
  10 # Check if compiler-rt is built as a standalone project.
  11 if (CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
  12   project(CompilerRT)
  13   set(COMPILER_RT_STANDALONE_BUILD TRUE)
  14 else()
  15   set(COMPILER_RT_STANDALONE_BUILD FALSE)
  16 endif()
  17
  18 # The CompilerRT build system requires CMake version 2.8.8 or higher in order
  19 # to use its support for building convenience "libraries" as a collection of
  20 # .o files. This is particularly useful in producing larger, more complex
  21 # runtime libraries.
  22 if (NOT MSVC)
  23   cmake_minimum_required(VERSION 2.8.8)
  24 else()
  25   # Version 2.8.12.1 is required to build with Visual Studion 2013.
  26   cmake_minimum_required(VERSION 2.8.12.1)
  27 endif()
  28
  29 # FIXME: It may be removed when we use 2.8.12.
  30 if(CMAKE_VERSION VERSION_LESS 2.8.12)
  31   # Invalidate a couple of keywords.
  32   set(cmake_2_8_12_INTERFACE)
  33   set(cmake_2_8_12_PRIVATE)
  34 else()
  35   # Use ${cmake_2_8_12_KEYWORD} intead of KEYWORD in target_link_libraries().
  36   set(cmake_2_8_12_INTERFACE INTERFACE)
  37   set(cmake_2_8_12_PRIVATE PRIVATE)
  38   if(POLICY CMP0022)
  39     cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  40   endif()
  41 endif()
  42
  43 # Top level target used to build all compiler-rt libraries.
  44 add_custom_target(compiler-rt ALL)
  45
  46 if (NOT COMPILER_RT_STANDALONE_BUILD)
  47   # Compute the Clang version from the LLVM version.
  48   # FIXME: We should be able to reuse CLANG_VERSION variable calculated
  49   #        in Clang cmake files, instead of copying the rules here.
  50   string(REGEX MATCH "[0-9]+\\.[0-9]+(\\.[0-9]+)?" CLANG_VERSION
  51          ${PACKAGE_VERSION})
  52   # Setup the paths where compiler-rt runtimes and headers should be stored.
  53   set(COMPILER_RT_OUTPUT_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR}/clang/${CLANG_VERSION})
  54   set(COMPILER_RT_EXEC_OUTPUT_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
  55   set(COMPILER_RT_INSTALL_PATH lib${LLVM_LIBDIR_SUFFIX}/clang/${CLANG_VERSION})
  56   option(COMPILER_RT_INCLUDE_TESTS "Generate and build compiler-rt unit tests."
  57          ${LLVM_INCLUDE_TESTS})
  58  option(COMPILER_RT_ENABLE_WERROR "Fail and stop if warning is triggered"
  59         ${LLVM_ENABLE_WERROR})
  60   # Use just-built Clang to compile/link tests on all platforms, except for
  61   # Windows where we need to use clang-cl instead.
  62   if(NOT MSVC)
  63     set(COMPILER_RT_TEST_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/clang)
  64     set(COMPILER_RT_TEST_COMPILER_EXE "-o")
  65     set(COMPILER_RT_TEST_COMPILER_OBJ "-o")
  66   else()
  67     set(COMPILER_RT_TEST_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/clang-cl.exe)
  68     set(COMPILER_RT_TEST_COMPILER_EXE "-Fe")
  69     set(COMPILER_RT_TEST_COMPILER_OBJ "-Fo")
  70   endif()
  71 else()
  72   # Take output dir and install path from the user.
  73   set(COMPILER_RT_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR} CACHE PATH
  74     "Path where built compiler-rt libraries should be stored.")
  75   set(COMPILER_RT_EXEC_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/bin CACHE PATH
  76     "Path where built compiler-rt executables should be stored.")
  77   set(COMPILER_RT_INSTALL_PATH ${CMAKE_INSTALL_PREFIX} CACHE PATH
  78     "Path where built compiler-rt libraries should be installed.")
  79   option(COMPILER_RT_INCLUDE_TESTS "Generate and build compiler-rt unit tests." OFF)
  80   option(COMPILER_RT_ENABLE_WERROR "Fail and stop if warning is triggered" OFF)
  81   # Use a host compiler to compile/link tests.
  82   set(COMPILER_RT_TEST_COMPILER ${CMAKE_C_COMPILER} CACHE PATH "Compiler to use for testing")
  83   set(COMPILER_RT_TEST_COMPILER_EXE "-o")
  84   set(COMPILER_RT_TEST_COMPILER_OBJ "-o")
  85
  86   if (NOT LLVM_CONFIG_PATH)
  87     find_program(LLVM_CONFIG_PATH "llvm-config"
  88                  DOC "Path to llvm-config binary")
  89     if (NOT LLVM_CONFIG_PATH)
  90       message(FATAL_ERROR "llvm-config not found: specify LLVM_CONFIG_PATH")
  91     endif()
  92   endif()
  93   execute_process(
  94     COMMAND ${LLVM_CONFIG_PATH} "--obj-root" "--bindir" "--libdir" "--src-root"
  95     RESULT_VARIABLE HAD_ERROR
  96     OUTPUT_VARIABLE CONFIG_OUTPUT)
  97   if (HAD_ERROR)
  98     message(FATAL_ERROR "llvm-config failed with status ${HAD_ERROR}")
  99   endif()
 100   string(REGEX REPLACE "[ \t]*[\r\n]+[ \t]*" ";" CONFIG_OUTPUT ${CONFIG_OUTPUT})
 101   list(GET CONFIG_OUTPUT 0 LLVM_BINARY_DIR)
 102   list(GET CONFIG_OUTPUT 1 LLVM_TOOLS_BINARY_DIR)
 103   list(GET CONFIG_OUTPUT 2 LLVM_LIBRARY_DIR)
 104   list(GET CONFIG_OUTPUT 3 LLVM_MAIN_SRC_DIR)
 105
 106   # Make use of LLVM CMake modules.
 107   file(TO_CMAKE_PATH ${LLVM_BINARY_DIR} LLVM_BINARY_DIR_CMAKE_STYLE)
 108   set(LLVM_CMAKE_PATH "${LLVM_BINARY_DIR_CMAKE_STYLE}/share/llvm/cmake")
 109   list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_PATH}")
 110   # Get some LLVM variables from LLVMConfig.
 111   include("${LLVM_CMAKE_PATH}/LLVMConfig.cmake")
 112
 113   set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib)
 114
 115   # Find Python interpreter.
 116   set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
 117   include(FindPythonInterp)
 118   if(NOT PYTHONINTERP_FOUND)
 119     message(FATAL_ERROR "
 120       Unable to find Python interpreter required testing. Please install Python
 121       or specify the PYTHON_EXECUTABLE CMake variable.")
 122   endif()
 123
 124   # Define default arguments to lit.
 125   set(LIT_ARGS_DEFAULT "-sv")
 126   if (MSVC OR XCODE)
 127     set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 128   endif()
 129   set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 130 endif()
 131
 132 if("${COMPILER_RT_TEST_COMPILER}" MATCHES "clang[+]*$")
 133   set(COMPILER_RT_TEST_COMPILER_ID Clang)
 134 elseif("${COMPILER_RT_TEST_COMPILER}" MATCHES "clang-cl.exe$")
 135   set(COMPILER_RT_TEST_COMPILER_ID Clang)
 136 else()
 137   set(COMPILER_RT_TEST_COMPILER_ID GNU)
 138 endif()
 139
 140 # Tests using XFAIL use the first value in COMPILER_RT_TEST_TARGET_TRIPLE
 141 set(COMPILER_RT_TEST_TARGET_TRIPLE ${TARGET_TRIPLE} CACHE STRING
 142     "Default triple for cross-compiled executables")
 143 string(REPLACE "-" ";" TARGET_TRIPLE_LIST ${COMPILER_RT_TEST_TARGET_TRIPLE})
 144 list(GET TARGET_TRIPLE_LIST 0 COMPILER_RT_TEST_TARGET_ARCH)
 145
 146 string(TOLOWER ${CMAKE_SYSTEM_NAME} COMPILER_RT_OS_DIR)
 147 set(COMPILER_RT_LIBRARY_OUTPUT_DIR
 148   ${COMPILER_RT_OUTPUT_DIR}/lib/${COMPILER_RT_OS_DIR})
 149 set(COMPILER_RT_LIBRARY_INSTALL_DIR
 150   ${COMPILER_RT_INSTALL_PATH}/lib/${COMPILER_RT_OS_DIR})
 151
 152 # Add path for custom compiler-rt modules.
 153 set(CMAKE_MODULE_PATH
 154   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 155   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules"
 156   ${CMAKE_MODULE_PATH}
 157   )
 158 include(CompilerRTUtils)
 159
 160 set(COMPILER_RT_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 161 set(COMPILER_RT_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 162 # Setup custom SDK sysroots.
 163 set(COMPILER_RT_DARWIN_SDK_SYSROOT ${COMPILER_RT_SOURCE_DIR}/SDKs/darwin)
 164 set(COMPILER_RT_LINUX_SDK_SYSROOT ${COMPILER_RT_SOURCE_DIR}/SDKs/linux)
 165
 166 set(COMPILER_RT_EXTRA_ANDROID_HEADERS ${COMPILER_RT_SOURCE_DIR}/android/include)
 167
 168 # Detect whether the current target platform is 32-bit or 64-bit, and setup
 169 # the correct commandline flags needed to attempt to target 32-bit and 64-bit.
 170 if (NOT CMAKE_SIZEOF_VOID_P EQUAL 4 AND
 171     NOT CMAKE_SIZEOF_VOID_P EQUAL 8)
 172   message(FATAL_ERROR "Please use architecture with 4 or 8 byte pointers.")
 173 endif()
 174 if (NOT MSVC)
 175   set(TARGET_64_BIT_CFLAGS "-m64")
 176   set(TARGET_32_BIT_CFLAGS "-m32")
 177 else()
 178   set(TARGET_64_BIT_CFLAGS "")
 179   set(TARGET_32_BIT_CFLAGS "")
 180 endif()
 181
 182 # List of architectures we can target.
 183 set(COMPILER_RT_SUPPORTED_ARCH)
 184
 185 function(get_target_flags_for_arch arch out_var)
 186   list(FIND COMPILER_RT_SUPPORTED_ARCH ${arch} ARCH_INDEX)
 187   if(ARCH_INDEX EQUAL -1)
 188     message(FATAL_ERROR "Unsupported architecture: ${arch}")
 189   else()
 190     set(${out_var} ${TARGET_${arch}_CFLAGS} PARENT_SCOPE)
 191   endif()
 192 endfunction()
 193
 194 # Try to compile a very simple source file to ensure we can target the given
 195 # platform. We use the results of these tests to build only the various target
 196 # runtime libraries supported by our current compilers cross-compiling
 197 # abilities.
 198 set(SIMPLE_SOURCE ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/simple.cc)
 199 file(WRITE ${SIMPLE_SOURCE} "#include <stdlib.h>\n#include <limits>\nint main() {}\n")
 200
 201 # test_target_arch(<arch> <target flags...>)
 202 # Sets the target flags for a given architecture and determines if this
 203 # architecture is supported by trying to build a simple file.
 204 macro(test_target_arch arch)
 205   set(TARGET_${arch}_CFLAGS ${ARGN})
 206   try_compile(CAN_TARGET_${arch} ${CMAKE_BINARY_DIR} ${SIMPLE_SOURCE}
 207               COMPILE_DEFINITIONS "${TARGET_${arch}_CFLAGS}"
 208               CMAKE_FLAGS "-DCMAKE_EXE_LINKER_FLAGS:STRING=${TARGET_${arch}_CFLAGS}")
 209   if(${CAN_TARGET_${arch}})
 210     list(APPEND COMPILER_RT_SUPPORTED_ARCH ${arch})
 211   endif()
 212 endmacro()
 213
 214 if(ANDROID_COMMON_FLAGS)
 215   test_target_arch(arm_android "${ANDROID_COMMON_FLAGS}")
 216 else()
 217   if("${LLVM_NATIVE_ARCH}" STREQUAL "X86")
 218     if (NOT MSVC)
 219       test_target_arch(x86_64 ${TARGET_64_BIT_CFLAGS})
 220     endif()
 221     test_target_arch(i386 ${TARGET_32_BIT_CFLAGS})
 222   elseif("${LLVM_NATIVE_ARCH}" STREQUAL "PowerPC")
 223     test_target_arch(powerpc64 ${TARGET_64_BIT_CFLAGS})
 224   elseif("${LLVM_NATIVE_ARCH}" STREQUAL "ARM")
 225     test_target_arch(arm "")
 226   endif()
 227 endif()
 228
 229 # We support running instrumented tests when we're not cross compiling
 230 # and target a UNIX-like system or Windows.
 231 # We can run tests on Android even when we are cross-compiling.
 232 if(("${CMAKE_HOST_SYSTEM}" STREQUAL "${CMAKE_SYSTEM}" AND (UNIX OR MSVC)) OR ANDROID
 233    OR COMPILER_RT_EMULATOR)
 234   option(COMPILER_RT_CAN_EXECUTE_TESTS "Can we execute instrumented tests" ON)
 235 else()
 236   option(COMPILER_RT_CAN_EXECUTE_TESTS "Can we execute instrumented tests" OFF)
 237 endif()
 238
 239 # Check if compiler-rt is built with libc++.
 240 find_flag_in_string("${CMAKE_CXX_FLAGS}" "-stdlib=libc++"
 241                     COMPILER_RT_USES_LIBCXX)
 242
 243 function(filter_available_targets out_var)
 244   set(archs)
 245   foreach(arch ${ARGN})
 246     list(FIND COMPILER_RT_SUPPORTED_ARCH ${arch} ARCH_INDEX)
 247     if(NOT (ARCH_INDEX EQUAL -1) AND CAN_TARGET_${arch})
 248       list(APPEND archs ${arch})
 249     endif()
 250   endforeach()
 251   set(${out_var} ${archs} PARENT_SCOPE)
 252 endfunction()
 253
 254 option(COMPILER_RT_DEBUG "Build runtimes with full debug info" OFF)
 255 # COMPILER_RT_DEBUG_PYBOOL is used by lit.common.configured.in.
 256 pythonize_bool(COMPILER_RT_DEBUG)
 257
 258 option(COMPILER_RT_BUILD_SHARED_ASAN "Build shared version of AddressSanitizer runtime" OFF)
 259
 260 #================================
 261 # Setup Compiler Flags
 262 #================================
 263 include(config-ix)
 264
 265 if(MSVC)
 266   append_string_if(COMPILER_RT_HAS_W3_FLAG /W3 CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 267 else()
 268   append_string_if(COMPILER_RT_HAS_WALL_FLAG -Wall CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 269 endif()
 270 if(COMPILER_RT_ENABLE_WERROR)
 271   append_string_if(COMPILER_RT_HAS_WERROR_FLAG -Werror CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 272   append_string_if(COMPILER_RT_HAS_WX_FLAG /WX CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 273 endif()
 274
 275 append_string_if(COMPILER_RT_HAS_STD_CXX11_FLAG -std=c++11 CMAKE_CXX_FLAGS)
 276
 277 # Emulate C99 and C++11's __func__ for MSVC prior to 2013 CTP.
 278 if(NOT COMPILER_RT_HAS_FUNC_SYMBOL)
 279   add_definitions(-D__func__=__FUNCTION__)
 280 endif()
 281
 282 # Provide some common commmandline flags for Sanitizer runtimes.
 283 append_if(COMPILER_RT_HAS_FPIC_FLAG -fPIC SANITIZER_COMMON_CFLAGS)
 284 append_if(COMPILER_RT_HAS_FNO_BUILTIN_FLAG -fno-builtin SANITIZER_COMMON_CFLAGS)
 285 append_if(COMPILER_RT_HAS_FNO_EXCEPTIONS_FLAG -fno-exceptions SANITIZER_COMMON_CFLAGS)
 286 append_if(COMPILER_RT_HAS_FOMIT_FRAME_POINTER_FLAG -fomit-frame-pointer SANITIZER_COMMON_CFLAGS)
 287 append_if(COMPILER_RT_HAS_FUNWIND_TABLES_FLAG -funwind-tables SANITIZER_COMMON_CFLAGS)
 288 append_if(COMPILER_RT_HAS_FNO_STACK_PROTECTOR_FLAG -fno-stack-protector SANITIZER_COMMON_CFLAGS)
 289 append_if(COMPILER_RT_HAS_FVISIBILITY_HIDDEN_FLAG -fvisibility=hidden SANITIZER_COMMON_CFLAGS)
 290 append_if(COMPILER_RT_HAS_FNO_FUNCTION_SECTIONS_FLAG -fno-function-sections SANITIZER_COMMON_CFLAGS)
 291
 292 if(MSVC)
 293   # Remove /MD flag so that it doesn't conflict with /MT.
 294   if(COMPILER_RT_HAS_MT_FLAG)
 295     string(REGEX REPLACE "(^| ) */MDd? *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 296     list(APPEND SANITIZER_COMMON_CFLAGS /MT)
 297   endif()
 298   append_if(COMPILER_RT_HAS_Oy_FLAG /Oy- SANITIZER_COMMON_CFLAGS)
 299   append_if(COMPILER_RT_HAS_GS_FLAG /GS- SANITIZER_COMMON_CFLAGS)
 300 endif()
 301
 302 # Build with optimization, unless we're in debug mode. If we're using MSVC,
 303 # always respect the optimization flags set by CMAKE_BUILD_TYPE instead.
 304 if(NOT COMPILER_RT_DEBUG AND NOT MSVC)
 305   list(APPEND SANITIZER_COMMON_CFLAGS -O3)
 306 endif()
 307
 308 # Build sanitizer runtimes with debug info.
 309 if(COMPILER_RT_HAS_GLINE_TABLES_ONLY_FLAG)
 310   list(APPEND SANITIZER_COMMON_CFLAGS -gline-tables-only)
 311 elseif(COMPILER_RT_HAS_G_FLAG)
 312   list(APPEND SANITIZER_COMMON_CFLAGS -g)
 313 elseif(COMPILER_RT_HAS_Zi_FLAG)
 314   list(APPEND SANITIZER_COMMON_CFLAGS /Zi)
 315 endif()
 316
 317 # Turn off several warnings.
 318 append_if(COMPILER_RT_HAS_WNO_GNU_FLAG -Wno-gnu SANITIZER_COMMON_CFLAGS)
 319 append_if(COMPILER_RT_HAS_WNO_VARIADIC_MACROS_FLAG -Wno-variadic-macros SANITIZER_COMMON_CFLAGS)
 320 append_if(COMPILER_RT_HAS_WNO_C99_EXTENSIONS_FLAG -Wno-c99-extensions SANITIZER_COMMON_CFLAGS)
 321 append_if(COMPILER_RT_HAS_WNO_NON_VIRTUAL_DTOR_FLAG -Wno-non-virtual-dtor SANITIZER_COMMON_CFLAGS)
 322 append_if(COMPILER_RT_HAS_WD4722_FLAG /wd4722 SANITIZER_COMMON_CFLAGS)
 323
 324 if(APPLE)
 325   # Obtain the iOS Simulator SDK path from xcodebuild.
 326   execute_process(
 327     COMMAND xcodebuild -version -sdk iphonesimulator Path
 328     OUTPUT_VARIABLE IOSSIM_SDK_DIR
 329     OUTPUT_STRIP_TRAILING_WHITESPACE
 330   )
 331   string(REGEX MATCH "-mmacosx-version-min="
 332          MACOSX_VERSION_MIN_FLAG "${CMAKE_CXX_FLAGS}")
 333   set(SANITIZER_COMMON_SUPPORTED_DARWIN_OS osx)
 334   if (IOSSIM_SDK_DIR AND NOT MACOSX_VERSION_MIN_FLAG)
 335     list(APPEND SANITIZER_COMMON_SUPPORTED_DARWIN_OS iossim)
 336   endif()
 337
 338   if(COMPILER_RT_USES_LIBCXX)
 339     set(SANITIZER_MIN_OSX_VERSION 10.7)
 340   else()
 341     set(SANITIZER_MIN_OSX_VERSION 10.6)
 342   endif()
 343   set(DARWIN_osx_CFLAGS -mmacosx-version-min=${SANITIZER_MIN_OSX_VERSION})
 344   set(DARWIN_iossim_CFLAGS
 345     -mios-simulator-version-min=7.0 -isysroot ${IOSSIM_SDK_DIR})
 346   set(DARWIN_osx_LINKFLAGS)
 347   set(DARWIN_iossim_LINKFLAGS
 348     -Wl,-ios_simulator_version_min,7.0.0
 349     -mios-simulator-version-min=7.0
 350     -isysroot ${IOSSIM_SDK_DIR})
 351 endif()
 352
 353 # Architectures supported by Sanitizer runtimes. Specific sanitizers may
 354 # support only subset of these (e.g. TSan works on x86_64 only).
 355 filter_available_targets(SANITIZER_COMMON_SUPPORTED_ARCH
 356   x86_64 i386 powerpc64 arm)
 357 filter_available_targets(ASAN_SUPPORTED_ARCH x86_64 i386 powerpc64)
 358 filter_available_targets(DFSAN_SUPPORTED_ARCH x86_64)
 359 filter_available_targets(LSAN_SUPPORTED_ARCH x86_64)
 360 filter_available_targets(MSAN_SUPPORTED_ARCH x86_64)
 361 filter_available_targets(PROFILE_SUPPORTED_ARCH x86_64 i386 arm)
 362 filter_available_targets(TSAN_SUPPORTED_ARCH x86_64)
 363 filter_available_targets(UBSAN_SUPPORTED_ARCH x86_64 i386)
 364
 365 add_subdirectory(include)
 366
 367 set(COMPILER_RT_LIBCXX_PATH ${LLVM_MAIN_SRC_DIR}/projects/libcxx)
 368 if(EXISTS ${COMPILER_RT_LIBCXX_PATH}/)
 369   set(COMPILER_RT_HAS_LIBCXX_SOURCES TRUE)
 370 else()
 371   set(COMPILER_RT_HAS_LIBCXX_SOURCES FALSE)
 372 endif()
 373
 374 add_subdirectory(lib)
 375
 376 if(COMPILER_RT_INCLUDE_TESTS)
 377   add_subdirectory(unittests)
 378 endif()
 379 add_subdirectory(test)