CMakeLists.txt

   1 # CMake build for CompilerRT.
   2 #
   3 # This build assumes that CompilerRT is checked out into the
   4 # 'projects/compiler-rt' inside of an LLVM tree.
   5 # Standalone build system for CompilerRT is not yet ready.
   6 #
   7 # An important constraint of the build is that it only produces libraries
   8 # based on the ability of the host toolchain to target various platforms.
   9
  10 # Check if compiler-rt is built as a standalone project.
  11 if (CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
  12   project(CompilerRT)
  13   set(COMPILER_RT_STANDALONE_BUILD TRUE)
  14 else()
  15   set(COMPILER_RT_STANDALONE_BUILD FALSE)
  16 endif()
  17
  18 # The CompilerRT build system requires CMake version 2.8.8 or higher in order
  19 # to use its support for building convenience "libraries" as a collection of
  20 # .o files. This is particularly useful in producing larger, more complex
  21 # runtime libraries.
  22 if (NOT MSVC)
  23   cmake_minimum_required(VERSION 2.8.8)
  24 else()
  25   # Version 2.8.12.1 is required to build with Visual Studion 2013.
  26   cmake_minimum_required(VERSION 2.8.12.1)
  27 endif()
  28
  29 # FIXME: It may be removed when we use 2.8.12.
  30 if(CMAKE_VERSION VERSION_LESS 2.8.12)
  31   # Invalidate a couple of keywords.
  32   set(cmake_2_8_12_INTERFACE)
  33   set(cmake_2_8_12_PRIVATE)
  34 else()
  35   # Use ${cmake_2_8_12_KEYWORD} intead of KEYWORD in target_link_libraries().
  36   set(cmake_2_8_12_INTERFACE INTERFACE)
  37   set(cmake_2_8_12_PRIVATE PRIVATE)
  38   if(POLICY CMP0022)
  39     cmake_policy(SET CMP0022 NEW) # automatic when 2.8.12 is required
  40   endif()
  41 endif()
  42
  43 # Top level target used to build all compiler-rt libraries.
  44 add_custom_target(compiler-rt ALL)
  45
  46 if (NOT COMPILER_RT_STANDALONE_BUILD)
  47   # Compute the Clang version from the LLVM version.
  48   # FIXME: We should be able to reuse CLANG_VERSION variable calculated
  49   #        in Clang cmake files, instead of copying the rules here.
  50   string(REGEX MATCH "[0-9]+\\.[0-9]+(\\.[0-9]+)?" CLANG_VERSION
  51          ${PACKAGE_VERSION})
  52   # Setup the paths where compiler-rt runtimes and headers should be stored.
  53   set(COMPILER_RT_OUTPUT_DIR ${LLVM_LIBRARY_OUTPUT_INTDIR}/clang/${CLANG_VERSION})
  54   set(COMPILER_RT_EXEC_OUTPUT_DIR ${LLVM_RUNTIME_OUTPUT_INTDIR})
  55   set(COMPILER_RT_INSTALL_PATH lib${LLVM_LIBDIR_SUFFIX}/clang/${CLANG_VERSION})
  56   option(COMPILER_RT_INCLUDE_TESTS "Generate and build compiler-rt unit tests."
  57          ${LLVM_INCLUDE_TESTS})
  58  option(COMPILER_RT_ENABLE_WERROR "Fail and stop if warning is triggered"
  59         ${LLVM_ENABLE_WERROR})
  60   # Use just-built Clang to compile/link tests on all platforms, except for
  61   # Windows where we need to use clang-cl instead.
  62   if(NOT MSVC)
  63     set(COMPILER_RT_TEST_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/clang)
  64   else()
  65     set(COMPILER_RT_TEST_COMPILER ${LLVM_RUNTIME_OUTPUT_INTDIR}/clang.exe)
  66   endif()
  67 else()
  68   # Take output dir and install path from the user.
  69   set(COMPILER_RT_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR} CACHE PATH
  70     "Path where built compiler-rt libraries should be stored.")
  71   set(COMPILER_RT_EXEC_OUTPUT_DIR ${CMAKE_CURRENT_BINARY_DIR}/bin CACHE PATH
  72     "Path where built compiler-rt executables should be stored.")
  73   set(COMPILER_RT_INSTALL_PATH ${CMAKE_INSTALL_PREFIX} CACHE PATH
  74     "Path where built compiler-rt libraries should be installed.")
  75   option(COMPILER_RT_INCLUDE_TESTS "Generate and build compiler-rt unit tests." OFF)
  76   option(COMPILER_RT_ENABLE_WERROR "Fail and stop if warning is triggered" OFF)
  77   # Use a host compiler to compile/link tests.
  78   set(COMPILER_RT_TEST_COMPILER ${CMAKE_C_COMPILER} CACHE PATH "Compiler to use for testing")
  79
  80   if (NOT LLVM_CONFIG_PATH)
  81     find_program(LLVM_CONFIG_PATH "llvm-config"
  82                  DOC "Path to llvm-config binary")
  83     if (NOT LLVM_CONFIG_PATH)
  84       message(FATAL_ERROR "llvm-config not found: specify LLVM_CONFIG_PATH")
  85     endif()
  86   endif()
  87   execute_process(
  88     COMMAND ${LLVM_CONFIG_PATH} "--obj-root" "--bindir" "--libdir" "--src-root"
  89     RESULT_VARIABLE HAD_ERROR
  90     OUTPUT_VARIABLE CONFIG_OUTPUT)
  91   if (HAD_ERROR)
  92     message(FATAL_ERROR "llvm-config failed with status ${HAD_ERROR}")
  93   endif()
  94   string(REGEX REPLACE "[ \t]*[\r\n]+[ \t]*" ";" CONFIG_OUTPUT ${CONFIG_OUTPUT})
  95   list(GET CONFIG_OUTPUT 0 LLVM_BINARY_DIR)
  96   list(GET CONFIG_OUTPUT 1 LLVM_TOOLS_BINARY_DIR)
  97   list(GET CONFIG_OUTPUT 2 LLVM_LIBRARY_DIR)
  98   list(GET CONFIG_OUTPUT 3 LLVM_MAIN_SRC_DIR)
  99
 100   # Make use of LLVM CMake modules.
 101   file(TO_CMAKE_PATH ${LLVM_BINARY_DIR} LLVM_BINARY_DIR_CMAKE_STYLE)
 102   set(LLVM_CMAKE_PATH "${LLVM_BINARY_DIR_CMAKE_STYLE}/share/llvm/cmake")
 103   list(APPEND CMAKE_MODULE_PATH "${LLVM_CMAKE_PATH}")
 104   # Get some LLVM variables from LLVMConfig.
 105   include("${LLVM_CMAKE_PATH}/LLVMConfig.cmake")
 106
 107   set(LLVM_LIBRARY_OUTPUT_INTDIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib)
 108
 109   # Find Python interpreter.
 110   set(Python_ADDITIONAL_VERSIONS 2.7 2.6 2.5)
 111   include(FindPythonInterp)
 112   if(NOT PYTHONINTERP_FOUND)
 113     message(FATAL_ERROR "
 114       Unable to find Python interpreter required testing. Please install Python
 115       or specify the PYTHON_EXECUTABLE CMake variable.")
 116   endif()
 117
 118   # Define default arguments to lit.
 119   set(LIT_ARGS_DEFAULT "-sv")
 120   if (MSVC OR XCODE)
 121     set(LIT_ARGS_DEFAULT "${LIT_ARGS_DEFAULT} --no-progress-bar")
 122   endif()
 123   set(LLVM_LIT_ARGS "${LIT_ARGS_DEFAULT}" CACHE STRING "Default options for lit")
 124 endif()
 125
 126 if("${COMPILER_RT_TEST_COMPILER}" MATCHES "clang[+]*$")
 127   set(COMPILER_RT_TEST_COMPILER_ID Clang)
 128 elseif("${COMPILER_RT_TEST_COMPILER}" MATCHES "clang.*.exe$")
 129   set(COMPILER_RT_TEST_COMPILER_ID Clang)
 130 else()
 131   set(COMPILER_RT_TEST_COMPILER_ID GNU)
 132 endif()
 133
 134 # Tests using XFAIL use the first value in COMPILER_RT_TEST_TARGET_TRIPLE
 135 set(COMPILER_RT_TEST_TARGET_TRIPLE ${TARGET_TRIPLE} CACHE STRING
 136     "Default triple for cross-compiled executables")
 137 string(REPLACE "-" ";" TARGET_TRIPLE_LIST ${COMPILER_RT_TEST_TARGET_TRIPLE})
 138 list(GET TARGET_TRIPLE_LIST 0 COMPILER_RT_TEST_TARGET_ARCH)
 139
 140 string(TOLOWER ${CMAKE_SYSTEM_NAME} COMPILER_RT_OS_DIR)
 141 set(COMPILER_RT_LIBRARY_OUTPUT_DIR
 142   ${COMPILER_RT_OUTPUT_DIR}/lib/${COMPILER_RT_OS_DIR})
 143 set(COMPILER_RT_LIBRARY_INSTALL_DIR
 144   ${COMPILER_RT_INSTALL_PATH}/lib/${COMPILER_RT_OS_DIR})
 145
 146 # Add path for custom compiler-rt modules.
 147 set(CMAKE_MODULE_PATH
 148   "${CMAKE_CURRENT_SOURCE_DIR}/cmake"
 149   "${CMAKE_CURRENT_SOURCE_DIR}/cmake/Modules"
 150   ${CMAKE_MODULE_PATH}
 151   )
 152 include(CompilerRTUtils)
 153
 154 set(COMPILER_RT_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
 155 set(COMPILER_RT_BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR})
 156 # Setup custom SDK sysroots.
 157 set(COMPILER_RT_DARWIN_SDK_SYSROOT ${COMPILER_RT_SOURCE_DIR}/SDKs/darwin)
 158 set(COMPILER_RT_LINUX_SDK_SYSROOT ${COMPILER_RT_SOURCE_DIR}/SDKs/linux)
 159
 160 set(COMPILER_RT_EXTRA_ANDROID_HEADERS ${COMPILER_RT_SOURCE_DIR}/android/include)
 161
 162 # Detect whether the current target platform is 32-bit or 64-bit, and setup
 163 # the correct commandline flags needed to attempt to target 32-bit and 64-bit.
 164 if (NOT CMAKE_SIZEOF_VOID_P EQUAL 4 AND
 165     NOT CMAKE_SIZEOF_VOID_P EQUAL 8)
 166   message(FATAL_ERROR "Please use architecture with 4 or 8 byte pointers.")
 167 endif()
 168 if (NOT MSVC)
 169   set(TARGET_64_BIT_CFLAGS "-m64")
 170   set(TARGET_32_BIT_CFLAGS "-m32")
 171 else()
 172   set(TARGET_64_BIT_CFLAGS "")
 173   set(TARGET_32_BIT_CFLAGS "")
 174 endif()
 175
 176 # List of architectures we can target.
 177 set(COMPILER_RT_SUPPORTED_ARCH)
 178
 179 function(get_target_flags_for_arch arch out_var)
 180   list(FIND COMPILER_RT_SUPPORTED_ARCH ${arch} ARCH_INDEX)
 181   if(ARCH_INDEX EQUAL -1)
 182     message(FATAL_ERROR "Unsupported architecture: ${arch}")
 183   else()
 184     set(${out_var} ${TARGET_${arch}_CFLAGS} PARENT_SCOPE)
 185   endif()
 186 endfunction()
 187
 188 # Try to compile a very simple source file to ensure we can target the given
 189 # platform. We use the results of these tests to build only the various target
 190 # runtime libraries supported by our current compilers cross-compiling
 191 # abilities.
 192 set(SIMPLE_SOURCE ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/simple.cc)
 193 file(WRITE ${SIMPLE_SOURCE} "#include <stdlib.h>\n#include <limits>\nint main() {}\n")
 194
 195 # test_target_arch(<arch> <target flags...>)
 196 # Sets the target flags for a given architecture and determines if this
 197 # architecture is supported by trying to build a simple file.
 198 macro(test_target_arch arch)
 199   set(TARGET_${arch}_CFLAGS ${ARGN})
 200   try_compile(CAN_TARGET_${arch} ${CMAKE_BINARY_DIR} ${SIMPLE_SOURCE}
 201               COMPILE_DEFINITIONS "${TARGET_${arch}_CFLAGS}"
 202               CMAKE_FLAGS "-DCMAKE_EXE_LINKER_FLAGS:STRING=${TARGET_${arch}_CFLAGS}")
 203   if(${CAN_TARGET_${arch}})
 204     list(APPEND COMPILER_RT_SUPPORTED_ARCH ${arch})
 205   endif()
 206 endmacro()
 207
 208 if(ANDROID_COMMON_FLAGS)
 209   test_target_arch(arm_android "${ANDROID_COMMON_FLAGS}")
 210 else()
 211   if("${LLVM_NATIVE_ARCH}" STREQUAL "X86")
 212     if (NOT MSVC)
 213       test_target_arch(x86_64 ${TARGET_64_BIT_CFLAGS})
 214     endif()
 215     test_target_arch(i386 ${TARGET_32_BIT_CFLAGS})
 216   elseif("${LLVM_NATIVE_ARCH}" STREQUAL "PowerPC")
 217     test_target_arch(powerpc64 ${TARGET_64_BIT_CFLAGS})
 218   endif()
 219
 220   # Build ARM libraries if we are configured to test on ARM
 221   if("${COMPILER_RT_TEST_TARGET_ARCH}" MATCHES "arm|aarch64")
 222     test_target_arch(arm "-march=armv7-a")
 223     test_target_arch(aarch64 "-march=armv8-a")
 224   endif()
 225 endif()
 226
 227 # We support running instrumented tests when we're not cross compiling
 228 # and target a UNIX-like system or Windows.
 229 # We can run tests on Android even when we are cross-compiling.
 230 if(("${CMAKE_HOST_SYSTEM}" STREQUAL "${CMAKE_SYSTEM}" AND (UNIX OR MSVC)) OR ANDROID
 231    OR COMPILER_RT_EMULATOR)
 232   option(COMPILER_RT_CAN_EXECUTE_TESTS "Can we execute instrumented tests" ON)
 233 else()
 234   option(COMPILER_RT_CAN_EXECUTE_TESTS "Can we execute instrumented tests" OFF)
 235 endif()
 236
 237 # Check if compiler-rt is built with libc++.
 238 find_flag_in_string("${CMAKE_CXX_FLAGS}" "-stdlib=libc++"
 239                     COMPILER_RT_USES_LIBCXX)
 240
 241 function(filter_available_targets out_var)
 242   set(archs)
 243   foreach(arch ${ARGN})
 244     list(FIND COMPILER_RT_SUPPORTED_ARCH ${arch} ARCH_INDEX)
 245     if(NOT (ARCH_INDEX EQUAL -1) AND CAN_TARGET_${arch})
 246       list(APPEND archs ${arch})
 247     endif()
 248   endforeach()
 249   set(${out_var} ${archs} PARENT_SCOPE)
 250 endfunction()
 251
 252 option(COMPILER_RT_DEBUG "Build runtimes with full debug info" OFF)
 253 # COMPILER_RT_DEBUG_PYBOOL is used by lit.common.configured.in.
 254 pythonize_bool(COMPILER_RT_DEBUG)
 255
 256 option(COMPILER_RT_BUILD_SHARED_ASAN "Build shared version of AddressSanitizer runtime" OFF)
 257
 258 #================================
 259 # Setup Compiler Flags
 260 #================================
 261 include(config-ix)
 262
 263 if(MSVC)
 264   append_string_if(COMPILER_RT_HAS_W3_FLAG /W3 CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 265 else()
 266   append_string_if(COMPILER_RT_HAS_WALL_FLAG -Wall CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 267 endif()
 268 if(COMPILER_RT_ENABLE_WERROR)
 269   append_string_if(COMPILER_RT_HAS_WERROR_FLAG -Werror CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 270   append_string_if(COMPILER_RT_HAS_WX_FLAG /WX CMAKE_C_FLAGS CMAKE_CXX_FLAGS)
 271 endif()
 272
 273 append_string_if(COMPILER_RT_HAS_STD_CXX11_FLAG -std=c++11 CMAKE_CXX_FLAGS)
 274
 275 # Emulate C99 and C++11's __func__ for MSVC prior to 2013 CTP.
 276 if(NOT COMPILER_RT_HAS_FUNC_SYMBOL)
 277   add_definitions(-D__func__=__FUNCTION__)
 278 endif()
 279
 280 # Provide some common commmandline flags for Sanitizer runtimes.
 281 append_if(COMPILER_RT_HAS_FPIC_FLAG -fPIC SANITIZER_COMMON_CFLAGS)
 282 append_if(COMPILER_RT_HAS_FNO_BUILTIN_FLAG -fno-builtin SANITIZER_COMMON_CFLAGS)
 283 append_if(COMPILER_RT_HAS_FNO_EXCEPTIONS_FLAG -fno-exceptions SANITIZER_COMMON_CFLAGS)
 284 append_if(COMPILER_RT_HAS_FOMIT_FRAME_POINTER_FLAG -fomit-frame-pointer SANITIZER_COMMON_CFLAGS)
 285 append_if(COMPILER_RT_HAS_FUNWIND_TABLES_FLAG -funwind-tables SANITIZER_COMMON_CFLAGS)
 286 append_if(COMPILER_RT_HAS_FNO_STACK_PROTECTOR_FLAG -fno-stack-protector SANITIZER_COMMON_CFLAGS)
 287 append_if(COMPILER_RT_HAS_FVISIBILITY_HIDDEN_FLAG -fvisibility=hidden SANITIZER_COMMON_CFLAGS)
 288 append_if(COMPILER_RT_HAS_FNO_FUNCTION_SECTIONS_FLAG -fno-function-sections SANITIZER_COMMON_CFLAGS)
 289
 290 if(MSVC)
 291   # Remove /MD flag so that it doesn't conflict with /MT.
 292   if(COMPILER_RT_HAS_MT_FLAG)
 293     string(REGEX REPLACE "(^| ) */MDd? *( |$)" "\\1 \\2" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 294     list(APPEND SANITIZER_COMMON_CFLAGS /MT)
 295   endif()
 296   append_if(COMPILER_RT_HAS_Oy_FLAG /Oy- SANITIZER_COMMON_CFLAGS)
 297   append_if(COMPILER_RT_HAS_GS_FLAG /GS- SANITIZER_COMMON_CFLAGS)
 298 endif()
 299
 300 # Build with optimization, unless we're in debug mode. If we're using MSVC,
 301 # always respect the optimization flags set by CMAKE_BUILD_TYPE instead.
 302 if(NOT COMPILER_RT_DEBUG AND NOT MSVC)
 303   list(APPEND SANITIZER_COMMON_CFLAGS -O3)
 304 endif()
 305
 306 # Build sanitizer runtimes with debug info.
 307 if(COMPILER_RT_HAS_GLINE_TABLES_ONLY_FLAG)
 308   list(APPEND SANITIZER_COMMON_CFLAGS -gline-tables-only)
 309 elseif(COMPILER_RT_HAS_G_FLAG)
 310   list(APPEND SANITIZER_COMMON_CFLAGS -g)
 311 elseif(COMPILER_RT_HAS_Zi_FLAG)
 312   list(APPEND SANITIZER_COMMON_CFLAGS /Zi)
 313 endif()
 314
 315 # Turn off several warnings.
 316 append_if(COMPILER_RT_HAS_WNO_GNU_FLAG -Wno-gnu SANITIZER_COMMON_CFLAGS)
 317 append_if(COMPILER_RT_HAS_WNO_VARIADIC_MACROS_FLAG -Wno-variadic-macros SANITIZER_COMMON_CFLAGS)
 318 append_if(COMPILER_RT_HAS_WNO_C99_EXTENSIONS_FLAG -Wno-c99-extensions SANITIZER_COMMON_CFLAGS)
 319 append_if(COMPILER_RT_HAS_WNO_NON_VIRTUAL_DTOR_FLAG -Wno-non-virtual-dtor SANITIZER_COMMON_CFLAGS)
 320 append_if(COMPILER_RT_HAS_WD4722_FLAG /wd4722 SANITIZER_COMMON_CFLAGS)
 321
 322 if(APPLE)
 323   # Obtain the iOS Simulator SDK path from xcodebuild.
 324   execute_process(
 325     COMMAND xcodebuild -version -sdk iphonesimulator Path
 326     OUTPUT_VARIABLE IOSSIM_SDK_DIR
 327     OUTPUT_STRIP_TRAILING_WHITESPACE
 328   )
 329   string(REGEX MATCH "-mmacosx-version-min="
 330          MACOSX_VERSION_MIN_FLAG "${CMAKE_CXX_FLAGS}")
 331   set(SANITIZER_COMMON_SUPPORTED_DARWIN_OS osx)
 332   if (IOSSIM_SDK_DIR AND NOT MACOSX_VERSION_MIN_FLAG)
 333     list(APPEND SANITIZER_COMMON_SUPPORTED_DARWIN_OS iossim)
 334   endif()
 335
 336   if(COMPILER_RT_USES_LIBCXX)
 337     set(SANITIZER_MIN_OSX_VERSION 10.7)
 338   else()
 339     set(SANITIZER_MIN_OSX_VERSION 10.6)
 340   endif()
 341   set(DARWIN_osx_CFLAGS -mmacosx-version-min=${SANITIZER_MIN_OSX_VERSION})
 342   set(DARWIN_iossim_CFLAGS
 343     -mios-simulator-version-min=7.0 -isysroot ${IOSSIM_SDK_DIR})
 344   set(DARWIN_osx_LINKFLAGS)
 345   set(DARWIN_iossim_LINKFLAGS
 346     -Wl,-ios_simulator_version_min,7.0.0
 347     -mios-simulator-version-min=7.0
 348     -isysroot ${IOSSIM_SDK_DIR})
 349 endif()
 350
 351 # Architectures supported by Sanitizer runtimes. Specific sanitizers may
 352 # support only subset of these (e.g. TSan works on x86_64 only).
 353 filter_available_targets(SANITIZER_COMMON_SUPPORTED_ARCH
 354   x86_64 i386 powerpc64 arm aarch64)
 355 filter_available_targets(ASAN_SUPPORTED_ARCH x86_64 i386 powerpc64 arm)
 356 filter_available_targets(DFSAN_SUPPORTED_ARCH x86_64)
 357 filter_available_targets(LSAN_SUPPORTED_ARCH x86_64)
 358 filter_available_targets(MSAN_SUPPORTED_ARCH x86_64)
 359 filter_available_targets(PROFILE_SUPPORTED_ARCH x86_64 i386 arm aarch64)
 360 filter_available_targets(TSAN_SUPPORTED_ARCH x86_64)
 361 filter_available_targets(UBSAN_SUPPORTED_ARCH x86_64 i386 arm aarch64)
 362
 363 add_subdirectory(include)
 364
 365 set(COMPILER_RT_LIBCXX_PATH ${LLVM_MAIN_SRC_DIR}/projects/libcxx)
 366 if(EXISTS ${COMPILER_RT_LIBCXX_PATH}/)
 367   set(COMPILER_RT_HAS_LIBCXX_SOURCES TRUE)
 368 else()
 369   set(COMPILER_RT_HAS_LIBCXX_SOURCES FALSE)
 370 endif()
 371
 372 add_subdirectory(lib)
 373
 374 if(COMPILER_RT_INCLUDE_TESTS)
 375   add_subdirectory(unittests)
 376 endif()
 377 add_subdirectory(test)