render_povray/templates_pov/subsurface.pov

   1 // This work is licensed under the Creative Commons Attribution 3.0 Unported License.
   2 // To view a copy of this license, visit http://creativecommons.org/licenses/by/3.0/
   3 // or send a letter to Creative Commons, 444 Castro Street, Suite 900, Mountain View,
   4 // California, 94041, USA.
   5
   6 // Persistence of Vision Ray Tracer Scene Description File
   7 // File: subsurface.pov
   8 // Vers: 3.7
   9 // Desc: Subsurface Scattering Demo - Candle on a Checkered Plane
  10 // Date: 2011-02-25
  11 // Auth: Christoph Lipka
  12 //
  13 // Recommended settings:
  14 //  +W640 +H480 +A0.3
  15 // Rendering time:
  16 //  ~4 min on a 2.3GHz AMD Phenom X4 9650 QuadCore
  17
  18 #version 3.7;
  19
  20 #include "colors.inc"
  21
  22 global_settings {
  23   assumed_gamma 1.0
  24   mm_per_unit 40
  25   subsurface { samples 400, 40 }
  26   ambient_light 0.3
  27 }
  28
  29 // ----------------------------------------
  30
  31 camera {
  32   location  <0.0, 2.5, -4.0>
  33   angle 50 // direction 1.5*z
  34   right     x*image_width/image_height
  35   look_at   <0.5, 1.0,  0.0>
  36 }
  37
  38 sky_sphere {
  39   pigment {
  40     gradient y
  41     color_map {
  42       [0.0 rgb <0.6,0.7,1.0>]
  43       [0.7 rgb <0.0,0.1,0.8>]
  44     }
  45   }
  46 }
  47
  48 light_source {
  49   <-30, 30, -30>
  50   color rgb <1,1,1>
  51 }
  52
  53 // ----------------------------------------
  54
  55 // a checkered white/"black" marble plane
  56 plane {
  57   y, -0.01
  58   texture {
  59     checker
  60     texture {
  61       // marble parameters derived from Jensen et al. "A Practical Model for Subsurface Light Transport", Siggraph 2001
  62       pigment {
  63       crackle
  64       turbulence 0.7
  65         color_map {
  66           [0.5 color rgb <0.83,0.79,0.75>*1.0]
  67           [0.9 color rgb <0.83,0.79,0.75>*0.8]
  68           [1.0 color rgb <1.00,0.75,0.70>*0.5]
  69         }
  70         scale 0.3
  71       }
  72       normal {
  73             agate 0.085
  74             turbulence 2
  75           }
  76       finish{
  77         diffuse 0.8
  78         specular 0.6
  79         reflection { 0.2 fresnel }
  80         conserve_energy
  81         subsurface { translucency <0.4562, 0.3811,0.3325> }
  82       }
  83     }
  84     texture {
  85     pigment{ crackle turbulence 0.25
  86              form <-1,1,0.05>
  87              color_map { [0.00 color rgb<1,1,1>]
  88                          [0.025 color rgb<0.252,0.482,0.372>]
  89                          [0.05 color rgb<0.082,0.092,0.072>]
  90                          [0.15 color rgb<0.05,0.09,0.06>]
  91                          [0.52 color rgb<0.008,0.019,0.012>]
  92                          [0.65 color rgb<0.0025,0.0029,0.0014>]
  93                          [0.75 color rgb<0.0060,0.0084,0.0065>]
  94                          [1.00 color rgb<0.008,0.012,0.012>]
  95                        }
  96         }
  97       normal {
  98             agate 0.085
  99             turbulence 2
 100           }
 101       finish{
 102         diffuse 0.8
 103         specular 0.6
 104         reflection { 0.2 fresnel }
 105         conserve_energy
 106         subsurface { translucency <0.4562, 0.3811,0.3325> }
 107       }
 108     }
 109     scale 4
 110     translate <0.7,0,1>
 111   }
 112   interior { ior 1.5 }
 113 }
 114
 115 // the classic chrome sphere
 116 sphere { <1.5,0.7,1>, 0.7
 117   pigment { color rgb 1 }
 118   finish {
 119     ambient 0 diffuse 0
 120     specular 0.7  roughness 0.01
 121     conserve_energy
 122     reflection { 0.7 metallic }
 123   }
 124 }
 125
 126 // a candle...
 127 blob {
 128   threshold 0.5
 129   cylinder { <0.0, 0.0,  0.0>,
 130              <0.0, 2.0,  0.0>,  1.0,   1.0 } // candle "body"
 131   sphere   { <0.0, 2.5,  0.0>,  0.8,  -2.0 } // (used to shape the candle top)
 132   sphere   { <0.0,-0.52, 0.0>,  0.8,  -2.0 } // (used to shape the candle bottom)
 133   sphere   { <0.0, 2.0, -0.5>,  0.1,  -0.2 } // the "notch" where wax runs over
 134   cylinder { <0.0, 1.88,-0.52>,
 135              <0.0, 1.5, -0.52>, 0.05,  0.2 } // a streak of wax running over
 136   sphere   { <0.0, 1.5, -0.55>, 0.07,  0.2 } // a drop of of wax running over
 137   texture {
 138     // bees' wax
 139     pigment { color rgb <0.8,0.50,0.01> }
 140     finish{
 141       diffuse 0.6 specular 0.6 roughness 0.1
 142       subsurface { translucency <5,3,1>*0.5 }
 143     }
 144   }
 145   interior { ior 1.45 }
 146   rotate -y*45
 147 }
 148
 149 // ... and the wick
 150 intersection {
 151   box { <-1,-1,-1>, <0,1,1> }
 152   torus { 0.15, 0.03 }
 153   rotate x*90
 154   translate <0.15, 1.95, 0.0>
 155   pigment { color rgb 0 }
 156   finish { ambient 0 diffuse 1 specular 0 }
 157   no_shadow
 158 }
 159
 160 // a classic-textured slab for comparison
 161 superellipsoid {
 162   <0.1,0.1>
 163   texture {
 164     pigment { color rgb <0.9,0.6,0.6> }
 165     finish{
 166       diffuse 1.0
 167       specular 0.6
 168       reflection { 0.2 fresnel }
 169       conserve_energy
 170     }
 171   }
 172   interior { ior 1.45 }
 173   scale <0.25,0.05,0.25>
 174   rotate y*30
 175   translate <1.2,0.05,0.25>
 176 }