tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4 # Copyright (C) 2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 # We want a recent Autotest.
  20 m4_version_prereq([2.58])
  21
  22
  23 ## ------------- ##
  24 ## Basic tests.  ##
  25 ## ------------- ##
  26
  27 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  28 # ------------------------------------------
  29 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  30 # taken in "slurp" mode, i.e., one can match end-of-lines.
  31 m4_define([AT_MATCHES_CHECK],
  32 [AT_CHECK([perl -0777 -ne '
  33 my $count = 0;
  34 s{$2}{ ++$count; "" }gem;
  35 printf "$count\n";' $1], [0], [$3
  36 ])])
  37
  38
  39 ## ------------------------------- ##
  40 ## Macros decoding Bison options.  ##
  41 ## ------------------------------- ##
  42
  43
  44 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
  45 # -----------------------------------------
  46 m4_define([AT_BISON_OPTION_PUSHDEFS],
  47 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])
  48
  49
  50 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
  51 # --------------------------------------------------
  52 # This macro works around the impossibility to define macros
  53 # inside macros, because issuing `[$1]' is not possible in M4 :(.
  54 # This sucks hard, GNU M4 should really provide M5-like $$1.
  55 m4_define([_AT_BISON_OPTION_PUSHDEFS],
  56 [m4_if([$1$2], $[1]$[2], [],
  57        [m4_fatal([$0: Invalid arguments: $@])])dnl
  58 m4_pushdef([AT_DEFINES_IF],
  59 [m4_bmatch([$3], [%defines], [$1], [$2])])
  60 m4_pushdef([AT_SKEL_CC_IF],
  61 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
  62 m4_pushdef([AT_GLR_IF],
  63 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\.], [$1], [$2])])
  64 m4_pushdef([AT_LALR1_CC_IF],
  65 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
  66 m4_pushdef([AT_GLR_CC_IF],
  67 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
  68 # Using yacc.c?
  69 m4_pushdef([AT_YACC_IF],
  70 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
  71 m4_pushdef([AT_LEXPARAM_IF],
  72 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
  73 m4_pushdef([AT_PARAM_IF],
  74 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
  75 m4_pushdef([AT_LOCATION_IF],
  76 [m4_bmatch([$3], [%locations], [$1], [$2])])
  77 m4_pushdef([AT_PURE_IF],
  78 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
  79            [m4_bmatch([$3], [%define  *api\.pure *"false"], [$2], [$1])],
  80            [$2])])
  81 m4_pushdef([AT_PURE_AND_LOC_IF],
  82 [m4_bmatch([$3], [%locations], [AT_PURE_IF($@)], [$2])])
  83 m4_pushdef([AT_GLR_OR_PARAM_IF],
  84 [m4_bmatch([$3], [%glr-parser\|%parse-param], [$1], [$2])])
  85 m4_pushdef([AT_NAME_PREFIX],
  86 [m4_bmatch([$3], [%name-prefix ".*"],
  87            [m4_bregexp([$3], [name-prefix "\([^"]*\)"], [\1])],
  88            [yy])])
  89 m4_pushdef([AT_TOKEN_PREFIX],
  90 [m4_bmatch([$3], [%define token.prefix ".*"],
  91            [m4_bregexp([$3], [%define token.prefix "\(.*\)"], [\1])])])
  92 # yyerror receives the location if %location & %pure & (%glr or %parse-param).
  93 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
  94 [AT_GLR_OR_PARAM_IF([AT_PURE_AND_LOC_IF([$1], [$2])],
  95                     [$2])])
  96 # yyerror always sees the locations (when activated), except if
  97 # (yacc & pure & !param).  FIXME: This is wrong.  See the manual.
  98 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
  99 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_PARAM_IF([$1], [$2])],
 100                                         [$1])],
 101                             [$1])],
 102                 [$2])])
 103
 104 # The interface is pure: either because %define api.pure, or because we
 105 # are using the C++ parsers.
 106 m4_pushdef([AT_PURE_LEX_IF],
 107 [AT_PURE_IF([$1],
 108             [AT_SKEL_CC_IF([$1], [$2])])])
 109
 110 AT_PURE_LEX_IF(
 111 [m4_pushdef([AT_LOC], [(*llocp)])
 112  m4_pushdef([AT_VAL], [(*lvalp)])
 113  m4_pushdef([AT_LEX_FORMALS],
 114             [YYSTYPE *lvalp[]AT_LOCATION_IF([, YYLTYPE *llocp])])
 115  m4_pushdef([AT_LEX_ARGS],
 116             [lvalp[]AT_LOCATION_IF([, llocp])])
 117  m4_pushdef([AT_USE_LEX_ARGS],
 118             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 119  m4_pushdef([AT_LEX_PRE_FORMALS],
 120             [AT_LEX_FORMALS, ])
 121  m4_pushdef([AT_LEX_PRE_ARGS],
 122             [AT_LEX_ARGS, ])
 123 ],
 124 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 125  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 126  m4_pushdef([AT_LEX_FORMALS],     [void])
 127  m4_pushdef([AT_LEX_ARGS],        [])
 128  m4_pushdef([AT_USE_LEX_ARGS],    [])
 129  m4_pushdef([AT_LEX_PRE_FORMALS], [])
 130  m4_pushdef([AT_LEX_PRE_ARGS],    [])
 131 ])
 132 AT_GLR_IF([AT_KEYWORDS([glr])])
 133 ])# _AT_BISON_OPTION_PUSHDEFS
 134
 135
 136 # AT_BISON_OPTION_POPDEFS
 137 # -----------------------
 138 m4_define([AT_BISON_OPTION_POPDEFS],
 139 [m4_popdef([AT_LEX_PRE_ARGS])
 140 m4_popdef([AT_LEX_PRE_FORMALS])
 141 m4_popdef([AT_USE_LEX_ARGS])
 142 m4_popdef([AT_LEX_ARGS])
 143 m4_popdef([AT_LEX_FORMALS])
 144 m4_popdef([AT_VAL])
 145 m4_popdef([AT_LOC])
 146 m4_popdef([AT_PURE_LEX_IF])
 147 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 148 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 149 m4_popdef([AT_NAME_PREFIX])
 150 m4_popdef([AT_GLR_OR_PARAM_IF])
 151 m4_popdef([AT_PURE_AND_LOC_IF])
 152 m4_popdef([AT_LOCATION_IF])
 153 m4_popdef([AT_PARAM_IF])
 154 m4_popdef([AT_LEXPARAM_IF])
 155 m4_popdef([AT_YACC_IF])
 156 m4_popdef([AT_GLR_IF])
 157 m4_popdef([AT_SKEL_CC_IF])
 158 m4_popdef([AT_GLR_CC_IF])
 159 m4_popdef([AT_LALR1_CC_IF])
 160 m4_popdef([AT_DEFINES_IF])
 161 ])# AT_BISON_OPTION_POPDEFS
 162
 163
 164
 165 ## -------------------------- ##
 166 ## Generating Grammar Files.  ##
 167 ## -------------------------- ##
 168
 169 # AT_DATA_SOURCE_PROLOGUE
 170 # ------------------------
 171 # The prologue that should be included in any source code that is
 172 # meant to be compiled.
 173 m4_define([AT_DATA_SOURCE_PROLOGUE],
 174 [[#include <config.h>
 175 /* We don't need perfect functions for these tests. */
 176 #undef malloc
 177 #undef memcmp
 178 #undef realloc
 179 ]])
 180
 181 # AT_DATA_GRAMMAR_PROLOGUE
 182 # ------------------------
 183 # The prologue that should be included in any grammar which parser is
 184 # meant to be compiled.
 185 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 186 [[%code top {
 187 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 188 [}
 189 ]])
 190
 191 # AT_DATA_SOURCE(NAME, CONTENT)
 192 # -----------------------------
 193 # Generate the file NAME, which CONTENT is preceded by
 194 # AT_DATA_SOURCE_PROLOGUE.
 195 m4_define([AT_DATA_SOURCE],
 196 [AT_DATA([$1],
 197 [AT_DATA_SOURCE_PROLOGUE
 198 $2])
 199 ])
 200
 201 # AT_DATA_GRAMMAR(NAME, CONTENT)
 202 # ------------------------------
 203 # Generate the file NAME, which CONTENT is preceded by
 204 # AT_DATA_GRAMMAR_PROLOGUE.
 205 m4_define([AT_DATA_GRAMMAR],
 206 [AT_DATA([$1],
 207 [AT_DATA_GRAMMAR_PROLOGUE
 208 $2])
 209 ])
 210
 211 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 212 # -------------------------------------------------
 213 # Check Bison by invoking `bison BISON_ARGS'.  OTHER_AT_CHECK_ARGS are the
 214 # usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 215 #
 216 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 217 # Bison in the test suite.  For now it ensures that:
 218 #
 219 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 220 #      a non-zero exit status since Bison doesn't always try to free all memory
 221 #      in that case.
 222 #
 223 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 224 #      --graph and --report=all output for every working grammar.
 225 m4_define([AT_BISON_CHECK],
 226 [m4_if(m4_quote($2), [0], [AT_BISON_CHECK_XML($@)],
 227        m4_quote($2), [], [AT_BISON_CHECK_XML($@)])
 228 AT_BISON_CHECK_NO_XML($@)])
 229
 230 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 231 # --------------------------------------------------------
 232 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 233 # when a tortured grammar's XML is known to be too large for xsltproc to
 234 # handle.
 235 m4_define([AT_BISON_CHECK_NO_XML],
 236 [AT_CHECK(m4_if(m4_quote($2), [0], [], m4_quote($2), [], [],
 237                 [AT_QUELL_VALGRIND ])[[bison ]]$@)])
 238
 239 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 240 # -----------------------------------------------------
 241 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 242 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 243 # have a non-zero exit status.
 244 m4_define([AT_BISON_CHECK_XML],
 245 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then
 246   mkdir xml-tests]
 247   m4_pushdef([AT_BISON_ARGS],
 248              [m4_bpatsubsts([[$1]],
 249                             [--report(-file)?=[^][ ]*], [],
 250                             [--graph=[^][ ]*], [],
 251                             [--xml=[^][ ]*], [])])dnl
 252   # Don't combine these Bison invocations since we want to be sure that
 253   # --report=all isn't required to get the full XML file.
 254   AT_CHECK([[bison --report=all --report-file=xml-tests/test.output \
 255              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 256            [[0]], [ignore], [ignore])
 257   AT_CHECK([[bison --xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 258            [[0]], [ignore], [ignore])
 259   m4_popdef([AT_BISON_ARGS])dnl
 260   [cp xml-tests/test.output expout]
 261   AT_CHECK([[$XSLTPROC \
 262              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 263              xml-tests/test.xml]], [[0]], [expout])
 264   [cp xml-tests/test.dot expout]
 265   AT_CHECK([[$XSLTPROC \
 266              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 267              xml-tests/test.xml]], [[0]], [expout])
 268   [rm -rf xml-tests expout
 269 fi]])
 270
 271 # AT_QUELL_VALGRIND
 272 # -----------------
 273 # Put this before a Bison invocation to keep Valgrind from complaining about
 274 # reachable memory.
 275 #
 276 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 277 # The triple quoting below will cause test cases to fail if you do.  If you do
 278 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 279 # will then fail to shell-escape its contents when attempting to print them.
 280 # The testsuite verbose output, at least, will be incorrect, but nothing may
 281 # fail to make sure you notice.
 282 m4_define([AT_QUELL_VALGRIND],
 283 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 284
 285 ## ------------------------ ##
 286 ## Compiling C, C++ Files.  ##
 287 ## ------------------------ ##
 288
 289
 290 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c])
 291 # ----------------------------------------
 292 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 293 # assume that we are linking too; this is a hack.
 294 m4_define([AT_COMPILE],
 295 [AT_CHECK([$CC $CFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.c])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 296            0, [ignore], [ignore])])
 297
 298 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc])
 299 # --------------------------------------------
 300 # Compile SOURCES into OUTPUT.  If OUTPUT does not contain '.',
 301 # assume that we are linking too; this is a hack.
 302 # If the C++ compiler does not work, ignore the test.
 303 m4_define([AT_COMPILE_CXX],
 304 [AT_KEYWORDS(c++)
 305 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 306 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS m4_bmatch([$1], [[.]], [], [$LDFLAGS ])-o $1 m4_default([$2], [$1.cc])[]m4_bmatch([$1], [[.]], [], [ $LIBS])],
 307          0, [ignore], [ignore])])
 308
 309
 310 # AT_FULL_COMPILE(OUTPUT, [OTHER])
 311 # --------------------------------
 312 # Compile OUTPUT.y to OUTPUT.c or OUTPUT.cc, and compile it to OUTPUT.
 313 # If OTHER is specified, compile OUTPUT-OTHER.c or OUTPUT-OTHER.cc to OUTPUT
 314 # along with it.
 315 # Relies on AT_SKEL_CC_IF.
 316 m4_define([AT_FULL_COMPILE],
 317 [AT_SKEL_CC_IF(
 318   [AT_BISON_CHECK([-o $1.cc $1.y])
 319    AT_COMPILE_CXX([$1]m4_ifval($2, [, [$1.cc $1-$2.cc]]))],
 320   [AT_BISON_CHECK([-o $1.c $1.y])
 321    AT_COMPILE([$1]m4_ifval($2, [, [$1.c $1-$2.c]]))])
 322 ])
 323
 324
 325 ## ---------------------------- ##
 326 ## Running a generated parser.  ##
 327 ## ---------------------------- ##
 328
 329 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 330 # ------------------------------------------------------------
 331 # So that we can run `./testsuite PREPARSER='valgrind -q' for instance.
 332 m4_define([AT_PARSER_CHECK],
 333 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [$4])])
 334
 335
 336
 337
 338 ## ----------------------- ##
 339 ## Launch the test suite.  ##
 340 ## ----------------------- ##
 341
 342 AT_INIT
 343
 344 AT_TESTED([bison])