djgpp/config.sed

   1 # DJGPP specific configuration file.
   2 # Sed script for additional DJGPP specific editing
   3 # of the configure script generated by autoconf 2.62.
   4
   5
   6 # Copyright (C) 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   7
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21
  22 # Additional editing of Makefiles
  23 /^eval sed.*ac_file_inputs.*tmp\/out \\$/ {
  24 :loop
  25 n
  26 /^$/!b loop
  27 a\
  28 cat > "$tmp/subs-djgpp.sed" << eof_djgpp\
  29 # DJGPP specific Makefile changes.\
  30 s,\\.deps,_deps,g\
  31 s,\\.libs,_libs,g\
  32 s,\\.new\\.,_new.,g\
  33 s,\\.old\\.,_old.,g\
  34 s,\\.tab\\.,_tab.,g\
  35 s,c++\\.at,cxx.at,g\
  36 s,c++\\.m4,cxx.m4,g\
  37 s,c++-skel\\.m4,cxx-skel.m4,g\
  38 s,calc++,calcxx,g\
  39 s,scan-gram-c,c-scan-gram,g\
  40 s,scan-skel-c,c-scan-skel,g\
  41 s,inttypes_,_inttypes,g\
  42 s,javacomp\\.sh\\.in,javacomp.sh-in,g\
  43 s,javaexec\\.sh\\.in,javaexec.sh-in,g\
  44 s,yacc\\.1\\.in,yacc.1-in,g\
  45 s,bench\\.pl\\.in,bench.pl-in,g\
  46 s,Makefile\\.am\\.in,Makefile.am-in,g\
  47 s,Makefile\\.in\\.in,Makefile.in-in,g\
  48 /^\\.y\\.c:/,/^$/ {\
  49   /\\\$(YACCCOMPILE)/ {\
  50     a\\\\\
  51         -@test -f y.tab.c && mv -f y.tab.c y_tab.c\\\\\
  52         -@test -f y.tab.h && mv -f y.tab.h y_tab.h\
  53   }\
  54 }\
  55 /^libbison.a:/ i\\\\\
  56 \\$(top_srcdir)/djgpp/subpipe.c: \\$(top_srcdir)/djgpp/subpipe.h\\\\\
  57 subpipe.o: \\$(top_srcdir)/djgpp/subpipe.c \\$(top_srcdir)/djgpp/subpipe.h\\\\\
  58         \\$(COMPILE) -c \\$<\
  59 /^yacc:/ i\\\\\
  60 yacc.bat:\\\\\
  61         echo "bison\\$(EXEEXT) -y %1 %2 %3 %4 %5 %6 %7 %8 %9" >\\$@\
  62 /^bin_SCRIPTS =/s/$/ yacc.bat/\
  63 /^MOSTLYCLEANFILES = yacc/s/$/ yacc.bat/\
  64 /cross-options.texi:/,/^$/ s|bison|&.exe|g\
  65 /^\\.x\\.1:/,/^$/ s|\\$program|&.exe|g\
  66 eof_djgpp\
  67 sed -f "\$tmp/subs-djgpp.sed" \$tmp/out > \$tmp/out.djgpp\
  68 mv -f \$tmp/out.djgpp \$tmp/out
  69 }
  70
  71 # Makefile.in.in is renamed to Makefile.in-in.
  72 /ac_config_files=/ {
  73   /runtime-po/!s|po/Makefile\.in|&:po/Makefile.in-in|
  74   s|runtime-po/Makefile\.in|&:runtime-po/Makefile.in-in|
  75   s|javacomp\.sh\.in|javacomp.sh-in|
  76   s|javaexec\.sh\.in|javaexec.sh-in|
  77   s|doc/yacc\.1|&:doc/yacc.1-in|
  78   s|etc/bench.pl|&:etc/bench.pl-in|
  79 }
  80
  81 /CONFIG_FILES=/ {
  82   /runtime-po/!s|po/Makefile\.in|&:po/Makefile.in-in|2
  83   s|runtime-po/Makefile\.in|&:runtime-po/Makefile.in-in|2
  84   s|javacomp\.sh\.in|javacomp.sh-in|
  85   s|javaexec\.sh\.in|javaexec.sh-in|
  86   s|doc/yacc\.1|&:doc/yacc.1-in|2
  87   s|etc/bench\.pl|&:etc/bench.pl-in|2
  88 }
  89
  90 # We always use _deps and _libs instead of .deps and .libs, because
  91 # the latter is an invalid name on 8+3 MS-DOS file system.  This makes
  92 # the generated Makefiles good for every DJGPP installation, not only
  93 # the one where the package was configured (which could happen to be
  94 # a Windows box, where leading dots in file names are allowed).
  95 /^rmdir[         ]*\.tst/ i\
  96 am__leading_dot=_
  97
  98 # Replace (command) > /dev/null with `command > /dev/null`, since
  99 # parenthesized commands always return zero status in the ported Bash,
 100 # even if the named command doesn't exist
 101 /if ([^|;`]*null/{
 102   s,(,`,
 103   s,),,
 104   /null[         ]*2>&1/ s,2>&1,&`,
 105   /null.*null/ s,null.*null,&`,
 106   /null.*null/ !{
 107     /null[       ]*2>&1/ !s,null,&`,
 108   }
 109 }
 110
 111 # DOS-style absolute file names should be supported as well
 112 /\*) top_srcdir=/s,/\*,[\\\\/]* | ?:[\\\\/]*,
 113
 114 # The following two items are changes needed for configuring
 115 # and compiling across partitions.
 116 # 1) The given srcdir value is always translated from the
 117 #    "x:" syntax into "/dev/x" syntax while we run configure.
 118 /^[      ]*-srcdir=\*.*$/ a\
 119     ac_optarg=`echo "$ac_optarg" | sed "s,^\\([A-Za-z]\\):,/dev/\\1,"`
 120 /set X `ls -Lt \$srcdir/ i\
 121    if `echo $srcdir | grep "^/dev/" - > /dev/null`; then\
 122      srcdir=`echo "$srcdir" | sed -e "s%^/dev/%%" -e "s%/%:/%"`\
 123    fi
 124
 125 # Autoconf 2.52e generated configure scripts
 126 # write absolute paths into Makefiles and bison.in
 127 # making them useless for DJGPP installations for
 128 # which the package has not been configured for.
 129 /MISSING=/,/^$/ {
 130   /^fi$/ a\
 131 am_missing_run=`echo "$am_missing_run" | sed 's%/dev/.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%${top_srcdir}%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%${top_srcdir}%'`
 132 }
 133 /^install_sh=/a\
 134 install_sh=`echo "$install_sh" | sed 's%/dev/.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%${top_srcdir}%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%${top_srcdir}%'`
 135
 136 # This will only work if the assumption that the
 137 # testsuite is ran from the following path:
 138 #   ${top_srcdir}/tests/testsuite.dir
 139 # holds. The explicit names are of no importance.
 140 #   ../../. == ${top_srcdir}
 141 #/^esac$/,/^ac_abs_srcdir=/ {
 142 /^ac_abs_srcdir=/ i\
 143 ac_abs_builddir=`echo "$ac_abs_builddir" | sed "s%/dev/.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../.%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../.%"`\
 144 ac_abs_top_builddir=`echo "$ac_abs_top_builddir" | sed "s%/dev/.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../..%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../..%"`\
 145 ac_abs_top_srcdir=`echo "$ac_abs_top_srcdir" | sed "s%/dev/.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../..%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../..%"`
 146 #ac_abs_srcdir=`echo "$ac_abs_srcdir" | sed "s%/dev/.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../.%;s%.:.*/bison[-_0-9]\\{1,1\\}[-.0-9A-Za-z+]*%../../.%"`
 147 /^ac_abs_srcdir=/ a\
 148 for dj_dir in $ac_abs_builddir $ac_abs_top_builddir $ac_abs_top_srcdir $ac_abs_srcdir\
 149 do\
 150   ac_abs_builddir=`echo "$ac_abs_builddir" | sed "s%//%/%g"`\
 151   ac_abs_top_builddir=`echo "$ac_abs_top_builddir" | sed "s%//%/%g"`\
 152   ac_abs_top_srcdir=`echo "$ac_abs_top_srcdir" | sed "s%//%/%g"`\
 153   ac_abs_srcdir=`echo "$ac_abs_srcdir" | sed "s%//%/%g"`\
 154 done
 155
 156 # Add DJGPP version information.
 157 /^#define VERSION/ s/\$VERSION/&  (DJGPP port (r1))/
 158
 159 # We need makeinfo to make the html formated docs.
 160 /\$am_missing_run[       ]*makeinfo/ s,\$am_missing_run,,
 161
 162 # The path to the FORTRAN compiler and libraries
 163 # shall contain no absolute path reference so it
 164 # will be good for all djgpp installations.
 165 /^FLIBS="\$ac_cv_flibs"/ i\
 166 ac_djgpp_path=`echo "$DJDIR" | sed 's%\\\\\\%/%g' | tr $as_cr_LETTERS $as_cr_letters`\
 167 ac_cv_flibs=`echo "$ac_cv_flibs" | sed "s%-L$ac_djgpp_path%-L/dev/env/DJDIR%g"`
 168
 169 # Autoconf generated configure scripts write absolute
 170 # paths of certain header files into Makefiles making
 171 # them useless for DJGPP installations for which the
 172 # package has not been configured for.
 173 /^.*echo "\$as_me:\$LINENO: result: \$gl_cv_absolute_.*$/ {
 174 h
 175 s,^.*\(gl_cv_absolute_\)\([a-z0-9_]*\)\(_h\).*$,\1\2\3=`echo $\1\2\3 | sed "s%[^:]:.*/include/%/dev/env/DJDIR/include/%"`,
 176 G
 177 }
 178 /^.*echo "\$as_me:\$LINENO: result: \$gl_cv_full_.*$/ {
 179 h
 180 s,^.*\(gl_cv_full_\)\([a-z0-9_]*\)\(_h\).*$,\1\2\3=`echo $\1\2\3 | sed "s%[^:]:.*/include/%/dev/env/DJDIR/include/%"`,
 181 G
 182 }
 183
 184 # The following is not a valid DOS file name
 185 s/calc++/calcxx/g
 186
 187 # The CR test for awk does not work for DJGPP.
 188 /^ac_cs_awk_cr=/,/^$/ {
 189   /^fi$/ a\
 190 ac_cs_awk_cr=$ac_cr
 191 }