configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001-2015, 2018-2020 Free Software Foundation, Inc.
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  17
  18 # In order for some versions of Sun Studio to compile our C++ test cases
  19 # correctly, we need Autoconf 2.64 or better to handle the restrict
  20 # keyword in at least string.h from gnulib.  We need Autoconf 2.68 or
  21 # better to avoid a typo in the 'configure --help' entry for the YACC
  22 # environment variable.
  23 AC_PREREQ([2.68])
  24 m4_pattern_forbid([^_?(gl_[A-Z]|AX_|BISON_)])
  25 m4_pattern_allow([^BISON_USE_NLS$])
  26
  27 AC_INIT([GNU Bison],
  28         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  29         [bug-bison@gnu.org],
  30         [],
  31         [https://www.gnu.org/software/bison/])
  32 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2020])
  33 AC_DEFINE_UNQUOTED([PACKAGE_COPYRIGHT_YEAR], [$PACKAGE_COPYRIGHT_YEAR],
  34                    [The copyright year for this package])
  35
  36 AC_CONFIG_AUX_DIR([build-aux])
  37 AC_CONFIG_MACRO_DIR([m4])
  38
  39 # When we move to Automake 1.16, simplify examples/c/reccalc/local.mk.
  40 # Our CI build the packages on Bionic, which has only Automake 1.15.
  41 #
  42 # We want gnits strictness only when rolling a stable release.  For
  43 # release candidates, we use version strings like 2.4.3_rc1, but gnits
  44 # doesn't like that, so we let the underscore disable gnits.  Between
  45 # releases, we want to be able run make dist without being required to
  46 # add a bogus NEWS entry.  In that case, the version string
  47 # automatically contains a dash, which we also let disable gnits.
  48 AM_INIT_AUTOMAKE([1.15 dist-lzip dist-xz nostdinc
  49                  color-tests parallel-tests
  50                  silent-rules]
  51                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [[-_]],
  52                            [gnu], [gnits]))
  53 AM_SILENT_RULES([yes])
  54 AC_CONFIG_HEADERS([lib/config.h:lib/config.in.h])
  55
  56 # Checks for the compiler.
  57 AC_PROG_CC_STDC
  58 AC_PROG_CXX
  59
  60 # Gnulib (early checks).
  61 gl_EARLY
  62
  63 # We want ostream_printf and hyperlink support.
  64 gl_LIBTEXTSTYLE_OPTIONAL([0.20.5])
  65
  66 # Gnulib uses '#pragma GCC diagnostic push' to silence some
  67 # warnings, but older gcc doesn't support this.
  68 AC_CACHE_CHECK([whether pragma GCC diagnostic push works],
  69   [lv_cv_gcc_pragma_push_works], [
  70   save_CFLAGS=$CFLAGS
  71   CFLAGS='-Wunknown-pragmas -Werror'
  72   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  73     #pragma GCC diagnostic push
  74     #pragma GCC diagnostic pop
  75   ]])],
  76   [lv_cv_gcc_pragma_push_works=yes],
  77   [lv_cv_gcc_pragma_push_works=no])
  78   CFLAGS=$save_CFLAGS])
  79
  80 AC_LANG_PUSH([C++])
  81 gl_WARN_ADD([-fno-exceptions], [NO_EXCEPTIONS_CXXFLAGS])
  82 BISON_CXXSTD([98])
  83 BISON_CXXSTD([03])
  84 BISON_CXXSTD([11])
  85 BISON_CXXSTD([14])
  86 BISON_CXXSTD([17])
  87 BISON_CXXSTD([2a])
  88 AM_CONDITIONAL([ENABLE_CXX11], [test x"$CXX11_CXXFLAGS" != x])
  89 AM_CONDITIONAL([ENABLE_CXX14], [test x"$CXX14_CXXFLAGS" != x])
  90 AC_LANG_POP([C++])
  91
  92 AC_ARG_ENABLE([gcc-warnings],
  93 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended).
  94                            Also, issue synclines from the examples/ to
  95                            the corresponding source in the Texinfo doc.],
  96 [case $enable_gcc_warnings in
  97    yes|no) ;;
  98    *)  AC_MSG_ERROR([invalid value for --gcc-warnings: $enable_gcc_warnings]);;
  99  esac],
 100               [enable_gcc_warnings=no])
 101 AM_CONDITIONAL([ENABLE_GCC_WARNINGS], [test "$enable_gcc_warnings" = yes])
 102 if test "$enable_gcc_warnings" = yes; then
 103   # -Wno-tautological-constant-out-of-range-compare for Clang 3.3 and
 104   # 3.4 on GNU/Linux that choke on intprops.h's INT_MULTIPLY_WRAPV,
 105   # etc.
 106   #
 107   # ICC: -wr188
 108   #
 109   # 1669  warnings warnings_default =
 110   # ../src/complain.c(318): error #188: enumerated type mixed with another type
 111   # 1670      Wconflicts_sr | Wconflicts_rr | Wdeprecated | Wother;
 112   # 1671      ^
 113   # 1672
 114   # 1673../src/complain.c(393): error #188: enumerated type mixed with another type
 115   # 1674          warnings w = 1 << wbit;
 116   # 1675                       ^
 117   #
 118   # ICC: -wr3179
 119   #
 120   # char const *usefulness
 121   #   = rule_useless_in_grammar_p (&rules[r]) ? "useless-in-grammar"
 122   #   : rule_useless_in_parser_p (&rules[r])  ? "useless-in-parser"
 123   #   :                                         "useful";
 124   #
 125   # gives
 126   #
 127   # error #3179: deprecated conversion of string literal to char* (should be const char*)
 128   #
 129   # ICC: -wr2259 (that's in C, in spite of what the error messages which seems to be about C++).
 130   # error #2259: non-pointer conversion from "int" to "yybool={signed char}" may lose significant bits
 131   #   yybool yynormal YY_ATTRIBUTE_UNUSED = yystackp->yysplitPoint == YY_NULLPTR;
 132   #                                         ^
 133   warn_common='-Wall -Wextra
 134     -Wcast-align -Wchar-subscripts
 135     -fparse-all-comments -Wdocumentation
 136     -Wformat -Wimplicit-fallthrough -Wnull-dereference
 137     -Wno-sign-compare -Wno-tautological-constant-out-of-range-compare
 138     -Wpointer-arith -Wshadow -Wstrict-aliasing
 139     -Wwrite-strings
 140     -wr188 -wr2259 -wr3179'
 141   warn_c='-Wbad-function-cast
 142     -Wmissing-prototypes
 143     -Wstrict-prototypes'
 144   warn_cxx='-Wextra-semi -Wnoexcept -Wold-style-cast -Wundefined-func-template
 145     -Wweak-vtables'
 146   # Warnings for the test suite only.
 147   #
 148   # -fno-color-diagnostics: Clang's use of colors in the error
 149   # messages is confusing the tests looking at the compiler's output
 150   # (e.g., synclines.at).
 151   #
 152   # -Wno-keyword-macro: We use the "#define private public" dirty
 153   # trick in the test suite to check some private implementation
 154   # details for lalr1.cc.
 155   warn_tests='-Wundef -pedantic -Wconversion
 156     -Wdeprecated -Wsign-compare -Wsign-conversion
 157     -Wtautological-constant-out-of-range-compare
 158     -fno-color-diagnostics
 159     -Wno-keyword-macro'
 160
 161
 162   AC_LANG_PUSH([C])
 163   # Clang supports many of GCC's -W options, but only issues warnings
 164   # on the ones it does not recognize.  In that case, gl_WARN_ADD
 165   # thinks the option is supported, and unknown options are then added
 166   # to CFLAGS.  But then, when -Werror is added in the test suite for
 167   # instance, the warning about the unknown option turns into an
 168   # error.
 169   #
 170   # This should be addressed by gnulib's gl_WARN_ADD, but in the
 171   # meanwhile, turn warnings about unknown options into errors in
 172   # CFLAGS, and restore CFLAGS after the tests.
 173   save_CFLAGS=$CFLAGS
 174   gl_WARN_ADD([-Werror=unknown-warning-option], [CFLAGS])
 175   # Accept this warning only if it is not too touchy (e.g., clang 3.3
 176   # and 3.4).
 177   gl_WARN_ADD([-Wunreachable-code], [WARN_CFLAGS],
 178               [AC_LANG_PROGRAM([],
 179               [[if (sizeof (long) < sizeof (int)) return 1;]])])
 180   for i in $warn_common $warn_c;
 181   do
 182     gl_WARN_ADD([$i], [WARN_CFLAGS])
 183   done
 184   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 185
 186   # Warnings for the test suite, and maybe for bison if GCC is modern
 187   # enough.
 188   test $lv_cv_gcc_pragma_push_works = yes &&
 189     AS_VAR_APPEND([WARN_CFLAGS], [" $WARN_CFLAGS_TEST"])
 190
 191   # Warnings for the test suite only.
 192   for i in $warn_tests -Wincompatible-pointer-types;
 193   do
 194     gl_WARN_ADD([$i], [WARN_CFLAGS_TEST])
 195   done
 196   CFLAGS=$save_CFLAGS
 197   AC_LANG_POP([C])
 198
 199
 200   AC_LANG_PUSH([C++])
 201   save_CXXFLAGS=$CXXFLAGS
 202   gl_WARN_ADD([-Werror=unknown-warning-option], [CXXFLAGS])
 203   for i in $warn_common $warn_cxx;
 204   do
 205     gl_WARN_ADD([$i], [WARN_CXXFLAGS])
 206   done
 207   # Accept this warning only if it is not too touchy (e.g., clang 3.3
 208   # and 3.4).
 209   gl_WARN_ADD([-Wunreachable-code], [WARN_CXXFLAGS],
 210               [AC_LANG_PROGRAM([],
 211               [[if (sizeof (long) < sizeof (int)) return 1;]])])
 212   gl_WARN_ADD([-Wzero-as-null-pointer-constant], [WARN_CXXFLAGS],
 213               [AC_LANG_PROGRAM([], [nullptr])])
 214   # Before GCC6, the pragmas don't work well enough to neutralize
 215   # this warning.
 216   gl_WARN_ADD([-Wuseless-cast], [WARN_CXXFLAGS],
 217               [AC_LANG_PROGRAM([], [
 218               #if defined __GNUC__ && ! defined __ICC && ! defined __clang__ && __GNUC__ < 6
 219               syntax error
 220               #endif
 221               ])])
 222   gl_WARN_ADD([-Werror], [WERROR_CXXFLAGS])
 223   # Warnings for the test suite only.
 224   for i in $warn_tests;
 225   do
 226     gl_WARN_ADD([$i], [WARN_CXXFLAGS_TEST])
 227   done
 228   # Too many compilers complain about Flex generated code.
 229   gl_WARN_ADD([-Wno-error], [FLEX_SCANNER_CXXFLAGS])
 230   # Clang++ deprecates compiling C.
 231   gl_WARN_ADD([-Wno-deprecated], [WNO_DEPRECATED_CXXFLAGS])
 232   CXXFLAGS=$save_CXXFLAGS
 233   AC_LANG_POP([C++])
 234 fi
 235
 236
 237 BISON_TEST_FOR_WORKING_C_COMPILER
 238 BISON_C_COMPILER_POSIXLY_CORRECT
 239 BISON_TEST_FOR_WORKING_CXX_COMPILER
 240 BISON_CXX_COMPILER_POSIXLY_CORRECT
 241
 242 # D.
 243 AC_CHECK_PROGS([DC], [dmd])
 244 AC_CHECK_PROGS([DCFLAGS], [-g])
 245 AM_CONDITIONAL([ENABLE_D], [test x"$DC" != x])
 246
 247 # Java.
 248 gt_JAVACOMP([1.7], [1.7])
 249 gt_JAVAEXEC
 250 AM_CONDITIONAL([ENABLE_JAVA], [test x"$CONF_JAVAC" != x && test x"$CONF_JAVA" != x])
 251
 252
 253 AC_ARG_ENABLE([yacc],
 254   [AC_HELP_STRING([--disable-yacc],
 255      [do not build a yacc command or an -ly library])],
 256   , [enable_yacc=yes])
 257 AM_CONDITIONAL([ENABLE_YACC], [test "$enable_yacc" = yes])
 258 AC_CONFIG_FILES([src/yacc], [chmod +x src/yacc])
 259
 260 # Checks for programs.
 261 AM_MISSING_PROG([DOT], [dot])
 262 AC_PROG_LEX
 263 if ! "$LEX_IS_FLEX" || test "X$LEX" = X:; then
 264   AC_MSG_WARN([bypassing lex because flex is required])
 265   LEX=:
 266 fi
 267 AM_CONDITIONAL([FLEX_WORKS], [$LEX_IS_FLEX && $FLEX_SUPPORTS_HEADER_OPT])
 268 AM_CONDITIONAL([FLEX_CXX_WORKS],
 269   [$LEX_IS_FLEX && $FLEX_SUPPORTS_HEADER_OPT && test $bison_cv_cxx_works = yes])
 270 AC_PROG_YACC
 271 AC_PROG_RANLIB
 272 AC_PROG_GNU_M4
 273 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 274 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 275 supports -g, otherwise to "".])
 276 AC_PATH_PROG([PERL], [perl])
 277 AM_MISSING_PROG([HELP2MAN], [help2man])
 278 AC_PATH_PROG([XSLTPROC], [xsltproc])
 279 AC_SUBST([XSLTPROC])
 280
 281 # Checks for header files.
 282 AC_CHECK_HEADERS_ONCE([locale.h])
 283
 284 # Checks for compiler characteristics.
 285 AC_C_INLINE
 286
 287 # Gnulib (later checks).  Putting them here rather than right after
 288 # gl_EARLY avoids some redundant checks.
 289 gl_INIT
 290
 291 # Checks for library functions.
 292 AC_CHECK_FUNCS_ONCE([setlocale])
 293
 294 # Gettext.
 295 # We use gnulib, which is only guaranteed to work properly with the
 296 # latest Gettext.
 297 AM_GNU_GETTEXT([external], [need-ngettext])
 298 AM_GNU_GETTEXT_VERSION([0.19])
 299 BISON_I18N
 300 AC_CONFIG_FILES([gnulib-po/Makefile.in])
 301
 302 # Internationalized parsers.
 303 AC_CONFIG_FILES([runtime-po/Makefile.in])
 304 # Autoconf macros for packages using internationalized parsers.
 305 aclocaldir='${datadir}/aclocal'
 306 AC_SUBST([aclocaldir])
 307
 308 # Create the benchmark script.
 309 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 310
 311 # Initialize the test suite.
 312 AC_CONFIG_TESTDIR(tests)
 313 AC_CONFIG_FILES([tests/atlocal])
 314 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 315
 316 AC_CHECK_PROGS([VALGRIND], [valgrind])
 317 # Use something simpler that $host_os to select our suppression file.
 318 uname=`uname`
 319 case $VALGRIND:$uname in
 320   '':*) ;;
 321   *:Darwin)
 322     # See README-hacking.md.
 323     VALGRIND=;;
 324   *:*)
 325     suppfile=build-aux/$uname.valgrind
 326     if test -f "$srcdir/$suppfile"; then
 327       AC_SUBST([VALGRIND_OPTS_SUPPRESSION],
 328                ["--suppressions=\$(abs_top_srcdir)/$suppfile"])
 329     fi
 330     ;;
 331 esac
 332 AC_MSG_CHECKING([Valgrind suppression file])
 333 AC_MSG_RESULT([$suppfile])
 334
 335 # Whether we cannot run the compiled bison.
 336 AM_CONDITIONAL([CROSS_COMPILING], [test "$cross_compiling" = yes])
 337
 338 # Build bistromathic if we have the lib and both readline/readline.h
 339 # and readline/history.h.
 340 AM_CONDITIONAL([ENABLE_BISTROMATHIC],
 341 [test "$gl_cv_lib_readline" != no &&
 342   test "$ac_cv_header_readline_readline_h" = yes &&
 343   test "$ac_cv_header_readline_history_h" = yes])
 344
 345 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 346 # Needed by tests/atlocal.in.
 347 AC_SUBST([GCC])
 348
 349 AC_CONFIG_FILES([Makefile
 350                  po/Makefile.in
 351                  doc/yacc.1])
 352
 353 # Fix LIBOBJS to give the Makefile the right file names.  Otherwise
 354 # compilation works, but with unexpected file names, so clean rules don't
 355 # remove the actual files and distcheck fails.
 356 AC_CONFIG_COMMANDS_PRE([
 357   case $am__api_version in
 358     1.14*|1.15*) gl_LIBOBJS=`echo "$gl_LIBOBJS" | sed -e 's, lib/, lib/lib_libbison_a-,g'`;;
 359     *)           gl_LIBOBJS=`echo "$gl_LIBOBJS" | sed -e 's, lib/, lib/libbison_a-,g'`;;
 360   esac
 361 ])
 362
 363 AC_OUTPUT