tests/local.at

   1 # Process this -*- Autotest -*- file with autom4te.
   2
   3 # Macros for the GNU Bison Test suite.
   4
   5 # Copyright (C) 2003-2015, 2018 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 m4_version_prereq([2.58])
  21
  22
  23 # m4_null_if(VAL, IF-TRUE, IF-FALSE)
  24 # ----------------------------------
  25 # If VAL evaluates to empty or 0, run IF-TRUE, otherwise IF-FALSE.
  26 m4_define([m4_null_if],
  27 [m4_case(m4_quote($1),
  28          [0], [$2],
  29          [],  [$2],
  30          [$3])])
  31
  32 # AT_SETUP_STRIP(TITLE)
  33 # ---------------------
  34 # Abbreviate the TITLE to be passed to AT_SETUP.  Remove new-lines
  35 # that completely break AT_SETUP.
  36 m4_define([AT_SETUP_STRIP],
  37 [m4_bpatsubsts([$1],
  38       [%\(language\|skeleton\) "?\([^\" ]*\)"?],
  39         [\2],
  40       [%define "?\([-A-Za-z0-9_.]+\)"? \({[^\}]+}\|"[^\"]+"\|[-A-Za-z0-9_.]+\)],
  41         [\1=\2],
  42       [%define "?\([-A-Za-z0-9_.]+\)"?],
  43         [\1],
  44       [ *
  45 + *],    [ ])dnl
  46 ])
  47
  48
  49 ## ------------- ##
  50 ## Basic tests.  ##
  51 ## ------------- ##
  52
  53 # AT_MATCHES_CHECK(FILE, PERL-REGEXP, COUNT)
  54 # ------------------------------------------
  55 # Expect COUNT matches of the PERL-REGEXP in FILE.  The file is
  56 # taken in "slurp" mode, i.e., one can match end-of-lines.
  57 m4_define([AT_MATCHES_CHECK],
  58 [AT_CHECK([$PERL -0777 -ne '
  59 my $count = 0;
  60 s{$2}{ ++$count; "" }gem;
  61 printf "$count\n";' $1], [0], [$3
  62 ])])
  63
  64
  65 # AT_SAVE_SPECIAL_FILES / AT_RESTORE_SPECIAL_FILES
  66 # ------------------------------------------------
  67 # Don't interfere with caller's files.
  68 m4_divert_text([PREPARE_TESTS],
  69 [at_save_special_files ()
  70 {
  71   for at_save_file in stderr experr expout
  72   do
  73     test ! -f at-bison-check-$at_save_file.bak ||
  74       as_fn_error 1 "fatal error: back-up on top of a back-up"
  75     test ! -f $at_save_file || mv $at_save_file at-bison-check-$at_save_file.bak
  76   done
  77 }
  78
  79 at_restore_special_files ()
  80 {
  81   for at_save_file in stderr experr expout
  82   do
  83     test ! -f at-bison-check-$at_save_file.bak ||
  84       mv at-bison-check-$at_save_file.bak $at_save_file
  85   done
  86 }
  87 ])
  88
  89 m4_define([AT_SAVE_SPECIAL_FILES],    [at_save_special_files])
  90 m4_define([AT_RESTORE_SPECIAL_FILES], [at_restore_special_files])
  91
  92
  93
  94 ## ------------------------------- ##
  95 ## Macros decoding Bison options.  ##
  96 ## ------------------------------- ##
  97
  98 # AT_LOC_PUSHDEF(FIRST-LINE, FIRST-COLUMN, LAST-LINE, LAST-COLUMN)
  99 # ----------------------------------------------------------------
 100 # Pushdef AT(_LOC)?_(FIRST|LAST)_(LINE|COLUMN).
 101 m4_define([AT_LOC_PUSHDEF],
 102 [m4_pushdef([AT_FIRST_LINE],  [$1])
 103 m4_pushdef([AT_FIRST_COLUMN], [$2])
 104 m4_pushdef([AT_LAST_LINE],    [$3])
 105 m4_pushdef([AT_LAST_COLUMN],  [$4])
 106 m4_pushdef([AT_LOC_FIRST_LINE],   [AT_LOC.AT_FIRST_LINE])
 107 m4_pushdef([AT_LOC_FIRST_COLUMN], [AT_LOC.AT_FIRST_COLUMN])
 108 m4_pushdef([AT_LOC_LAST_LINE],    [AT_LOC.AT_LAST_LINE])
 109 m4_pushdef([AT_LOC_LAST_COLUMN],  [AT_LOC.AT_LAST_COLUMN])])
 110
 111 # AT_LOC_POPDEF
 112 # -------------
 113 # Popdef AT(_LOC)?_(FIRST|LAST)_(LINE|COLUMN).
 114 m4_define([AT_LOC_POPDEF],
 115 [m4_popdef([AT_LOC_FIRST_LINE])
 116 m4_popdef([AT_LOC_FIRST_COLUMN])
 117 m4_popdef([AT_LOC_LAST_LINE])
 118 m4_popdef([AT_LOC_LAST_COLUMN])
 119 m4_popdef([AT_FIRST_LINE])
 120 m4_popdef([AT_FIRST_COLUMN])
 121 m4_popdef([AT_LAST_LINE])
 122 m4_popdef([AT_LAST_COLUMN])
 123 ])
 124
 125
 126
 127 # AT_BISON_OPTION_PUSHDEFS([BISON-OPTIONS])
 128 # -----------------------------------------
 129 m4_define([AT_BISON_OPTION_PUSHDEFS],
 130 [m4_divert_text([KILL],
 131                 [_AT_BISON_OPTION_PUSHDEFS($[1], $[2], [$1])])])
 132
 133
 134 # _AT_BISON_OPTION_PUSHDEFS($1, $2, [BISON-OPTIONS])
 135 # --------------------------------------------------
 136 # This macro works around the impossibility to define macros
 137 # inside macros, because issuing '[$1]' is not possible in M4 :(.
 138 # This sucks hard, GNU M4 should really provide M5-like $$1.
 139 m4_define([_AT_BISON_OPTION_PUSHDEFS],
 140 [m4_if([$1$2], $[1]$[2], [],
 141        [m4_fatal([$0: Invalid arguments: $@])])dnl
 142 m4_pushdef([AT_AUTOMOVE_IF],
 143 [m4_bmatch([$3], [%define api\.value\.automove], [$1], [$2])])
 144 m4_pushdef([AT_DEFINES_IF],
 145 [m4_bmatch([$3], [%defines], [$1], [$2])])
 146 m4_pushdef([AT_DEBUG_IF],
 147 [m4_bmatch([$3], [%debug\|%define parse.trace], [$1], [$2])])
 148 m4_pushdef([AT_SKEL_CC_IF],
 149 [m4_bmatch([$3], [%language "[Cc]\+\+"\|%skeleton "[a-z0-9]+\.cc"], [$1], [$2])])
 150 m4_pushdef([AT_SKEL_JAVA_IF],
 151 [m4_bmatch([$3], [%language "[Jj][Aa][Vv][Aa]"\|%skeleton "[a-z0-9]+\.java"], [$1], [$2])])
 152 # The target language: "c", "c++", or "java".
 153 m4_pushdef([AT_LANG],
 154 [AT_SKEL_JAVA_IF([java],
 155                  [AT_SKEL_CC_IF([c++],
 156                                 [c])])])
 157 m4_pushdef([AT_GLR_IF],
 158 [m4_bmatch([$3], [%glr-parser\|%skeleton "glr\..*"], [$1], [$2])])
 159 m4_pushdef([AT_LALR1_CC_IF],
 160 [AT_SKEL_CC_IF([AT_GLR_IF([$2], [$1])], [$2])])
 161 m4_pushdef([AT_GLR_CC_IF],
 162 [AT_SKEL_CC_IF([AT_GLR_IF([$1], [$2])], [$2])])
 163 # Using yacc.c?
 164 m4_pushdef([AT_YACC_IF],
 165 [m4_bmatch([$3], [%language\|%glr-parser\|%skeleton], [$2], [$1])])
 166 m4_pushdef([AT_LEXPARAM_IF],
 167 [m4_bmatch([$3], [%lex-param], [$1], [$2])])
 168 m4_pushdef([AT_LOCATION_IF],
 169 [m4_bmatch([$3], [%locations], [$1], [$2])])
 170 m4_pushdef([AT_LOCATION_TYPE_IF],
 171 [m4_bmatch([$3], [%define \(api\.location\.type\|location_type\)], [$1], [$2])])
 172 m4_pushdef([AT_PARAM_IF],
 173 [m4_bmatch([$3], [%parse-param], [$1], [$2])])
 174 # Comma-terminated list of formals parse-parameters.
 175 # E.g., %parse-param { int x } %parse-param {int y} -> "int x, int y, ".
 176 # FIXME: Support grouped parse-param.
 177 m4_pushdef([AT_PARSE_PARAMS])
 178 m4_bpatsubst([$3], [%parse-param { *\([^{}]*[^{} ]\) *}],
 179              [m4_append([AT_PARSE_PARAMS], [\1, ])])
 180
 181 m4_pushdef([AT_PURE_IF],
 182 [m4_bmatch([$3], [%define  *api\.pure\|%pure-parser],
 183            [m4_bmatch([$3], [%define  *api\.pure *false], [$2], [$1])],
 184            [$2])])
 185 m4_pushdef([AT_PUSH_IF],
 186 [m4_bmatch([$3], [%define api.push-pull \(both\|pull\)], [$1], [$2])])
 187 # AT_NAME_PREFIX: also consider api.namespace.
 188 m4_pushdef([AT_NAME_PREFIX],
 189 [m4_bmatch([$3], [\(%define api\.\(namespace\|prefix\)\|%name-prefix\) .*],
 190    [m4_bregexp([$3],
 191      [\(%define api\.\(namespace\|prefix\)\|%name-prefix\) [\{\"]\([^\"\}]*\)[\"\}]],
 192      [\3])],
 193    [yy])])
 194 m4_pushdef([AT_TOKEN_CTOR_IF],
 195 [m4_bmatch([$3], [%define api\.token\.constructor], [$1], [$2])])
 196 m4_pushdef([AT_TOKEN_PREFIX],
 197 [m4_bmatch([$3], [%define api\.token\.prefix {.*}],
 198            [m4_bregexp([$3], [%define api\.token\.prefix {\(.*\)}], [\1])])])
 199 m4_pushdef([AT_VARIANT_IF],
 200 [m4_bmatch([$3], [%define api\.value\.type variant], [$1], [$2])])
 201 m4_pushdef([AT_API_prefix],
 202 [m4_bmatch([$3], [%define api\.prefix {.*}],
 203            [m4_bregexp([$3], [%define api\.prefix {\([^\}]*\)}], [\1])],
 204            [yy])])
 205 m4_pushdef([AT_API_PREFIX],
 206 [m4_toupper(AT_API_prefix)])
 207 # yyerror receives the location if %location, and if the parser is pure. For
 208 # historical reasons, with the "yacc.c" skeleton, the location is not passed
 209 # unless an additional "%parse-param" is present, or if the purity is defined
 210 # as "full".
 211 m4_pushdef([AT_YYERROR_ARG_LOC_IF],
 212 [AT_LOCATION_IF([AT_PURE_IF([m4_bmatch([$3],
 213                                        m4_quote(m4_join([\|],
 214                                                         [%define api\.pure full],
 215                                                         [%glr-parser],
 216                                                         [%parse-param],
 217                                                         [%skeleton "?glr.c"?])),
 218                                        [$1], [$2])],
 219                             [$2])],
 220                     [$2])])
 221
 222 # yyerror always sees the locations (when activated) if the parser is impure.
 223 # When the parser is pure, yyerror sees the location if it is received as an
 224 # argument.
 225 m4_pushdef([AT_YYERROR_SEES_LOC_IF],
 226 [AT_LOCATION_IF([AT_YACC_IF([AT_PURE_IF([AT_YYERROR_ARG_LOC_IF([$1], [$2])],
 227                                         [$1])],
 228                             [$1])],
 229                 [$2])])
 230
 231 # The interface is pure: either because %define api.pure, or because we
 232 # are using the C++ parsers.
 233 m4_pushdef([AT_PURE_LEX_IF],
 234 [AT_PURE_IF([$1],
 235             [AT_SKEL_CC_IF([$1], [$2])])])
 236
 237 m4_pushdef([AT_YYSTYPE],
 238 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::semantic_type]],
 239                [AT_API_PREFIX[STYPE]])])
 240 m4_pushdef([AT_YYLTYPE],
 241 [AT_SKEL_CC_IF([AT_NAME_PREFIX[::parser::location_type]],
 242                [AT_API_PREFIX[LTYPE]])])
 243
 244
 245 AT_PURE_LEX_IF(
 246 [m4_pushdef([AT_LOC], [(*llocp)])
 247  m4_pushdef([AT_VAL], [(*lvalp)])
 248  m4_pushdef([AT_YYLEX_FORMALS],
 249             [AT_YYSTYPE *lvalp[]AT_LOCATION_IF([, AT_YYLTYPE *llocp])])
 250  m4_pushdef([AT_YYLEX_ARGS],
 251             [lvalp[]AT_LOCATION_IF([, llocp])])
 252  m4_pushdef([AT_USE_LEX_ARGS],
 253             [(void) lvalp;AT_LOCATION_IF([(void) llocp])])
 254  m4_pushdef([AT_YYLEX_PRE_FORMALS],
 255             [AT_YYLEX_FORMALS, ])
 256  m4_pushdef([AT_YYLEX_PRE_ARGS],
 257             [AT_YYLEX_ARGS, ])
 258 ],
 259 [m4_pushdef([AT_LOC], [[(]AT_NAME_PREFIX[lloc)]])
 260  m4_pushdef([AT_VAL], [[(]AT_NAME_PREFIX[lval)]])
 261  m4_pushdef([AT_YYLEX_FORMALS],     [void])
 262  m4_pushdef([AT_YYLEX_ARGS],        [])
 263  m4_pushdef([AT_USE_LEX_ARGS],    [])
 264  m4_pushdef([AT_YYLEX_PRE_FORMALS], [])
 265  m4_pushdef([AT_YYLEX_PRE_ARGS],    [])
 266 ])
 267
 268 # Handle the different types of location components.
 269
 270 AT_SKEL_CC_IF(
 271   [AT_LOCATION_TYPE_IF(
 272     [AT_LOC_PUSHDEF([first.l], [first.c], [last.l], [last.c])],
 273     [AT_LOC_PUSHDEF([begin.line], [begin.column], [end.line], [end.column])])],
 274   [AT_LOC_PUSHDEF([first_line], [first_column], [last_line], [last_column])])
 275
 276
 277 AT_GLR_IF([AT_KEYWORDS([glr])])
 278 ])# _AT_BISON_OPTION_PUSHDEFS
 279
 280
 281 # AT_BISON_OPTION_POPDEFS
 282 # -----------------------
 283 m4_define([AT_BISON_OPTION_POPDEFS],
 284 [m4_divert_text([KILL],
 285 [m4_popdef([AT_YYLEX_PRE_ARGS])
 286 m4_popdef([AT_YYLEX_PRE_FORMALS])
 287 m4_popdef([AT_USE_LEX_ARGS])
 288 m4_popdef([AT_YYLEX_ARGS])
 289 m4_popdef([AT_YYLEX_FORMALS])
 290 m4_popdef([AT_YYLTYPE])
 291 m4_popdef([AT_YYSTYPE])
 292 m4_popdef([AT_VAL])
 293 m4_popdef([AT_LOC])
 294 m4_popdef([AT_PURE_LEX_IF])
 295 m4_popdef([AT_YYERROR_SEES_LOC_IF])
 296 m4_popdef([AT_YYERROR_ARG_LOC_IF])
 297 m4_popdef([AT_API_PREFIX])
 298 m4_popdef([AT_API_prefix])
 299 m4_popdef([AT_VARIANT_IF])
 300 m4_popdef([AT_TOKEN_PREFIX])
 301 m4_popdef([AT_TOKEN_CTOR_IF])
 302 m4_popdef([AT_NAME_PREFIX])
 303 m4_popdef([AT_LOCATION_TYPE_IF])
 304 m4_popdef([AT_LOCATION_IF])
 305 m4_popdef([AT_PARSE_PARAMS])
 306 m4_popdef([AT_PUSH_IF])
 307 m4_popdef([AT_PURE_IF])
 308 m4_popdef([AT_PARAM_IF])
 309 m4_popdef([AT_LEXPARAM_IF])
 310 m4_popdef([AT_YACC_IF])
 311 m4_popdef([AT_GLR_IF])
 312 m4_popdef([AT_SKEL_CC_IF])
 313 m4_popdef([AT_LANG])
 314 m4_popdef([AT_SKEL_JAVA_IF])
 315 m4_popdef([AT_GLR_CC_IF])
 316 m4_popdef([AT_LALR1_CC_IF])
 317 m4_popdef([AT_DEFINES_IF])
 318 m4_popdef([AT_DEBUG_IF])
 319 AT_LOC_POPDEF])dnl
 320 ])# AT_BISON_OPTION_POPDEFS
 321
 322
 323
 324 ## -------------------------- ##
 325 ## Generating Grammar Files.  ##
 326 ## -------------------------- ##
 327
 328 # _AT_LANG_DISPATCH(LANG, MACRO, ARGS)
 329 # ------------------------------------
 330 # Call the specialization of MACRO for LANG with ARGS.  Complain if
 331 # unavailable.
 332 m4_define([_AT_LANG_DISPATCH],
 333 [m4_ifdef([$2($1)],
 334        [m4_indir([$2($1)], m4_shift2($@))],
 335        [m4_fatal([$2: unknown language: $1])])])
 336
 337
 338 # AT_LANG_DISPATCH(MACRO, ARGS)
 339 # -----------------------------
 340 # Call the specialization of MACRO for AT_LANG with ARGS.  Complain if
 341 # unavailable.
 342 m4_define([AT_LANG_DISPATCH],
 343 [_AT_LANG_DISPATCH(AT_LANG, $@)])
 344
 345
 346
 347 # AT_DATA_SOURCE_PROLOGUE
 348 # -----------------------
 349 # The prologue that should be included in any source code that is
 350 # meant to be compiled.  Keep atlocal.in sync (BISON_CXX_WORKS).
 351 m4_define([AT_DATA_SOURCE_PROLOGUE],
 352 [[/* Load config.h, and adjust to the compiler.
 353   We used to do it here, but each time we add a new line,
 354   we have to adjust all the line numbers in error messages.
 355   It's simpler to use a constant include to a varying file.  */
 356 #include <testsuite.h>
 357 ]])
 358
 359 # AT_DATA_GRAMMAR_PROLOGUE
 360 # ------------------------
 361 # The prologue that should be included in any grammar which parser is
 362 # meant to be compiled.
 363 m4_define([AT_DATA_GRAMMAR_PROLOGUE],
 364 [[%code top {
 365 ]AT_DATA_SOURCE_PROLOGUE[]dnl
 366 [}
 367 ]])
 368
 369 # AT_DATA_SOURCE(NAME, CONTENT)
 370 # -----------------------------
 371 # Generate the file NAME, which CONTENT is preceded by
 372 # AT_DATA_SOURCE_PROLOGUE.
 373 m4_define([AT_DATA_SOURCE],
 374 [AT_DATA([$1],
 375 [AT_DATA_SOURCE_PROLOGUE
 376 $2])
 377 ])
 378
 379 # AT_DATA_GRAMMAR(NAME, CONTENT)
 380 # ------------------------------
 381 # Generate the file NAME, which CONTENT is preceded by
 382 # AT_DATA_GRAMMAR_PROLOGUE.
 383 m4_define([AT_DATA_GRAMMAR],
 384 [AT_DATA([$1],
 385 [AT_DATA_GRAMMAR_PROLOGUE
 386 $2])
 387 ])
 388
 389 # AT_YYLEX_PROTOTYPE
 390 # AT_YYLEX_DECLARE_EXTERN
 391 # AT_YYLEX_DECLARE
 392 # AT_YYLEX_DEFINE([INPUT], [ACTION])
 393 # ----------------------------------
 394 # INPUT can be empty, or in double quotes, or a list (in braces).
 395 # ACTION may compute yylval for instance, using "res" as token type,
 396 # and "toknum" as the number of calls to yylex (starting at 0).
 397 m4_define([AT_YYLEX_PROTOTYPE],
 398 [int AT_NAME_PREFIX[]lex (]AT_YYLEX_FORMALS[)[]dnl
 399 ])
 400
 401 m4_define([AT_YYLEX_DECLARE_EXTERN],
 402 [AT_YYLEX_PROTOTYPE;dnl
 403 ])
 404
 405 m4_define([AT_YYLEX_DECLARE],
 406 [static AT_YYLEX_DECLARE_EXTERN[]dnl
 407 ])
 408
 409 m4_define([AT_YYLEX_DEFINE],
 410 [[#include <assert.h>
 411 static
 412 ]AT_YYLEX_PROTOTYPE[
 413 {
 414   ]m4_bmatch([$1], [^\(".*"\)?$],
 415              [[static char const input[] = ]m4_default([$1], [""])],
 416              [[static int const input[] = ]$1])[;
 417   static size_t toknum = 0;
 418   int res;
 419   ]AT_USE_LEX_ARGS[;
 420   assert (toknum < sizeof input / sizeof input[0]);
 421   res = input[toknum++];
 422   ]$2[;]AT_LOCATION_IF([[
 423   ]AT_LOC_FIRST_LINE[ = ]AT_LOC_LAST_LINE[ = 1;
 424   ]AT_LOC_FIRST_COLUMN[ = ]AT_LOC_LAST_COLUMN[ = toknum;]])[
 425   return res;
 426 }]dnl
 427 ])
 428
 429 # AT_YYERROR_FORMALS
 430 # AT_YYERROR_PROTOTYPE
 431 # AT_YYERROR_DECLARE_EXTERN
 432 # AT_YYERROR_DECLARE
 433 # AT_YYERROR_DEFINE
 434 # -------------------------
 435 # Must be called inside a AT_BISON_OPTION_PUSHDEFS/POPDEFS pair.
 436 m4_define([AT_YYERROR_FORMALS],  [AT_LANG_DISPATCH([$0], $@)])
 437 m4_define([AT_YYERROR_PROTOTYPE],[AT_LANG_DISPATCH([$0], $@)])
 438 m4_define([AT_YYERROR_DECLARE_EXTERN], [AT_LANG_DISPATCH([$0], $@)])
 439 m4_define([AT_YYERROR_DECLARE],  [AT_LANG_DISPATCH([$0], $@)])
 440 m4_define([AT_YYERROR_DEFINE],   [AT_LANG_DISPATCH([$0], $@)])
 441
 442 # AT_MAIN_DEFINE
 443 # --------------
 444 m4_define([AT_MAIN_DEFINE],   [AT_LANG_DISPATCH([$0], $@)])
 445
 446
 447
 448 ## --- ##
 449 ## C.  ##
 450 ## --- ##
 451
 452 m4_define([AT_YYERROR_FORMALS(c)],
 453 [AT_YYERROR_ARG_LOC_IF([AT_YYLTYPE const * const llocp, ])AT_PARSE_PARAMS[const char *msg]])
 454
 455 m4_define([AT_YYERROR_PROTOTYPE(c)],
 456 [[void ]AT_NAME_PREFIX[error (]AT_YYERROR_FORMALS[)]])
 457
 458 m4_define([AT_YYERROR_DECLARE_EXTERN(c)],
 459 [AT_YYERROR_PROTOTYPE;])
 460
 461 m4_define([AT_YYERROR_DECLARE(c)],
 462 [#include <stdio.h>
 463 ]AT_LOCATION_IF([[
 464 #if defined ]AT_YYLTYPE[_IS_TRIVIAL && ]AT_YYLTYPE[_IS_TRIVIAL
 465 static unsigned location_print (FILE *yyo, ]AT_YYLTYPE[ const * const yylocp);
 466 # ifndef LOCATION_PRINT
 467 #  define LOCATION_PRINT(File, Loc) location_print (File, &(Loc))
 468 # endif
 469 #endif
 470 ]])[
 471 static AT_YYERROR_DECLARE_EXTERN])
 472
 473
 474 m4_define([AT_YYERROR_DEFINE(c)],
 475 [[
 476 ]AT_LOCATION_IF([[
 477 # if defined ]AT_YYLTYPE[_IS_TRIVIAL && ]AT_YYLTYPE[_IS_TRIVIAL
 478 /* Print *YYLOCP on YYO. */
 479 __attribute__((__unused__))
 480 static unsigned
 481 location_print (FILE *yyo, ]AT_YYLTYPE[ const * const yylocp)
 482 {
 483   unsigned res = 0;
 484   int end_col = 0 != yylocp->last_column ? yylocp->last_column - 1 : 0;
 485   if (0 <= yylocp->first_line)
 486     {
 487       res += fprintf (yyo, "%d", yylocp->first_line);
 488       if (0 <= yylocp->first_column)
 489         res += fprintf (yyo, ".%d", yylocp->first_column);
 490     }
 491   if (0 <= yylocp->last_line)
 492     {
 493       if (yylocp->first_line < yylocp->last_line)
 494         {
 495           res += fprintf (yyo, "-%d", yylocp->last_line);
 496           if (0 <= end_col)
 497             res += fprintf (yyo, ".%d", end_col);
 498         }
 499       else if (0 <= end_col && yylocp->first_column < end_col)
 500         res += fprintf (yyo, "-%d", end_col);
 501     }
 502   return res;
 503 }
 504 #endif
 505 ]])[
 506 /* A C error reporting function.  */
 507 static
 508 ]AT_YYERROR_PROTOTYPE[
 509 {]m4_bpatsubst(m4_defn([AT_PARSE_PARAMS]),
 510               [[^,]+[^A-Za-z_0-9]\([A-Za-z_][A-Za-z_0-9]*\), *], [
 511   YYUSE(\1);])dnl
 512 AT_YYERROR_SEES_LOC_IF([[
 513   LOCATION_PRINT (stderr, ]AT_LOC[);
 514   fprintf (stderr, ": ");]])[
 515   fprintf (stderr, "%s\n", msg);
 516 }]])
 517
 518
 519 m4_define([AT_MAIN_DEFINE(c)],
 520 [[#include <stdlib.h> /* getenv. */
 521 #include <string.h> /* strcmp. */
 522 int
 523 main (int argc, char const* argv[])
 524 {]AT_DEBUG_IF([[
 525   if (getenv("YYDEBUG")
 526       || (argc == 2
 527           && (!strcmp (argv[1], "-d") || !strcmp (argv[1], "--debug"))))
 528     yydebug |= 1;]], [[
 529   (void) argc;
 530   (void) argv;]])[
 531   return ]AT_NAME_PREFIX[parse ();
 532 }]])
 533
 534
 535 ## ----- ##
 536 ## C++.  ##
 537 ## ----- ##
 538
 539 # No need to declare, it's part of the class interface.
 540 m4_define([AT_YYERROR_DECLARE(c++)],        [])
 541 m4_define([AT_YYERROR_DECLARE_EXTERN(c++)], [])
 542
 543 m4_define([AT_YYERROR_DEFINE(c++)],
 544 [[/* A C++ error reporting function.  */
 545 void
 546 ]AT_NAME_PREFIX[::parser::error (]AT_LOCATION_IF([[const location_type& l, ]])[const std::string& m)
 547 {
 548   std::cerr << ]AT_LOCATION_IF([l << ": " << ])[m << '\n';
 549 }]])
 550
 551
 552 m4_define([AT_MAIN_DEFINE(c++)],
 553 [[#include <cstdlib> // getenv.
 554 #include <cstring> // strcmp.
 555 int
 556 main (int argc, char const* argv[])
 557 {
 558   ]AT_NAME_PREFIX[::parser p;]AT_DEBUG_IF([[
 559   if (getenv("YYDEBUG")
 560       || (argc == 2
 561           && (!strcmp (argv[1], "-d") || !strcmp (argv[1], "--debug"))))
 562     p.set_debug_level (true);]], [[
 563   (void) argc;
 564   (void) argv;]])[
 565   return p.parse ();
 566 }]])
 567
 568 m4_define([AT_FOR_EACH_CXX],
 569 [[at_for_each_cxx_CXXFLAGS_save=$CXXFLAGS
 570 for at_cxx_std in '' \
 571                   ${CXX98_CXXFLAGS:+"$CXX98_CXXFLAGS"} \
 572                   ${CXX03_CXXFLAGS:+"$CXX03_CXXFLAGS"} \
 573                   ${CXX11_CXXFLAGS:+"$CXX11_CXXFLAGS"} \
 574                   ${CXX14_CXXFLAGS:+"$CXX14_CXXFLAGS"} \
 575                   ${CXX17_CXXFLAGS:+"$CXX17_CXXFLAGS"} \
 576                   ${CXX2A_CXXFLAGS:+"$CXX2A_CXXFLAGS"}
 577 do
 578   ]AS_ECHO(["======== Testing with C++ standard flags: '$at_cxx_std'"])[
 579   CXXFLAGS="$at_for_each_cxx_CXXFLAGS_save $at_cxx_std"
 580   ]$1[
 581 done
 582 CXXFLAGS=$at_for_each_cxx_CXXFLAGS_save
 583 ]])
 584
 585 ## ------ ##
 586 ## Java.  ##
 587 ## ------ ##
 588
 589 m4_define([AT_YYERROR_DEFINE(java)],
 590 [AT_LOCATION_IF([[public void yyerror (Calc.Location l, String s)
 591 {
 592     if (l == null)
 593       System.err.println (s);
 594     else
 595       System.err.println (l + ": " + s);
 596   }
 597 ]], [[
 598   public void yyerror (String s)
 599   {
 600     System.err.println (s);
 601   }
 602 ]])])
 603
 604 m4_define([AT_MAIN_DEFINE(java)],
 605 [[class input
 606 {
 607   public static void main (String args[]) throws IOException
 608   {
 609     YYParser p = new YYParser ();
 610     p.parse ();
 611   }
 612 }]])
 613
 614
 615
 616 ## --------------- ##
 617 ## Running Bison.  ##
 618 ## --------------- ##
 619
 620 # AT_BISON_CHECK(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 621 # -------------------------------------------------
 622 # High-level routine that may call bison several times, under different
 623 # conditions.
 624 #
 625 # Check Bison by invoking 'bison BISON_ARGS'.  BISON_ARGS should not contain
 626 # shell constructs (such as redirection or pipes) that would prevent
 627 # appending additional command-line arguments for bison. OTHER_AT_CHECK_ARGS
 628 # are the usual remaining arguments to AT_CHECK: STATUS, STDOUT, etc.
 629 #
 630 # This macro or AT_BISON_CHECK_NO_XML should always be used whenever invoking
 631 # Bison in the test suite.  For now it ensures that:
 632 #
 633 #   1. Valgrind doesn't report reachable memory when Bison is expected to have
 634 #      a non-zero exit status since Bison doesn't always try to free all memory
 635 #      in that case.
 636 #
 637 #   2. In the case of maintainer-xml-check, XML/XSLT output is compared with
 638 #      --graph and --report=all output for every working grammar.
 639 #
 640 #   3. If stderr contains a warning, -Werror and --warnings=error
 641 #      convert the warning to an error.
 642 #
 643 #   4. If stderr contains a warning, -Wnone and --warnings=none suppress it.
 644 m4_define([AT_BISON_CHECK],
 645 [m4_null_if([$2], [AT_BISON_CHECK_XML($@)])
 646 AT_BISON_CHECK_NO_XML($@)])
 647
 648 # AT_BISON_CHECK_(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 649 # --------------------------------------------------
 650 # Low-level macro to run bison once.
 651 m4_define([AT_BISON_CHECK_],
 652 [AT_CHECK(AT_QUELL_VALGRIND[[ bison -fno-caret ]]$@)])
 653
 654
 655 # AT_BISON_CHECK_WARNINGS(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 656 # ----------------------------------------------------------
 657 # Check that warnings (if some are expected) are correctly
 658 # turned into errors with -Werror, etc.
 659 #
 660 # When -Wno-error is used, the rules are really different, don't try.
 661 m4_define([AT_BISON_CHECK_WARNINGS],
 662 [m4_if(m4_bregexp([$4], [: warning: ]), [-1], [],
 663        m4_bregexp([$1], [-Wno-error=]), [-1],
 664                   [m4_null_if([$2], [AT_BISON_CHECK_WARNINGS_($@)])])])
 665
 666 m4_define([AT_BISON_CHECK_WARNINGS_],
 667 [[# Defining POSIXLY_CORRECT causes bison to complain if options are
 668 # added after the grammar file name, so skip these checks in that
 669 # case.
 670 if test "$POSIXLY_CORRECT_IS_EXPORTED" = false; then
 671           ]AT_SAVE_SPECIAL_FILES[
 672
 673   # To avoid expanding it repeatedly, store specified stdout.
 674   ]AT_DATA([expout], [$3])[
 675
 676   # Run with -Werror.
 677   ]AT_BISON_CHECK_([$1[ -Werror]], [[1]], [expout], [stderr])[
 678
 679   # Build expected stderr up to and including the "warnings being
 680   # treated as errors" message.
 681   ]AT_DATA([[experr]], [$4])[
 682   $PERL -pi -e 's{(.*): warning: (.*)\[-W(.*)\]$}
 683                  {$][1: error: $][2\@<:@-Werror=$][3@:>@}' experr
 684   ]AT_CHECK([[sed 's,.*/$,,' stderr 1>&2]], [[0]], [[]], [experr])[
 685
 686   # Now check --warnings=error.
 687   cp stderr experr
 688   ]AT_BISON_CHECK_([$1[ --warnings=error]], [[1]], [expout], [experr])[
 689
 690   # Now check -Wnone and --warnings=none by making sure that
 691   # -Werror doesn't change the exit status when -Wnone or
 692   # --warnings=none is specified.
 693   ]AT_BISON_CHECK_([$1[ -Wnone -Werror]], [[0]], [expout])[
 694   ]AT_BISON_CHECK_([$1[ --warnings=none -Werror]], [[0]], [expout])[
 695
 696   ]AT_RESTORE_SPECIAL_FILES[
 697 fi]dnl
 698 ])
 699
 700 # AT_BISON_CHECK_NO_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 701 # --------------------------------------------------------
 702 # Same as AT_BISON_CHECK except don't perform XML/XSLT checks.  This is useful
 703 # when a tortured grammar's XML is known to be too large for xsltproc to
 704 # handle.
 705 m4_define([AT_BISON_CHECK_NO_XML],
 706 [AT_CHECK(m4_null_if([$2], [], [AT_QUELL_VALGRIND ])[[bison -fno-caret ]]$@)
 707 AT_BISON_CHECK_WARNINGS($@)])
 708
 709 # AT_BISON_CHECK_XML(BISON_ARGS, [OTHER_AT_CHECK_ARGS])
 710 # -----------------------------------------------------
 711 # Run AT_BISON_CHECK's XML/XSLT checks if $BISON_TEST_XML=1 and $XSLTPROC is
 712 # defined.  It doesn't make sense to invoke this macro if Bison is expected to
 713 # have a non-zero exit status.
 714 m4_define([AT_BISON_CHECK_XML],
 715 [[if test x"$BISON_TEST_XML" = x1 && test x"$XSLTPROC" != x""; then]
 716   AT_SAVE_SPECIAL_FILES
 717   [mkdir xml-tests]
 718   m4_pushdef([AT_BISON_ARGS],
 719              [m4_bpatsubsts([[$1]],
 720                             [--report(-file)?=[^][ ]*], [],
 721                             [--graph=[^][ ]*], [],
 722                             [--xml=[^][ ]*], [])])dnl
 723   # Don't combine these Bison invocations since we want to be sure that
 724   # --report=all isn't required to get the full XML file.
 725   AT_BISON_CHECK_([[--report=all --report-file=xml-tests/test.output \
 726              --graph=xml-tests/test.dot ]]AT_BISON_ARGS,
 727            [[0]], [ignore], [ignore])
 728   AT_BISON_CHECK_([[--xml=xml-tests/test.xml ]]AT_BISON_ARGS,
 729            [[0]], [ignore], [ignore])
 730   m4_popdef([AT_BISON_ARGS])dnl
 731   [cp xml-tests/test.output expout]
 732   AT_CHECK([[$XSLTPROC \
 733              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2text.xsl \
 734              xml-tests/test.xml]], [[0]], [expout])
 735   [sort xml-tests/test.dot > expout]
 736   AT_CHECK([[$XSLTPROC \
 737              `]]AT_QUELL_VALGRIND[[ bison --print-datadir`/xslt/xml2dot.xsl \
 738              xml-tests/test.xml | sort]], [[0]], [expout])
 739   [rm -rf xml-tests expout]
 740   AT_RESTORE_SPECIAL_FILES
 741 [fi]])
 742
 743 # AT_QUELL_VALGRIND
 744 # -----------------
 745 # Put this before a Bison invocation to keep Valgrind from complaining about
 746 # reachable memory.
 747 #
 748 # Do not quote invocations of this macro within the first argument of AT_CHECK.
 749 # The triple quoting below will cause test cases to fail if you do.  If you do
 750 # so anyway but also decrease the quoting below to avoid that problem, AT_CHECK
 751 # will then fail to shell-escape its contents when attempting to print them.
 752 # The testsuite verbose output, at least, will be incorrect, but nothing may
 753 # fail to make sure you notice.
 754 m4_define([AT_QUELL_VALGRIND],
 755 [[[VALGRIND_OPTS="$VALGRIND_OPTS --leak-check=summary --show-reachable=no"; export VALGRIND_OPTS;]]])
 756
 757
 758
 759 ## ------------------------ ##
 760 ## Compiling C, C++ Files.  ##
 761 ## ------------------------ ##
 762
 763
 764 # AT_COMPILE(OUTPUT, [SOURCES = OUTPUT.c], [EXTRA-COMPILER-FLAGS])
 765 # ----------------------------------------------------------------
 766 # Compile SOURCES into OUTPUT.
 767 #
 768 # If OUTPUT does not contain '.', assume that we are linking too,
 769 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 770 # with trailing .o removed, and ".c" appended.
 771 m4_define([AT_COMPILE],
 772 [AT_CHECK([$BISON_C_WORKS], 0, ignore, ignore)
 773 AT_CHECK(m4_join([ ],
 774                  [$CC $CFLAGS $CPPFLAGS $3],
 775                  [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 776                  [-o $1],
 777                  [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).c])],
 778                  [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 779          0, [ignore], [ignore])])
 780
 781
 782 # AT_COMPILE_CXX(OUTPUT, [SOURCES = OUTPUT.cc], [EXTRA-COMPILER-FLAGS])
 783 # ---------------------------------------------------------------------
 784 # Compile SOURCES into OUTPUT.  If the C++ compiler does not work,
 785 # ignore the test.
 786 #
 787 # If OUTPUT does not contain '.', assume that we are linking too,
 788 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 789 # with trailing ".o" removed, and ".cc" appended.
 790 m4_define([AT_COMPILE_CXX],
 791 [AT_KEYWORDS(c++)
 792 AT_CHECK([$BISON_CXX_WORKS], 0, ignore, ignore)
 793 AT_CHECK(m4_join([ ],
 794                  [$CXX $CXXFLAGS $CPPFLAGS $3],
 795                  [m4_bmatch([$1], [[.]], [-c], [$LDFLAGS])],
 796                  [-o $1],
 797                  [m4_default([$2], [m4_bpatsubst([$1], [\.o$]).cc])],
 798                  [m4_bmatch([$1], [[.]], [], [$LIBS])]),
 799          0, [ignore], [ignore])])
 800
 801
 802 # AT_JAVA_COMPILE(SOURCES)
 803 # ------------------------
 804 # Compile SOURCES into Java class files.  Skip the test if java or javac
 805 # is not installed.
 806 m4_define([AT_JAVA_COMPILE],
 807 [AT_KEYWORDS(java)
 808 AT_SKIP_IF([[test -z "$CONF_JAVAC"]])
 809 AT_SKIP_IF([[test -z "$CONF_JAVA"]])
 810 AT_CHECK([[$SHELL ../../../javacomp.sh ]$1],
 811          [[0]], [ignore], [ignore])])
 812
 813
 814 # AT_LANG_COMPILE(OUTPUT, [SOURCES = OUTPUT.c], [EXTRA-COMPILER-FLAGS])
 815 # ---------------------------------------------------------------------
 816 # Compile SOURCES into OUTPUT.  Skip if compiler does not work.
 817 #
 818 # If OUTPUT does not contain '.', assume that we are linking too,
 819 # otherwise pass "-c"; this is a hack.  The default SOURCES is OUTPUT
 820 # with trailing .o removed, and ".c"/".cc" appended.
 821 m4_define([AT_LANG_COMPILE],  [AT_LANG_DISPATCH([$0], $@)])
 822 m4_define([AT_LANG_COMPILE(c)],    [AT_COMPILE([$1], [$2], [$3])])
 823 m4_define([AT_LANG_COMPILE(c++)],  [AT_COMPILE_CXX([$1], [$2], [$3])])
 824 m4_define([AT_LANG_COMPILE(java)], [AT_JAVA_COMPILE([$1.java], [$2], [$3])])
 825
 826
 827 # AT_LANG_EXT
 828 # -----------
 829 # The file extension corresponding to the language: c, cc, or java.
 830 m4_define([AT_LANG_EXT],  [AT_LANG_DISPATCH([$0], $@)])
 831 m4_define([AT_LANG_EXT(c)],    [c])
 832 m4_define([AT_LANG_EXT(c++)],  [cc])
 833 m4_define([AT_LANG_EXT(java)], [java])
 834
 835
 836 # AT_FULL_COMPILE(OUTPUT, [OTHER1], [OTHER2], [EXTRA-COMPILER-FLAGS)
 837 # ------------------------------------------------------------------
 838 # Compile OUTPUT.y to OUTPUT.c, OUTPUT.cc, or OUTPUT.java, and then
 839 # compile it to OUTPUT or OUTPUT.class.  If OTHER is specified, compile
 840 # OUTPUT-OTHER.c, OUTPUT-OTHER.cc, or OUTPUT-OTHER.java to OUTPUT or
 841 # OUTPUT.java along with it.  Relies on AT_SKEL_CC_IF and
 842 # AT_SKEL_JAVA_IF.
 843 m4_define([AT_FULL_COMPILE],
 844 [AT_BISON_CHECK([-o $1.AT_LANG_EXT $1.y])
 845  AT_LANG_COMPILE([$1],
 846                  m4_join([ ],
 847                          [$1.AT_LANG_EXT],
 848                          m4_ifval($2, [[$1-$2.]AT_LANG_EXT]),
 849                          m4_ifval($3, [[$1-$3.]AT_LANG_EXT])),
 850                  [$4])])
 851
 852
 853
 854 # AT_SKIP_IF_CANNOT_LINK_C_AND_CXX
 855 # --------------------------------
 856 # Check that we can link together C and C++ objects.
 857 m4_define([AT_SKIP_IF_CANNOT_LINK_C_AND_CXX],
 858 [AT_DATA([c-and-cxx.h],
 859 [[#ifdef __cplusplus
 860 extern "C"
 861 {
 862 #endif
 863   int fortytwo (void);
 864 #ifdef __cplusplus
 865 }
 866 #endif
 867 ]])
 868 AT_DATA([c-only.c],
 869 [[#include "c-and-cxx.h"
 870 int
 871 main (void)
 872 {
 873   return fortytwo () == 42 ? 0 : 1;
 874 }
 875 ]])
 876 AT_DATA([cxx-only.cc],
 877 [[#include "c-and-cxx.h"
 878 int fortytwo ()
 879 {
 880   return 42;
 881 }
 882 ]])
 883 AT_COMPILE([c-only.o], [c-only.c])
 884 AT_COMPILE_CXX([cxx-only.o], [cxx-only.cc])
 885 AT_CHECK([$CXX $CXXFLAGS $CPPFLAGS $LDFLAGS c-only.o cxx-only.o -o c-and-cxx ||
 886           exit 77], [0], [ignore], [ignore])
 887 AT_PARSER_CHECK([./c-and-cxx])
 888 ])
 889
 890
 891 # AT_SKIP_IF_EXCEPTION_SUPPORT_IS_POOR
 892 # ------------------------------------
 893 # Check that we can expect exceptions to be handled properly.
 894 # GCC 4.3 and 4.4 fail https://trac.macports.org/ticket/40853.
 895 m4_define([AT_SKIP_IF_EXCEPTION_SUPPORT_IS_POOR],
 896 [AT_DATA_SOURCE([exception.cc],
 897 [[#include <iostream>
 898 #include <stdexcept>
 899
 900 void foo()
 901 {
 902   try
 903     {
 904       throw std::runtime_error("foo");
 905     }
 906   catch (...)
 907     {
 908       std::cerr << "Inner caught\n";
 909       throw;
 910     }
 911 }
 912
 913 int main()
 914 {
 915   try
 916     {
 917       foo();
 918     }
 919   catch (...)
 920     {
 921       std::cerr << "Outer caught\n";
 922       return 0;
 923     }
 924   return 1;
 925 }
 926 ]])
 927 AT_COMPILE_CXX([exception])
 928 # The "empty" quadrigraph is to protect from cfg.mk's
 929 # sc_at_parser_check.
 930 AT_CHECK([@&t@./exception || exit 77], [0], [], [ignore])
 931 ])
 932
 933
 934 ## ---------------------------- ##
 935 ## Running a generated parser.  ##
 936 ## ---------------------------- ##
 937
 938
 939 # AT_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 940 # ------------------------------------------------------------
 941 # So that we can run './testsuite PREPARSER='valgrind -q' for instance.
 942 #
 943 # Get rid of spurious messages when compiled with --coverage:
 944 # +profiling:/[...]/lib/fprintf.gcda:Merge mismatch for summaries
 945 m4_define([AT_PARSER_CHECK],
 946 [AT_CHECK([$5 $PREPARSER $1], [$2], [$3], [stderr])
 947 AT_CHECK([sed >&2 -e '/^profiling:.*:Merge mismatch for summaries/d' stderr],
 948          [0], [], [$4])
 949 ])
 950
 951
 952 # AT_JAVA_PARSER_CHECK(COMMAND, EXIT-STATUS, EXPOUT, EXPERR, [PRE])
 953 # -----------------------------------------------------------------
 954 m4_define([AT_JAVA_PARSER_CHECK],
 955 [AT_CHECK([$5[ $SHELL ../../../javaexec.sh ]$1], [$2], [$3], [$4])])
 956
 957
 958 # AT_TEST_TABLES_AND_PARSE(TITLE, COND-VALUE, TEST-SPEC,
 959 #                          DECLS, GRAMMAR, INPUT,
 960 #                          BISON-STDERR, TABLES-OR-LAST-STATE,
 961 #                          [OTHER-CHECKS],
 962 #                          [PARSER-EXIT-VALUE],
 963 #                          [PARSER-STDOUT], [PARSER-STDERR])
 964 # -------------------------------------------------------------
 965 # Using TITLE as the test group title, check the generated parser tables
 966 # and parser for a specified grammar file under a condition labeled by
 967 # COND-VALUE.
 968 #
 969 # TEST-SPEC is a comma-delimited list of attributes of this test.  Each
 970 # recognized attribute is described below where it is relevant.
 971 #
 972 # Insert DECLS and GRAMMAR into the declarations and grammar section of
 973 # the grammar file.  Insert basic yyerror, yylex, and main function
 974 # definitions as well.  Hardcode yylex to return the (possibly empty)
 975 # comma-delimited series of tokens in INPUT followed by token 0.
 976 #
 977 # If TEST-SPEC contains the attribute no-xml, then invoke bison using
 978 # AT_BISON_CHECK_NO_XML.  Otherwise, invoke bison using AT_BISON_CHECK.
 979 # On the bison command-line, specify `--report=all --defines'.  Check
 980 # that Bison exits with value 0, has no stdout, and has stderr
 981 # BISON-STDERR.
 982 #
 983 # If TEST-SPEC contains the attribute 'last-state', check that the value
 984 # of TABLES-OR-LAST-STATE is the index of the last state generated for
 985 # the grammar; in other words, check the number of states (minus one).
 986 # Otherwise, check that everything in the '.output' file starting with
 987 # the definition of state 0 is the same as the entire value of
 988 # TABLES-OR-LAST-STATE.
 989 #
 990 # Expand the M4 in OTHER-CHECKS to perform additional checks of the
 991 # '.output' file, which is named 'input.output', and/or grammar file,
 992 # which is named 'input.y'.
 993 #
 994 # Finally, compile the generated parser and then run it using
 995 # AT_PARSER_CHECK with PARSER-EXIT-VALUE, PARSER-STDOUT, and
 996 # PARSER-STDERR as the 2nd-4th arguments.
 997 #
 998 # As a precondition, you must properly double-quote all arguments that
 999 # are to be interpreted as strings.
1000 #
1001 # AT_COND_CASE (when appearing in single-quoted segments of arguments)
1002 # invokes m4_case with its own arguments but COND-VALUE inserted as the
1003 # first argument.  This is useful, for example, when wrapping multiple
1004 # AT_TEST_TABLES_AND_PARSE invocations, each representing a different
1005 # condition, in another macro.
1006 #
1007 # For example:
1008 #
1009 #   # AT_TEST_SYNTAX_ERROR(DESCRIPTION, DECLS, GRAMMAR, INPUT, LAST-STATE,
1010 #   #                      PARSER-EXIT-VALUE, PARSER-STDOUT, PARSER-STDERR)
1011 #   # ---------------------------------------------------------------------
1012 #   m4_define([AT_TEST_SYNTAX_ERROR],
1013 #   [
1014 #     AT_TEST_TABLES_AND_PARSE([$1[ with %error-verbose]], [[verbose]],
1015 #                              [[last-state]],
1016 #                              [[%error-verbose ]$2], [$3], [$4],
1017 #                              [[]], [$5], [], [$6], [$7], [$8])
1018 #     AT_TEST_TABLES_AND_PARSE([$1[ with no %error-verbose]], [[no verbose]],
1019 #                              [[last-state]],
1020 #                              [$2], [$3], [$4],
1021 #                              [[]], [$5], [], [$6], [$7], [$8])
1022 #   ])
1023 #
1024 #   AT_TEST_SYNTAX_ERROR([[Single Char Grammar]],
1025 #                        [[%token 'b']], [[start: 'a' ;]], [['a', 'b']],
1026 #                        [[3]],
1027 #                        [[1]], [[]],
1028 #                        [AT_COND_CASE([[no verbose]],
1029 #                                      [[syntax error
1030 #   ]],
1031 #                                      [[syntax error, unexpected 'b', expecting $end
1032 #   ]])])
1033 m4_define([AT_TEST_TABLES_AND_PARSE],
1034 [m4_pushdef([AT_COND_CASE], [m4_case([$2], $][@)])
1035
1036 AT_SETUP([$1])
1037 AT_BISON_OPTION_PUSHDEFS([$4])
1038 AT_DATA_GRAMMAR([[input.y]],
1039 [[%code {
1040   ]AT_YYERROR_DECLARE[
1041   ]AT_YYLEX_DECLARE[
1042 }
1043
1044 ]$4[
1045
1046 %%
1047
1048 ]$5[
1049
1050 %%
1051 ]AT_YYERROR_DEFINE[
1052 static int
1053 yylex (void)
1054 {
1055   static int const input[] = {
1056     ]m4_if([$6], [], [], [$6], [[]], [], [$6[, ]])[0
1057   };
1058   static int const *inputp = input;
1059   return *inputp++;
1060 }
1061
1062 ]AT_MAIN_DEFINE[
1063 ]])
1064
1065 # In some versions of Autoconf, AT_CHECK invokes AS_ESCAPE before
1066 # expanding macros, so it corrupts some special characters in the
1067 # macros.  To avoid this, expand now and pass it the result with proper
1068 # string quotation.  Assume args 7 through 12 expand to properly quoted
1069 # strings.
1070
1071 m4_if(m4_index(m4_quote($3), [no-xml]), -1,
1072       [AT_BISON_CHECK],
1073       [AT_BISON_CHECK_NO_XML])([[-Wall --report=all --defines -o input.c input.y]],
1074                                [0], [], m4_dquote($7))
1075
1076 m4_if(m4_index(m4_quote($3), [last-state]), -1,
1077       [AT_CHECK([[sed -n '/^State 0$/,$p' input.output]], [[0]],
1078                 m4_dquote($8))],
1079       [AT_CHECK([[sed -n 's/^State //p' input.output | tail -1]], [[0]],
1080                 m4_dquote($8)[[
1081 ]])])
1082
1083 $9
1084
1085 # Canonical LR generates very large tables, resulting in very long
1086 # files with #line directives that may overflow what the standards
1087 # (C90 and C++98) guarantee: 32767.  In that case, GCC's -pedantic
1088 # will issue an error.
1089 #
1090 # There is no "" around `wc` since some indent the result.
1091 m4_bmatch([$4], [%define lr.type canonical-lr],
1092 [if test 32767 -lt `wc -l < input.c`; then
1093   CFLAGS=`echo " $CFLAGS " | sed -e 's/ -pedantic / /'`
1094   CXXFLAGS=`echo " $CXXFLAGS " | sed -e 's/ -pedantic / /'`
1095 fi])
1096 AT_COMPILE([[input]])
1097
1098 AT_PARSER_CHECK([[./input]],
1099                 m4_ifval([$10], [m4_dquote($10)]),
1100                 m4_ifval([$11], [m4_dquote($11)]),
1101                 m4_ifval([$12], [m4_dquote($12)]))
1102
1103 AT_BISON_OPTION_POPDEFS
1104 AT_CLEANUP
1105
1106 m4_popdef([AT_COND_CASE])])
1107
1108
1109
1110
1111 ## ----------------------- ##
1112 ## Launch the test suite.  ##
1113 ## ----------------------- ##
1114
1115 AT_INIT
1116
1117 # AT_SETUP([TITLE])
1118 # -----------------
1119 # Redefine AT_SETUP to be more concise.  Must be done after AT_INIT.
1120 m4_copy_force([AT_SETUP], [B4_SETUP])
1121 m4_define([AT_SETUP],
1122 [B4_SETUP(m4_expand([AT_SETUP_STRIP([[$1]])]))])
1123
1124 # Cannot assign CC and CFLAGS here, since atlocal is loaded after
1125 # options are processed, so we don't know the value of CXX and
1126 # CXXFLAGS yet.
1127 #
1128 # Note that it also means that command line values for CXX and
1129 # CXXFLAGS will not be propagated to CC and CFLAGS.
1130 AT_ARG_OPTION([compile-c-with-cxx],
1131               [compile C parsers with the C++ compiler])
1132
1133 AT_COLOR_TESTS
1134
1135 AT_TESTED([bison])