configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001-2015, 2018-2022 Free Software Foundation, Inc.
   4 #
   5 # This program is free software: you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation, either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program.  If not, see <https://www.gnu.org/licenses/>.
  17
  18 AC_PREREQ([2.71])
  19 m4_pattern_forbid([^_?(gl_[A-Z]|AX_|BISON_)])
  20 m4_pattern_allow([^BISON_USE_NLS$])
  21
  22 AC_INIT([GNU Bison],
  23         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  24         [bug-bison@gnu.org],
  25         [],
  26         [https://www.gnu.org/software/bison/])
  27 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2022])
  28 AC_DEFINE_UNQUOTED([PACKAGE_COPYRIGHT_YEAR], [$PACKAGE_COPYRIGHT_YEAR],
  29                    [The copyright year for this package])
  30
  31 AC_CONFIG_AUX_DIR([build-aux])
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 # When we move to Automake 1.16, simplify examples/c/reccalc/local.mk.
  35 # Our CI build the packages on Bionic, which has only Automake 1.15.
  36 #
  37 # We want gnits strictness only when rolling a stable release.  For
  38 # release candidates, we use version strings like 2.4.3_rc1, but gnits
  39 # doesn't like that, so we let the underscore disable gnits.  Between
  40 # releases, we want to be able run make dist without being required to
  41 # add a bogus NEWS entry.  In that case, the version string
  42 # automatically contains a dash, which we also let disable gnits.
  43 AM_INIT_AUTOMAKE([1.15 dist-lzip dist-xz nostdinc
  44                  color-tests parallel-tests
  45                  silent-rules]
  46                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [[-_]],
  47                            [gnu], [gnits]))
  48 AM_SILENT_RULES([yes])
  49 AC_CONFIG_HEADERS([lib/config.h:lib/config.in.h])
  50
  51 # Checks for the compiler.
  52 AC_PROG_CC
  53 AC_PROG_CXX
  54
  55 # Gnulib (early checks).
  56 gl_EARLY
  57
  58 # Gnulib uses '#pragma GCC diagnostic push' to silence some
  59 # warnings, but older gcc doesn't support this.
  60 AC_CACHE_CHECK([whether pragma GCC diagnostic push works],
  61   [lv_cv_gcc_pragma_push_works], [
  62   save_CFLAGS=$CFLAGS
  63   CFLAGS='-Wunknown-pragmas -Werror'
  64   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
  65     #pragma GCC diagnostic push
  66     #pragma GCC diagnostic pop
  67   ]])],
  68   [lv_cv_gcc_pragma_push_works=yes],
  69   [lv_cv_gcc_pragma_push_works=no])
  70   CFLAGS=$save_CFLAGS])
  71
  72 AC_LANG_PUSH([C++])
  73 gl_WARN_ADD([-fno-exceptions], [NO_EXCEPTIONS_CXXFLAGS])
  74 BISON_CXXSTD([98])
  75 BISON_CXXSTD([03])
  76 BISON_CXXSTD([11])
  77 BISON_CXXSTD([14])
  78 BISON_CXXSTD([17])
  79 BISON_CXXSTD([20])
  80 BISON_CXXSTD([2b])
  81 AM_CONDITIONAL([ENABLE_CXX11], [test x"$CXX11_CXXFLAGS" != x])
  82 AM_CONDITIONAL([ENABLE_CXX14], [test x"$CXX14_CXXFLAGS" != x])
  83 AC_LANG_POP([C++])
  84
  85 AC_ARG_ENABLE([gcc-warnings],
  86 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended).
  87                            Also, issue synclines from the examples/ to
  88                            the corresponding source in the Texinfo doc.],
  89 [case $enable_gcc_warnings in
  90    yes|no) ;;
  91    *)  AC_MSG_ERROR([invalid value for --gcc-warnings: $enable_gcc_warnings]);;
  92  esac],
  93               [enable_gcc_warnings=no])
  94 AM_CONDITIONAL([ENABLE_GCC_WARNINGS], [test "$enable_gcc_warnings" = yes])
  95 if test "$enable_gcc_warnings" = yes; then
  96   # -Wno-tautological-constant-out-of-range-compare for Clang 3.3 and
  97   # 3.4 on GNU/Linux that choke on intprops.h's INT_MULTIPLY_WRAPV,
  98   # etc.
  99   #
 100   # ICC: -wr188
 101   #
 102   # 1669  warnings warnings_default =
 103   # ../src/complain.c(318): error #188: enumerated type mixed with another type
 104   # 1670      Wconflicts_sr | Wconflicts_rr | Wdeprecated | Wother;
 105   # 1671      ^
 106   # 1672
 107   # 1673../src/complain.c(393): error #188: enumerated type mixed with another type
 108   # 1674          warnings w = 1 << wbit;
 109   # 1675                       ^
 110   #
 111   # ICC: -wr3179
 112   #
 113   # char const *usefulness
 114   #   = rule_useless_in_grammar_p (&rules[r]) ? "useless-in-grammar"
 115   #   : rule_useless_in_parser_p (&rules[r])  ? "useless-in-parser"
 116   #   :                                         "useful";
 117   #
 118   # gives
 119   #
 120   # error #3179: deprecated conversion of string literal to char* (should be const char*)
 121   #
 122   # ICC: -wr2259 (that's in C, in spite of what the error messages which seems to be about C++).
 123   # error #2259: non-pointer conversion from "int" to "yybool={signed char}" may lose significant bits
 124   #   yybool yynormal YY_ATTRIBUTE_UNUSED = yystackp->yysplitPoint == YY_NULLPTR;
 125   #                                         ^
 126   warn_common='-Wall -Wextra
 127     -Wcast-align -Wchar-subscripts
 128     -fparse-all-comments -Wdocumentation
 129     -Wformat -Wimplicit-fallthrough -Wmismatched-dealloc -Wnull-dereference
 130     -Wno-sign-compare -Wno-tautological-constant-out-of-range-compare
 131     -Wpointer-arith -Wshadow -Wstrict-aliasing
 132     -Wwrite-strings
 133     -wr188 -wr2259 -wr3179'
 134   warn_c='-Wbad-function-cast
 135     -Wmissing-prototypes
 136     -Wstrict-prototypes'
 137   warn_cxx='-Wextra-semi -Wnoexcept -Wsubobject-linkage
 138     -Wold-style-cast -Wundefined-func-template
 139     -Wweak-vtables'
 140   # Warnings for the test suite only.
 141   #
 142   # -fno-color-diagnostics: Clang's use of colors in the error
 143   # messages is confusing the tests looking at the compiler's output
 144   # (e.g., synclines.at).
 145   #
 146   # -Wno-keyword-macro: We use the "#define private public" dirty
 147   # trick in the test suite to check some private implementation
 148   # details for lalr1.cc.
 149   warn_tests='-Wundef -pedantic -Wconversion
 150     -Wdeprecated -Wsign-compare -Wsign-conversion
 151     -Wtautological-constant-out-of-range-compare
 152     -fno-color-diagnostics
 153     -Wno-keyword-macro'
 154
 155
 156   AC_LANG_PUSH([C])
 157   # Clang supports many of GCC's -W options, but only issues warnings
 158   # on the ones it does not recognize.  In that case, gl_WARN_ADD
 159   # thinks the option is supported, and unknown options are then added
 160   # to CFLAGS.  But then, when -Werror is added in the test suite for
 161   # instance, the warning about the unknown option turns into an
 162   # error.
 163   #
 164   # This should be addressed by gnulib's gl_WARN_ADD, but in the
 165   # meanwhile, turn warnings about unknown options into errors in
 166   # CFLAGS, and restore CFLAGS after the tests.
 167   save_CFLAGS=$CFLAGS
 168   gl_WARN_ADD([-Werror=unknown-warning-option], [CFLAGS])
 169   # Accept this warning only if it is not too touchy (e.g., clang 3.3
 170   # and 3.4).
 171   gl_WARN_ADD([-Wunreachable-code], [WARN_CFLAGS],
 172               [AC_LANG_PROGRAM([],
 173               [[if (sizeof (long) < sizeof (int)) return 1;]])])
 174   for i in $warn_common $warn_c;
 175   do
 176     gl_WARN_ADD([$i], [WARN_CFLAGS])
 177   done
 178   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 179
 180   # Warnings for the test suite, and maybe for bison if GCC is modern
 181   # enough.
 182   test $lv_cv_gcc_pragma_push_works = yes &&
 183     AS_VAR_APPEND([WARN_CFLAGS], [" $WARN_CFLAGS_TEST"])
 184
 185   # Warnings for the test suite only.
 186   for i in $warn_tests -Wincompatible-pointer-types;
 187   do
 188     gl_WARN_ADD([$i], [WARN_CFLAGS_TEST])
 189   done
 190   CFLAGS=$save_CFLAGS
 191   AC_LANG_POP([C])
 192
 193
 194   AC_LANG_PUSH([C++])
 195   save_CXXFLAGS=$CXXFLAGS
 196   gl_WARN_ADD([-Werror=unknown-warning-option], [CXXFLAGS])
 197   for i in $warn_common $warn_cxx;
 198   do
 199     gl_WARN_ADD([$i], [WARN_CXXFLAGS])
 200   done
 201   # Accept this warning only if it is not too touchy (e.g., clang 3.3
 202   # and 3.4).
 203   gl_WARN_ADD([-Wunreachable-code], [WARN_CXXFLAGS],
 204               [AC_LANG_PROGRAM([],
 205               [[if (sizeof (long) < sizeof (int)) return 1;]])])
 206   gl_WARN_ADD([-Wzero-as-null-pointer-constant], [WARN_CXXFLAGS],
 207               [AC_LANG_PROGRAM([], [nullptr])])
 208   # Before GCC6, the pragmas don't work well enough to neutralize
 209   # this warning.
 210   gl_WARN_ADD([-Wuseless-cast], [WARN_CXXFLAGS],
 211               [AC_LANG_PROGRAM([], [
 212               #if defined __GNUC__ && ! defined __ICC && ! defined __clang__ && __GNUC__ < 6
 213               syntax error
 214               #endif
 215               ])])
 216   gl_WARN_ADD([-Werror], [WERROR_CXXFLAGS])
 217   # Warnings for the test suite only.
 218   for i in $warn_tests;
 219   do
 220     gl_WARN_ADD([$i], [WARN_CXXFLAGS_TEST])
 221   done
 222   # Too many compilers complain about Flex generated code.
 223   gl_WARN_ADD([-Wno-error], [FLEX_SCANNER_CXXFLAGS])
 224   # Clang++ deprecates compiling C.
 225   gl_WARN_ADD([-Wno-deprecated], [WNO_DEPRECATED_CXXFLAGS])
 226   CXXFLAGS=$save_CXXFLAGS
 227   AC_LANG_POP([C++])
 228 fi
 229
 230
 231 BISON_TEST_FOR_WORKING_C_COMPILER
 232 BISON_C_COMPILER_POSIXLY_CORRECT
 233 BISON_TEST_FOR_WORKING_CXX_COMPILER
 234 BISON_CXX_COMPILER_POSIXLY_CORRECT
 235
 236 # D.
 237 AC_CHECK_PROGS([DC], [dmd])
 238 AC_CHECK_PROGS([DCFLAGS], [-g])
 239 AM_CONDITIONAL([ENABLE_D], [test x"$DC" != x])
 240
 241 # Java.
 242 gt_JAVACOMP([1.7], [1.7])
 243 gt_JAVAEXEC
 244 AM_CONDITIONAL([ENABLE_JAVA], [test x"$CONF_JAVAC" != x && test x"$CONF_JAVA" != x])
 245
 246
 247 AC_ARG_ENABLE([yacc],
 248   [AS_HELP_STRING([--disable-yacc],
 249      [do not build a yacc command or an -ly library])],
 250   , [enable_yacc=yes])
 251 AM_CONDITIONAL([ENABLE_YACC], [test "$enable_yacc" = yes])
 252 AC_CONFIG_FILES([src/yacc], [chmod +x src/yacc])
 253
 254 # Checks for programs.
 255 AM_MISSING_PROG([DOT], [dot])
 256 AC_PROG_LEX
 257 if ! "$LEX_IS_FLEX" || test "X$LEX" = X:; then
 258   AC_MSG_WARN([bypassing lex because flex is required])
 259   LEX=:
 260 fi
 261 AM_CONDITIONAL([FLEX_WORKS], [$LEX_IS_FLEX && $FLEX_SUPPORTS_HEADER_OPT])
 262 AM_CONDITIONAL([FLEX_CXX_WORKS],
 263   [$LEX_IS_FLEX && $FLEX_SUPPORTS_HEADER_OPT && test $bison_cv_cxx_works = yes])
 264 AC_PROG_YACC
 265 AC_PROG_RANLIB
 266 AC_PROG_GNU_M4
 267 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 268 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 269 supports -g, otherwise to "".])
 270 AC_PATH_PROG([PERL], [perl])
 271 AM_MISSING_PROG([HELP2MAN], [help2man])
 272 AC_PATH_PROG([XSLTPROC], [xsltproc])
 273 AC_SUBST([XSLTPROC])
 274
 275 # Checks for header files.
 276 AC_CHECK_HEADERS_ONCE([locale.h])
 277
 278 # Checks for compiler characteristics.
 279 AC_C_INLINE
 280
 281 # Gnulib (later checks).  Putting them here rather than right after
 282 # gl_EARLY avoids some redundant checks.
 283 gl_INIT
 284
 285 # We want ostream_printf and hyperlink support.
 286 gl_LIBTEXTSTYLE_OPTIONAL([0.20.5])
 287
 288 # Checks for library functions.
 289 AC_CHECK_FUNCS_ONCE([setlocale])
 290
 291 # Gettext.
 292 # We use gnulib, which is only guaranteed to work properly with the
 293 # latest Gettext.
 294 AM_GNU_GETTEXT([external], [need-ngettext])
 295 AM_GNU_GETTEXT_VERSION([0.19])
 296 BISON_I18N
 297 AC_CONFIG_FILES([gnulib-po/Makefile.in])
 298
 299 # Internationalized parsers.
 300 AC_CONFIG_FILES([runtime-po/Makefile.in])
 301 # Autoconf macros for packages using internationalized parsers.
 302 aclocaldir='${datadir}/aclocal'
 303 AC_SUBST([aclocaldir])
 304
 305 # Create the benchmark script.
 306 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 307
 308 # Initialize the test suite.
 309 AC_CONFIG_TESTDIR(tests)
 310 AC_CONFIG_FILES([tests/atlocal])
 311 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 312
 313 AC_CHECK_PROGS([VALGRIND], [valgrind])
 314 # Use something simpler that $host_os to select our suppression file.
 315 uname=`uname`
 316 case $VALGRIND:$uname in
 317   '':*) ;;
 318   *:Darwin)
 319     # See README-hacking.md.
 320     VALGRIND=;;
 321   *:*)
 322     suppfile=build-aux/$uname.valgrind
 323     if test -f "$srcdir/$suppfile"; then
 324       AC_SUBST([VALGRIND_OPTS_SUPPRESSION],
 325                ["--suppressions=\$(abs_top_srcdir)/$suppfile"])
 326     fi
 327     ;;
 328 esac
 329 AC_MSG_CHECKING([Valgrind suppression file])
 330 AC_MSG_RESULT([$suppfile])
 331
 332 # Whether we cannot run the compiled bison.
 333 AM_CONDITIONAL([CROSS_COMPILING], [test "$cross_compiling" = yes])
 334
 335 # Build bistromathic if we have the lib and both readline/readline.h
 336 # and readline/history.h.
 337 AM_CONDITIONAL([ENABLE_BISTROMATHIC],
 338 [test "$gl_cv_lib_readline" != no &&
 339   test "$ac_cv_header_readline_readline_h" = yes &&
 340   test "$ac_cv_header_readline_history_h" = yes])
 341
 342 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 343 # Needed by tests/atlocal.in.
 344 AC_SUBST([GCC])
 345
 346 AC_CONFIG_FILES([Makefile
 347                  po/Makefile.in
 348                  doc/yacc.1])
 349
 350 # Fix LIBOBJS to give the Makefile the right file names.  Otherwise
 351 # compilation works, but with unexpected file names, so clean rules don't
 352 # remove the actual files and distcheck fails.
 353 AC_CONFIG_COMMANDS_PRE([
 354   case $am__api_version in
 355     1.14*|1.15*) gl_LIBOBJS=`echo "$gl_LIBOBJS" | sed -e 's, lib/, lib/lib_libbison_a-,g'`;;
 356     *)           gl_LIBOBJS=`echo "$gl_LIBOBJS" | sed -e 's, lib/, lib/libbison_a-,g'`;;
 357   esac
 358 ])
 359
 360 AC_OUTPUT