configure.ac

   1 # Configure template for GNU Bison.                   -*-Autoconf-*-
   2 #
   3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009,
   4 # 2010 Free Software Foundation, Inc.
   5 #
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 # In order for some versions of Sun Studio to compile our C++ test cases
  20 # correctly, we need Autoconf 2.64 or better to handle the restrict
  21 # keyword in at least string.h from gnulib.
  22 AC_PREREQ(2.64)
  23
  24 AC_INIT([GNU Bison],
  25         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  26         [bug-bison@gnu.org])
  27 AC_DEFINE([PACKAGE_COPYRIGHT_YEAR], [2010],
  28           [The copyright year for this package])
  29 AC_SUBST([PACKAGE_COPYRIGHT_YEAR], [2010])
  30
  31 AC_CONFIG_AUX_DIR([build-aux])
  32 AC_CONFIG_MACRO_DIR([m4])
  33
  34 # Automake 1.10.3 and 1.11.1 fix a security flaw discussed here:
  35 #
  36 #   http://thread.gmane.org/gmane.comp.sysutils.autotools.announce/131
  37 #
  38 # To avoid 1.11, we make 1.11.1 the minimum version.
  39 #
  40 # We want gnits strictness only when rolling a stable release.  For
  41 # release candidates, we use version strings like 2.4.3_rc1, but gnits
  42 # doesn't like that, so we let the underscore disable gnits.  Between
  43 # releases, we want to be able run make dist without being required to
  44 # add a bogus NEWS entry.  In that case, the version string
  45 # automatically contains a dash, which we also let disable gnits.
  46 AM_INIT_AUTOMAKE([1.11.1 dist-bzip2]
  47                  m4_bmatch(m4_defn([AC_PACKAGE_VERSION]), [[-_]],
  48                            [gnu], [gnits]))
  49 AC_CONFIG_HEADERS([lib/config.h:lib/config.hin])
  50
  51 # Checks for the compiler.
  52 AC_PROG_CC_STDC
  53
  54 # Gnulib (early checks).
  55 gl_EARLY
  56
  57 AC_ARG_ENABLE(gcc-warnings,
  58 [  --enable-gcc-warnings   turn on lots of GCC warnings (not recommended)],
  59 [case "${enableval}" in
  60    yes|no) ;;
  61    *)      AC_MSG_ERROR([bad value ${enableval} for gcc-warnings option]) ;;
  62  esac],
  63               [enableval=no])
  64 if test "${enableval}" = yes; then
  65   gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
  66   AC_SUBST([WERROR_CFLAGS])
  67   gl_WARN_ADD([-Wall])
  68   gl_WARN_ADD([-Wextra -Wno-sign-compare])
  69   gl_WARN_ADD([-Wcast-align])
  70   gl_WARN_ADD([-Wcast-qual])
  71   gl_WARN_ADD([-Wformat])
  72   gl_WARN_ADD([-Wpointer-arith])
  73   gl_WARN_ADD([-Wwrite-strings])
  74   AC_SUBST([WARN_CXXFLAGS], [$WARN_CFLAGS])
  75   # The following warnings are not suitable for C++.
  76   gl_WARN_ADD([-Wbad-function-cast])
  77   gl_WARN_ADD([-Wmissing-declarations])
  78   gl_WARN_ADD([-Wmissing-prototypes])
  79   gl_WARN_ADD([-Wshadow])
  80   gl_WARN_ADD([-Wstrict-prototypes])
  81   AC_SUBST([WARN_CFLAGS])
  82   # Warnings for the test suite only.
  83   gl_WARN_ADD([-Wundef], [WARN_CFLAGS_TEST])
  84   WARN_CXXFLAGS_TEST="$WARN_CXXFLAGS $WARN_CFLAGS_TEST"
  85   WARN_CFLAGS_TEST="$WARN_CFLAGS $WARN_CFLAGS_TEST"
  86   AC_SUBST([WARN_CXXFLAGS_TEST])
  87   AC_SUBST([WARN_CFLAGS_TEST])
  88   AC_DEFINE([lint], 1, [Define to 1 if the compiler is checking for lint.])
  89 fi
  90
  91 BISON_TEST_FOR_WORKING_C_COMPILER
  92
  93 AC_ARG_ENABLE([yacc],
  94   [AC_HELP_STRING([--disable-yacc],
  95      [do not build a yacc command or an -ly library])],
  96   , [enable_yacc=yes])
  97 case $enable_yacc in
  98 yes)
  99   YACC_SCRIPT=yacc
 100   YACC_LIBRARY=liby.a;;
 101 *)
 102   YACC_SCRIPT=
 103   YACC_LIBRARY=;;
 104 esac
 105 AC_SUBST([YACC_SCRIPT])
 106 AC_SUBST([YACC_LIBRARY])
 107
 108 # Checks for programs.
 109 AC_PROG_LEX
 110 AC_PROG_YACC
 111 AC_PROG_RANLIB
 112 AC_PROG_GNU_M4
 113 AC_DEFINE_UNQUOTED([M4], ["$M4"], [Define to the GNU M4 executable name.])
 114 AC_DEFINE_UNQUOTED([M4_GNU_OPTION], ["$M4_GNU"], [Define to "-g" if GNU M4
 115 supports -g, otherwise to "".])
 116 AM_MISSING_PROG([HELP2MAN], [help2man])
 117 AC_PATH_PROG([XSLTPROC], [xsltproc])
 118 AC_SUBST([XSLTPROC])
 119
 120 # Checks for header files.
 121 AC_CHECK_HEADERS_ONCE([locale.h])
 122
 123 # Checks for compiler characteristics.
 124 AC_C_INLINE
 125
 126 # Gnulib (later checks).  Putting them here rather than right after
 127 # gl_EARLY avoids some redundant checks.
 128 gl_INIT
 129
 130 # Checks for library functions.
 131 AC_CHECK_FUNCS_ONCE([setlocale])
 132 AM_WITH_DMALLOC
 133 BISON_PREREQ_SUBPIPE
 134 BISON_PREREQ_TIMEVAR
 135
 136 # Gettext.
 137 # We use gnulib, which is only guaranteed to work properly with the
 138 # latest Gettext.
 139 AM_GNU_GETTEXT([external], [need-ngettext])
 140 AM_GNU_GETTEXT_VERSION([0.18])
 141 BISON_I18N
 142
 143 # Internationalized parsers.
 144 AC_CONFIG_FILES([runtime-po/Makefile.in])
 145 # Autoconf macros for packages using internationalized parsers.
 146 aclocaldir='${datadir}/aclocal'
 147 AC_SUBST([aclocaldir])
 148
 149 # Create the benchmark script.
 150 AC_CONFIG_FILES([etc/bench.pl], [chmod +x etc/bench.pl])
 151
 152 # Initialize the test suite.
 153 AC_CONFIG_TESTDIR(tests)
 154 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
 155 AC_CONFIG_FILES([tests/bison], [chmod +x tests/bison])
 156 AC_CHECK_PROGS([VALGRIND], [valgrind])
 157 AC_PROG_CXX
 158 BISON_TEST_FOR_WORKING_CXX_COMPILER
 159 AM_MISSING_PROG([AUTOM4TE], [autom4te])
 160 # Needed by tests/atlocal.in.
 161 AC_SUBST([GCC])
 162 AC_SUBST([O0CFLAGS],   [`echo $CFLAGS   | sed 's/-O[[0-9]] *//'`])
 163 AC_SUBST([O0CXXFLAGS], [`echo $CXXFLAGS | sed 's/-O[[0-9]] *//'`])
 164
 165 gt_JAVACOMP([1.3])
 166 gt_JAVAEXEC
 167
 168 AC_CONFIG_FILES([Makefile
 169                  build-aux/Makefile
 170                  po/Makefile.in
 171                  data/Makefile
 172                  etc/Makefile
 173                  examples/Makefile
 174                     examples/calc++/Makefile
 175                  lib/Makefile src/Makefile
 176                  doc/Makefile
 177                    doc/yacc.1])
 178 AC_OUTPUT