m4/flex.m4

   1 # flex.m4 serial 2
   2 # Copyright (C) 2012-2015, 2018-2021 Free Software Foundation, Inc.
   3 # This file is free software; the Free Software Foundation
   4 # gives unlimited permission to copy and/or distribute it,
   5 # with or without modifications, as long as this notice is preserved.
   6
   7 # AC_PROG_LEX
   8 # -----------
   9 # Look for flex or lex.  Set its associated library to LEXLIB.
  10 # Check if lex declares yytext as a char * by default, not a char[].
  11 AN_MAKEVAR([LEX],  [AC_PROG_LEX])
  12 AN_PROGRAM([lex],  [AC_PROG_LEX])
  13 AN_PROGRAM([flex], [AC_PROG_LEX])
  14 AC_DEFUN_ONCE([AC_PROG_LEX],
  15 [AC_CHECK_PROGS([LEX], [flex lex], [:])
  16 if test "x$LEX" != "x:"; then
  17   _AC_PROG_LEX_YYTEXT_DECL
  18 fi
  19 AC_SUBST([LEX_IS_FLEX],
  20          [`test "$ac_cv_prog_lex_is_flex" = yes && echo true || echo false`])dnl
  21 ])
  22
  23
  24 # _AC_PROG_LEX_YYTEXT_DECL
  25 # ------------------------
  26 # Check whether this is Flex, for the Lex output root, the Lex library,
  27 # and whether Lex declares yytext as a char * by default.
  28 m4_define([_AC_PROG_LEX_YYTEXT_DECL],
  29 [AC_CACHE_CHECK([whether lex is flex],
  30                 [ac_cv_prog_lex_is_flex],
  31 [cat >conftest.l <<_ACEOF[
  32 %option debug nodefault noinput nounput noyywrap never-interactive
  33 %x SC_CONF_TEST
  34 %%
  35 a { BEGIN SC_CONF_TEST; }
  36 ]_ACEOF
  37 if _AC_DO_VAR([LEX conftest.l]); then
  38   ac_cv_prog_lex_is_flex=yes
  39 else
  40   ac_cv_prog_lex_is_flex=no
  41 fi
  42 ])
  43
  44
  45 AC_CACHE_CHECK([whether flex supports --header=FILE],
  46                 [ac_cv_prog_lex_supports_header_opt],
  47 [if _AC_DO_VAR([LEX --header=conftest.h conftest.l]); then
  48   ac_cv_prog_lex_supports_header_opt=yes
  49 else
  50   ac_cv_prog_lex_supports_header_opt=no
  51 fi
  52 ])
  53 if test "$ac_cv_prog_lex_supports_header_opt" = yes; then
  54   FLEX_SUPPORTS_HEADER_OPT=true
  55 else
  56   FLEX_SUPPORTS_HEADER_OPT=false
  57 fi
  58
  59
  60 cat >conftest.l <<_ACEOF[
  61 %%
  62 a { ECHO; }
  63 b { REJECT; }
  64 c { yymore (); }
  65 d { yyless (1); }
  66 e { /* IRIX 6.5 flex 2.5.4 underquotes its yyless argument.  */
  67     yyless ((input () != 0)); }
  68 f { unput (yytext[0]); }
  69 . { BEGIN INITIAL; }
  70 %%
  71 #ifdef YYTEXT_POINTER
  72 extern char *yytext;
  73 #endif
  74 int
  75 main (void)
  76 {
  77   return ! yylex () + ! yywrap ();
  78 }
  79 ]_ACEOF
  80 _AC_DO_VAR([LEX conftest.l])
  81 AC_CACHE_CHECK([lex output file root], [ac_cv_prog_lex_root], [
  82 if test -f lex.yy.c; then
  83   ac_cv_prog_lex_root=lex.yy
  84 elif test -f lexyy.c; then
  85   ac_cv_prog_lex_root=lexyy
  86 else
  87   AC_MSG_ERROR([cannot find output from $LEX; giving up])
  88 fi])
  89 AC_SUBST([LEX_OUTPUT_ROOT], [$ac_cv_prog_lex_root])dnl
  90
  91 if test -z "${LEXLIB+set}"; then
  92   AC_CACHE_CHECK([lex library], [ac_cv_lib_lex], [
  93     ac_save_LIBS=$LIBS
  94     ac_cv_lib_lex='none needed'
  95     for ac_lib in '' -lfl -ll; do
  96       LIBS="$ac_lib $ac_save_LIBS"
  97       AC_LINK_IFELSE([AC_LANG_DEFINES_PROVIDED[`cat $LEX_OUTPUT_ROOT.c`]],
  98         [ac_cv_lib_lex=$ac_lib])
  99       test "$ac_cv_lib_lex" != 'none needed' && break
 100     done
 101     LIBS=$ac_save_LIBS
 102   ])
 103   test "$ac_cv_lib_lex" != 'none needed' && LEXLIB=$ac_cv_lib_lex
 104 fi
 105 AC_SUBST([LEXLIB])
 106
 107 AC_CACHE_CHECK([whether yytext is a pointer],
 108                [ac_cv_prog_lex_yytext_pointer],
 109 [# POSIX says lex can declare yytext either as a pointer or an array; the
 110 # default is implementation-dependent.  Figure out which it is, since
 111 # not all implementations provide the %pointer and %array declarations.
 112 ac_cv_prog_lex_yytext_pointer=no
 113 ac_save_LIBS=$LIBS
 114 LIBS="$LEXLIB $ac_save_LIBS"
 115 AC_LINK_IFELSE([AC_LANG_DEFINES_PROVIDED
 116   [#define YYTEXT_POINTER 1
 117 `cat $LEX_OUTPUT_ROOT.c`]],
 118   [ac_cv_prog_lex_yytext_pointer=yes])
 119 LIBS=$ac_save_LIBS
 120 ])
 121 dnl
 122 if test $ac_cv_prog_lex_yytext_pointer = yes; then
 123   AC_DEFINE([YYTEXT_POINTER], [1],
 124             [Define to 1 if `lex' declares `yytext' as a `char *' by default,
 125              not a `char[]'.])
 126 fi
 127 rm -f conftest.l $LEX_OUTPUT_ROOT.c
 128 ])# _AC_PROG_LEX_YYTEXT_DECL