ModuleBuildBioperl.pm

   1 #!/usr/bin/perl -w
   2
   3 # This is a subclass of Module::Build so we can override certain methods and do
   4 # fancy stuff
   5
   6 # It was first written against Module::Build::Base v0.2805. Many of the methods
   7 # here are copy/pasted from there in their entirety just to change one or two
   8 # minor things, since for the most part Module::Build::Base code is hard to
   9 # cleanly override.
  10
  11 # This was written by Sendu Bala and is released under the same license as
  12 # Bioperl itself
  13
  14 package ModuleBuildBioperl;
  15
  16 BEGIN {
  17     # we really need Module::Build to be installed
  18     unless (eval "use Module::Build 0.2805; 1") {
  19         print "This package requires Module::Build v0.2805 or greater to install itself.\n";
  20
  21         require ExtUtils::MakeMaker;
  22         my $yn = ExtUtils::MakeMaker::prompt('  Install Module::Build now from CPAN?', 'y');
  23
  24         unless ($yn =~ /^y/i) {
  25             die " *** Cannot install without Module::Build.  Exiting ...\n";
  26         }
  27
  28         require Cwd;
  29         require File::Spec;
  30         require File::Copy;
  31         require CPAN;
  32
  33         # Save this because CPAN will chdir all over the place.
  34         my $cwd = Cwd::cwd();
  35
  36         my $build_pl = File::Spec->catfile($cwd, "Build.PL");
  37
  38         File::Copy::move($build_pl, $build_pl."hidden"); # avoid bizarre bug with Module::Build tests using the wrong Build.PL if it happens to be in PERL5LIB
  39         CPAN::Shell->install('Module::Build');
  40         File::Copy::move($build_pl."hidden", $build_pl);
  41         CPAN::Shell->expand("Module", "Module::Build")->uptodate or die "Couldn't install Module::Build, giving up.\n";
  42
  43         chdir $cwd or die "Cannot chdir() back to $cwd: $!\n\n***\nInstallation will probably work fine if you now quit CPAN and try again.\n***\n\n";
  44     }
  45
  46     eval "use base Module::Build; 1" or die $@;
  47
  48     # ensure we'll be able to reload this module later by adding its path to inc
  49     use Cwd;
  50     use lib Cwd::cwd();
  51 }
  52
  53 use strict;
  54 use warnings;
  55
  56 our $VERSION = 1.005002101;
  57 our @extra_types = qw(options excludes_os feature_requires test); # test must always be last in the list!
  58 our $checking_types = "requires|conflicts|".join("|", @extra_types);
  59
  60
  61 # our modules are in Bio, not lib
  62 sub find_pm_files {
  63     my $self = shift;
  64     foreach my $pm (@{$self->rscan_dir('Bio', qr/\.pm$/)}) {
  65         $self->{properties}{pm_files}->{$pm} = File::Spec->catfile('lib', $pm);
  66     }
  67
  68     $self->_find_file_by_type('pm', 'lib');
  69 }
  70
  71 # ask what scripts to install (this method is unique to bioperl)
  72 sub choose_scripts {
  73     my $self = shift;
  74     my $accept = shift;
  75
  76     # we can offer interactive installation by groups only if we have subdirs
  77     # in scripts and no .PLS files there
  78     opendir(my $scripts_dir, 'scripts') or die "Can't open directory 'scripts': $!\n";
  79     my $int_ok = 0;
  80     my @group_dirs;
  81     while (my $thing = readdir($scripts_dir)) {
  82         next if $thing =~ /^\./;
  83         next if $thing eq 'CVS';
  84         if ($thing =~ /PLS$|pl$/) {
  85             $int_ok = 0;
  86             last;
  87         }
  88         $thing = File::Spec->catfile('scripts', $thing);
  89         if (-d $thing) {
  90             $int_ok = 1;
  91             push(@group_dirs, $thing);
  92         }
  93     }
  94     closedir($scripts_dir);
  95     my $question = $int_ok ? "Install [a]ll Bioperl scripts, [n]one, or choose groups [i]nteractively?" : "Install [a]ll Bioperl scripts or [n]one?";
  96
  97     my $prompt = $accept ? 'a' : $self->prompt($question, 'a');
  98
  99     if ($prompt =~ /^[aA]/) {
 100         $self->log_info("  - will install all scripts\n");
 101         $self->notes(chosen_scripts => 'all');
 102     }
 103     elsif ($prompt =~ /^[iI]/) {
 104         $self->log_info("  - will install interactively:\n");
 105
 106         my @chosen_scripts;
 107         foreach my $group_dir (@group_dirs) {
 108             my $group = File::Basename::basename($group_dir);
 109             print "    * group '$group' has:\n";
 110
 111             my @script_files = @{$self->rscan_dir($group_dir, qr/\.PLS$|\.pl$/)};
 112             foreach my $script_file (@script_files) {
 113                 my $script = File::Basename::basename($script_file);
 114                 print "      $script\n";
 115             }
 116
 117             my $result = $self->prompt("    Install scripts for group '$group'? [y]es [n]o [q]uit", 'n');
 118             die if $result =~ /^[qQ]/;
 119             if ($result =~ /^[yY]/) {
 120                 $self->log_info("      + will install group '$group'\n");
 121                 push(@chosen_scripts, @script_files);
 122             }
 123             else {
 124                 $self->log_info("      - will not install group '$group'\n");
 125             }
 126         }
 127
 128         my $chosen_scripts = @chosen_scripts ? join("|", @chosen_scripts) : 'none';
 129
 130         $self->notes(chosen_scripts => $chosen_scripts);
 131     }
 132     else {
 133         $self->log_info("  - won't install any scripts\n");
 134         $self->notes(chosen_scripts => 'none');
 135     }
 136
 137     print "\n";
 138 }
 139
 140 # our version of script_files doesn't take args but just installs those scripts
 141 # requested by the user after choose_scripts() is called. If it wasn't called,
 142 # installs all scripts in scripts directory
 143 sub script_files {
 144     my $self = shift;
 145
 146     unless (-d 'scripts') {
 147         return {};
 148     }
 149
 150     my $chosen_scripts = $self->notes('chosen_scripts');
 151     if ($chosen_scripts) {
 152         return if $chosen_scripts eq 'none';
 153         return { map {$_, 1} split(/\|/, $chosen_scripts) } unless $chosen_scripts eq 'all';
 154     }
 155
 156     return $_ = { map {$_,1} @{$self->rscan_dir('scripts', qr/\.PLS$|\.pl$/)} };
 157 }
 158
 159 # process scripts normally, except that we change name from *.PLS to bp_*.pl
 160 sub process_script_files {
 161     my $self = shift;
 162     my $files = $self->find_script_files;
 163     return unless keys %$files;
 164
 165     my $script_dir = File::Spec->catdir($self->blib, 'script');
 166     File::Path::mkpath( $script_dir );
 167
 168     foreach my $file (keys %$files) {
 169         my $result = $self->copy_if_modified($file, $script_dir, 'flatten') or next;
 170         $self->fix_shebang_line($result) unless $self->os_type eq 'VMS';
 171         $self->make_executable($result);
 172
 173         my $final = File::Basename::basename($result);
 174         $final =~ s/\.PLS$/\.pl/;                  # change from .PLS to .pl
 175         $final =~ s/^/bp_/ unless $final =~ /^bp/; # add the "bp" prefix
 176         $final = File::Spec->catfile($script_dir, $final);
 177         $self->log_info("$result -> $final\n");
 178         File::Copy::move($result, $final) or die "Can't rename '$result' to '$final': $!";
 179     }
 180 }
 181
 182 # extended to handle extra checking types
 183 sub features {
 184     my $self = shift;
 185     my $ph = $self->{phash};
 186
 187     if (@_) {
 188         my $key = shift;
 189         if ($ph->{features}->exists($key)) {
 190             return $ph->{features}->access($key, @_);
 191         }
 192
 193         if (my $info = $ph->{auto_features}->access($key)) {
 194             my $failures = $self->prereq_failures($info);
 195             my $disabled = grep( /^(?:\w+_)?(?:$checking_types)$/, keys %$failures ) ? 1 : 0;
 196             return !$disabled;
 197         }
 198
 199         return $ph->{features}->access($key, @_);
 200     }
 201
 202     # No args - get the auto_features & overlay the regular features
 203     my %features;
 204     my %auto_features = $ph->{auto_features}->access();
 205     while (my ($name, $info) = each %auto_features) {
 206         my $failures = $self->prereq_failures($info);
 207         my $disabled = grep( /^(?:\w+_)?(?:$checking_types)$/, keys %$failures ) ? 1 : 0;
 208         $features{$name} = $disabled ? 0 : 1;
 209     }
 210     %features = (%features, $ph->{features}->access());
 211
 212     return wantarray ? %features : \%features;
 213 }
 214 *feature = \&features;
 215
 216 # overridden to fix a stupid bug in Module::Build and extended to handle extra
 217 # checking types
 218 sub check_autofeatures {
 219     my ($self) = @_;
 220     my $features = $self->auto_features;
 221
 222     return unless %$features;
 223
 224     $self->log_info("Checking features:\n");
 225
 226     my $max_name_len = 0; # this wasn't set to 0 in Module::Build, causing warning in next line
 227     $max_name_len = ( length($_) > $max_name_len ) ? length($_) : $max_name_len for keys %$features;
 228
 229     while (my ($name, $info) = each %$features) {
 230         $self->log_info("  $name" . '.' x ($max_name_len - length($name) + 4));
 231         if ($name eq 'PL_files') {
 232             print "got $name => $info\n";
 233             print "info has:\n";
 234             while (my ($key, $val) = each %$info) {
 235                 print "  $key => $val\n";
 236             }
 237         }
 238
 239         if ( my $failures = $self->prereq_failures($info) ) {
 240             my $disabled = grep( /^(?:\w+_)?(?:$checking_types)$/, keys %$failures ) ? 1 : 0;
 241             $self->log_info( $disabled ? "disabled\n" : "enabled\n" );
 242
 243             my $log_text;
 244             while (my ($type, $prereqs) = each %$failures) {
 245                 while (my ($module, $status) = each %$prereqs) {
 246                     my $required = ($type =~ /^(?:\w+_)?(?:requires|conflicts)$/) ? 1 : 0;
 247                     my $prefix = ($required) ? '-' : '*';
 248                     $log_text .= "    $prefix $status->{message}\n";
 249                 }
 250             }
 251             $self->log_warn($log_text) if $log_text && ! $self->quiet;
 252         }
 253         else {
 254             $self->log_info("enabled\n");
 255         }
 256     }
 257
 258     $self->log_info("\n");
 259 }
 260
 261 # overriden just to hide pointless ugly warnings
 262 sub check_installed_status {
 263     my $self = shift;
 264     open (my $olderr, ">&", \*STDERR);
 265     open(STDERR, "/dev/null");
 266     my $return = $self->SUPER::check_installed_status(@_);
 267     open(STDERR, ">&", $olderr);
 268     return $return;
 269 }
 270
 271 # extend to handle option checking (which takes an array ref) and code test
 272 # checking (which takes a code ref and must return a message only on failure)
 273 # and excludes_os (which takes an array ref of regexps).
 274 # also handles more informative output of recommends section
 275 sub prereq_failures {
 276     my ($self, $info) = @_;
 277
 278     my @types = (@{ $self->prereq_action_types }, @extra_types);
 279     $info ||= {map {$_, $self->$_()} @types};
 280
 281     my $out = {};
 282     foreach my $type (@types) {
 283         my $prereqs = $info->{$type} || next;
 284
 285         my $status = {};
 286         if ($type eq 'test') {
 287             unless (keys %$out) {
 288                 if (ref($prereqs) eq 'CODE') {
 289                     $status->{message} = &{$prereqs};
 290
 291                     # drop the code-ref to avoid Module::Build trying to store
 292                     # it with Data::Dumper, generating warnings. (And also, may
 293                     # be expensive to run the sub multiple times.)
 294                     $info->{$type} = $status->{message};
 295                 }
 296                 else {
 297                     $status->{message} = $prereqs;
 298                 }
 299                 $out->{$type}{'test'} = $status if $status->{message};
 300             }
 301         }
 302         elsif ($type eq 'options') {
 303             my @not_ok;
 304             foreach my $wanted_option (@{$prereqs}) {
 305                 unless ($self->args($wanted_option)) {
 306                     push(@not_ok, $wanted_option);
 307                 }
 308             }
 309
 310             if (@not_ok > 0) {
 311                 $status->{message} = "Command line option(s) '@not_ok' not supplied";
 312                 $out->{$type}{'options'} = $status;
 313             }
 314         }
 315         elsif ($type eq 'excludes_os') {
 316             foreach my $os (@{$prereqs}) {
 317                 if ($^O =~ /$os/i) {
 318                     $status->{message} = "This feature isn't supported under your OS ($os)";
 319                     $out->{$type}{'excludes_os'} = $status;
 320                     last;
 321                 }
 322             }
 323         }
 324         else {
 325             while ( my ($modname, $spec) = each %$prereqs ) {
 326                 $status = $self->check_installed_status($modname, $spec);
 327
 328                 if ($type =~ /^(?:\w+_)?conflicts$/) {
 329                     next if !$status->{ok};
 330                     $status->{conflicts} = delete $status->{need};
 331                     $status->{message} = "$modname ($status->{have}) conflicts with this distribution";
 332                 }
 333                 elsif ($type =~ /^(?:\w+_)?recommends$/) {
 334                     next if $status->{ok};
 335
 336                     my ($preferred_version, $why, $by_what) = split("/", $spec);
 337                     $by_what = join(", ", split(",", $by_what));
 338                     $by_what =~ s/, (\S+)$/ and $1/;
 339
 340                     $status->{message} = (!ref($status->{have}) && $status->{have} eq '<none>'
 341                                   ? "Optional prerequisite $modname is not installed"
 342                                   : "$modname ($status->{have}) is installed, but we prefer to have $preferred_version");
 343
 344                     $status->{message} .= "\n   (wanted for $why, used by $by_what)";
 345
 346                     my $installed = $self->install_optional($modname, $preferred_version, $status->{message});
 347                     next if $installed eq 'ok';
 348                     $status->{message} = $installed unless $installed eq 'skip';
 349                 }
 350                 elsif ($type =~ /^feature_requires/) {
 351                     next if $status->{ok};
 352
 353                     # if there is a test code-ref, drop it to avoid
 354                     # Module::Build trying to store it with Data::Dumper,
 355                     # generating warnings.
 356                     delete $info->{test};
 357                 }
 358                 else {
 359                     next if $status->{ok};
 360
 361                     my $installed = $self->install_required($modname, $spec, $status->{message});
 362                     next if $installed eq 'ok';
 363                     $status->{message} = $installed;
 364                 }
 365
 366                 $out->{$type}{$modname} = $status;
 367             }
 368         }
 369     }
 370
 371     return keys %{$out} ? $out : return;
 372 }
 373
 374 # install an external module using CPAN prior to testing and installation
 375 # should only be called by install_required or install_optional
 376 sub install_prereq {
 377     my ($self, $desired, $version) = @_;
 378
 379     if ($self->under_cpan) {
 380         # Just add to the required hash, which CPAN >= 1.81 will check prior
 381         # to install
 382         $self->{properties}{requires}->{$desired} = $version;
 383         $self->log_info("   I'll get CPAN to prepend the installation of this\n");
 384         return 'ok';
 385     }
 386     else {
 387         # Here we use CPAN to actually install the desired module, the benefit
 388         # being we continue even if installation fails, and that this works
 389         # even when not using CPAN to install.
 390         require Cwd;
 391         require CPAN;
 392
 393         # Save this because CPAN will chdir all over the place.
 394         my $cwd = Cwd::cwd();
 395
 396         CPAN::Shell->install($desired);
 397         my $msg;
 398         my $expanded = CPAN::Shell->expand("Module", $desired);
 399         if ($expanded && $expanded->uptodate) {
 400             $self->log_info("\n\n*** (back in Bioperl Build.PL) ***\n * You chose to install $desired and it installed fine\n");
 401             $msg = 'ok';
 402         }
 403         else {
 404             $self->log_info("\n\n*** (back in Bioperl Build.PL) ***\n");
 405             $msg = "You chose to install $desired but it failed to install";
 406         }
 407
 408         chdir $cwd or die "Cannot chdir() back to $cwd: $!";
 409         return $msg;
 410     }
 411 }
 412
 413 # install required modules listed in 'requires' or 'build_requires' arg to
 414 # new that weren't already installed. Should only be called by prereq_failures
 415 sub install_required {
 416     my ($self, $desired, $version, $msg) = @_;
 417
 418     $self->log_info(" - ERROR: $msg\n");
 419
 420     return $self->install_prereq($desired, $version);
 421 }
 422
 423 # install optional modules listed in 'recommends' arg to new that weren't
 424 # already installed. Should only be called by prereq_failures
 425 sub install_optional {
 426     my ($self, $desired, $version, $msg) = @_;
 427
 428     unless (defined $self->{ask_optional}) {
 429         $self->{ask_optional} = $self->args->{accept}
 430                               ? 'n' : $self->prompt("Install [a]ll optional external modules, [n]one, or choose [i]nteractively?", 'n');
 431     }
 432     return 'skip' if $self->{ask_optional} =~ /^n/i;
 433
 434     my $install;
 435     if ($self->{ask_optional} =~ /^a/i) {
 436         $self->log_info(" * $msg\n");
 437         $install = 1;
 438     }
 439     else {
 440         $install = $self->y_n(" * $msg\n   Do you want to install it? y/n", 'n');
 441     }
 442
 443     if ($install) {
 444         return $self->install_prereq($desired, $version);
 445     }
 446     else {
 447         $self->log_info(" * You chose not to install $desired\n");
 448         return 'ok';
 449     }
 450 }
 451
 452 # there's no official way to discover if being run by CPAN, we take an approach
 453 # similar to that of Module::AutoInstall
 454 sub under_cpan {
 455     my $self = shift;
 456
 457     unless (defined $self->{under_cpan}) {
 458         ## modified from Module::AutoInstall
 459
 460         # load cpan config
 461         require CPAN;
 462         if ($CPAN::HandleConfig::VERSION) {
 463             # Newer versions of CPAN have a HandleConfig module
 464             CPAN::HandleConfig->load;
 465         }
 466         else {
 467             # Older versions had the load method in Config directly
 468             CPAN::Config->load;
 469         }
 470
 471         # Find the CPAN lock-file
 472         my $lock = File::Spec->catfile($CPAN::Config->{cpan_home}, '.lock');
 473         if (-f $lock) {
 474             # Module::AutoInstall now goes on to open the lock file and compare
 475             # its pid to ours, but we're not in a situation where we expect
 476             # the pids to match, so we take the windows approach for all OSes:
 477             # find out if we're in cpan_home
 478             my $cwd  = File::Spec->canonpath(Cwd::cwd());
 479             my $cpan = File::Spec->canonpath($CPAN::Config->{cpan_home});
 480
 481             $self->{under_cpan} = index($cwd, $cpan) > -1;
 482         }
 483
 484         if ($self->{under_cpan}) {
 485             $self->log_info("(I think I'm being run by CPAN, so will rely on CPAN to handle prerequisite installation)\n");
 486         }
 487         else {
 488             $self->log_info("(I think you ran Build.PL directly, so will use CPAN to install prerequisites on demand)\n");
 489             $self->{under_cpan} = 0;
 490         }
 491     }
 492
 493     return $self->{under_cpan};
 494 }
 495
 496 # overridden simply to not print the default answer if chosen by hitting return
 497 sub prompt {
 498     my $self = shift;
 499     my $mess = shift or die "prompt() called without a prompt message";
 500
 501     my $def;
 502     if ( $self->_is_unattended && !@_ ) {
 503         die <<EOF;
 504 ERROR: This build seems to be unattended, but there is no default value
 505 for this question.  Aborting.
 506 EOF
 507     }
 508     $def = shift if @_;
 509     ($def, my $dispdef) = defined $def ? ($def, "[$def] ") : ('', ' ');
 510
 511     local $|=1;
 512     print "$mess $dispdef";
 513
 514     my $ans = $self->_readline();
 515
 516     if ( !defined($ans)        # Ctrl-D or unattended
 517          or !length($ans) ) {  # User hit return
 518         #print "$def\n"; didn't like this!
 519         $ans = $def;
 520     }
 521
 522     return $ans;
 523 }
 524
 525 # like the Module::Build version, except that we always get version from
 526 # dist_version
 527 sub find_dist_packages {
 528     my $self = shift;
 529
 530     # Only packages in .pm files are candidates for inclusion here.
 531     # Only include things in the MANIFEST, not things in developer's
 532     # private stock.
 533
 534     my $manifest = $self->_read_manifest('MANIFEST') or die "Can't find dist packages without a MANIFEST file - run 'manifest' action first";
 535
 536     # Localize
 537     my %dist_files = map { $self->localize_file_path($_) => $_ } keys %$manifest;
 538
 539     my @pm_files = grep {exists $dist_files{$_}} keys %{ $self->find_pm_files };
 540
 541     my $actual_version = $self->dist_version;
 542
 543     # First, we enumerate all packages & versions,
 544     # seperating into primary & alternative candidates
 545     my( %prime, %alt );
 546     foreach my $file (@pm_files) {
 547         next if $dist_files{$file} =~ m{^t/};  # Skip things in t/
 548
 549         my @path = split( /\//, $dist_files{$file} );
 550         (my $prime_package = join( '::', @path[1..$#path] )) =~ s/\.pm$//;
 551
 552         my $pm_info = Module::Build::ModuleInfo->new_from_file( $file );
 553
 554         foreach my $package ( $pm_info->packages_inside ) {
 555             next if $package eq 'main';  # main can appear numerous times, ignore
 556             next if grep /^_/, split( /::/, $package ); # private package, ignore
 557
 558             my $version = $pm_info->version( $package );
 559             if ($version && $version != $actual_version) {
 560                 $self->log_warn("Package $package had version $version!\n");
 561             }
 562             $version = $actual_version;
 563
 564             if ( $package eq $prime_package ) {
 565                 if ( exists( $prime{$package} ) ) {
 566                     # M::B::ModuleInfo will handle this conflict
 567                     die "Unexpected conflict in '$package'; multiple versions found.\n";
 568                 }
 569                 else {
 570                     $prime{$package}{file} = $dist_files{$file};
 571                     $prime{$package}{version} = $version if defined( $version );
 572                 }
 573             }
 574             else {
 575                 push( @{$alt{$package}}, { file => $dist_files{$file}, version => $version } );
 576             }
 577         }
 578     }
 579
 580     # Then we iterate over all the packages found above, identifying conflicts
 581     # and selecting the "best" candidate for recording the file & version
 582     # for each package.
 583     foreach my $package ( keys( %alt ) ) {
 584         my $result = $self->_resolve_module_versions( $alt{$package} );
 585
 586         if ( exists( $prime{$package} ) ) { # primary package selected
 587             if ( $result->{err} ) {
 588                 # Use the selected primary package, but there are conflicting
 589                  # errors amoung multiple alternative packages that need to be
 590                  # reported
 591                  $self->log_warn("Found conflicting versions for package '$package'\n" .
 592                                  "  $prime{$package}{file} ($prime{$package}{version})\n" . $result->{err});
 593             }
 594             elsif ( defined( $result->{version} ) ) {
 595                 # There is a primary package selected, and exactly one
 596                 # alternative package
 597
 598                 if ( exists( $prime{$package}{version} ) && defined( $prime{$package}{version} ) ) {
 599                     # Unless the version of the primary package agrees with the
 600                     # version of the alternative package, report a conflict
 601                     if ( $self->compare_versions( $prime{$package}{version}, '!=', $result->{version} ) ) {
 602                         $self->log_warn("Found conflicting versions for package '$package'\n" .
 603                                         "  $prime{$package}{file} ($prime{$package}{version})\n" .
 604                                         "  $result->{file} ($result->{version})\n");
 605                     }
 606                 }
 607                 else {
 608                   # The prime package selected has no version so, we choose to
 609                   # use any alternative package that does have a version
 610                   $prime{$package}{file}    = $result->{file};
 611                   $prime{$package}{version} = $result->{version};
 612                 }
 613             }
 614             else {
 615                 # no alt package found with a version, but we have a prime
 616                 # package so we use it whether it has a version or not
 617             }
 618         }
 619         else { # No primary package was selected, use the best alternative
 620             if ( $result->{err} ) {
 621                 $self->log_warn("Found conflicting versions for package '$package'\n" . $result->{err});
 622             }
 623
 624             # Despite possible conflicting versions, we choose to record
 625             # something rather than nothing
 626             $prime{$package}{file}    = $result->{file};
 627             $prime{$package}{version} = $result->{version} if defined( $result->{version} );
 628         }
 629     }
 630
 631     # Stringify versions
 632     for (grep exists $_->{version}, values %prime) {
 633         $_->{version} = $_->{version}->stringify if ref($_->{version});
 634     }
 635
 636     return \%prime;
 637 }
 638
 639 # our recommends syntax contains extra info that needs to be ignored at this
 640 # stage
 641 sub _parse_conditions {
 642     my ($self, $spec) = @_;
 643
 644     ($spec) = split("/", $spec);
 645
 646     if ($spec =~ /^\s*([\w.]+)\s*$/) { # A plain number, maybe with dots, letters, and underscores
 647         return (">= $spec");
 648     }
 649     else {
 650         return split /\s*,\s*/, $spec;
 651     }
 652 }
 653
 654 # when generating META.yml, we output optional_features syntax (instead of
 655 # recommends syntax). Note that as of CPAN v1.8802 nothing useful is done
 656 # with this information, which is why we implement our own request to install
 657 # the optional modules in install_optional()
 658 sub prepare_metadata {
 659     my ($self, $node, $keys) = @_;
 660     my $p = $self->{properties};
 661
 662     # A little helper sub
 663     my $add_node = sub {
 664         my ($name, $val) = @_;
 665         $node->{$name} = $val;
 666         push @$keys, $name if $keys;
 667     };
 668
 669     foreach (qw(dist_name dist_version dist_author dist_abstract license)) {
 670         (my $name = $_) =~ s/^dist_//;
 671         $add_node->($name, $self->$_());
 672         die "ERROR: Missing required field '$_' for META.yml\n" unless defined($node->{$name}) && length($node->{$name});
 673     }
 674     $node->{version} = '' . $node->{version}; # Stringify version objects
 675
 676     if (defined( $self->license ) && defined( my $url = $self->valid_licenses->{ $self->license } )) {
 677         $node->{resources}{license} = $url;
 678     }
 679
 680     foreach ( @{$self->prereq_action_types} ) {
 681         if (exists $p->{$_} and keys %{ $p->{$_} }) {
 682             if ($_ eq 'recommends') {
 683                 my $hash;
 684                 while (my ($req, $val) = each %{ $p->{$_} }) {
 685                     my ($ver, $why, $used_by) = split("/", $val);
 686                     my $info = {};
 687                     $info->{description} = $why;
 688                     $info->{requires} = { $req => $ver };
 689                     $hash->{$used_by} = $info;
 690                 }
 691                 $add_node->('optional_features', $hash);
 692             }
 693             else {
 694                 $add_node->($_, $p->{$_});
 695             }
 696         }
 697     }
 698
 699     if (exists $p->{dynamic_config}) {
 700         $add_node->('dynamic_config', $p->{dynamic_config});
 701     }
 702     my $pkgs = eval { $self->find_dist_packages };
 703     if ($@) {
 704         $self->log_warn("$@\nWARNING: Possible missing or corrupt 'MANIFEST' file.\n" . "Nothing to enter for 'provides' field in META.yml\n");
 705     }
 706     else {
 707         $node->{provides} = $pkgs if %$pkgs;
 708     };
 709
 710     if (exists $p->{no_index}) {
 711         $add_node->('no_index', $p->{no_index});
 712     }
 713
 714     $add_node->('generated_by', "Module::Build version $Module::Build::VERSION");
 715
 716     $add_node->('meta-spec',
 717             {version => '1.2',
 718              url     => 'http://module-build.sourceforge.net/META-spec-v1.2.html',
 719             });
 720
 721     while (my($k, $v) = each %{$self->meta_add}) {
 722         $add_node->($k, $v);
 723     }
 724
 725     while (my($k, $v) = each %{$self->meta_merge}) {
 726         $self->_hash_merge($node, $k, $v);
 727     }
 728
 729     return $node;
 730 }
 731
 732 # let us store extra things persistently in _build
 733 sub _construct {
 734     my $self = shift;
 735     $self = $self->SUPER::_construct(@_);
 736
 737     my ($p, $ph) = ($self->{properties}, $self->{phash});
 738
 739     foreach (qw(manifest_skip post_install_scripts)) {
 740         my $file = File::Spec->catfile($self->config_dir, $_);
 741         $ph->{$_} = Module::Build::Notes->new(file => $file);
 742         $ph->{$_}->restore if -e $file;
 743     }
 744
 745     return $self;
 746 }
 747 sub write_config {
 748     my $self = shift;
 749     $self->SUPER::write_config;
 750
 751     # write extra things
 752     $self->{phash}{$_}->write() foreach qw(manifest_skip post_install_scripts);
 753
 754     # be even more certain we can reload ourselves during a resume by copying
 755     # ourselves to _build\lib
 756     my $filename = File::Spec->catfile($self->{properties}{config_dir}, 'lib', 'ModuleBuildBioperl.pm');
 757     my $filedir  = File::Basename::dirname($filename);
 758
 759     File::Path::mkpath($filedir);
 760     warn "Can't create directory $filedir: $!" unless -d $filedir;
 761
 762     File::Copy::copy('ModuleBuildBioperl.pm', $filename);
 763     warn "Unable to copy 'ModuleBuildBioperl.pm' to '$filename'\n" unless -e $filename;
 764 }
 765
 766 # add a file to the default MANIFEST.SKIP
 767 sub add_to_manifest_skip {
 768     my $self = shift;
 769     my %files = map {$self->localize_file_path($_), 1} @_;
 770     $self->{phash}{manifest_skip}->write(\%files);
 771 }
 772
 773 # we always generate a new MANIFEST and MANIFEST.SKIP here, instead of allowing
 774 # existing files to remain
 775 sub ACTION_manifest {
 776     my ($self) = @_;
 777
 778     my $maniskip = 'MANIFEST.SKIP';
 779     if ( -e 'MANIFEST' || -e $maniskip ) {
 780         $self->log_warn("MANIFEST files already exist, will overwrite them\n");
 781         unlink('MANIFEST');
 782         unlink($maniskip);
 783     }
 784     $self->_write_default_maniskip($maniskip);
 785
 786     require ExtUtils::Manifest;  # ExtUtils::Manifest is not warnings clean.
 787     local ($^W, $ExtUtils::Manifest::Quiet) = (0,1);
 788     ExtUtils::Manifest::mkmanifest();
 789 }
 790
 791 # extended to add extra things to the default MANIFEST.SKIP
 792 sub _write_default_maniskip {
 793     my $self = shift;
 794     $self->SUPER::_write_default_maniskip;
 795
 796     my @extra = keys %{$self->{phash}{manifest_skip}->read};
 797     if (@extra) {
 798         open(my $fh, '>>', 'MANIFEST.SKIP') or die "Could not open MANIFEST.SKIP file\n";
 799         print $fh "\n# Avoid additional run-time generated things\n";
 800         foreach my $line (@extra) {
 801             print $fh $line, "\n";
 802         }
 803         close($fh);
 804     }
 805 }
 806
 807 # extended to run scripts post-installation
 808 sub ACTION_install {
 809   my ($self) = @_;
 810   require ExtUtils::Install;
 811   $self->depends_on('build');
 812   ExtUtils::Install::install($self->install_map, !$self->quiet, 0, $self->{args}{uninst}||0);
 813   $self->run_post_install_scripts;
 814 }
 815 sub add_post_install_script {
 816     my $self = shift;
 817     my %files = map {$self->localize_file_path($_), 1} @_;
 818     $self->{phash}{post_install_scripts}->write(\%files);
 819 }
 820 sub run_post_install_scripts {
 821     my $self = shift;
 822     my @scripts = keys %{$self->{phash}{post_install_scripts}->read};
 823     foreach my $script (@scripts) {
 824         $self->run_perl_script($script);
 825     }
 826 }
 827
 828 # for use with auto_features, which should require LWP::UserAgent as one of
 829 # its reqs
 830 sub test_internet {
 831     eval {require LWP::UserAgent;};
 832     if ($@) {
 833         # ideally this won't happen because auto_feature already specified
 834         # LWP::UserAgent, so this sub wouldn't get called if LWP not installed
 835         return "LWP::UserAgent not installed";
 836     }
 837     my $ua = LWP::UserAgent->new;
 838     $ua->timeout(10);
 839     $ua->env_proxy;
 840     my $response = $ua->get('http://search.cpan.org/');
 841     unless ($response->is_success) {
 842         return "Could not connect to the internet (http://search.cpan.org/)";
 843     }
 844     return;
 845 }
 846
 847 # nice directory names for dist-related actions
 848 sub dist_dir {
 849     my ($self) = @_;
 850     my $version = $self->dist_version;
 851     if ($version =~ /^\d\.\d{6}\d$/) {
 852         # 1.x.x.100 returned as 1.x.x.1
 853         $version .= '00';
 854     }
 855     $version =~ s/00(\d)/$1./g;
 856     $version =~ s/\.$//;
 857
 858     if (my ($minor, $rev) = $version =~ /^\d\.(\d)\.\d\.(\d+)$/) {
 859         my $dev = ! ($minor % 2 == 0);
 860         if ($rev == 100) {
 861             my $replace = $dev ? "_$rev" : '';
 862             $version =~ s/\.\d+$/$replace/;
 863         }
 864         elsif ($rev < 100) {
 865             $rev = sprintf("%03d", $rev);
 866             $version =~ s/\.\d+$/_$rev-RC/;
 867         }
 868         else {
 869             $rev -= 100 unless $dev;
 870             my $replace = $dev ? "_$rev" : ".$rev";
 871             $version =~ s/\.\d+$/$replace/;
 872         }
 873     }
 874
 875     return "$self->{properties}{dist_name}-$version";
 876 }
 877 sub ppm_name {
 878     my $self = shift;
 879     return $self->dist_dir.'-ppm';
 880 }
 881
 882 # generate complete ppd4 version file
 883 sub ACTION_ppd {
 884     my $self = shift;
 885
 886     my $file = $self->make_ppd(%{$self->{args}});
 887     $self->add_to_cleanup($file);
 888     $self->add_to_manifest_skip($file);
 889 }
 890
 891 # add pod2htm temp files to MANIFEST.SKIP, generated during ppmdist most likely
 892 sub htmlify_pods {
 893     my $self = shift;
 894     $self->SUPER::htmlify_pods(@_);
 895     $self->add_to_manifest_skip('pod2htm*');
 896 }
 897
 898 # don't copy across man3 docs since they're of little use under Windows and
 899 # have bad filenames
 900 sub ACTION_ppmdist {
 901     my $self = shift;
 902     my @types = $self->install_types(1);
 903     $self->SUPER::ACTION_ppmdist(@_);
 904     $self->install_types(0);
 905 }
 906
 907 # when supplied a true value, pretends libdoc doesn't exist (preventing man3
 908 # installation for ppmdist). when supplied false, they exist again
 909 sub install_types {
 910     my ($self, $no_libdoc) = @_;
 911     $self->{no_libdoc} = $no_libdoc if defined $no_libdoc;
 912     my @types = $self->SUPER::install_types;
 913     if ($self->{no_libdoc}) {
 914         my @altered_types;
 915         foreach my $type (@types) {
 916             push(@altered_types, $type) unless $type eq 'libdoc';
 917         }
 918         return @altered_types;
 919     }
 920     return @types;
 921 }
 922
 923 # overridden from Module::Build::PPMMaker for ppd4 compatability
 924 sub make_ppd {
 925     my ($self, %args) = @_;
 926
 927     require Module::Build::PPMMaker;
 928     my $mbp = Module::Build::PPMMaker->new();
 929
 930     my %dist;
 931     foreach my $info (qw(name author abstract version)) {
 932         my $method = "dist_$info";
 933         $dist{$info} = $self->$method() or die "Can't determine distribution's $info\n";
 934     }
 935     $dist{codebase} = $self->ppm_name.'.tar.gz';
 936     $mbp->_simple_xml_escape($_) foreach $dist{abstract}, $dist{codebase}, @{$dist{author}};
 937
 938     my (undef, undef, undef, $mday, $mon, $year) = localtime();
 939     $year += 1900;
 940     $mon++;
 941     my $date = "$year-$mon-$mday";
 942
 943     my $softpkg_version = $self->dist_dir;
 944     $softpkg_version =~ s/^$dist{name}-//;
 945
 946     # to avoid a ppm bug, instead of including the requires in the softpackage
 947     # for the distribution we're making, we'll make a seperate Bundle::
 948     # softpackage that contains all the requires, and require only the Bundle in
 949     # the real softpackage
 950     my ($bundle_name) = $dist{name} =~ /^.+-(.+)/;
 951     $bundle_name ||= 'core';
 952     $bundle_name =~ s/^(\w)/\U$1/;
 953     my $bundle_dir = "Bundle-BioPerl-$bundle_name-$softpkg_version-ppm";
 954     my $bundle_file = "$bundle_dir.tar.gz";
 955     my $bundle_softpkg_name = "Bundle-BioPerl-$bundle_name";
 956     $bundle_name = "Bundle::BioPerl::$bundle_name";
 957
 958     # header
 959     my $ppd = <<"PPD";
 960     <SOFTPKG NAME=\"$dist{name}\" VERSION=\"$softpkg_version\" DATE=\"$date\">
 961         <TITLE>$dist{name}</TITLE>
 962         <ABSTRACT>$dist{abstract}</ABSTRACT>
 963 @{[ join "\n", map "        <AUTHOR>$_</AUTHOR>", @{$dist{author}} ]}
 964         <PROVIDE NAME=\"$dist{name}::\" VERSION=\"$dist{version}\"/>
 965 PPD
 966
 967     # provide section
 968     foreach my $pm (@{$self->rscan_dir('Bio', qr/\.pm$/)}) {
 969         # convert these filepaths to Module names
 970         $pm =~ s/\//::/g;
 971         $pm =~ s/\.pm//;
 972
 973         $ppd .= sprintf(<<'EOF', $pm, $dist{version});
 974         <PROVIDE NAME="%s" VERSION="%s"/>
 975 EOF
 976     }
 977
 978     # rest of softpkg
 979     $ppd .= <<"PPD";
 980         <IMPLEMENTATION>
 981             <ARCHITECTURE NAME=\"MSWin32-x86-multi-thread-5.8\"/>
 982             <CODEBASE HREF=\"$dist{codebase}\"/>
 983             <REQUIRE NAME=\"$bundle_name\" VERSION=\"$dist{version}\"/>
 984         </IMPLEMENTATION>
 985     </SOFTPKG>
 986 PPD
 987
 988     # now a new softpkg for the bundle
 989     $ppd .= <<"PPD";
 990
 991     <SOFTPKG NAME=\"$bundle_softpkg_name\" VERSION=\"$softpkg_version\" DATE=\"$date\">
 992         <TITLE>$bundle_name</TITLE>
 993         <ABSTRACT>Bundle of pre-requisites for $dist{name}</ABSTRACT>
 994 @{[ join "\n", map "        <AUTHOR>$_</AUTHOR>", @{$dist{author}} ]}
 995         <PROVIDE NAME=\"$bundle_name\" VERSION=\"$dist{version}\"/>
 996         <IMPLEMENTATION>
 997             <ARCHITECTURE NAME=\"MSWin32-x86-multi-thread-5.8\"/>
 998             <CODEBASE HREF=\"$bundle_file\"/>
 999 PPD
1000
1001     # required section
1002     # we do both requires and recommends to make installation on Windows as
1003     # easy (mindless) as possible
1004     for my $type ('requires', 'recommends') {
1005         my $prereq = $self->$type;
1006         while (my ($modname, $version) = each %$prereq) {
1007             next if $modname eq 'perl';
1008             ($version) = split("/", $version) if $version =~ /\//;
1009
1010             # Module names must have at least one ::
1011             unless ($modname =~ /::/) {
1012                 $modname .= '::';
1013             }
1014
1015             # Bio::Root::Version number comes out as triplet number like 1.5.2;
1016             # convert to our own version
1017             if ($modname eq 'Bio::Root::Version') {
1018                 $version = $dist{version};
1019             }
1020
1021             $ppd .= sprintf(<<'EOF', $modname, $version || '');
1022             <REQUIRE NAME="%s" VERSION="%s"/>
1023 EOF
1024         }
1025     }
1026
1027     # footer
1028     $ppd .= <<'EOF';
1029         </IMPLEMENTATION>
1030     </SOFTPKG>
1031 EOF
1032
1033     my $ppd_file = "$dist{name}.ppd";
1034     my $fh = IO::File->new(">$ppd_file") or die "Cannot write to $ppd_file: $!";
1035     print $fh $ppd;
1036     close $fh;
1037
1038     $self->delete_filetree($bundle_dir);
1039     mkdir($bundle_dir) or die "Cannot create '$bundle_dir': $!";
1040     $self->make_tarball($bundle_dir);
1041     $self->delete_filetree($bundle_dir);
1042     $self->add_to_cleanup($bundle_file);
1043     $self->add_to_manifest_skip($bundle_file);
1044
1045     return $ppd_file;
1046 }
1047
1048 # we make all archive formats we want, not just .tar.gz
1049 # we also auto-run manifest action, since we always want to re-create
1050 # MANIFEST and MANIFEST.SKIP just-in-time
1051 sub ACTION_dist {
1052     my ($self) = @_;
1053
1054     $self->depends_on('manifest');
1055     $self->depends_on('distdir');
1056
1057     my $dist_dir = $self->dist_dir;
1058
1059     $self->make_zip($dist_dir);
1060     $self->make_tarball($dist_dir);
1061     $self->delete_filetree($dist_dir);
1062 }
1063
1064 # makes zip file for windows users and bzip2 files as well
1065 sub make_zip {
1066     my ($self, $dir, $file) = @_;
1067     $file ||= $dir;
1068
1069     $self->log_info("Creating $file.zip\n");
1070     my $zip_flags = $self->verbose ? '-r' : '-rq';
1071     $self->do_system($self->split_like_shell("zip"), $zip_flags, "$file.zip", $dir);
1072
1073     $self->log_info("Creating $file.bz2\n");
1074     require Archive::Tar;
1075     # Archive::Tar versions >= 1.09 use the following to enable a compatibility
1076     # hack so that the resulting archive is compatible with older clients.
1077     $Archive::Tar::DO_NOT_USE_PREFIX = 0;
1078     my $files = $self->rscan_dir($dir);
1079     Archive::Tar->create_archive("$file.tar", 0, @$files);
1080     $self->do_system($self->split_like_shell("bzip2"), "-k", "$file.tar");
1081 }
1082
1083 1;