examples/root/exceptions2.pl

   1 #!/usr/bin/perl
   2
   3 # This shows how Error.pm-based objects can be thrown
   4 # by Bio::Root::Root::throw() when Error.pm is available.
   5 # When Error.pm isn't available, Bio::Root::Root::throw()
   6 # works as usual.
   7 #
   8 # It also demonstrates what happens when you use an outer eval{}
   9 # instead of a try{} to trap thrown Error.pm-based exceptions.
  10 # The behavior is the same as when Error.pm is not used.
  11 # This is important for backward compatibility.
  12 #
  13 # Author: Steve Chervitz <sac@bioperl.org>
  14 #
  15
  16 use strict;
  17
  18
  19 # Uncomment this line to force Bio::Root::Root::throw() to
  20 # not use Error.pm even if it's available.
  21 # Some of the tests in this script will be skipped .
  22 #BEGIN { $main::DONT_USE_ERROR = 1; }
  23
  24 use Bio::Root::Root;
  25 #use Bio::Root::Exception;  # Not necessary since Bio::Root::Root uses it.
  26 use Error qw(:try);
  27
  28 my $foo = Bio::Root::Root->new();
  29
  30 if (!$main::DONT_USE_ERROR) {
  31     try {
  32         # This is the new, fancier way to handle exceptions.
  33         # You must have Error.pm to do this (tarball included in this dir).
  34
  35         print "[1] Throwing Error within try block via call to Bio::Root::Root::throw()\n";
  36         $foo->throw( -class => 'Bio::Root::Exception',
  37                      -text  => "Oopsie!",
  38                      -value => "123"
  39                    );
  40     }
  41
  42     catch Bio::Root::Exception with {
  43         my $err = shift;
  44         print "[1] Caught Bio::Root::Exception:\n$err";
  45
  46     }
  47
  48     otherwise {
  49         my $err = shift;
  50         print "[1] Caught other Error: ", ref($err), "\n$err";
  51     };
  52
  53
  54     print "\n\n";
  55 }
  56
  57 eval {
  58
  59     # This example demonstrates the traditional method for throwing
  60     # an exception using Bio::Root::Root->throw('string').
  61     # Notice how an exception of type Bio::Root::Exception is created.
  62
  63     print "[2] Calling Bio::Root::Root->throw('string') within an eval{}\n";
  64     $foo->throw("Error message string.");
  65
  66 };
  67
  68 if($@) {
  69     print "[2] Caught eval{}-based exception: ", ref($@), "\n$@";
  70 }
  71 else {
  72     print "[2] Nothing to catch.\n";
  73 }
  74
  75
  76
  77 print "\n\n";
  78
  79 eval {
  80
  81     # This example shows that calling Error::throw directly within
  82     # an eval{} doesn't lead to a true value in $@ if
  83     # the error lacks a value.
  84
  85     print "[3] Attempting to throw a valueless Error within an eval{} block\n    (this should fail to be caught by Error.pm v0.13 but is caught by v0.14 and greater).\n";
  86
  87     if( $ENV{OSTYPE} =~ /cygwin/ ) {
  88         die "[3] This causes a segmentation fault with cygwin perl! Skipping.\n";
  89     }
  90
  91     throw Error::Simple ("A simple error.");
  92
  93 };
  94
  95 if($@) {
  96     print "[3] Caught eval{}-based exception: ", ref($@), "\n$@\n";
  97 }
  98 else {
  99     print "[3] Nothing to catch.\n";
 100 }
 101
 102
 103 print "\n\n";
 104
 105 eval {
 106
 107     # This example shows that calling Error::throw directly within
 108     # an eval{} *does* lead to a true value in $@ if the error
 109     # contains a non-zero value.
 110
 111     print "[4] Attempting to throw a valued Error within an eval{} block.\n";
 112
 113     throw Error::Simple ("A simple error.", 42);
 114
 115 };
 116
 117 if($@) {
 118     print "[4] Caught eval{}-based exception: ", ref($@), "\n$@\n";
 119 }
 120 else {
 121     print "[4] Nothing to catch.\n";
 122 }
 123
 124 print "\n\n";
 125
 126 if (!$main::DONT_USE_ERROR) {
 127     eval {
 128
 129         # This example shows what happens if we try to create a
 130         # Bio::Root::IOException (a subclass of Bio::Root::Exception)
 131         # with a zero value. Bio::Root::Exception::new() catches this
 132         # faux pas and substitutes a value that will register as true in if($@).
 133
 134         print "[5] Attempting to throw a zero-valued Bio::Root::IOException\n    within an eval{} block.\n";
 135
 136         throw Bio::Root::IOException ( -text =>"An error with zero value.",
 137                                    -value => 0);
 138
 139     };
 140
 141     if($@) {
 142         print "[5] Caught eval{}-based zero-valued exception: ", ref($@), "\n$@\n";
 143     }
 144     else {
 145         print "[5] Nothing to catch.\n";
 146     }
 147     print "\n\n";
 148 }
 149
 150
 151 eval {
 152
 153     # If Error::throw is called *indirectly* within an eval{}
 154     # (i.e., by calling a method which then calls Error::throw),
 155     # $@ is defined and it consists of a reference to the Error.pm object.
 156
 157     print "[6] Attempting to throw Error indirectly within an eval{} block \n    via Bio::Root::Root::throw()\n";
 158
 159     $foo->throw( -class => 'Bio::Root::Exception',
 160                  -text  => "Oopsie!",
 161                  -value => "456"
 162                 );
 163
 164 };
 165
 166 if($@) {
 167     print "[6] Caught eval{}-based exception: ", ref($@), "\n$@";
 168 }
 169 else {
 170     print "[6] Nothing to catch.\n";
 171 }
 172
 173 print "Done.\n";
 174
 175