Bio/Tools/SiRNA/Ruleset/saigo.pm

   1 # BioPerl module for Bio::Tools::SiRNA::Ruleset::saigo
   2 #
   3 # Please direct questions and support issues to <bioperl-l@bioperl.org>
   4 #
   5 # Cared for by Donald Jackson, donald.jackson@bms.com
   6 #
   7 # Copyright Bristol-Myers Squibb
   8 #
   9 # You may distribute this module under the same terms as perl itself
  10
  11 # POD documentation - main docs before the code
  12
  13 =head1 NAME
  14
  15 Bio::Tools::SiRNA::Ruleset::saigo - Perl object implementing the Saigo
  16 group's rules for designing small inhibitory RNAs
  17
  18 =head1 SYNOPSIS
  19
  20 Do not use this module directly.  Instead, use Bio::Tools::SiRNA and
  21 specify the saigo ruleset:
  22
  23   use Bio::Tools::SiRNA;
  24
  25   my $sirna_designer = Bio::Tools::SiRNA->new( -target => $bio_seq,
  26                                                -rules  => 'saigo'
  27     );
  28   my @pairs = $sirna_designer->design;
  29
  30   foreach $pair (@pairs) {
  31       my $sense_oligo_sequence = $pair->sense->seq;
  32       my $antisense_oligo_sequence = $pair->antisense->seq;
  33
  34       # print out results
  35       print join ("\t", $pair->start, $pair->end, $pair->rank,
  36                   $sense_oligo_sequence, $antisense_oligo_sequence), "\n";
  37   }
  38
  39 =head1 DESCRIPTION
  40
  41 This package implements the rules for designing siRNA reagents
  42 published by Ui-Tei et al (2004).  The rules are:
  43
  44 =over 5
  45
  46 =item 1.
  47
  48 The first base in the sense strand of the duplex must be a G or C
  49
  50 =item 2.
  51
  52 The first base in the antisense strand of the duplex must be an A or U
  53
  54 =item 3.
  55
  56 The first 7 nucleotides in the antisense strand of the duplex must be
  57 A or U
  58
  59 =item 4.
  60
  61 There cannot be more than 9 consecutive G or C nucleotides
  62
  63 =item 5.
  64
  65 The first 12 nucleotides in the sense strand of the duplex should have
  66 33-66% GC
  67
  68 =back
  69
  70 The module inherits from Bio::Tools::SiRNA.  See the documentation for
  71 that module for information on how to specify the target and recover
  72 the SiRNA duplex information.
  73
  74 =head2 EXPORT
  75
  76 None.
  77
  78 =head1 SEE ALSO
  79
  80 L<Bio::Tools::SiRNA>,
  81 L<Bio::SeqFeature::SiRNA::Pair>,
  82 L<Bio::SeqFeature::SiRNA::Oligo>.
  83
  84 =head1 FEEDBACK
  85
  86 =head2 Mailing Lists
  87
  88 User feedback is an integral part of the evolution of this and other
  89 Bioperl modules. Send your comments and suggestions preferably to
  90 the Bioperl mailing list.  Your participation is much appreciated.
  91
  92   bioperl-l@bioperl.org                  - General discussion
  93   http://bioperl.org/wiki/Mailing_lists  - About the mailing lists
  94
  95 =head2 Support
  96
  97 Please direct usage questions or support issues to the mailing list:
  98
  99 I<bioperl-l@bioperl.org>
 100
 101 rather than to the module maintainer directly. Many experienced and
 102 reponsive experts will be able look at the problem and quickly
 103 address it. Please include a thorough description of the problem
 104 with code and data examples if at all possible.
 105
 106 =head2 Reporting Bugs
 107
 108 Report bugs to the Bioperl bug tracking system to help us keep track
 109 of the bugs and their resolution. Bug reports can be submitted via
 110 the web:
 111
 112   https://github.com/bioperl/bioperl-live/issues
 113
 114 =head1 AUTHOR
 115
 116 Donald Jackson (donald.jackson@bms.com)
 117
 118 =head1 APPENDIX
 119
 120 The rest of the documentation details each of the object methods.
 121 Internal methods are usually preceded with a _
 122
 123 =cut
 124
 125 package Bio::Tools::SiRNA::Ruleset::saigo;
 126
 127 use strict;
 128 use warnings;
 129
 130 use base qw(Bio::Tools::SiRNA);
 131
 132 =head2 new
 133
 134   Title : new
 135   Usage  : Do not call directly - use Bio::Tools::SiRNA->new instead.
 136   Returns : Bio::Tools::SiRNA::Ruleset::saigo object
 137   Args  : none
 138
 139 =cut
 140
 141 sub new {
 142     my ($proto, %args) = @_;
 143     my $class = ref($proto) || $proto;
 144
 145     $args{'RULES'} = 'saigo';
 146
 147     return $class->SUPER::new(%args);
 148  }
 149
 150 sub _get_oligos {
 151     my ($self) = @_;
 152
 153     my ($targseq, $targstart) = $self->_get_targetregion;
 154
 155     foreach my $i (0 .. (length($targseq) - 23)) {
 156         my $testseq = substr($targseq, $i, 23);
 157         $self->add_oligos($testseq, $targstart + $i + 1) if ($self->_oligo_ok($testseq));
 158     }
 159 }
 160
 161
 162 sub _get_sense {
 163     my ($self, $target) = @_;
 164     #trim off 1st 2 nt to get overhang
 165     $target =~ s/^..//;
 166     #convert T's to U's (transcribe)
 167     $target =~ s/T/U/gi;
 168
 169     return $target;
 170 }
 171
 172 sub _get_anti {
 173     my ($self, $target) = @_;
 174     my @target = split(//, $target);
 175     my ($nt,@antitarget);
 176
 177     while ($nt = pop @target) {
 178         push(@antitarget, $self->_comp($nt));
 179     }
 180     my $anti = join('', @antitarget);
 181     #trim off 1st 2 nt to get overhang
 182     $anti =~ s/^..//;
 183     #convert T's to U's
 184     $anti =~ s/T/U/gi;
 185
 186     return $anti;
 187 }
 188
 189 sub _oligo_ok {
 190     my ($self, $testseq) = @_;
 191
 192     $self->debug("Testing $testseq...\n");
 193
 194     my @testseq = split(//, $testseq);
 195     # is 5p end of sense strand a G/C?
 196     unless ($testseq[2] =~ /[GC]/i) {
 197         $self->debug("No G/C at sense 5' end\n");
 198         return 0;
 199     }
 200     # is 5p end of antisense strand an A/T?
 201     unless ($testseq[20] =~ /[AT]/i) {
 202         $self->debug("No A/T at antisense 5' end\n");
 203         return 0;
 204     }
 205
 206     # are 4 of the last 7 bases in the duplex A/T?
 207     my $atcount_3p = grep { /[AT]/i } @testseq[14 .. 20];
 208     unless ($atcount_3p >= 4) {
 209         $self->debug("Found $atcount_3p A/T in last 7 bases of duplex\n");
 210         return 0;
 211     }
 212     # what is gc fraction in rest of duplex? Target: 33 to 66 pct gc (4-8 of 12)
 213     my $gccount_5p = grep { /[GC]/i } @testseq[2 .. 13];
 214     if ($gccount_5p < 4) {
 215         $self->debug("Found only $gccount_5p GCs in 5p end of duplex\n");
 216         return 0;
 217     }
 218     if ($gccount_5p > 8) {
 219         $self->debug("Found only $gccount_5p GCs in 5p end of duplex\n");
 220         return 0;
 221     }
 222
 223     # no more than 9 consecutive GC
 224     if ($testseq =~ /[GC]{9,}?/i) {
 225         $self->debug("Found more than 9 consecutive GCs\n");
 226         return 0;
 227     }
 228
 229     $self->debug("Oligo passed \n");
 230     return 1;
 231 }
 232
 233 1;