Build.PL

   1 #!/usr/bin/perl -w
   2
   3 # This is a Module::Build script for Bioperl installation.
   4 # See http://search.cpan.org/~kwilliams/Module-Build/lib/Module/Build.pm
   5
   6 # Uses a custom subclass of Module::Build called Bio::Root::Build
   7
   8 # In the future developers may need to alter the requires and recommends
   9 # sections of Bio::Root::Build->new() below, but otherwise nothing else here is
  10 # likely to need changing.
  11
  12 use strict;
  13 use lib '.';
  14 use Bio::Root::Build;
  15
  16 our @drivers;
  17
  18 my $mysql_ok = 0;
  19
  20 # Set up the Bio::Root::Build object
  21 my $build = Bio::Root::Build->new(
  22     module_name         => 'Bio',
  23     dist_name           => 'BioPerl',
  24     dist_version_from   => 'Bio/Root/Version.pm',
  25     dist_author         => 'BioPerl Team <bioperl-l@bioperl.org>',
  26     dist_abstract       => 'Bioinformatics Toolkit',
  27     license             => 'perl',
  28     requires            => {
  29                             'perl'                      => '5.6.1',
  30                             'IO::String'                => 0,
  31                             'DB_File'                   => 0,
  32                             'Data::Stag'                => 0.11, # Bio::SeqIO::swiss, we can change to 'recommend' if needed
  33                             'Scalar::Util'              => 0 # not in Perl 5.6.1, arrived in core in 5.7.3
  34                            },
  35     build_requires      => {
  36                             'Test::More'                => 0,
  37                             'Module::Build'             => 0.2805,
  38                             'Test::Harness'             => 2.62,
  39                             'CPAN'                      => 1.81
  40                            },
  41     recommends          => { # does what you would expect of recommends, except more informative output and generates optional_features in META.yml
  42                             'Ace'                       => '0/access of ACeDB database/Bio::DB::Ace,Bio::DB::GFF::Adaptor::ace',
  43                             'Algorithm::Munkres'        => '0/Phylogenetic Networks/Bio::PhyloNetwork',
  44                             'Array::Compare'            => '0/Phylogenetic Networks/Bio::PhyloNetwork',
  45                             # this won't actually install due to circular dep, but we have no way of doing a post-install
  46                             # the [circular dependency!] specifies it is only installed on explicit request for this specific module,
  47                             # not when simply choosing to install 'all' modules
  48                             'Bio::ASN1::EntrezGene'     => '0/parsing entrezgene/Bio::SeqIO::entrezgene [circular dependency!]',
  49                             # we actually need 1.01 of Class::AutoClass, but unfortunately it is versioned as 1.0
  50                             'Clone'                     => '0/cloning objects/Bio::Tools::Primer3',
  51                             'Convert::Binary::C'        => '0/strider functionality/Bio::SeqIO::strider',
  52                             # we specifically want Graph::Directed, but that has no VERSION
  53                             'Graph'                     => '0/ontology engine implementation for the GO parser/Bio::PhyloNetwork',
  54                             'GraphViz'                  => '0/Phylogenetic Network Visulization/Bio::PhyloNetwork::GraphViz',
  55                             'HTML::Entities'            => '0/remote analysis POST submissions/Bio::SearchIO::blastxml',
  56                             'HTML::HeadParser'          => '3/parsing <HEAD> section of HTML docs/Bio::Tools::Analysis::DNA::ESEfinder',
  57                             'HTTP::Request::Common'     => '0/GenBank+GenPept sequence retrieval, remote http Blast jobs/Bio::DB::*,Bio::Tools::Run::RemoteBlast,Bio::Tools::Analysis::Protein*,Bio::Tools::Analysis::DNA*',
  58                             'LWP::UserAgent'            => '0/remote access/Bio::DB::*,Bio::Tools::Run::RemoteBlast,Bio::WebAgent',
  59                             'Math::Random'              => '0/Random Phylogenetic Networks/Bio::PhyloNetwork::RandomFactory',
  60                             'PostScript::TextBlock'     => '0/EPS output/Bio::Tree::Draw::Cladogram',
  61                             'Set::Scalar'               => '0/proper operation/Bio::Tree::Compatible',
  62                             'SOAP::Lite'                => '0/Bibliographic queries/Bio::DB::Biblio::soap',
  63                             'Spreadsheet::ParseExcel'   => '0/parsing Excel files/Bio::SeqIO::excel',
  64                             'Storable'                  => '2.05/storing sequence objects in local file cache/Bio::DB::FileCache,Bio::SeqFeature::Collection,Bio::PopGen::HtSNP,Bio::PopGen::TagHaplotype,Bio::DB::GFF::Adaptor::berkeleydb',
  65                             'SVG::Graph'                => '0.01/creating SVG images/Bio::TreeIO::svggraph',
  66                             'Text::ParseWords'          => '0/test scripts/Bio::DB::SeqFeature::Store::FeatureFileLoader',
  67                             'URI::Escape'               => '0/dealing with web resources/Bio::FeatureIO::gff,Bio::FeatureIO::interpro,Bio::DB::Biblio::eutils,Bio::DB::EUtilParameters,Bio::DB::Query::GenBank,Bio::DB::NCBIHelper,Bio::SeqFeature::Annotated',
  68                             'XML::DOM::XPath'           => '0.13/parsing interpro features/Bio::FeatureIO::interpro',
  69                             'XML::Parser'               => '0/parsing xml/Bio::Biblio::IO::medlinexml',
  70                             'XML::Parser::PerlSAX'      => '0/parsing xml/Bio::SeqIO::tinyseq,Bio::SeqIO::game::gameSubs,Bio::OntologyIO::InterProParser,Bio::ClusterIO::dbsnp',
  71                             'XML::SAX'                  => '0.15/parsing xml/Bio::SearchIO::blastxml,Bio::SeqIO::tigrxml,Bio::SeqIO::bsml_sax',
  72                             'XML::SAX::Writer'          => '0/writing xml/Bio::SeqIO::tigrxml',
  73                             'XML::Twig'                 => '0/parsing xml/Bio::Variation::IO::xml,Bio::DB::Taxonomy::entrez,Bio::DB::Biblio::eutils',
  74                             'XML::Writer'               => '0.4/parsing and writing xml/Bio::SeqIO::agave,Bio::SeqIO::game::gameWriter,Bio::SeqIO::chadoxml,Bio::SeqIO::tinyseq,Bio::Variation::IO::xml,Bio::SearchIO::Writer::BSMLResultWriter',
  75     },
  76     get_options         => {
  77                             network => { } # say 'perl Build.PL --network' to manually request network tests
  78                            },
  79     auto_features       => {
  80                             BioDBSeqFeature_BDB   => {
  81                                                         description      => "BDB tests for Bio::DB::SeqFeature::Store",
  82                                                         feature_requires => { 'DB_File' => 0 } # feature_requires is like requires, except that it doesn't trigger installation
  83                                                      },
  84                             BioDBGFF              => {
  85                                                         description      => "BioDBGFF database tests (will need to answer questions before really enabling)",
  86                                                         feature_requires => { 'DBI' => 0 },
  87                                                         excludes_os      => ['mswin'],
  88                                                         test             => \&test_biodbgff # Bio::Root::Build unique requirement that after everything else succeeds, supplied code ref must also return undef
  89                                                      },
  90                             BioDBSeqFeature_mysql => {
  91                                                         description      => "MySQL tests for Bio::DB::SeqFeature::Store",
  92                                                         feature_requires => { 'DBI' => 0, 'DBD::mysql' => 0 },
  93                                                         test             => \&test_db_sf
  94                                                      },
  95                             Network               => {
  96                                                         description => "Enable tests that need an internet connection",
  97                                                         requires    => { 'LWP::UserAgent' => 0 },
  98                                                         test        => \&Bio::Root::Build::test_internet
  99                                                      }
 100                            },
 101     dynamic_config      => 1,
 102     create_makefile_pl  => 'passthrough',
 103     recursive_test_files => 1,
 104     # Extra files needed for BioPerl modules
 105     xml_files => {'./Bio/DB/HIV/lanl-schema.xml' => 'lib/Bio/DB/HIV/lanl-schema.xml'},
 106
 107     #pm_files           => {} # modules in Bio are treated as if they were in lib and auto-installed
 108     #script_files       => [] # scripts in scripts directory are installed on-demand
 109 );
 110
 111 my $accept = $build->args->{accept};
 112
 113 my $proceed = prompt_for_biodb($accept) if $build->feature('BioDBGFF') || $build->feature('BioDBSeqFeature_mysql');
 114
 115 # Handle auto features
 116 if ($proceed && $build->feature('BioDBSeqFeature_BDB')) {
 117     # will return without doing anything if user chose not to run tests during
 118     # prompt_for_biodb() above
 119     make_bdb_test();
 120 }
 121 if ($proceed && ($build->feature('BioDBSeqFeature_mysql'))) {
 122     make_dbi_test();
 123 }
 124
 125 # Ask questions
 126 $build->choose_scripts($accept);
 127 #prompt_for_biodbgff($accept) if $build->feature('BioDBGFF');
 128 {
 129     if ($build->args('network')) {
 130         if ($build->feature('Network')) {
 131             $build->notes(network => 1);
 132             $build->log_info("  - will run internet-requiring tests\n");
 133         }
 134         else {
 135             $build->notes(network => 0);
 136             $build->log_info("  - will not run network tests since I seem to be missing essential network functionality\n");
 137         }
 138     }
 139     else {
 140         $build->prompt_for_network($accept) if $build->feature('Network');
 141     }
 142     # then in test script:
 143     #   use Bio::Root::Build;
 144     #   my $build = Module::Build->current;
 145     #   my $do_network_tests = $build->notes('network');
 146 }
 147
 148 # Request that some scripts run post-installation
 149 $build->add_post_install_script('maintenance/symlink_script.pl'); # takes a unix file path regardless of local OS
 150
 151 # Add extra things to MANIFEST.SKIP
 152 $build->add_to_manifest_skip('bioperl.lisp');
 153
 154 # Add additional files here
 155 $build->add_build_element('xml');
 156
 157 # Create the build script and exit
 158 $build->create_build_script;
 159
 160 exit;
 161
 162 sub make_bdb_test {
 163     my $path0 = File::Spec->catfile('t', 'LocalDB', 'SeqFeature.t');
 164     my $path = File::Spec->catfile('t', 'LocalDB','SeqFeature_BDB.t');
 165     unlink($path) if (-e $path);
 166     open(my $F, ">", $path) || die "Can't create test file\n";
 167     print $F <<END;
 168 system '$^X $path0 -adaptor berkeleydb -create 1 -temp 1';
 169 END
 170     close $F;
 171     $build->add_to_cleanup($path);
 172     $build->add_to_manifest_skip($path);
 173 }
 174
 175 sub test_db_sf {
 176     eval {require DBI;};  # if not installed, this sub won't actually be called
 177     @drivers = DBI->available_drivers;
 178     unless (grep {/mysql/i} @drivers) {
 179         $mysql_ok = 0;
 180         return "Only MySQL driver is supported for Bio::DB::SeqFeature RDMS tests";
 181     }
 182     $mysql_ok = 1;
 183     return;
 184 }
 185
 186 sub make_dbi_test {
 187     my $dsn = $build->notes('test_dsn') || return;
 188     my $path0 = File::Spec->catfile('t', 'LocalDB', 'SeqFeature.t');
 189     my $driver = $build->notes('dbd_driver');
 190     my $path = File::Spec->catfile('t', 'LocalDB', 'SeqFeature_mysql.t' );
 191     my $test_db = $build->notes('test_db');
 192     my $user = $build->notes('test_user');
 193     my $pass = $build->notes('test_pass');
 194     open my $F,">$path";
 195     my $str = "$path0 -adaptor DBI::$driver -create 1 -temp 1 -dsn $dsn";
 196     $str .= " -user $user" if $user;
 197     $str .= " -password $pass" if $pass;
 198     print $F <<END;
 199 system '$^X $str';
 200 END
 201     close $F;
 202     $build->add_to_cleanup($path);
 203     $build->add_to_manifest_skip($path);
 204 }
 205
 206 sub test_biodbgff {
 207     eval {require DBI;};  # if not installed, this sub won't actually be called
 208     @drivers = DBI->available_drivers;
 209     unless (grep {/mysql|Pg|Oracle/i} @drivers) {
 210         return "MySQL, Pg nor Oracle DBI drivers are installed";
 211     }
 212     return;
 213 }
 214
 215 sub prompt_for_biodb {
 216     my $accept = shift;
 217     my $proceed = $accept ? 0 : $build->y_n("Do you want to run the Bio::DB::GFF or ".
 218                               "Bio::DB::SeqFeature::Store live database tests? ".
 219                               "y/n", 'n');
 220
 221     if ($proceed) {
 222         my @driver_choices;
 223         foreach my $poss ('mysql', 'Pg', 'Oracle') {
 224             if (grep {/$poss/i} @drivers) {
 225                 my $choice = $poss;
 226                 $choice =~ s/^(.)/[$1]/;
 227                 push(@driver_choices, $choice);
 228             }
 229         }
 230
 231         my $driver;
 232         if (@driver_choices > 1) {
 233             my ($default) = $driver_choices[0] =~ /\[(.)/;
 234             $driver = $build->prompt("Which database driver should be used? ".join(" ", @driver_choices), $default);
 235         }
 236         else {
 237             ($driver) = $driver_choices[0] =~ /\[(.)/;
 238         }
 239         if ($driver =~ /^[mM]/) {
 240             $driver = 'mysql';
 241         }
 242         elsif ($driver =~ /^[pP]/) {
 243             $driver = 'Pg';
 244         }
 245         elsif ($driver =~ /^[oO]/) {
 246             $driver = 'Oracle';
 247         }
 248
 249         my $test_db = $build->prompt("Which database should I use for testing the $driver driver?\n".
 250                                      "This database should already be present but doesn't have to ".
 251                                      "be preloaded for any schema", 'test');
 252         my $test_host = $build->prompt("On which host is database '$test_db' running (hostname, ip address or host:port)", 'localhost');
 253         my $test_user = $build->prompt("User name for connecting to database '$test_db'?", 'undef');
 254         my $test_pass = $build->prompt("Password for connecting to database '$test_db'?", 'undef');
 255
 256         my $use_host = 1;
 257         if ($test_host eq 'undef' || $test_host eq 'localhost') {
 258             $use_host = 0;
 259         }
 260
 261         my $test_dsn;
 262         if ($driver eq 'Pg') {
 263             $test_dsn = "dbi:$driver:dbname=$test_db";
 264             $mysql_ok = 0;
 265         }
 266         else {
 267             $test_dsn = "dbi:$driver:database=$test_db";
 268             $mysql_ok = 0;
 269         }
 270         if ($use_host) {
 271             $test_dsn .= ";host=$test_host";
 272         }
 273
 274         $build->notes(dbd_driver => $driver);
 275         $build->notes(test_db => $test_db);
 276         $build->notes(test_host => $test_host);
 277         $build->notes(test_user => $test_user eq 'undef' ? undef : $test_user);
 278         $build->notes(test_pass => $test_pass eq 'undef' ? undef : $test_pass);
 279         $build->notes(test_dsn => $test_dsn);
 280
 281         $build->log_info("  - will run tests with database driver '$driver' and these settings:\n",
 282                         "    Database $test_db\n",
 283                         "    Host     $test_host\n",
 284                         "    DSN      $test_dsn\n",
 285                         "    User     $test_user\n",
 286                         "    Password $test_pass\n");
 287         $build->log_info("  - will not run the BioDBSeqFeature live ".
 288                          "database tests (requires MySQL driver)\n") unless ($driver eq 'mysql');
 289     }
 290     else {
 291         $build->log_info("  - will not run the BioDBGFF or BioDBSeqFeature live database tests\n");
 292     }
 293
 294     $build->log_info("\n");
 295     return $proceed;
 296 }