Bio/PrimarySeq.pm

   1 #
   2 # bioperl module for Bio::PrimarySeq
   3 #
   4 # Please direct questions and support issues to <bioperl-l@bioperl.org>
   5 #
   6 # Cared for by Ewan Birney <birney@ebi.ac.uk>
   7 #
   8 # Copyright Ewan Birney
   9 #
  10 # You may distribute this module under the same terms as perl itself
  11
  12 # POD documentation - main docs before the code
  13
  14 =head1 NAME
  15
  16 Bio::PrimarySeq - Bioperl lightweight Sequence Object
  17
  18 =head1 SYNOPSIS
  19
  20   # Bio::SeqIO for file reading, Bio::DB::GenBank for
  21   # database reading
  22
  23   use Bio::Seq;
  24   use Bio::SeqIO;
  25   use Bio::DB::GenBank;
  26
  27   # make from memory
  28
  29   $seqobj = Bio::PrimarySeq->new ( -seq => 'ATGGGGTGGGCGGTGGGTGGTTTG',
  30                                    -id  => 'GeneFragment-12',
  31                                    -accession_number => 'X78121',
  32                                    -alphabet => 'dna',
  33                                    -is_circular => 1 );
  34   print "Sequence ", $seqobj->id(), " with accession ",
  35     $seqobj->accession_number, "\n";
  36
  37   # read from file
  38
  39   $inputstream = Bio::SeqIO->new(-file => "myseq.fa",
  40                                  -format => 'Fasta');
  41   $seqobj = $inputstream->next_seq();
  42   print "Sequence ", $seqobj->id(), " and desc ", $seqobj->desc, "\n";
  43
  44   # to get out parts of the sequence.
  45
  46   print "Sequence ", $seqobj->id(), " with accession ",
  47     $seqobj->accession_number, " and desc ", $seqobj->desc, "\n";
  48
  49   $string  = $seqobj->seq();
  50   $string2 = $seqobj->subseq(1,40);
  51
  52 =head1 DESCRIPTION
  53
  54 PrimarySeq is a lightweight Sequence object, storing the sequence, its
  55 name, a computer-useful unique name, and other fundamental attributes.
  56 It does not contain sequence features or other information.  To have a
  57 sequence with sequence features you should use the Seq object which uses
  58 this object.
  59
  60 Although new users will use Bio::PrimarySeq a lot, in general you will
  61 be using it from the Bio::Seq object. For more information on Bio::Seq
  62 see L<Bio::Seq>. For interest you might like to know that
  63 Bio::Seq has-a Bio::PrimarySeq and forwards most of the function calls
  64 to do with sequence to it (the has-a relationship lets us get out of a
  65 otherwise nasty cyclical reference in Perl which would leak memory).
  66
  67 Sequence objects are defined by the Bio::PrimarySeqI interface, and this
  68 object is a pure Perl implementation of the interface. If that's
  69 gibberish to you, don't worry. The take home message is that this
  70 object is the bioperl default sequence object, but other people can
  71 use their own objects as sequences if they so wish. If you are
  72 interested in wrapping your own objects as compliant Bioperl sequence
  73 objects, then you should read the Bio::PrimarySeqI documentation
  74
  75 The documentation of this object is a merge of the Bio::PrimarySeq and
  76 Bio::PrimarySeqI documentation.  This allows all the methods which you can
  77 call on sequence objects here.
  78
  79 =head1 FEEDBACK
  80
  81 =head2 Mailing Lists
  82
  83 User feedback is an integral part of the evolution of this and other
  84 Bioperl modules. Send your comments and suggestions preferably to one
  85 of the Bioperl mailing lists.  Your participation is much appreciated.
  86
  87   bioperl-l@bioperl.org                  - General discussion
  88   http://bioperl.org/wiki/Mailing_lists  - About the mailing lists
  89
  90 =head2 Support
  91
  92 Please direct usage questions or support issues to the mailing list:
  93
  94 I<bioperl-l@bioperl.org>
  95
  96 rather than to the module maintainer directly. Many experienced and
  97 reponsive experts will be able look at the problem and quickly
  98 address it. Please include a thorough description of the problem
  99 with code and data examples if at all possible.
 100
 101 =head2 Reporting Bugs
 102
 103 Report bugs to the Bioperl bug tracking system to help us keep track
 104 the bugs and their resolution.  Bug reports can be submitted via the
 105 web:
 106
 107   https://redmine.open-bio.org/projects/bioperl/
 108
 109 =head1 AUTHOR - Ewan Birney
 110
 111 Email birney@ebi.ac.uk
 112
 113 =head1 APPENDIX
 114
 115 The rest of the documentation details each of the object
 116 methods. Internal methods are usually preceded with a _
 117
 118 =cut
 119
 120
 121 # Let the code begin...
 122
 123
 124 package Bio::PrimarySeq;
 125 use vars qw($MATCHPATTERN $GAP_SYMBOLS);
 126 use strict;
 127
 128 $MATCHPATTERN = 'A-Za-z\-\.\*\?=~';
 129 $GAP_SYMBOLS = '-~';
 130
 131 use base qw(Bio::Root::Root Bio::PrimarySeqI
 132             Bio::IdentifiableI Bio::DescribableI);
 133
 134 #
 135 # setup the allowed values for alphabet()
 136 #
 137
 138 my %valid_type = map {$_, 1} qw( dna rna protein );
 139
 140 =head2 new
 141
 142  Title   : new
 143  Usage   : $seq    = Bio::PrimarySeq->new( -seq => 'ATGGGGGTGGTGGTACCCT',
 144                                            -id  => 'human_id',
 145                                            -accession_number => 'AL000012',
 146                                            );
 147
 148  Function: Returns a new primary seq object from
 149            basic constructors, being a string for the sequence
 150            and strings for id and accession_number.
 151
 152            Note that you can provide an empty sequence string. However, in
 153            this case you MUST specify the type of sequence you wish to
 154            initialize by the parameter -alphabet. See alphabet() for possible
 155            values.
 156  Returns : a new Bio::PrimarySeq object
 157  Args    : -seq              => sequence string
 158            -display_id       => display id of the sequence (locus name)
 159            -accession_number => accession number
 160            -primary_id       => primary id (Genbank id)
 161            -version          => version number
 162            -namespace        => the namespace for the accession
 163            -authority        => the authority for the namespace
 164            -description      => description text
 165            -desc             => alias for description
 166            -alphabet         => sequence type (alphabet) (dna|rna|protein)
 167            -id               => alias for display id
 168            -is_circular      => boolean field for whether or not sequence is circular
 169            -direct           => boolean field for directly setting sequence (requires alphabet also set)
 170            -ref_to_seq       => boolean field indicating the sequence is a reference (?!?)
 171            -nowarnonempty    => boolean field for whether or not to warn when sequence is empty
 172
 173 =cut
 174
 175
 176 sub new {
 177     my ($class, @args) = @_;
 178     my $self = $class->SUPER::new(@args);
 179
 180     my($seq,$id,$acc,$pid,$ns,$auth,$v,$oid,
 181        $desc,$description,
 182        $alphabet,$given_id,$is_circular,$direct,$ref_to_seq,$len,$nowarnonempty) =
 183       $self->_rearrange([qw(SEQ
 184                             DISPLAY_ID
 185                             ACCESSION_NUMBER
 186                             PRIMARY_ID
 187                             NAMESPACE
 188                             AUTHORITY
 189                             VERSION
 190                             OBJECT_ID
 191                             DESC
 192                             DESCRIPTION
 193                             ALPHABET
 194                             ID
 195                             IS_CIRCULAR
 196                             DIRECT
 197                             REF_TO_SEQ
 198                             LENGTH
 199                             NOWARNONEMPTY
 200                             )],
 201                             @args);
 202
 203     # private var _nowarnonempty, need to be set before calling _guess_alphabet
 204     $self->{'_nowarnonempty'} = $nowarnonempty;
 205
 206     if( defined $id && defined $given_id ) {
 207       if( $id ne $given_id ) {
 208         $self->throw("Provided both id and display_id constructor ".
 209             "functions. [$id] [$given_id]");
 210       }
 211     }
 212     if( defined $given_id ) { $id = $given_id; }
 213
 214     # let's set the length before the seq -- if there is one, this length is
 215     # going to be invalidated
 216     defined $len && $self->length($len);
 217
 218     # if alphabet is provided we set it first, so that it won't be guessed
 219     # when the sequence is set
 220     $alphabet && $self->alphabet($alphabet);
 221
 222     # bernd's idea: define ids so that invalid sequence messages
 223     # can be more informative...
 224     defined $id  && $self->display_id($id);
 225     $acc         && $self->accession_number($acc);
 226     defined $pid && $self->primary_id($pid);
 227
 228     # if there is an alphabet, and direct is passed in, assume the alphabet
 229     # and sequence is ok
 230
 231     if( $direct && $ref_to_seq) {
 232       $self->{'seq'} = $$ref_to_seq;
 233         if( ! $alphabet ) {
 234           $self->_guess_alphabet();
 235         } # else it has been set already above
 236     } else {
 237         # print STDERR "DEBUG: setting sequence to [$seq]\n";
 238         # note: the sequence string may be empty
 239         $self->seq($seq) if defined($seq);
 240     }
 241
 242     $desc        && $self->desc($desc);
 243     $description && $self->description($description);
 244     $is_circular && $self->is_circular($is_circular);
 245     $ns          && $self->namespace($ns);
 246     $auth        && $self->authority($auth);
 247     defined($v)  && $self->version($v);
 248     defined($oid) && $self->object_id($oid);
 249
 250
 251     return $self;
 252 }
 253
 254 sub direct_seq_set {
 255     my $obj = shift;
 256     return $obj->{'seq'} = shift if @_;
 257     return;
 258 }
 259
 260
 261 =head2 seq
 262
 263  Title   : seq
 264  Usage   : $string = $obj->seq();
 265  Function: Returns the sequence as a string of letters. The
 266            case of the letters is left up to the implementer.
 267            Suggested cases are upper case for proteins and lower case for
 268            DNA sequence (IUPAC standard), but you should not rely on this.
 269  Returns : A scalar
 270  Args    : Optionally on set the new value (a string). An optional second
 271            argument presets the alphabet (otherwise it will be guessed).
 272
 273 =cut
 274
 275 sub seq {
 276    my ($obj,@args) = @_;
 277
 278    if( scalar(@args) == 0 ) {
 279        return $obj->{'seq'};
 280    }
 281
 282    my ($value,$alphabet) = @args;
 283
 284    if(@args) {
 285        if(defined($value) && (! $obj->validate_seq($value))) {
 286            $obj->throw("Attempting to set the sequence '".(defined($obj->id) ||
 287                "[unidentified sequence]")."' to [$value] which does not look healthy");
 288        }
 289        # if a sequence was already set we make sure that we re-adjust the
 290        # alphabet, otherwise we skip guessing if alphabet is already set
 291        # note: if the new seq is empty or undef, we don't consider that a
 292        # change (we wouldn't have anything to guess on anyway)
 293        my $is_changed_seq =
 294          exists($obj->{'seq'}) && (CORE::length($value || '') > 0);
 295        $obj->{'seq'} = $value;
 296        # new alphabet overridden by arguments?
 297        if($alphabet) {
 298            # yes, set it no matter what
 299            $obj->alphabet($alphabet);
 300        } elsif ($is_changed_seq || (! defined($obj->alphabet()))) {
 301            # if we changed a previous sequence to a new one or if there is no
 302            # alphabet yet at all, we need to guess the (possibly new) alphabet
 303            $obj->_guess_alphabet();
 304        } # else (seq not changed and alphabet was defined) do nothing
 305        # if the seq is changed, make sure we unset a possibly set length
 306        $obj->length(undef) if $is_changed_seq || $obj->{'seq'};
 307    }
 308    return $obj->{'seq'};
 309 }
 310
 311 =head2 validate_seq
 312
 313  Title   : validate_seq
 314  Usage   : if(! $seq->validate_seq($seq_str) ) {
 315                 print "sequence $seq_str is not valid for an object of
 316                 alphabet ",$seq->alphabet, "\n";
 317            }
 318  Function: Validates a given sequence string. A validating sequence string
 319            must be accepted by seq(). A string that does not validate will
 320            lead to an exception if passed to seq().
 321
 322            The implementation provided here does not take alphabet() into
 323            account. Allowed are all letters (A-Z) and '-','.','*','?','=',
 324            and '~'.
 325
 326  Example :
 327  Returns : 1 if the supplied sequence string is valid for the object, and
 328            0 otherwise.
 329  Args    : The sequence string to be validated.
 330
 331
 332 =cut
 333
 334 sub validate_seq {
 335     my ($self,$seqstr) = @_;
 336     if( ! defined $seqstr ){ $seqstr = $self->seq(); }
 337     return 0 unless( defined $seqstr);
 338     if((CORE::length($seqstr) > 0) &&
 339         ($seqstr !~ /^([$MATCHPATTERN]+)$/)) {
 340             $self->warn("sequence '".(defined($self->id) || "[unidentified sequence]").
 341             "' doesn't validate, mismatch is " .
 342             join(",",($seqstr =~ /([^$MATCHPATTERN]+)/g)));
 343         return 0;
 344     }
 345     return 1;
 346 }
 347
 348 =head2 subseq
 349
 350  Title   : subseq
 351  Usage   : $substring = $obj->subseq(10,40);
 352            $substring = $obj->subseq(10,40,NOGAP)
 353            $substring = $obj->subseq(-START=>10,-END=>40,-REPLACE_WITH=>'tga')
 354  Function: returns the subseq from start to end, where the first sequence
 355            character has coordinate 1 number is inclusive, ie 1-2 are the
 356            first two characters of the sequence
 357  Returns : a string
 358  Args    : integer for start position
 359            integer for end position
 360                  OR
 361            Bio::LocationI location for subseq (strand honored)
 362            Specify -NOGAP=>1 to return subseq with gap characters removed
 363            Specify -REPLACE_WITH=>$new_subseq to replace the subseq returned
 364            with $new_subseq in the sequence object
 365
 366 =cut
 367
 368 sub subseq {
 369    my $self = shift;
 370    my @args = @_;
 371    my ($start,$end,$nogap,$replace) = $self->_rearrange([qw(START
 372                                                             END
 373                                                             NOGAP
 374                                                             REPLACE_WITH)],@args);
 375
 376    # if $replace is specified, have the constructor validate it as seq
 377    my $dummy = new Bio::PrimarySeq(-seq=>$replace, -alphabet=>$self->alphabet) if defined($replace);
 378
 379    if( ref($start) && $start->isa('Bio::LocationI') ) {
 380        my $loc = $start;
 381        my $seq = "";
 382        foreach my $subloc ($loc->each_Location()) {
 383            my $piece = $self->subseq(-START=>$subloc->start(),
 384                                      '-END'=>$subloc->end(),
 385                                      -REPLACE_WITH=>$replace,
 386                                      -NOGAP=>$nogap);
 387            $piece =~ s/[$GAP_SYMBOLS]//g if $nogap;
 388            if($subloc->strand() < 0) {
 389                $piece = Bio::PrimarySeq->new('-seq' => $piece)->revcom()->seq();
 390            }
 391            $seq .= $piece;
 392        }
 393        return $seq;
 394    } elsif(  defined  $start && defined $end ) {
 395        if( $start > $end ){
 396            $self->throw("Bad start,end parameters. Start [$start] has to be ".
 397              "less than end [$end]");
 398        }
 399        if( $start <= 0 ) {
 400            $self->throw("Bad start parameter ($start). Start must be positive.");
 401        }
 402
 403        # remove one from start, and then length is end-start
 404        $start--;
 405        my @ss_args = map { eval "defined $_"  ? $_ : () } qw( $self->{seq} $start $end-$start $replace);
 406        my $seqstr = eval join( '', "substr(", join(',',@ss_args), ")");
 407
 408        if( $end > $self->length) {
 409            if ($self->is_circular) {
 410                my $start = 0;
 411                my $end = $end - $self->length;
 412                my @ss_args = map { eval "defined $_"  ? $_ : () } qw( $self->{seq} $start $end-$start $replace);
 413                my $appendstr = eval join( '', "substr(", join(',',@ss_args), ")");
 414                $seqstr .= $appendstr;
 415        } else {
 416            $self->throw("Bad end parameter ($end). End must be less than the total length of sequence (total=".$self->length.")")
 417            }
 418        }
 419
 420        $seqstr =~ s/[$GAP_SYMBOLS]//g if ($nogap);
 421        return $seqstr;
 422
 423    } else {
 424        $self->warn("Incorrect parameters to subseq - must be two integers or a Bio::LocationI object. Got:", $self,$start,$end,$replace,$nogap);
 425        return;
 426    }
 427 }
 428
 429 =head2 length
 430
 431  Title   : length
 432  Usage   : $len = $seq->length();
 433  Function: Get the length of the sequence in number of symbols (bases
 434            or amino acids).
 435
 436            You can also set this attribute, even to a number that does
 437            not match the length of the sequence string. This is useful
 438            if you don''t want to set the sequence too, or if you want
 439            to free up memory by unsetting the sequence. In the latter
 440            case you could do e.g.
 441
 442                $seq->length($seq->length);
 443                $seq->seq(undef);
 444
 445            Note that if you set the sequence to a value other than
 446            undef at any time, the length attribute will be
 447            invalidated, and the length of the sequence string will be
 448            reported again. Also, we won''t let you lie about the length.
 449
 450  Example :
 451  Returns : integer representing the length of the sequence.
 452  Args    : Optionally, the value on set
 453
 454 =cut
 455
 456 sub length {
 457     my ($self, $val) = @_;
 458     if (defined $val) {
 459         my $len = CORE::length($self->seq() || '');
 460         if ($len && ($len != $val)) {
 461             $self->throw("You're trying to lie about the length: ".
 462                 "is $len but you say ".$val);
 463         }
 464         $self->{'_seq_length'} = $val;
 465         return $val;
 466     } else {
 467         if (defined $self->{'_seq_length'}) {
 468            return $self->{'_seq_length'};
 469         } else {
 470            return CORE::length($self->seq() || '');
 471         }
 472     }
 473 }
 474
 475
 476 =head2 display_id
 477
 478  Title   : display_id or display_name
 479  Usage   : $id_string = $obj->display_id();
 480  Function: returns the display id, aka the common name of the Sequence object.
 481
 482            The semantics of this is that it is the most likely string to
 483            be used as an identifier of the sequence, and likely to have
 484            "human" readability.  The id is equivalent to the ID field of
 485            the GenBank/EMBL databanks and the id field of the
 486            Swissprot/sptrembl database. In fasta format, the >(\S+) is
 487            presumed to be the id, though some people overload the id to
 488            embed other information. Bioperl does not use any embedded
 489            information in the ID field, and people are encouraged to use
 490            other mechanisms (accession field for example, or extending
 491            the sequence object) to solve this.
 492
 493            With the new Bio::DescribeableI interface, display_name aliases
 494            to this method.
 495
 496  Returns : A string
 497  Args    : None
 498
 499
 500 =cut
 501
 502 sub display_id {
 503    my ($obj,$value) = @_;
 504    if( defined $value) {
 505       $obj->{'display_id'} = $value;
 506     }
 507     return $obj->{'display_id'};
 508 }
 509
 510 =head2 accession_number
 511
 512  Title   : accession_number or object_id
 513  Usage   : $unique_key = $obj->accession_number;
 514  Function: Returns the unique biological id for a sequence, commonly
 515            called the accession_number. For sequences from established
 516            databases, the implementors should try to use the correct
 517            accession number. Notice that primary_id() provides the
 518            unique id for the implemetation, allowing multiple objects
 519            to have the same accession number in a particular implementation.
 520
 521            For sequences with no accession number, this method should
 522            return "unknown".
 523
 524            [Note this method name is likely to change in 1.3]
 525
 526            With the new Bio::IdentifiableI interface, this is aliased
 527            to object_id
 528
 529  Returns : A string
 530  Args    : A string (optional) for setting
 531
 532 =cut
 533
 534 sub accession_number {
 535     my( $obj, $acc ) = @_;
 536
 537     if (defined $acc) {
 538         $obj->{'accession_number'} = $acc;
 539     } else {
 540         $acc = $obj->{'accession_number'};
 541         $acc = 'unknown' unless defined $acc;
 542     }
 543     return $acc;
 544 }
 545
 546 =head2 primary_id
 547
 548  Title   : primary_id
 549  Usage   : $unique_key = $obj->primary_id;
 550  Function: Returns the unique id for this object in this
 551            implementation. This allows implementations to manage their
 552            own object ids in a way the implementaiton can control
 553            clients can expect one id to map to one object.
 554
 555            For sequences with no natural primary id, this method
 556            should return a stringified memory location.
 557
 558  Returns : A string
 559  Args    : A string (optional, for setting)
 560
 561 =cut
 562
 563 sub primary_id {
 564     my $obj = shift;
 565
 566     if(@_) {
 567         $obj->{'primary_id'} = shift;
 568     }
 569     if( ! defined($obj->{'primary_id'}) ) {
 570         return "$obj";
 571     }
 572     return $obj->{'primary_id'};
 573 }
 574
 575
 576 =head2 alphabet
 577
 578  Title   : alphabet
 579  Usage   : if( $obj->alphabet eq 'dna' ) { /Do Something/ }
 580  Function: Get/Set the alphabet of sequence, one of
 581            'dna', 'rna' or 'protein'. This is case sensitive.
 582
 583            This is not called <type> because this would cause
 584            upgrade problems from the 0.5 and earlier Seq objects.
 585
 586  Returns : a string either 'dna','rna','protein'. NB - the object must
 587            make a call of the type - if there is no alphabet specified it
 588            has to guess.
 589  Args    : optional string to set : 'dna' | 'rna' | 'protein'
 590
 591
 592 =cut
 593
 594 sub alphabet {
 595     my ($obj,$value) = @_;
 596     if (defined $value) {
 597         $value = lc $value;
 598         unless ( $valid_type{$value} ) {
 599         $obj->throw("Alphabet '$value' is not a valid alphabet (".
 600             join(',', map "'$_'", sort keys %valid_type) .") lowercase");
 601         }
 602         $obj->{'alphabet'} = $value;
 603     }
 604     return $obj->{'alphabet'};
 605 }
 606
 607 =head2 desc
 608
 609  Title   : desc or description
 610  Usage   : $obj->desc($newval)
 611  Function: Get/set description of the sequence.
 612
 613            'description' is an alias for this for compliance with the
 614            Bio::DescribeableI interface.
 615
 616  Example :
 617  Returns : value of desc (a string)
 618  Args    : newvalue (a string or undef, optional)
 619
 620
 621 =cut
 622
 623 sub desc{
 624     my $self = shift;
 625
 626     return $self->{'desc'} = shift if @_;
 627     return $self->{'desc'};
 628 }
 629
 630 =head2 can_call_new
 631
 632  Title   : can_call_new
 633  Usage   :
 634  Function:
 635  Example :
 636  Returns : true
 637  Args    :
 638
 639
 640 =cut
 641
 642 sub can_call_new {
 643    my ($self) = @_;
 644
 645    return 1;
 646 }
 647
 648 =head2 id
 649
 650  Title   : id
 651  Usage   : $id = $seq->id()
 652  Function: This is mapped on display_id
 653  Example :
 654  Returns :
 655  Args    :
 656
 657
 658 =cut
 659
 660 sub  id {
 661    return shift->display_id(@_);
 662 }
 663
 664 =head2 is_circular
 665
 666  Title   : is_circular
 667  Usage   : if( $obj->is_circular) { /Do Something/ }
 668  Function: Returns true if the molecule is circular
 669  Returns : Boolean value
 670  Args    : none
 671
 672 =cut
 673
 674 sub is_circular{
 675     my $self = shift;
 676
 677     return $self->{'is_circular'} = shift if @_;
 678     return $self->{'is_circular'};
 679 }
 680
 681
 682 =head1 Methods for Bio::IdentifiableI compliance
 683
 684 =cut
 685
 686 =head2 object_id
 687
 688  Title   : object_id
 689  Usage   : $string    = $obj->object_id()
 690  Function: A string which represents the stable primary identifier
 691            in this namespace of this object. For DNA sequences this
 692            is its accession_number, similarly for protein sequences.
 693
 694            This is aliased to accession_number().
 695  Returns : A scalar
 696
 697
 698 =cut
 699
 700 sub object_id {
 701     return shift->accession_number(@_);
 702 }
 703
 704 =head2 version
 705
 706  Title   : version
 707  Usage   : $version    = $obj->version()
 708  Function: A number which differentiates between versions of
 709            the same object. Higher numbers are considered to be
 710            later and more relevant, but a single object described
 711            the same identifier should represent the same concept.
 712
 713  Returns : A number
 714
 715 =cut
 716
 717 sub version{
 718     my ($self,$value) = @_;
 719     if( defined $value) {
 720         $self->{'_version'} = $value;
 721     }
 722     return $self->{'_version'};
 723 }
 724
 725
 726 =head2 authority
 727
 728  Title   : authority
 729  Usage   : $authority    = $obj->authority()
 730  Function: A string which represents the organisation which
 731            granted the namespace, written as the DNS name for
 732            organisation (eg, wormbase.org).
 733
 734  Returns : A scalar
 735
 736 =cut
 737
 738 sub authority {
 739     my ($obj,$value) = @_;
 740     if( defined $value) {
 741         $obj->{'authority'} = $value;
 742     }
 743     return $obj->{'authority'};
 744 }
 745
 746 =head2 namespace
 747
 748  Title   : namespace
 749  Usage   : $string    = $obj->namespace()
 750  Function: A string representing the name space this identifier
 751            is valid in, often the database name or the name
 752            describing the collection.
 753
 754  Returns : A scalar
 755
 756
 757 =cut
 758
 759 sub namespace{
 760     my ($self,$value) = @_;
 761     if( defined $value) {
 762         $self->{'namespace'} = $value;
 763     }
 764     return $self->{'namespace'} || "";
 765 }
 766
 767 =head1 Methods for Bio::DescribableI compliance
 768
 769 This comprises of display_name and description.
 770
 771 =cut
 772
 773 =head2 display_name
 774
 775  Title   : display_name
 776  Usage   : $string    = $obj->display_name()
 777  Function: A string which is what should be displayed to the user.
 778            The string should have no spaces (ideally, though a cautious
 779            user of this interface would not assumme this) and should be
 780            less than thirty characters (though again, double checking
 781            this is a good idea).
 782
 783            This is aliased to display_id().
 784  Returns : A scalar
 785
 786 =cut
 787
 788 sub display_name {
 789     return shift->display_id(@_);
 790 }
 791
 792 =head2 description
 793
 794  Title   : description
 795  Usage   : $string    = $obj->description()
 796  Function: A text string suitable for displaying to the user a
 797            description. This string is likely to have spaces, but
 798            should not have any newlines or formatting - just plain
 799            text. The string should not be greater than 255 characters
 800            and clients can feel justified at truncating strings at 255
 801            characters for the purposes of display.
 802
 803            This is aliased to desc().
 804  Returns : A scalar
 805
 806 =cut
 807
 808 sub description {
 809     return shift->desc(@_);
 810 }
 811
 812 =head1 Methods Inherited from Bio::PrimarySeqI
 813
 814 These methods are available on Bio::PrimarySeq, although they are
 815 actually implemented on Bio::PrimarySeqI
 816
 817 =head2 revcom
 818
 819  Title   : revcom
 820  Usage   : $rev = $seq->revcom()
 821  Function: Produces a new Bio::SeqI implementing object which
 822            is the reversed complement of the sequence. For protein
 823            sequences this throws an exception of
 824            "Sequence is a protein. Cannot revcom".
 825
 826            The id is the same id as the orginal sequence, and the
 827            accession number is also indentical. If someone wants to
 828            track that this sequence has be reversed, it needs to
 829            define its own extensions.
 830
 831            To do an inplace edit of an object you can go:
 832
 833            $seqobj = $seqobj->revcom();
 834
 835            This of course, causes Perl to handle the garbage
 836            collection of the old object, but it is roughly speaking as
 837            efficient as an inplace edit.
 838
 839  Returns : A new (fresh) Bio::SeqI object
 840  Args    : none
 841
 842 =cut
 843
 844 =head2 trunc
 845
 846  Title   : trunc
 847  Usage   : $subseq = $myseq->trunc(10,100);
 848  Function: Provides a truncation of a sequence,
 849
 850  Example :
 851  Returns : A fresh Bio::SeqI implementing object.
 852  Args    :
 853
 854
 855 =cut
 856
 857 =head1 Internal methods
 858
 859 These are internal methods to PrimarySeq
 860
 861 =cut
 862
 863 =head2 _guess_alphabet
 864
 865  Title   : _guess_alphabet
 866  Usage   :
 867  Function: Automatically guess and set the type of sequence: dna, rna, protein
 868            or '' if the sequence was empty. This method first removes dots (.),
 869            dashes (-) and question marks (?) before guessing the alphabet
 870            using the IUPAC conventions for ambiguous residues. Since the DNA and
 871            RNA characters are also valid characters for proteins, there is
 872            no foolproof way of determining the right alphabet. This is our best
 873            guess only!
 874  Example :
 875  Returns : string 'dna', 'rna', 'protein' or ''.
 876  Args    : none
 877
 878
 879 =cut
 880
 881 sub _guess_alphabet {
 882     my ($self) = @_;
 883     # Guess alphabet
 884     my $alphabet = $self->_guess_alphabet_from_string($self->seq, $self->{'_nowarnonempty'});
 885     # Set alphabet unless it is unknown
 886     $self->alphabet($alphabet) if $alphabet;
 887     return $alphabet;
 888 }
 889
 890
 891 sub _guess_alphabet_from_string {
 892     # Get the alphabet from a sequence string
 893     my ($self, $str, $nowarnonempty) = @_;
 894
 895     $nowarnonempty = 0 if not defined $nowarnonempty;
 896
 897     # Remove chars that clearly don't denote nucleic or amino acids
 898     $str =~ s/[-.?]//gi;
 899
 900     # Check for sequences without valid letters
 901     my $alphabet;
 902     my $total = CORE::length($str);
 903     if( $total == 0 ) {
 904         if (not $nowarnonempty) {
 905             $self->warn("Got a sequence without letters. Could not guess alphabet");
 906         }
 907         $alphabet = '';
 908     }
 909
 910     # Determine alphabet now
 911     if (not defined $alphabet) {
 912         if ($str =~ m/[EFIJLOPQXZ]/i) {
 913             # Start with a safe method to find proteins.
 914             # Unambiguous IUPAC letters for proteins are: E,F,I,J,L,O,P,Q,X,Z
 915             $alphabet = 'protein';
 916         } else {
 917             # Alphabet is unsure, could still be DNA, RNA or protein
 918             # DNA and RNA contain mostly A, T, U, G, C and N, but the other
 919             # letters they use are also among the 15 valid letters that a
 920             # protein sequence can contain at this stage. Make our best guess
 921             # based on sequence composition. If it contains over 70% of ACGTUN,
 922             # it is likely nucleic.
 923             if( ($str =~ tr/ATUGCNatugcn//) / $total > 0.7 ) {
 924                 if ( $str =~ m/U/i ) {
 925                     $alphabet = 'rna';
 926                 } else {
 927                     $alphabet = 'dna';
 928                 }
 929             } else {
 930                 $alphabet = 'protein';
 931             }
 932         }
 933     }
 934
 935     return $alphabet;
 936 }
 937
 938
 939 ############################################################################
 940 # aliases due to name changes or to compensate for our lack of consistency #
 941 ############################################################################
 942
 943 sub accession {
 944     my $self = shift;
 945
 946     $self->warn(ref($self)."::accession is deprecated, ".
 947         "use accession_number() instead");
 948     return $self->accession_number(@_);
 949 }
 950
 951 1;
 952