tkmain.d

   1 /* coded by Ketmar // Invisible Vector <ketmar@ketmar.no-ip.org>
   2  * Understanding is not required. Only obedience.
   3  *
   4  * This program is free software: you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation, version 3 of the License ONLY.
   7  *
   8  * This program is distributed in the hope that it will be useful,
   9  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  10  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11  * GNU General Public License for more details.
  12  *
  13  * You should have received a copy of the GNU General Public License
  14  * along with this program. If not, see <http://www.gnu.org/licenses/>.
  15  */
  16 module tkmain is aliced;
  17
  18 import std.datetime;
  19
  20 import arsd.color;
  21 import arsd.image;
  22 import arsd.simpledisplay;
  23
  24 import iv.cmdcon;
  25 import iv.cmdcon.gl;
  26 import iv.gxx;
  27 import iv.meta;
  28 import iv.nanovega;
  29 import iv.nanovega.blendish;
  30 import iv.nanovega.textlayouter;
  31 import iv.strex;
  32 import iv.tox;
  33 import iv.sdpyutil;
  34 import iv.unarray;
  35 import iv.utfutil;
  36 import iv.vfs.io;
  37
  38 version(sfnt_test) import iv.nanovega.simplefont;
  39
  40 import accdb;
  41 import accobj;
  42 import fonts;
  43 import icondata;
  44 import notifyicon;
  45 import toxproto;
  46
  47 import tkclist;
  48 import tklog;
  49
  50
  51 // ////////////////////////////////////////////////////////////////////////// //
  52 __gshared bool mainWindowActive = false;
  53 __gshared bool mainWindowVisible = false;
  54 __gshared SimpleWindow sdmain;
  55 __gshared CList clist;
  56
  57
  58 void setupToxCoreSender () {
  59   toxCoreSendEvent = delegate (Object msg) {
  60     if (msg is null) return; // just in case
  61     try {
  62       if (glconCtlWindow is null || glconCtlWindow.closed) return;
  63       glconCtlWindow.postEvent(msg);
  64     } catch (Exception e) {}
  65   };
  66 }
  67
  68
  69 // ////////////////////////////////////////////////////////////////////////// //
  70 string getBrowserCommand (bool forceOpera=false) {
  71   __gshared string browser;
  72   if (forceOpera) return "opera";
  73   if (browser.length == 0) {
  74     import core.stdc.stdlib : getenv;
  75     const(char)* evar = getenv("BROWSER");
  76     if (evar !is null && evar[0]) {
  77       import std.string : fromStringz;
  78       browser = evar.fromStringz.idup;
  79     } else {
  80       browser = "opera";
  81     }
  82   }
  83   return browser;
  84 }
  85
  86
  87 void openUrl (ConString url, bool forceOpera=false) {
  88   if (url.length) {
  89     import std.stdio : File;
  90     import std.process;
  91     try {
  92       auto frd = File("/dev/null");
  93       auto fwr = File("/dev/null", "w");
  94       spawnProcess([getBrowserCommand(forceOpera), url.idup], frd, fwr, fwr, null, Config.detached);
  95     } catch (Exception e) {
  96       conwriteln("ERROR executing URL viewer (", e.msg, ")");
  97     }
  98   }
  99 }
 100
 101
 102 // ////////////////////////////////////////////////////////////////////////// //
 103 struct UrlInfo {
 104   int pos = -1, len = 0;
 105
 106   @property bool valid () const pure nothrow @safe @nogc => (pos >= 0 && len > 0);
 107   @property int end () const pure nothrow @safe @nogc => (pos >= 0 && len > 0 ? pos+len : 0);
 108
 109   static UrlInfo Invalid () pure nothrow @safe @nogc => UrlInfo.init;
 110 }
 111
 112
 113 UrlInfo urlDetect (const(char)[] text) nothrow @trusted @nogc {
 114   import iv.strex;
 115   UrlInfo res;
 116   auto dlpos = text.indexOf("://");
 117   if (dlpos < 3) return res;
 118
 119   //{ import core.stdc.stdio; printf("det: <%.*s>\n", cast(uint)text.length, text.ptr); }
 120
 121   bool isProto (const(char)[] prt) nothrow @trusted @nogc {
 122     if (dlpos < prt.length) return false;
 123     if (!strEquCI(prt, text[dlpos-prt.length..dlpos])) return false;
 124     // check word boundary
 125     if (dlpos == prt.length) return true;
 126     return !isalpha(text[dlpos-prt.length-1]);
 127   }
 128
 129        if (isProto("ftp")) res.pos = cast(int)(dlpos-3);
 130   else if (isProto("http")) res.pos = cast(int)(dlpos-4);
 131   else if (isProto("https")) res.pos = cast(int)(dlpos-5);
 132   else return res;
 133
 134   dlpos += 3; // skip "://"
 135
 136   // skip host name
 137   for (; dlpos < text.length; ++dlpos) {
 138     char ch = text[dlpos];
 139     if (ch == '/') break;
 140     if (!(isalnum(ch) || ch == '.' || ch == '-' || ch == ':' || ch == '@')) break;
 141   }
 142
 143   // skip path
 144   char[64] brcStack;
 145   int brcSP = 0;
 146   bool wasSharp = false;
 147
 148   for (; dlpos < text.length; ++dlpos) {
 149     char ch = text[dlpos];
 150     if (ch <= ' ' || ch == '<' || ch == '>' || ch == '"' || ch == '\'' || ch >= 127) break;
 151     // hash
 152     if (ch == '#') {
 153       if (wasSharp) break;
 154       wasSharp = true;
 155       brcSP = 0;
 156       continue;
 157     }
 158     // next path part
 159     if (ch == '/') {
 160       brcSP = 0;
 161       continue;
 162     }
 163     // opening bracket
 164     if (ch == '(' || ch == '[' || ch == '{') {
 165       if (dlpos+1 >= text.length || (!isalnum(text[dlpos+1]) && text[dlpos+1] != '_')) break;
 166       final switch (ch) {
 167         case '(': ch = ')'; break;
 168         case '[': ch = ']'; break;
 169         case '{': ch = '}'; break;
 170       }
 171       if (brcSP < brcStack.length) brcStack[brcSP++] = ch;
 172       continue;
 173     }
 174     // closing bracket
 175     if (ch == ')' || ch == ']' || ch == '}') {
 176       if (brcSP == 0 || brcStack[brcSP-1] != ch) break;
 177       --brcSP;
 178       continue;
 179     }
 180     if (brcSP == 0) {
 181       if (ch == '.') {
 182         if (brcSP == 0) {
 183           if (dlpos+1 >= text.length || (!isalnum(text[dlpos+1]) && text[dlpos+1] != '_')) break;
 184         }
 185         continue;
 186       }
 187       if (!isalnum(ch)) {
 188         // other special chars
 189         if (dlpos+1 >= text.length) break; // no more chars, ignore
 190         if (!isalnum(text[dlpos+1]) && text[dlpos+1] != '_') {
 191           if (ch == '.' || ch == '!' || ch == ';' || ch == ',' || text[dlpos+1] != ch) break; // ignore
 192         }
 193         continue;
 194       }
 195     }
 196   }
 197
 198   res.len = cast(int)(dlpos-res.pos);
 199
 200   return res;
 201 }
 202
 203
 204 // ////////////////////////////////////////////////////////////////////////// //
 205 __gshared NVGContext nvg = null;
 206 __gshared NVGImage nvgSkullsImg;
 207 __gshared NVGImage kittyOut, kittyMsg, kittyFish;
 208 __gshared NVGImage[5] statusImgId;
 209
 210 __gshared int lastWindowWidth = -1;
 211
 212
 213 shared static ~this () {
 214   //{ import core.stdc.stdio; printf("******************************\n"); }
 215   nvgSkullsImg.clear();
 216   //{ import core.stdc.stdio; printf("---\n"); }
 217   foreach (ref img; statusImgId[]) img.clear();
 218   kittyOut.clear();
 219   kittyMsg.clear();
 220   kittyFish.clear();
 221 }
 222
 223
 224 void buildStatusImages () {
 225   version(none) {
 226     statusImgId[ContactStatus.Offline] = nvg.createImageRGBA(16, 16, ctiOffline[], NVGImageFlags.NoFiltering);
 227     statusImgId[ContactStatus.Online] = nvg.createImageRGBA(16, 16, ctiOnline[], NVGImageFlags.NoFiltering);
 228     statusImgId[ContactStatus.Away] = nvg.createImageRGBA(16, 16, ctiAway[], NVGImageFlags.NoFiltering);
 229     statusImgId[ContactStatus.Connecting] = nvg.createImageRGBA(16, 16, ctiOffline[], NVGImageFlags.NoFiltering);
 230   } else {
 231     //{ import core.stdc.stdio; printf("creating status image: Offline\n"); }
 232     statusImgId[ContactStatus.Offline] = nvg.createImageRGBA(16, 16, baph16Gray[], NVGImageFlags.NoFiltering);
 233     //{ import core.stdc.stdio; printf("creating status image: Online\n"); }
 234     statusImgId[ContactStatus.Online] = nvg.createImageRGBA(16, 16, baph16Online[], NVGImageFlags.NoFiltering);
 235     //{ import core.stdc.stdio; printf("creating status image: Away\n"); }
 236     statusImgId[ContactStatus.Away] = nvg.createImageRGBA(16, 16, baph16Away[], NVGImageFlags.NoFiltering);
 237     //{ import core.stdc.stdio; printf("creating status image: Busy\n"); }
 238     statusImgId[ContactStatus.Busy] = nvg.createImageRGBA(16, 16, baph16Busy[], NVGImageFlags.NoFiltering);
 239     //{ import core.stdc.stdio; printf("creating status image: Connecting\n"); }
 240     statusImgId[ContactStatus.Connecting] = nvg.createImageRGBA(16, 16, baph16Orange[], NVGImageFlags.NoFiltering);
 241     //{ import core.stdc.stdio; printf("+++ creatied status images...\n"); }
 242     kittyOut = nvg.createImageRGBA(16, 16, kittyOutgoing[], NVGImageFlags.NoFiltering);
 243     kittyMsg = nvg.createImageRGBA(16, 16, kittyMessage[], NVGImageFlags.NoFiltering);
 244     kittyFish = nvg.createImageRGBA(16, 16, kittyFish16[], NVGImageFlags.NoFiltering);
 245   }
 246 }
 247
 248
 249 // ////////////////////////////////////////////////////////////////////////// //
 250 void loadFonts () {
 251   nvg.fonsContext.addFontsFrom(fstash);
 252   bndSetFont(nvg.findFont("ui"));
 253 }
 254
 255
 256 // ////////////////////////////////////////////////////////////////////////// //
 257 void loadAccount (string nick, bool allowCreate) {
 258   if (nick.length == 0) assert(0, "wtf?!");
 259
 260   Account acc;
 261   bool newAcc = false;
 262
 263   try {
 264     acc = new Account(nick);
 265   } catch (Exception e) {
 266     conwriteln("error opening account... (error: ", e.msg, ")");
 267     if (!allowCreate) throw e;
 268     acc = Account.CreateNew(nick, nick);
 269     newAcc = true;
 270   }
 271
 272   // create fake contact
 273   if (newAcc && acc.contacts.length == 0 && nick == "_fakeacc") {
 274     conwriteln("creating fake contact...");
 275     auto c = acc.createEmptyContact();
 276     c.info.nick = "test contact";
 277     c.info.pubkey[] = 0x55;
 278     c.save();
 279   }
 280
 281   clist.buildAccount(acc);
 282 }
 283
 284
 285 // ////////////////////////////////////////////////////////////////////////// //
 286 // null: deactivate
 287 void doActivateContact (Contact ct) {
 288   if (sdmain is null || sdmain.closed) return;
 289   if (activeContact is ct) return;
 290
 291   activeContact = ct;
 292   wipeLog();
 293   if (ct is null) {
 294     //conwriteln("clear log");
 295     if (clist !is null) clist.resetActiveItem();
 296     sdmain.title = "BioAcid";
 297     glconPostScreenRepaint();
 298   } else if (ct.acceptPending) {
 299     addTextToLog(ct.acc, ct, LogFile.Msg.Kind.Notification, false, (ct.statusmsg.length ? ct.statusmsg : "I brought you a tasty fish!"), systimeNow);
 300   } else {
 301     import std.format : format;
 302     sdmain.title = "%s [%s] -- BioAcid".format(ct.info.nick, tox_hex(ct.info.pubkey));
 303     LogFile log;
 304     ct.loadLogInto(log);
 305     auto mcount = cast(int)log.messages.length;
 306     int left = ct.hmcOnOpen;
 307     if (left < ct.unreadCount) left = ct.unreadCount;
 308     if (left > mcount) left = mcount;
 309     if (mcount > left) mcount = left;
 310     if (mcount > 0) {
 311       foreach (const ref msg; log.messages[$-mcount..$]) {
 312         if (left == ct.unreadCount) addDividerLine();
 313         addTextToLog(ct.acc, ct, msg);
 314         --left;
 315       }
 316     }
 317     if (ct.unreadCount != 0) { ct.unreadCount = 0; ct.saveUnreadCount(); }
 318   }
 319
 320   fixTrayIcon();
 321 }
 322
 323
 324 //FIXME: scan all accounts
 325 void fixTrayIcon () {
 326   if (clist is null) return;
 327   auto acc = clist.mainAccount;
 328   if (acc is null) return;
 329   int unc = 0;
 330   foreach (Contact ct; acc) unc += ct.unreadCount;
 331   if (unc) {
 332     import std.format : format;
 333     setTrayUnread();
 334     setHint("unread: %d".format(unc));
 335   } else {
 336     setTrayStatus(acc.status);
 337     final switch (acc.status) {
 338       case ContactStatus.Connecting: setHint("connecting..."); break;
 339       case ContactStatus.Offline: setHint("offline"); break;
 340       case ContactStatus.Online: setHint("online"); break;
 341       case ContactStatus.Away: setHint("away"); break;
 342       case ContactStatus.Busy: setHint("busy"); break;
 343     }
 344   }
 345 }
 346
 347
 348 void fixUnreadIndicators () {
 349   if (!mainWindowVisible || !mainWindowActive) return; // nothing to do
 350   if (activeContact is null || activeContact.unreadCount == 0) return; // nothing to do
 351   activeContact.unreadCount = 0;
 352   activeContact.unreadCount = 0;
 353   activeContact.saveUnreadCount();
 354   fixTrayIcon();
 355 }
 356
 357
 358 // ////////////////////////////////////////////////////////////////////////// //
 359 void addContactCommands () {
 360   conRegFunc!((ConString grpname) {
 361     if (clist is null || sdmain is null || sdmain.closed) return;
 362     auto acc = clist.mainAccount;
 363     if (acc is null) return;
 364     if (grpname.length == 0) { conwriteln("group name?"); return; }
 365     if (acc.findGroupByName(grpname) != uint.max) { conwriteln("group <", grpname, "> already exists"); return; }
 366     auto gid = acc.createGroup(grpname);
 367     if (gid == uint.max) { conwriteln("cannot create group <", grpname, ">"); return; }
 368     clist.buildAccount(acc);
 369     glconPostScreenRepaint();
 370   })("group_create", "create group");
 371
 372
 373   conRegFunc!((ConString grpname) {
 374     if (clist is null || sdmain is null || sdmain.closed) return;
 375     if (activeContact is null) { conwriteln("please, select contact first"); return; }
 376     if (grpname.length == 0) { conwriteln("group name?"); return; }
 377     auto gid = activeContact.acc.createGroup(grpname);
 378     if (gid == uint.max) { conwriteln("cannot create group <", grpname, ">"); return; }
 379     if (activeContact.acc.moveContactToGroup(activeContact, gid)) {
 380       clist.buildAccount(activeContact.acc);
 381       glconPostScreenRepaint();
 382     } else {
 383       conwriteln("cannot move contact to new group");
 384     }
 385   })("move_to_group", "move current contact to named group");
 386
 387
 388   conRegFunc!(() {
 389     if (clist is null || sdmain is null || sdmain.closed) return;
 390     if (activeContact is null) { conwriteln("please, select contact first"); return; }
 391     auto acc = activeContact.acc;
 392     if (!acc.isOnline) { conwriteln("you must be online to remove contacts"); return; }
 393     if (!acc.removeContact(activeContact)) { conwriteln("cannot remove current contact"); return; }
 394     wipeLog();
 395     activeContact = null;
 396     clist.buildAccount(acc);
 397     glconPostScreenRepaint();
 398   })("contact_remove", "unfriend and remove current contact");
 399 }