ld/ldlex.l

   1 %{
   2
   3 /* Copyright 1991, 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4    2000, 2001, 2002, 2003, 2004, 2005, 2007, 2009
   5    Free Software Foundation, Inc.
   6    Written by Steve Chamberlain of Cygnus Support.
   7
   8    This file is part of the GNU Binutils.
   9
  10    This program is free software; you can redistribute it and/or modify
  11    it under the terms of the GNU General Public License as published by
  12    the Free Software Foundation; either version 3 of the License, or
  13    (at your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful,
  16    but WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18    GNU General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston,
  23    MA 02110-1301, USA.  */
  24
  25 #include "sysdep.h"
  26 #include "bfd.h"
  27 #include "safe-ctype.h"
  28 #include "bfdlink.h"
  29 #include "ld.h"
  30 #include "ldmisc.h"
  31 #include "ldexp.h"
  32 #include "ldlang.h"
  33 #include <ldgram.h>
  34 #include "ldfile.h"
  35 #include "ldlex.h"
  36 #include "ldmain.h"
  37 #include "libiberty.h"
  38
  39 /* The type of top-level parser input.
  40    yylex and yyparse (indirectly) both check this.  */
  41 input_type parser_input;
  42
  43 /* Line number in the current input file.
  44    (FIXME Actually, it doesn't appear to get reset for each file?)  */
  45 unsigned int lineno = 1;
  46
  47 /* The string we are currently lexing, or NULL if we are reading a
  48    file.  */
  49 const char *lex_string = NULL;
  50
  51 /* Support for flex reading from more than one input file (stream).
  52    `include_stack' is flex's input state for each open file;
  53    `file_name_stack' is the file names.  `lineno_stack' is the current
  54    line numbers.
  55
  56    If `include_stack_ptr' is 0, we haven't started reading anything yet.
  57    Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid.  */
  58
  59 #undef YY_INPUT
  60 #define YY_INPUT(buf,result,max_size) yy_input (buf, &result, max_size)
  61
  62 #define YY_NO_UNPUT
  63
  64 #define MAX_INCLUDE_DEPTH 10
  65 static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  66 static const char *file_name_stack[MAX_INCLUDE_DEPTH];
  67 static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
  68 static unsigned int include_stack_ptr = 0;
  69 static int vers_node_nesting = 0;
  70
  71 static void yy_input (char *, int *, int);
  72 static void comment (void);
  73 static void lex_warn_invalid (char *where, char *what);
  74
  75 /* STATES
  76         EXPRESSION      definitely in an expression
  77         SCRIPT          definitely in a script
  78         BOTH            either EXPRESSION or SCRIPT
  79         DEFSYMEXP       in an argument to -defsym
  80         MRI             in an MRI script
  81         VERS_START      starting a Sun style mapfile
  82         VERS_SCRIPT     a Sun style mapfile
  83         VERS_NODE       a node within a Sun style mapfile
  84 */
  85 #define RTOKEN(x)  {  yylval.token = x; return x; }
  86
  87 /* Some versions of flex want this.  */
  88 #ifndef yywrap
  89 int yywrap (void) { return 1; }
  90 #endif
  91 %}
  92
  93 %a 4000
  94 %o 5000
  95
  96 CMDFILENAMECHAR   [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
  97 CMDFILENAMECHAR1  [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
  98 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\_\~]
  99 SYMBOLCHARN     [_a-zA-Z\/\.\\\$\_\~0-9]
 100 FILENAMECHAR    [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
 101 WILDCHAR        [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~\?\*]
 102 WHITE           [ \t\n\r]+
 103
 104 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
 105
 106 V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
 107 V_IDENTIFIER [*?.$_a-zA-Z\[\]\-\!\^\\]([*?.$_a-zA-Z0-9\[\]\-\!\^\\]|::)*
 108
 109 %s SCRIPT
 110 %s EXPRESSION
 111 %s BOTH
 112 %s DEFSYMEXP
 113 %s MRI
 114 %s VERS_START
 115 %s VERS_SCRIPT
 116 %s VERS_NODE
 117 %%
 118
 119   if (parser_input != input_selected)
 120     {
 121       /* The first token of the input determines the initial parser state.  */
 122       input_type t = parser_input;
 123       parser_input = input_selected;
 124       switch (t)
 125         {
 126         case input_script: return INPUT_SCRIPT; break;
 127         case input_mri_script: return INPUT_MRI_SCRIPT; break;
 128         case input_version_script: return INPUT_VERSION_SCRIPT; break;
 129         case input_dynamic_list: return INPUT_DYNAMIC_LIST; break;
 130         case input_defsym: return INPUT_DEFSYM; break;
 131         default: abort ();
 132         }
 133     }
 134
 135 <BOTH,SCRIPT,EXPRESSION,VERS_START,VERS_NODE,VERS_SCRIPT>"/*"   { comment (); }
 136
 137
 138 <DEFSYMEXP>"-"                  { RTOKEN('-');}
 139 <DEFSYMEXP>"+"                  { RTOKEN('+');}
 140 <DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}*   { yylval.name = xstrdup (yytext); return NAME; }
 141 <DEFSYMEXP>"="                  { RTOKEN('='); }
 142
 143 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 144                                 yylval.integer = bfd_scan_vma (yytext + 1, 0, 16);
 145                                 yylval.bigint.str = NULL;
 146                                 return INT;
 147                         }
 148
 149 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|h|X|x|B|b|O|o|D|d) {
 150                                    int ibase ;
 151                                    switch (yytext[yyleng - 1]) {
 152                                     case 'X':
 153                                     case 'x':
 154                                     case 'H':
 155                                     case 'h':
 156                                      ibase = 16;
 157                                      break;
 158                                     case 'O':
 159                                     case 'o':
 160                                      ibase = 8;
 161                                      break;
 162                                     case 'B':
 163                                     case 'b':
 164                                      ibase = 2;
 165                                      break;
 166                                     default:
 167                                      ibase = 10;
 168                                    }
 169                                    yylval.integer = bfd_scan_vma (yytext, 0,
 170                                                                   ibase);
 171                                    yylval.bigint.str = NULL;
 172                                    return INT;
 173                                  }
 174 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>((("$"|0[xX])([0-9A-Fa-f])+)|(([0-9])+))(M|K|m|k)? {
 175                                   char *s = yytext;
 176                                   int ibase = 0;
 177
 178                                   if (*s == '$')
 179                                     {
 180                                       ++s;
 181                                       ibase = 16;
 182                                     }
 183                                   yylval.integer = bfd_scan_vma (s, 0, ibase);
 184                                   yylval.bigint.str = NULL;
 185                                   if (yytext[yyleng - 1] == 'M'
 186                                       || yytext[yyleng - 1] == 'm')
 187                                     {
 188                                       yylval.integer *= 1024 * 1024;
 189                                     }
 190                                   else if (yytext[yyleng - 1] == 'K'
 191                                       || yytext[yyleng - 1]=='k')
 192                                     {
 193                                       yylval.integer *= 1024;
 194                                     }
 195                                   else if (yytext[0] == '0'
 196                                            && (yytext[1] == 'x'
 197                                                || yytext[1] == 'X'))
 198                                     {
 199                                       yylval.bigint.str = xstrdup (yytext + 2);
 200                                     }
 201                                   return INT;
 202                                 }
 203 <BOTH,SCRIPT,EXPRESSION,MRI>"]"         { RTOKEN(']');}
 204 <BOTH,SCRIPT,EXPRESSION,MRI>"["         { RTOKEN('[');}
 205 <BOTH,SCRIPT,EXPRESSION,MRI>"<<="       { RTOKEN(LSHIFTEQ);}
 206 <BOTH,SCRIPT,EXPRESSION,MRI>">>="       { RTOKEN(RSHIFTEQ);}
 207 <BOTH,SCRIPT,EXPRESSION,MRI>"||"        { RTOKEN(OROR);}
 208 <BOTH,SCRIPT,EXPRESSION,MRI>"=="        { RTOKEN(EQ);}
 209 <BOTH,SCRIPT,EXPRESSION,MRI>"!="        { RTOKEN(NE);}
 210 <BOTH,SCRIPT,EXPRESSION,MRI>">="        { RTOKEN(GE);}
 211 <BOTH,SCRIPT,EXPRESSION,MRI>"<="        { RTOKEN(LE);}
 212 <BOTH,SCRIPT,EXPRESSION,MRI>"<<"        { RTOKEN(LSHIFT);}
 213 <BOTH,SCRIPT,EXPRESSION,MRI>">>"        { RTOKEN(RSHIFT);}
 214 <BOTH,SCRIPT,EXPRESSION,MRI>"+="        { RTOKEN(PLUSEQ);}
 215 <BOTH,SCRIPT,EXPRESSION,MRI>"-="        { RTOKEN(MINUSEQ);}
 216 <BOTH,SCRIPT,EXPRESSION,MRI>"*="        { RTOKEN(MULTEQ);}
 217 <BOTH,SCRIPT,EXPRESSION,MRI>"/="        { RTOKEN(DIVEQ);}
 218 <BOTH,SCRIPT,EXPRESSION,MRI>"&="        { RTOKEN(ANDEQ);}
 219 <BOTH,SCRIPT,EXPRESSION,MRI>"|="        { RTOKEN(OREQ);}
 220 <BOTH,SCRIPT,EXPRESSION,MRI>"&&"        { RTOKEN(ANDAND);}
 221 <BOTH,SCRIPT,EXPRESSION,MRI>">"         { RTOKEN('>');}
 222 <BOTH,SCRIPT,EXPRESSION,MRI>","         { RTOKEN(',');}
 223 <BOTH,SCRIPT,EXPRESSION,MRI>"&"         { RTOKEN('&');}
 224 <BOTH,SCRIPT,EXPRESSION,MRI>"|"         { RTOKEN('|');}
 225 <BOTH,SCRIPT,EXPRESSION,MRI>"~"         { RTOKEN('~');}
 226 <BOTH,SCRIPT,EXPRESSION,MRI>"!"         { RTOKEN('!');}
 227 <BOTH,SCRIPT,EXPRESSION,MRI>"?"         { RTOKEN('?');}
 228 <BOTH,SCRIPT,EXPRESSION,MRI>"*"         { RTOKEN('*');}
 229 <BOTH,SCRIPT,EXPRESSION,MRI>"+"         { RTOKEN('+');}
 230 <BOTH,SCRIPT,EXPRESSION,MRI>"-"         { RTOKEN('-');}
 231 <BOTH,SCRIPT,EXPRESSION,MRI>"/"         { RTOKEN('/');}
 232 <BOTH,SCRIPT,EXPRESSION,MRI>"%"         { RTOKEN('%');}
 233 <BOTH,SCRIPT,EXPRESSION,MRI>"<"         { RTOKEN('<');}
 234 <BOTH,SCRIPT,EXPRESSION,MRI>"="         { RTOKEN('=');}
 235 <BOTH,SCRIPT,EXPRESSION,MRI>"}"         { RTOKEN('}') ; }
 236 <BOTH,SCRIPT,EXPRESSION,MRI>"{"         { RTOKEN('{'); }
 237 <BOTH,SCRIPT,EXPRESSION,MRI>")"         { RTOKEN(')');}
 238 <BOTH,SCRIPT,EXPRESSION,MRI>"("         { RTOKEN('(');}
 239 <BOTH,SCRIPT,EXPRESSION,MRI>":"         { RTOKEN(':'); }
 240 <BOTH,SCRIPT,EXPRESSION,MRI>";"         { RTOKEN(';');}
 241 <BOTH,SCRIPT>"MEMORY"                   { RTOKEN(MEMORY);}
 242 <BOTH,SCRIPT>"REGION_ALIAS"             { RTOKEN(REGION_ALIAS);}
 243 <BOTH,SCRIPT,EXPRESSION>"ORIGIN"        { RTOKEN(ORIGIN);}
 244 <BOTH,SCRIPT>"VERSION"                  { RTOKEN(VERSIONK);}
 245 <EXPRESSION,BOTH,SCRIPT>"BLOCK"         { RTOKEN(BLOCK);}
 246 <EXPRESSION,BOTH,SCRIPT>"BIND"          { RTOKEN(BIND);}
 247 <BOTH,SCRIPT,EXPRESSION>"LENGTH"        { RTOKEN(LENGTH);}
 248 <EXPRESSION,BOTH,SCRIPT>"ALIGN"         { RTOKEN(ALIGN_K);}
 249 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_ALIGN"    { RTOKEN(DATA_SEGMENT_ALIGN);}
 250 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_RELRO_END"        { RTOKEN(DATA_SEGMENT_RELRO_END);}
 251 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_END"      { RTOKEN(DATA_SEGMENT_END);}
 252 <EXPRESSION,BOTH,SCRIPT>"ADDR"          { RTOKEN(ADDR);}
 253 <EXPRESSION,BOTH,SCRIPT>"LOADADDR"      { RTOKEN(LOADADDR);}
 254 <EXPRESSION,BOTH,SCRIPT>"ALIGNOF"       { RTOKEN(ALIGNOF); }
 255 <EXPRESSION,BOTH>"MAX"                  { RTOKEN(MAX_K); }
 256 <EXPRESSION,BOTH>"MIN"                  { RTOKEN(MIN_K); }
 257 <EXPRESSION,BOTH,SCRIPT>"ASSERT"        { RTOKEN(ASSERT_K); }
 258 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 259 <BOTH,SCRIPT,MRI>"EXTERN"               { RTOKEN(EXTERN);}
 260 <EXPRESSION,BOTH,SCRIPT>"NEXT"          { RTOKEN(NEXT);}
 261 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 262 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 263 <EXPRESSION,BOTH,SCRIPT>"SEGMENT_START" { RTOKEN(SEGMENT_START);}
 264 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 265 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"        { RTOKEN(SIZEOF);}
 266 <BOTH,SCRIPT>"TARGET"                   { RTOKEN(TARGET_K);}
 267 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 268 <BOTH,SCRIPT>"OUTPUT"                   { RTOKEN(OUTPUT);}
 269 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 270 <EXPRESSION,BOTH,SCRIPT>"GROUP"         { RTOKEN(GROUP);}
 271 <EXPRESSION,BOTH,SCRIPT>"AS_NEEDED"     { RTOKEN(AS_NEEDED);}
 272 <EXPRESSION,BOTH,SCRIPT>"DEFINED"       { RTOKEN(DEFINED);}
 273 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 274 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 275 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION"  { RTOKEN(FORCE_COMMON_ALLOCATION);}
 276 <BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
 277 <BOTH,SCRIPT>"SECTIONS"                 { RTOKEN(SECTIONS);}
 278 <BOTH,SCRIPT>"INSERT"                   { RTOKEN(INSERT_K);}
 279 <BOTH,SCRIPT>"AFTER"                    { RTOKEN(AFTER);}
 280 <BOTH,SCRIPT>"BEFORE"                   { RTOKEN(BEFORE);}
 281 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 282 <BOTH,SCRIPT>"STARTUP"                  { RTOKEN(STARTUP);}
 283 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 284 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 285 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 286 <BOTH,SCRIPT>"SYSLIB"                   { RTOKEN(SYSLIB);}
 287 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 288 <BOTH,SCRIPT>"QUAD"                     { RTOKEN( QUAD);}
 289 <BOTH,SCRIPT>"SQUAD"                    { RTOKEN( SQUAD);}
 290 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 291 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 292 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 293 <BOTH,SCRIPT>"NOFLOAT"                  { RTOKEN(NOFLOAT);}
 294 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS"   { RTOKEN(NOCROSSREFS);}
 295 <BOTH,SCRIPT>"OVERLAY"                  { RTOKEN(OVERLAY); }
 296 <BOTH,SCRIPT>"SORT_BY_NAME"             { RTOKEN(SORT_BY_NAME); }
 297 <BOTH,SCRIPT>"SORT_BY_ALIGNMENT"        { RTOKEN(SORT_BY_ALIGNMENT); }
 298 <BOTH,SCRIPT>"SORT"                     { RTOKEN(SORT_BY_NAME); }
 299 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"        { RTOKEN(NOLOAD);}
 300 <EXPRESSION,BOTH,SCRIPT>"DSECT"         { RTOKEN(DSECT);}
 301 <EXPRESSION,BOTH,SCRIPT>"COPY"          { RTOKEN(COPY);}
 302 <EXPRESSION,BOTH,SCRIPT>"INFO"          { RTOKEN(INFO);}
 303 <EXPRESSION,BOTH,SCRIPT>"OVERLAY"       { RTOKEN(OVERLAY);}
 304 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RO"    { RTOKEN(ONLY_IF_RO); }
 305 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RW"    { RTOKEN(ONLY_IF_RW); }
 306 <EXPRESSION,BOTH,SCRIPT>"SPECIAL"       { RTOKEN(SPECIAL); }
 307 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 308 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 309 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 310 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 311 <EXPRESSION,BOTH,SCRIPT>"INCLUDE"       { RTOKEN(INCLUDE);}
 312 <BOTH,SCRIPT>"PHDRS"                    { RTOKEN (PHDRS); }
 313 <EXPRESSION,BOTH,SCRIPT>"AT"            { RTOKEN(AT);}
 314 <EXPRESSION,BOTH,SCRIPT>"SUBALIGN"      { RTOKEN(SUBALIGN);}
 315 <EXPRESSION,BOTH,SCRIPT>"PROVIDE"       { RTOKEN(PROVIDE); }
 316 <EXPRESSION,BOTH,SCRIPT>"PROVIDE_HIDDEN" { RTOKEN(PROVIDE_HIDDEN); }
 317 <EXPRESSION,BOTH,SCRIPT>"KEEP"          { RTOKEN(KEEP); }
 318 <EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE"  { RTOKEN(EXCLUDE_FILE); }
 319 <EXPRESSION,BOTH,SCRIPT>"CONSTANT"      { RTOKEN(CONSTANT);}
 320 <MRI>"#".*\n?                   { ++ lineno; }
 321 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 322 <MRI>"*".*                      { /* Mri comment line */ }
 323 <MRI>";".*                      { /* Mri comment line */ }
 324 <MRI>"END"                      { RTOKEN(ENDWORD); }
 325 <MRI>"ALIGNMOD"                 { RTOKEN(ALIGNMOD);}
 326 <MRI>"ALIGN"                    { RTOKEN(ALIGN_K);}
 327 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 328 <MRI>"BASE"                     { RTOKEN(BASE); }
 329 <MRI>"ALIAS"                    { RTOKEN(ALIAS); }
 330 <MRI>"TRUNCATE"                 { RTOKEN(TRUNCATE); }
 331 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 332 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 333 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 334 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 335 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 336 <MRI>"CASE"                     { RTOKEN(CASE); }
 337 <MRI>"START"                    { RTOKEN(START); }
 338 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 339 <MRI>"SECT"                     { RTOKEN(SECT); }
 340 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 341 <MRI>"end"                      { RTOKEN(ENDWORD); }
 342 <MRI>"alignmod"                 { RTOKEN(ALIGNMOD);}
 343 <MRI>"align"                    { RTOKEN(ALIGN_K);}
 344 <MRI>"chip"                     { RTOKEN(CHIP); }
 345 <MRI>"base"                     { RTOKEN(BASE); }
 346 <MRI>"alias"                    { RTOKEN(ALIAS); }
 347 <MRI>"truncate"                 { RTOKEN(TRUNCATE); }
 348 <MRI>"load"                     { RTOKEN(LOAD); }
 349 <MRI>"public"                   { RTOKEN(PUBLIC); }
 350 <MRI>"order"                    { RTOKEN(ORDER); }
 351 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 352 <MRI>"format"                   { RTOKEN(FORMAT); }
 353 <MRI>"case"                     { RTOKEN(CASE); }
 354 <MRI>"extern"                   { RTOKEN(EXTERN); }
 355 <MRI>"start"                    { RTOKEN(START); }
 356 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 357 <MRI>"sect"                     { RTOKEN(SECT); }
 358 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 359
 360 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 361 /* Filename without commas, needed to parse mri stuff */
 362                                  yylval.name = xstrdup (yytext);
 363                                   return NAME;
 364                                 }
 365
 366
 367 <BOTH>{FILENAMECHAR1}{FILENAMECHAR}*    {
 368                                  yylval.name = xstrdup (yytext);
 369                                   return NAME;
 370                                 }
 371 <BOTH>"-l"{FILENAMECHAR}+ {
 372                                   yylval.name = xstrdup (yytext + 2);
 373                                   return LNAME;
 374                                 }
 375 <EXPRESSION>{FILENAMECHAR1}{NOCFILENAMECHAR}*   {
 376                                  yylval.name = xstrdup (yytext);
 377                                   return NAME;
 378                                 }
 379 <EXPRESSION>"-l"{NOCFILENAMECHAR}+ {
 380                                   yylval.name = xstrdup (yytext + 2);
 381                                   return LNAME;
 382                                 }
 383 <SCRIPT>{WILDCHAR}* {
 384                 /* Annoyingly, this pattern can match comments, and we have
 385                    longest match issues to consider.  So if the first two
 386                    characters are a comment opening, put the input back and
 387                    try again.  */
 388                 if (yytext[0] == '/' && yytext[1] == '*')
 389                   {
 390                     yyless (2);
 391                     comment ();
 392                   }
 393                 else
 394                   {
 395                     yylval.name = xstrdup (yytext);
 396                     return NAME;
 397                   }
 398         }
 399
 400 <EXPRESSION,BOTH,SCRIPT,VERS_NODE>"\""[^\"]*"\"" {
 401                                         /* No matter the state, quotes
 402                                            give what's inside */
 403                                         yylval.name = xstrdup (yytext + 1);
 404                                         yylval.name[yyleng - 2] = 0;
 405                                         return NAME;
 406                                 }
 407 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 408 <MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+    { }
 409
 410 <VERS_NODE,VERS_SCRIPT>[:,;]    { return *yytext; }
 411
 412 <VERS_NODE>global               { RTOKEN(GLOBAL); }
 413
 414 <VERS_NODE>local                { RTOKEN(LOCAL); }
 415
 416 <VERS_NODE>extern               { RTOKEN(EXTERN); }
 417
 418 <VERS_NODE>{V_IDENTIFIER}       { yylval.name = xstrdup (yytext);
 419                                   return VERS_IDENTIFIER; }
 420
 421 <VERS_SCRIPT>{V_TAG}            { yylval.name = xstrdup (yytext);
 422                                   return VERS_TAG; }
 423
 424 <VERS_START>"{"                 { BEGIN(VERS_SCRIPT); return *yytext; }
 425
 426 <VERS_SCRIPT>"{"                { BEGIN(VERS_NODE);
 427                                   vers_node_nesting = 0;
 428                                   return *yytext;
 429                                 }
 430 <VERS_SCRIPT>"}"                { return *yytext; }
 431 <VERS_NODE>"{"                  { vers_node_nesting++; return *yytext; }
 432 <VERS_NODE>"}"                  { if (--vers_node_nesting < 0)
 433                                     BEGIN(VERS_SCRIPT);
 434                                   return *yytext;
 435                                 }
 436
 437 <VERS_START,VERS_NODE,VERS_SCRIPT>[\n]          { lineno++; }
 438
 439 <VERS_START,VERS_NODE,VERS_SCRIPT>#.*           { /* Eat up comments */ }
 440
 441 <VERS_START,VERS_NODE,VERS_SCRIPT>[ \t\r]+      { /* Eat up whitespace */ }
 442
 443 <<EOF>> {
 444   include_stack_ptr--;
 445
 446   if (include_stack_ptr == 0)
 447   {
 448     yyterminate ();
 449   }
 450   else
 451   {
 452     yy_switch_to_buffer (include_stack[include_stack_ptr]);
 453   }
 454
 455   ldfile_input_filename = file_name_stack[include_stack_ptr - 1];
 456   lineno = lineno_stack[include_stack_ptr];
 457
 458   return END;
 459 }
 460
 461 <SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>.  lex_warn_invalid (" in script", yytext);
 462 <EXPRESSION,DEFSYMEXP,BOTH>.    lex_warn_invalid (" in expression", yytext);
 463
 464 %%
 465 \f
 466
 467 /* Switch flex to reading script file NAME, open on FILE,
 468    saving the current input info on the include stack.  */
 469
 470 void
 471 lex_push_file (FILE *file, const char *name)
 472 {
 473   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 474     {
 475       einfo ("%F:includes nested too deeply\n");
 476     }
 477   file_name_stack[include_stack_ptr] = name;
 478   lineno_stack[include_stack_ptr] = lineno;
 479   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 480
 481   include_stack_ptr++;
 482   lineno = 1;
 483   yyin = file;
 484   yy_switch_to_buffer (yy_create_buffer (yyin, YY_BUF_SIZE));
 485 }
 486
 487 /* Return a newly created flex input buffer containing STRING,
 488    which is SIZE bytes long.  */
 489
 490 static YY_BUFFER_STATE
 491 yy_create_string_buffer (const char *string, size_t size)
 492 {
 493   YY_BUFFER_STATE b;
 494
 495   /* Calls to m-alloc get turned by sed into xm-alloc.  */
 496   b = malloc (sizeof (struct yy_buffer_state));
 497   b->yy_input_file = 0;
 498   b->yy_buf_size = size;
 499
 500   /* yy_ch_buf has to be 2 characters longer than the size given because
 501      we need to put in 2 end-of-buffer characters.  */
 502   b->yy_ch_buf = malloc ((unsigned) (b->yy_buf_size + 3));
 503
 504   b->yy_ch_buf[0] = '\n';
 505   strcpy (b->yy_ch_buf+1, string);
 506   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 507   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 508   b->yy_n_chars = size+1;
 509   b->yy_buf_pos = &b->yy_ch_buf[1];
 510
 511   b->yy_is_our_buffer = 1;
 512   b->yy_is_interactive = 0;
 513   b->yy_at_bol = 1;
 514   b->yy_fill_buffer = 0;
 515
 516   /* flex 2.4.7 changed the interface.  FIXME: We should not be using
 517      a flex internal interface in the first place!  */
 518 #ifdef YY_BUFFER_NEW
 519   b->yy_buffer_status = YY_BUFFER_NEW;
 520 #else
 521   b->yy_eof_status = EOF_NOT_SEEN;
 522 #endif
 523
 524   return b;
 525 }
 526
 527 /* Switch flex to reading from STRING, saving the current input info
 528    on the include stack.  */
 529
 530 void
 531 lex_redirect (const char *string)
 532 {
 533   YY_BUFFER_STATE tmp;
 534
 535   yy_init = 0;
 536   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 537     {
 538       einfo("%F: macros nested too deeply\n");
 539     }
 540   file_name_stack[include_stack_ptr] = "redirect";
 541   lineno_stack[include_stack_ptr] = lineno;
 542   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 543   include_stack_ptr++;
 544   lineno = 1;
 545   tmp = yy_create_string_buffer (string, strlen (string));
 546   yy_switch_to_buffer (tmp);
 547 }
 548 \f
 549 /* Functions to switch to a different flex start condition,
 550    saving the current start condition on `state_stack'.  */
 551
 552 static int state_stack[MAX_INCLUDE_DEPTH * 2];
 553 static int *state_stack_p = state_stack;
 554
 555 void
 556 ldlex_script (void)
 557 {
 558   *(state_stack_p)++ = yy_start;
 559   BEGIN (SCRIPT);
 560 }
 561
 562 void
 563 ldlex_mri_script (void)
 564 {
 565   *(state_stack_p)++ = yy_start;
 566   BEGIN (MRI);
 567 }
 568
 569 void
 570 ldlex_version_script (void)
 571 {
 572   *(state_stack_p)++ = yy_start;
 573   BEGIN (VERS_START);
 574 }
 575
 576 void
 577 ldlex_version_file (void)
 578 {
 579   *(state_stack_p)++ = yy_start;
 580   BEGIN (VERS_SCRIPT);
 581 }
 582
 583 void
 584 ldlex_defsym (void)
 585 {
 586   *(state_stack_p)++ = yy_start;
 587   BEGIN (DEFSYMEXP);
 588 }
 589
 590 void
 591 ldlex_expression (void)
 592 {
 593   *(state_stack_p)++ = yy_start;
 594   BEGIN (EXPRESSION);
 595 }
 596
 597 void
 598 ldlex_both (void)
 599 {
 600   *(state_stack_p)++ = yy_start;
 601   BEGIN (BOTH);
 602 }
 603
 604 void
 605 ldlex_popstate (void)
 606 {
 607   yy_start = *(--state_stack_p);
 608 }
 609 \f
 610
 611 /* Place up to MAX_SIZE characters in BUF and return in *RESULT
 612    either the number of characters read, or 0 to indicate EOF.  */
 613
 614 static void
 615 yy_input (char *buf, int *result, int max_size)
 616 {
 617   *result = 0;
 618   if (YY_CURRENT_BUFFER->yy_input_file)
 619     {
 620       if (yyin)
 621         {
 622           *result = fread (buf, 1, max_size, yyin);
 623           if (*result < max_size && ferror (yyin))
 624             einfo ("%F%P: read in flex scanner failed\n");
 625         }
 626     }
 627 }
 628
 629 /* Eat the rest of a C-style comment.  */
 630
 631 static void
 632 comment (void)
 633 {
 634   int c;
 635
 636   while (1)
 637   {
 638     c = input();
 639     while (c != '*' && c != EOF)
 640     {
 641       if (c == '\n')
 642         lineno++;
 643       c = input();
 644     }
 645
 646     if (c == '*')
 647     {
 648       c = input();
 649       while (c == '*')
 650        c = input();
 651       if (c == '/')
 652        break;                   /* found the end */
 653     }
 654
 655     if (c == '\n')
 656       lineno++;
 657
 658     if (c == EOF)
 659     {
 660       einfo( "%F%P: EOF in comment\n");
 661       break;
 662     }
 663   }
 664 }
 665
 666 /* Warn the user about a garbage character WHAT in the input
 667    in context WHERE.  */
 668
 669 static void
 670 lex_warn_invalid (char *where, char *what)
 671 {
 672   char buf[5];
 673
 674   /* If we have found an input file whose format we do not recognize,
 675      and we are therefore treating it as a linker script, and we find
 676      an invalid character, then most likely this is a real object file
 677      of some different format.  Treat it as such.  */
 678   if (ldfile_assumed_script)
 679     {
 680       bfd_set_error (bfd_error_file_not_recognized);
 681       einfo ("%F%s: file not recognized: %E\n", ldfile_input_filename);
 682     }
 683
 684   if (! ISPRINT (*what))
 685     {
 686       sprintf (buf, "\\%03o", (unsigned int) *what);
 687       what = buf;
 688     }
 689
 690   einfo ("%P:%S: ignoring invalid character `%s'%s\n", what, where);
 691 }